Есть рабочий отчет. Отчет сильно "навороченый". В запросе связываются множество таблиц, объектов. В отчете множество колонок, расчет значений которых настраивется при помощи элементов управления на форме.
Отчет нужный. Позволяет просмотреть ситуацию в различных разрезах.
Но у заказчика появилось желание (дабы убрать лишнюю, незначимую в данный момент информацию) выводить в отчет не все данные, а только выбранные.
Или, например, нужно ограничить вывод в зависимости от роли пользователя.
Да, конечно, при помощи СКД эта задача решается элементарно. На первый взгляд...
Но, с учетом множества настроек, не так просто программно заставить СКД выводить то, что нужно, и туда, куда нужно.
Есть готовый рабочий отчет. Есть готовый запрос. Макет вывода -- нарисован и настроен...
И у меня есть пара простых функций, которые позволяют решить эту задачу за считанные минуты.
Что нужно сделать.
1. На форму добавить либо список, либо таблицу с перечнем выводимых колонок, в которой пользователь может отмечать, что и в какой последовательности ему нужно вывести (или как-то определить список программно);
2. В макете все эти колонки (вертикальные области) назвать соответствующим образом;
3. Добавить в модуль формы 3 процедуры (см. далее);
4. В коде, перед выводом результата, вызовы типа "ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");" заменить на "ОбластьЗаголовок = Макеты.Заголовок".
Вот, собственно, и все.
Для демонстрации вложил совершенно абстрактный отчет с совершенно абстрактными данными.
А вот необходимые процедуры:
Функция ПостроитьМакет()
Макет = ПолучитьМакет("Макет");
// Перечень горизонтальных областей макета, используемых для вывода группировок и данных
Макеты = Новый Структура("Заголовок,ШапкаТаблицы,ОбщиеИтоги,Период,Исполнитель,Детали");
// Вертикальные области, которые выводятся безусловно
ДобавитьКолонкуКШаблону(Макет, Макеты, "Основа");
// Добавляем вертикальные области, которые выводятся опционально
Для каждого Эл Из СписокКолонок Цикл
Если Эл.Пометка Тогда
ДобавитьКолонкуКШаблону(Макет, Макеты, Эл.Значение);
КонецЕсли;
КонецЦикла;
Возврат Макеты;
КонецФункции
Процедура ДобавитьКолонкуКШаблону(Макет, Макеты, ИмяКолонки)
Для каждого Ш Из Макеты Цикл
Если Ш.Значение = Неопределено Тогда
Шаблон = Новый ТабличныйДокумент;
Иначе
Шаблон = Ш.Значение;
КонецЕсли;
Источник = Макет.ПолучитьОбласть(Ш.Ключ + "|" + ИмяКолонки);
ПрисоединитьКМакету(Шаблон, Источник);
Макеты.Вставить(Ш.Ключ, Шаблон);
КонецЦикла;
КонецПроцедуры
Процедура ПрисоединитьКМакету(Получатель, Источник)
кП = Получатель.ШиринаТаблицы;
Получатель.Присоединить(Источник);
Для с=1 По Источник.ВысотаТаблицы Цикл
Для к=1 По Источник.ШиринаТаблицы Цикл
ячИ = Источник.Область (с, к);
ячП = Получатель.Область(с, кП+к);
ячП.Заполнение = ячИ.Заполнение;
ячП.Расшифровка = ячИ.Расшифровка;
ячП.ПараметрРасшифровки = ячИ.ПараметрРасшифровки;
Если ячИ.Заполнение = ТипЗаполненияОбластиТабличногоДокумента.Параметр Тогда
ячП.Параметр = ячИ.Параметр;
ИначеЕсли ячИ.Заполнение = ТипЗаполненияОбластиТабличногоДокумента.Шаблон Тогда
ячП.Текст = ячИ.Текст;
КонецЕсли;
КонецЦикла;
КонецЦикла;
КонецПроцедуры
(Отчет протестирован не версии платформы 1С:Предприятие 8.3 (8.3.6.2530))
Вступайте в нашу телеграмм-группу Инфостарт
