gifts2017

Передача значения "Истина" по COM-соединению из 1С 7.7 в 1С 8.х

Опубликовал Invaa (Invaa) в раздел Обмен - Перенос данных из 1С7.7 в 1C8.X

В данной статье описывается один из способов решения проблемы передачи булевых значений Истина/Ложь по OLE или COM-соединению из 1С 7.7 в 1С 8.х без модификации конфигурации, в которую необходимо передать эти значения. Как известно, 1С 7.7 в режиме OLE или COM-соединения с 1С 8.х умеет получать значение Истина как -1 и Ложь как 0. Обратное преобразование вызывает ошибку несоответствия типов.

Суть проблемы

Существует интересная проблема - соединяясь с платформой 8.х по OLE или COM-соединению из платформы 7.7 мы можем получить значение «Истина» как число «-1» и «Ложь» как число «0», но вернуть в 8.х как булевое обратно не можем. Получаем ошибку несоответствия типов.

Например, присвоение ДокументОбъект.ОбменДанными.Загрузка = 0 работать не будет. Важным моментом является так же то, что во многих случаях может быть нежелательным редактировать конфигурацию 8.х, в которую нужно передать значение "Истина"/"Ложь", назовем ее конфигурацией-приемником.

Детально сабж обсуждался здесь:

http://1cniku.ru/Articles/V8OLE.html#trabl1

http://www.forum.mista.ru/topic.php?id=149298

Решение проблемы

Не найдя решения проблемы без модификации конфигурации-приемника, я решил данную проблему при помощи новой конфигурации 8.х содержащей процедуры, которые заворачивают присваивание булевого значения "Истина"/"Ложь" необходимому реквизиту или свойству.

Для демонстрации данного решения я использовал платформу 8.1 и создал 2 конфигурации:

Demo81 –конфигурация-приемник, которую нельзя изменять, с одним документом «Док».

Wrapper – искусственная конфигурация, которая «умеет» присваивать булевое значение «Истина» нужному свойству или реквизиту

Метод присвоения выглядит следующим образом:

Процедура УстановитьЗначениеИстина(Объект, Флаг) Экспорт
    Если
Флаг = 0 Тогда
      
Объект.ОбменДанными.Загрузка = Ложь;
    Иначе
       
Объект.ОбменДанными.Загрузка = Истина;
    КонецЕсли;
КонецПроцедуры


Для того, чтобы данный метод можно было вызывать по COM-соединению, достаточно сделать его экспортным и поместить в модуль внешнего соединения. Аналогично, для вызова из OLE-соединения достаточно сделать его экспортным и поместить в модуль приложения.

Управляет соединениями с этими конфигурациями обработка для 7.7 Test.ert с модулем следующего содержания:

//*******************************************
Процедура Сформировать()

       
//COM
       
V81 = СоздатьОбъект("V81.COMConnector");
       
СоединениеВрапперCOM = "";
        Попытка
           
СоединениеВрапперCOM = V81.Connect ("File="""+СокрЛП(ПутьКВрапперу)+""";");
        Исключение
           
Сообщить("Ошибка подключения к Врапперу","!!!");
            Возврат;
        КонецПопытки;

       
//OLE
       
СоединениеВрапперOLE =СоздатьОбъект("V81.Application");
       
Результат = СоединениеВрапперOLE.Connect ("File="""+СокрЛП(ПутьКВрапперу)+""";");
        Если
Результат = 0 Тогда
           
Сообщить("Ошибка подключения к Врапперу","!!!");
            Возврат;
        КонецЕсли;

       
//Test
       
СоединениеПриемник = "";
        Попытка
           
СоединениеПриемник = V81.Connect ("File="""+СокрЛП(ПутьКПриемнику)+""";");
        Исключение
           
Сообщить("Ошибка подключения к Примнику","!!!");
            Возврат;
        КонецПопытки;

       
ДокПриемник = СоединениеПриемник.Документы.Док.СоздатьДокумент();
       
Сообщить(ДокПриемник.ОбменДанными.Загрузка); //По-умолчанию значение Ложь, вернется 0

       
СоединениеВрапперCOM.УстановитьЗначениеИстина(ДокПриемник, -1); //Успешно присваиваем значение Истина
       
Сообщить(ДокПриемник.ОбменДанными.Загрузка); //Получим числовое значение Ложь, вернется -1
       
СоединениеВрапперOLE.УстановитьЗначениеИстина(ДокПриемник, 0); //Успешно присваиваем значение Ложь
       
Сообщить(ДокПриемник.ОбменДанными.Загрузка); //Получим числовое значение Ложь, вернется 0

       
ДокПриемник.ОбменДанными.Загрузка = 0; //Здесь получим ошибку несоответствия типов

       
СоединениеПриемник = "";

       
СоединениеВрапперCOM = "";
       
СоединениеВрапперOLE = "";
КонецПроцедуры

ПутьКВрапперу = "D:\1CBASE\Wrapper"; //Путь к конфигурации-заворачивателю
ПутьКПриемнику = "D:\1CBASE\Demo81"; //Путь к конфигурации-приемнику


Таким образом, можно присваивать булевое значение не редактируя конфигурацию-приемник.

Можно реализовать присвоение Истина/Ложь и при помощи внешней компоненты, но у данного подхода есть свои плюсы: 

  1. Не нужно регистрировать внешнюю компоненту т.к. объекты «V81.COMConnector» и «V81.Application» уже зарегистрированы в системе (по условию проблемы).
  2. Очень простая реализация заворачивателя.
  3. Для доработки этого решения не требуются никакие IDE, кроме конфигуратора.

Демонстрационная обработка и конфигурации доступны для скачивания.

Скачать файлы

Наименование Файл Версия Размер Кол. Скачив.
Демонстрация присвоения значения истина/ложь
.zip 25,13Kb
27.12.11
8
.zip 25,13Kb 8 Скачать

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Алексей Бобылкин (alex_bob) 27.12.11 09:38
А вот так не проще:

ДокПриемник.ОбменДанными.Загрузка = СоединениеПриемник.ЗначениеИзСтрокиВнутр("{""B"",1}");  //Истина
ДокПриемник.ОбменДанными.Загрузка = СоединениеПриемник.ЗначениеИзСтрокиВнутр("{""B"",0}");  //Ложь
Froloid; Nicholas; +2 Ответить
2. Invaa (Invaa) 27.12.11 12:11
Было бы проще, если бы работало :)
Правое значение 1С 7.7 преобразует в -1 или 0 и в результате получишь ошибку "Несоответствие типов".

Уже после статьи придумал более изящное решение, правда не универсальное, так не передашь Истину, скажем функции, но зато без доп. конфигураций :

ЗапросОбъект = СоединениеПриемник.NewObject("Запрос"); //СоединениеПриемник - COM-соединение с конфигурацией-приемником
			
Запр = "
|ВЫБРАТЬ
| Истина Как Загрузка"; //Важно чтобы алиас совпадал с именем реквизита, которому присвоим значение 
			    
ЗапросОбъект.Текст = Запр;
Результат = ЗапросОбъект.Выполнить();
			
Выборка = Результат.Выбрать();
Выборка.Следующий();
              
ДокПриемник = СоединениеПриемник.Документы.Док.СоздатьДокумент();
Сообщить(ДокПриемник.ОбменДанными.Загрузка); //По-умолчанию значение Ложь, вернется 0	
СоединениеПриемник.ЗаполнитьЗначенияСвойств(ДокПриемник.ОбменДанными, Выборка);
Сообщить(ДокПриемник.ОбменДанными.Загрузка); //Уже "Истина", вернется -1

...Показать Скрыть
Cyberhawk; nl8; +2 Ответить 1
3. Alxd (salexdv) 27.12.11 12:29
Я вообще не понял, зачем такой велосипед, когда можно написать
Объект.ОбменДанными.Загрузка = 1; //Истина
Объект.ОбменДанными.Загрузка = 0; // Ложь
?
4. Invaa (Invaa) 27.12.11 12:39
Alxd пишет:
...

Собственно, зачем изобретать такой велосипед описано в разделе "Суть проблемы" и во внешних ссылках на данный сабж.
5. Алексей Бобылкин (alex_bob) 27.12.11 12:43
(2)

Было бы проще, если бы работало :)


Я вообще-то код проверял. У меня работает. См. (7)
6. Invaa (Invaa) 27.12.11 12:54
alex_bob пишет:
(5)

Странно. Может в новых релизах 1С что-то улучшили.

У меня не работает в связке 1С 7.70.025 - 1С 8.1.15.14.
7. Алексей Бобылкин (alex_bob) 27.12.11 13:02
Хм.. Беру свои слова назад. Описываемая мной конструкция работает при присвоении значений свойствам объекта типа Булево (как впрочем и то, что описано в (3), но для данного случая действительно не работает - видимо косяк в платформе. Тогда плюс за публикацию.
8. Alxd (salexdv) 27.12.11 13:11
(4)
Собственно, зачем изобретать такой велосипед описано в разделе "Суть проблемы" и во внешних ссылках на данный сабж.


Может для 8.0-8.1 это и проблема, на 8.2 установка 1 или 0 прекрасно работает и не возникает никакого несоответствия типов
9. Invaa (Invaa) 27.12.11 14:59
(8) Alxd,

Конвертнул прикрепленную к публикации конфигурацию-приемник "Demo81" в 8.2. Попробовал на релизе 8.2.13.219 в режиме совместимости с 8.1 и без. Эффект из 7.7 оба раза одинаковый:

10. Alxd (salexdv) 27.12.11 15:35
(9) Ну вообще забавно конечно. Скорее тут частный случай какой-то
ДокПриемник.Отменен = 1; // Все хорошо (Отменен - Тип: Булево)
ДокПриемник.ОбменДанными.Загрузка = 1; // Несоответствие типов
11. Алексей Бобылкин (alex_bob) 27.12.11 16:04
Кстати, как альтернативный вариант - засунуть процедуру УстановитьЗначениеИстина(Объект, Флаг) в модуль объекта внешней обработки с ключевым словом Экспорт. Тогда вызов будет:

Обработка = СоединениеПриемник.ВнешниеОбработки.Создать(ПолноеИмяФайла);
Обработка.УстановитьЗначениеИстина(ДокПриемник, 1);
Anything; +1 Ответить
12. Invaa (Invaa) 27.12.11 16:16
alex_bob пишет:
Кстати, как альтернативный вариант - засунуть процедуру УстановитьЗначениеИстина(Объект, Флаг) в модуль объекта внешней обработки с ключевым словом Экспорт. Тогда вызов будет...

Да, тоже можно взять на заметку :)
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа