Три урока 1С81 для переходящих с 1с77

09.02.12

Разработка - Механизмы платформы 1С

Три урока, которые я решил сам при изучении восьмерки, когда переходил с семерки. Уроки касаются работы с коллекциями, регистрами и формами восьмерки.

Скачать файлы

Наименование Файл Версия Размер
1s8zoo.zip
.zip 5,44Kb
44
.zip 5,44Kb 44 Скачать

// //

Учебные планы.

Я программист, три года с ноября 1999 года программировавший на 1С:Предприятие 7.7. На дворе зима 2003 года, 1С выпускает новую платформу, очень хочется ее изучить.

Договариваюсь со знакомыми и вот в моем распоряжении 1С:Предприятие 8.0 и около трех дней рабочего времени, чтобы ее изучить, пока ключ не отдали другому программисту. Кряк периодически выбивает систему, работать с ним неудобно. Буду изучать на нормальном "переходящем" ключе.

Итак, ставлю себе задачу: написать почти простейшую конфигурацию складского учета для ячеистого склада:

  1. Имееются склады, номенклатура
  2. Учет ведется только по количеству, без единиц измерения
  3. Документы Приход, Расход, Перемещение
  4. При проведении должен быть контроль: нельзя превышать остаток при расходе и нельзя ставить в занятую ячейку.
  5. Должен быть отчет по движению товаров по складам и ячейкам.
  6. Настроить удобный интерфейс пользователя.

Склад может состоять из ячеек, товар может быть размещен на паллетах. У склада есть параметры флИспользоватьЯчейки и флИспользоватьПаллеты, которые определяют, используются ли на складе ячейки и паллеты.

Если на складе не используются ни ячейки, ни паллеты, то это самый обычный склад.

Наспех прочитан С.А.Митичкин "Разработка в системе 1С:Предприятие 8.0". Освоена буквально за половину рабочего дня и его остаток в двухчасовой электричке. Читается запоем. Наступает время попробовать теорию на практике.

Вот, как я учился 1с 8-ке. Получилась некоторая последовательность шагов. Шаги были не только прямо к конфигурации, но и влево-вправо.

 

Урок 1. Проведение документов в 1С:8.0

// //

Создаю из шаблона демо-конфигурацию "Управление торговлей" и пустую базу. В демо-конфигурации уже имеются данные, пустая база девственно чиста.

Создаю справочник Номенклатура, Ячейки и подчиненный номенклатуре справочник ЕдиницыИзмерения.

Создаю документ WHSПриход.
Оказывается у документа есть параметр Движения, который предоставляет доступ к фиксированному набору записей по каждому регистру.

Оперативное проведение

Для удобства пользователей проведение бывает двух видов - оперативное и неоперативное.
При оперативном проведении принимается решение - дать совершить операцию или нет, т.е. нужно проверить имеется остаток или нет. При неоперативном проведении факт операции уже зафиксирован и нужно только повторить движения.

При перепроведении документов используется неоперативное проведение - экономится время на контроль остатков, к тому же перепроведение не останавливается, если остатков не хватает.

В принципе, можно игнорировать эти два способа и проводить однообразно, но это действительно грамотный ход. К тому же, на эти два способа можно разграничить доступ.

При проведении документа до точки актуальности итогов (ТА) спрашивается как его проводить - оперативно или нет? Если оперативно по умолчанию время ставится после точки актуальности.

Проведение документов

Простой пример проведения (записывается в модуле документа):

Процедура ОбработкаПроведения(Отказ, Режим)
    Набор = Движения["WHSОстатки"];
    Для каждого СтрокаТЧ из Товары Цикл
        Движ = Набор.ДобавитьРасход();
        Движ.Период = Дата;
        Движ.Склад = Склад;
        Движ.Ячейка = СтрокаТЧ.Ячейка;
        Движ.Паллет = СтрокаТЧ.Паллет;
        Движ.Номенклатура = СтрокаТЧ.Номенклатура;
        Движ.Количество = СтрокаТЧ.Количество * СтрокаТЧ.ЕдиницаИзмерения.Коэффициент;
    КонецЦикла
КонецПроцедуры // ОбработкаПроведения

Сначала через обращение к доступной в модуле документа переменной Движения определяется набор движений по регистру WHSОстатки.
Затем в переменной СтрокаТЧ перебираются все строки табличной части Товары.
Затем в набор добавляется очередное движение прихода Движ.
Устанавливаются реквизиты движения.
Набор в конце не записывается, 1С запишет его сама.
Для каждого движения нужно указать период движения (можно указывать разные даты).
По умолчанию регистратором движения указывается текущий документ.

Как видно, все реквизиты документа доступны по именам, но можно обращаться к ним и так, например: ЭтотОбъект.Дата.

Проверка наличия остатков

Сразу решил отказаться от использование функции Остатки, т.к. при изменении измерений регистров придется переписывать вызов этой функции, т.к. в ней количество и порядок параметров определяется количеством и порядком измерений регистра.

Итак, будем использовать запрос.

Если Режим = РежимПроведенияДокумента.Оперативный Тогда
    Для каждого СтрокаТЧ из Товары Цикл
        ТекКоличество = СтрокаТЧ.Количество * СтрокаТЧ.ЕдиницаИзмерения.Коэффициент;
        ТекТовар = СтрокаТЧ.Номенклатура;
        ТекДата = Дата;
        ТекстЗапроса = "
            |ВЫБРАТЬ
            |	WHSОстатки.Номенклатура КАК Номенклатура,
            |	WHSОстатки.КоличествоОстаток КАК Остаток
            |ИЗ
            |  	РегистрНакопления.WHSОстатки.Остатки(&Дата) КАК WHSОстатки 
            |ГДЕ
            |  	(Номенклатура=&Товар)
            |";
        
    КонецЦикла;
    флДостаточноОстатка = Истина;
    
    Запрос = Новый Запрос(ТекстЗапроса);
    Запрос.УстановитьПараметр("Дата", Дата);
    Запрос.УстановитьПараметр("Товар", ТекТовар);
    РезультатЗапроса = Запрос.Выполнить();
    Выборка = РезультатЗапроса.Выбрать();
    Пока Выборка.Следующий() Цикл
        Если Выборка.Остаток < ТекКоличество Тогда
            Сообщить("Недостаточно остатка товара " + Выборка.Номенклатура + " нужно " + ТекКоличество + ", а имется только " + Выборка.Остаток);
            флДостаточноОстатка = Ложь;
        КонецЕсли;
    КонецЦикла;
    Если Не флДостаточноОстатка Тогда
        Отказ = Истина;
        Возврат;
    КонецЕсли;
КонецЕсли;

Запрос написан на SQL-подобном языке запросов 1С, SQL - это приятно.

Итак, мы строим запрос к таблице остатков регистров накопления WHSОстатки на дату (позицию) документа.
Остатки получаем только в разрезе номенклатуры. Строим запрос для каждой номенклатуры в документе и сравниваем количества.

Отказ в проведении осуществляется через выставление параметра Отказ, переданного в Обработку проведения в Истину.

Контроль остатков осуществляется только при оперативном проведении.

Конечно, это не самый производительный код, было бы удобнее прямо в запросе сравнить количество товара из табличной части и остаток товара из регистра.

Ковыряния в интерфейсе

Мне нужно было, чтобы ячейка в табличной части выбиралась только из списка ячеек, подчиненных данному складу (реквизиту документа). Оказывается, у реквизитов формы есть параметр "Использовать владельца"

 

Урок 2. Игра "Угадай животное" для 1С:8.0

Компьютер пробует угадать животное, загаданное человеком, задавая вопросы. Если компьютер не угадал, он спрашивает человека, кого он загадал и чем загаданное отличается от того животного, что назвал компьютер.

Можно обойтись практически без элементов интерфейса, используя только диалоговые окна.

Результаты игры сохраняются в файл "C:\zoo.txt"

В обработке мы можем поучиться работать с объектом "Структура", как создавать такие объекты, как оперировать с значениями структуры.

Также попутно я выяснил, что обработчики событий формы определяются не по имени процедуры, а назначаются в форме.

В игре используются два вида структур: одна (Да, Нет, Содержание) а другая (Животное). Значением ключа может быть опять же структура. Я например, обнаружил, что если вызываешь Структура.Животное, выдается ошибка, если такого ключа нет. Поэтому для проверки нужно использовать Если Структура.Свойство("Животное") Тогда.

Обработку 1s8zoo.zip прилагаю к статье.

Вот текст обработки:

Перем Дерево;

Процедура Сдаться(Узел)
    Животное = "";
    Отличие = "";
    //Определяем у пользователя название нового животного
    Если ВвестиЗначение(Животное, "Сдаюсь, что за животное вы задумали?", "Строка") Тогда
        //Определяем у пользователя отличие нового животного
        Если Узел <> Неопределено Тогда
            Если НЕ ВвестиЗначение(Отличие, "Отличается от " + Узел.Животное + ",  оно (какое?):", "Строка") Тогда
                Возврат;
            КонецЕсли;
        КонецЕсли;
        
        УзелЖивотное = Новый Структура("Животное", Животное);
        
        Если Узел <> Неопределено Тогда
            УзелСтароеЖивотное = Новый Структура("Животное", Узел.Животное);
            Узел.Вставить("Отличие", Отличие);
            Узел.Вставить("Да", УзелЖивотное);
            Узел.Вставить("Нет", УзелСтароеЖивотное);
            Узел.Удалить("Животное");
            Предупреждение("Заведено новое животное " + Животное + ". Оно " + Отличие);
        Иначе
            Предупреждение("Заведено новое животное " + Животное + ".");
            Дерево = УзелЖивотное;
        КонецЕсли;
        
    КонецЕсли;
КонецПроцедуры

Процедура Выигрыш()
    Предупреждение("То-то же, вам не стоит тягаться с искусственным интеллектом");
КонецПроцедуры


Процедура Угадай(Узел)
    Если Узел = Неопределено Тогда
        Сдаться(Узел);
        Возврат;
    КонецЕсли;
    
    Если Узел.Свойство("Животное") Тогда
        //Если подошли к животному
        Если
            Вопрос("Попробую угадать. Гм... Это " + Узел.Животное + "?", РежимДиалогаВопрос.ДаНет) = КодВозвратаДиалога.Да
            Тогда
            Выигрыш();
        Иначе
            Сдаться(Узел);
        КонецЕсли;
    Иначе
        //Если находимся в вопросе
        Если
            Вопрос("Оно " + Узел.Отличие + "?", РежимДиалогаВопрос.ДаНет) = КодВозвратаДиалога.Да
            Тогда
            Угадай(Узел.Да);
        Иначе
            Угадай(Узел.Нет);
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры



// ОБРАБОТЧИКИ СОБЫТИЙ ФОРМЫ

Процедура ПриОткрытии()
    Сообщить("Открылись");
    Попытка
        Дерево = ЗначениеИзФайла("C:\zoo.txt");
    Исключение
    КонецПопытки;
КонецПроцедуры // ПриОткрытии()

Процедура ПриЗакрытии()
    Сообщить("Закрылись");
    Если Вопрос("Сохранить игу в файл C:\zoo.txt?", РежимДиалогаВопрос.ДаНет) = КодВозвратаДиалога.Да Тогда
        Попытка
            Дерево = ЗначениеВФайл("C:\zoo.txt", Дерево);
        Исключение
            Предупреждение("Сохранить не удалось");
        КонецПопытки;
    КонецЕсли;
КонецПроцедуры // ПриОткрытии()


//

Процедура Игра()
    Предупреждение("Загадайте животное и нажмите < ОК >");
    Угадай(Дерево);
КонецПроцедуры

Процедура КнопкаВыполнитьНажатие(Элемент)
    // Вставить содержимое обработчика.
    Игра();
КонецПроцедуры


//Для восстановления обработки из ее текста создайте обработку, назовите ее "животные"
//Создайте форму обработки
//На закладке "Диалог" на пустом месте щелкните "Свойства"
//В событиях ПриОткрытии и ПриЗакрытии пропишите вызов процедур ПриОткрытии и ПриЗакрытии
//В корень диска C: поместите файл zoo.txt
//В обработчике главной кнопки КнопкаВыполнитьНажатие пропишите вызов Игра()
//Запустите обработку.
//Все, можно играть!

 Урок 3. Несколько иерархий справочника

//

Когда восьмерка еще только готовилась к выходу, один мудрый человек (не я) мечтал о том, что можно будет заводить несколько иерархий для справочников и система будет разрешать пользователю выбирать, какой иерархией пользоваться при навигации по списку.

Например, справочник товаров может быть сгруппирован по виду товаров (как это обычно и делается) - Промтовары, Бакалея, Алкоголь и т.п., но может быть сгруппирован и по производителям товаров, т.е. Наши товары, Импортные товары, Российские, Китайские и т.п.

Ожидания не оправдались, однако восьмерка легко позволяет сделать такую иерархию самостоятельно. Единственное неудобство - это не делается автоматически, системой.

Моделирование нескольких иерархий

Имеются иерархические (с группами) справочники товаров Номенклатура и производителей Производители.

Для иерархии по производителям в справочнике Номенклатура заведем реквизит Производитель типа СправочникСсылка.Производители.

Заведем новую форму списка для Номенклатуры. На ней разместим поле ДереваЗначений "МастерДерево" и поле ТаблицыЗначений "ПодчТаблица":

В МастерДерево будет отображаться группы текущей иерархии. А в ПодчТаблица будут выводиться только те товары, которые попадают в группу иерархии. В надписи НадпГруппа будет отображаться текущая выбранная группа МастерДерево, а в надписи НадписьОтбор - список элементов текущей иерархии, входящих в эту группу.

Для учебных целей мы рассмотрим только отбор по иерархии Производители. Можно конечно в дереве делать иерархию на выбор - по Производителю, по группам номенклатуры, по поставщику и т.п. Было бы желание.

Вот как выглядит форма, когда мы просматриваем товары отечественных производителей:

А вот так, когда просматриваем импортных производителей:

А вот просмотр только по одному производителю:

Когда пользователь выбирает группу из дерева (щелкает дважды мышью или нажимает Enter, происходит событие Выбор объекта формы МастерДерево). В обработчике этого события содержится код, который отображает ПодчТаблица согласно выбранной группе:

Процедура СправочникДеревоВыбор(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)
    
    //Находим отбор по производителю
    //Внимание! Его может и не быть...
    ТекОтбор = ЭлементыФормы.ПодчТаблица.Значение.Отбор["Производитель"];
    
    //Если группа в дереве не выбрана (в начале)
    Если ЭлементыФормы.МастерДерево.ТекущиеДанные = Неопределено Тогда
        МастерГруппа = Неопределено;
        ТекОтбор.Использование = Ложь;
    Иначе
        
        МастерГруппа = ЭлементыФормы.МастерДерево.ТекущиеДанные.Ссылка;
        
        //Формируем список производителей, которые входят
        //в группу МастерГруппа
        
        Список = Новый СписокЗначений; //Создаем список значений
        
        ТекстЗапроса = " //Условие запроса - элемент входит в группу
            |ВЫБРАТЬ
            |	МастерСправочник.Ссылка КАК Элемент
            |ИЗ
            |  	Справочник.Производители КАК МастерСправочник
            |ГДЕ
            |  	МастерСправочник.Ссылка В ИЕРАРХИИ (&ГруппаИерархии)
            |";
        
        
        Запрос = Новый Запрос(ТекстЗапроса); //Создаем запрос
        
        Запрос.УстановитьПараметр("ГруппаИерархии", МастерГруппа); //Устанавливаем параметр запроса
        РезультатЗапроса = Запрос.Выполнить(); //Выполняем запрос
        Таб = РезультатЗапроса.Выгрузить(ОбходРезультатаЗапроса.Прямой);
        
        //Выгружаем производителей из таблицы в массив, из массива в список
        Список.ЗагрузитьЗначения(Таб.ВыгрузитьКолонку("Элемент"));
        
        //Устанавливаем отбор
        //Вид - в списке, значение - наш список
        ТекОтбор.ВидСравнения = ВидСравнения.ВСписке;
        ТекОтбор.Значение = Список;
        
        
        //Включаем отбор
        ТекОтбор.Использование = Истина;
    КонецЕсли;
    
    
КонецПроцедуры

Дополнительно нужно завести реквизиты формы:

МастерСправочник - служит источником записей для МастерДерево, а ПодчСправочник - источником записей для ПодчТаблица.

При выборе производителя в МастерДерево в ПодчТаблица устанавливается отбор по производителям, входящим в выбранную группу производителя, или (если выбран элемент) с выбранным производителем.

Объект, к которому привязано табличное поле в 1С8 имеет возможность использовать отбор. Отборов может быть несколько, причем различных (по коду, наименованию, диапазону значений, подчинению группе, вхождению в список). Получить привязанный объект можно через ЭлементыФормы.ПодчТаблица.Значение, а элемент отбора по производителю через ЭлементыФормы.ПодчТаблица.Значение.Отбор["Производитель"]. Отбор и элемент отбора - это тоже объекты и описания их можно прочитать в RTFM.

Так как фильтра вхождения реквизита в группу не существует, формируем простой запрос, который выдает нам список элементов, соответствующих выбранному производителю (иерархически входящих в выбранную группу). И по данному списку устанавливаем отбор, затем его включаем.

Если производитель не выбран, отбор отключается.

Код простой и сердитый. Можете брать за основу.

Вывод в форму произвольной таблицы значений

Я захотел вывести в форму таблицу значений и знаете, пришлось возиться полчаса, прежде чем понял, как это сделать. Дело в том, что источником данных для табличного поля в форме может выступать только реквизит формы, саму таблицу нельзя передать в качестве источника данных.

Поэтому я завел табличное поле, завел реквизит формы, указал в поле "Данные" табличного поля реквизит формы, затем сформировал нужную мне таблицу значений и присвоил ее реквизиту формы. Тип значения реквизита формы был "ТаблицаЗначений", поэтому при присваивании таблица скопировалась. Если бы тип был "ТаблицаЗначений.Ссылка", то была бы только ссылка.

После этого еще нужно вызвать для табличного поля процедуру СформироватьКолонки(), чтобы сформировать набор колонок, исходя из переданной таблицы значений.

Приведенный ниже код формирует список элементов справочника Номенклатура и выводит его в таблицу значений Таб а затем в табличное поле ТабПоле на форме, используя реквизит формы ТабПолеДанные:

ТекстЗапроса = "
    |ВЫБРАТЬ
    |	Номенклатура.Ссылка КАК Элемент
    |ИЗ
    |  	Справочник.Номенклатура КАК Номенклатура
    |";
Запрос = Новый Запрос(ТекстЗапроса);
РезультатЗапроса = Запрос.Выполнить(); //Выполняем запрос
Таб = РезультатЗапроса.Выгрузить(ОбходРезультатаЗапроса.Прямой); //Выгружаем запрос в таблицу
ТабПолеДанные = Таб; //Перекачиваем данные из таблицы в реквизит формы
ЭлементыФормы.ТабПоле.СоздатьКолонки(); //Создаем выводимые колонки

Точно так же можно выгружать данные и в дерево, только используя не прямой способ выгрузки, а иерархический.

См. также

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор?

Обмен между базами 1C Администрирование СУБД Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В платформе 8.3.17 появился замечательный механизм «Сервисы интеграции». Многие считают, что это просто коннектор 1С:Шины. Так ли это?

11.03.2024    3652    dsdred    48    

66

Как готовить и есть массивы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024    5047    YA_418728146    25    

62

Планы обмена VS История данных

Обмен между базами 1C Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023    6176    dsdred    36    

110

1С-ная магия

Механизмы платформы 1С Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?». 

06.10.2023    18207    SeiOkami    46    

116

Дефрагментация и реиндексация после перехода на платформу 8.3.22

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Начиная с версии платформы 8.3.22 1С снимает стандартные блокировки БД на уровне страниц. Делаем рабочий скрипт, как раньше.

14.09.2023    11787    human_new    27    

72

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8570    YA_418728146    6    

139

Внешние компоненты Native API на языке Rust - Просто!

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Внешние компоненты для 1С можно разработывать очень просто, пользуясь всеми преимуществами языка Rust - от безопасности и кроссплатформенности до удобного менеджера библиотек.

20.08.2023    6207    sebekerga    54    

93

Все скопируем и вставим! (Буфер обмена в 1С 8.3.24)

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим новую возможность 8.3.24 и как её можно эффективно использовать

27.06.2023    15558    SeiOkami    31    

103
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. AnryMc 849 09.02.12 21:09 Сейчас в теме
Надо переходить на 8.2.
2. stormtg 13.02.12 14:40 Сейчас в теме
А мне интересно было прочитать, спасибо!
3. fixin 4252 13.02.12 15:34 Сейчас в теме
(2) из личной практики...
4. Veduin 15.02.12 10:32 Сейчас в теме
Я программист, три года с ноября 1999 года, а на дворе 2012год.
Серьезная шутка!!!!
6. fixin 4252 15.02.12 10:47 Сейчас в теме
(4) вы никогда не читали рассказы, написанные в сложной форме времени? Т.е. когда действие происходит в прошлом, но герой говорит в настоящем времени? Не буквоедствуйте, хотя реально забавно. Статья старая, но не утратившая актуальности. Это мой опыт.

(5) запрос в цикле не всегда зло. Помнится когда то все пытались запихнуть в один запрос, а счас в моде пакетные запросы. ;-0
5. StAsya_1C 105 15.02.12 10:42 Сейчас в теме
Наверное, много лет прошло с написания статьи... сейчас за запрос в цикле убивают, а не пишут "не самый оптимальный код" )))
А вообще спасибо, интересная статья!
7. Nata 8 26.02.12 02:57 Сейчас в теме
Спасибо! Очень не плохой пример как начинать. Обычно начало намного хуже, методом "тыка" и без литературы, пытаясь сделать какую-нибудь реальную задачу.
8. ГСГ 24.09.12 08:53 Сейчас в теме
Чет слишком сложно написано.
9. fixin 4252 24.09.12 11:00 Сейчас в теме
(8) Эх, если бы 1с мне заплатило, я бы написал степ-бай-степ, а так нету времени.
11. AlexO 135 04.12.12 11:31 Сейчас в теме
(9)
Сергей, я постоЯнно на 7.7 перехожу - мне бы уроки в обратку, а? А то забываю через месяц, каждый раз заново надо привыкать к простоте 7.7... :)
10. a1ex4ndr 5 04.12.12 11:28 Сейчас в теме
животного кто нибудь угадал? :)
12. AlexO 135 04.12.12 11:35 Сейчас в теме
По этим урокам - Сергей в кои-то веки! написал уроки! с картинками и разжеванные! :)
Однозначно плюс и - Серега, давай исчо! по любым темам :)
Оставьте свое сообщение