Функция создания вложенных каталогов + ф-ции извлечения имен файлов для 1с 7.7

12.11.07

Разработка - Универсальные функции

Расширим возможности ФС.
Вы когда-нибудь пытались создать вложенные папки из 1с?
Как ни странно, стандартной функции для этой операции нет.

ФС.СоздатьКаталог() позволяет создать папку лишь на один уровень вглубь, а порой хочется глубже,
и чтобы функция нормально относилась к уже существующим папкам, не пыталась создавать их повторно.

Так появилась функция глСоздатьКаталог().

А вот пример использования - создание файла приказа на основании шаблона.
На форме расположен объект "СписокЗначений" с именем "спШаблоны".

1. Заполним список шаблонов
// ...
спШаблоны.УдалитьВсе();
ПутьКПапкеШаблонов = КаталогИБ()+"Приказы\\Шаблоны";
Если глСоздатьКаталог(ПутьКПапкеШаблонов) = 1 Тогда
	ФС.УстТекКаталог(ПутьКПапкеШаблонов);
	ИмяШаблона = ФС.НайтиПервыйФайл("*.doc");
	Пока ИмяШаблона <> "" Цикл
		Если Лев(ИмяШаблона, 1) <> "~" Тогда
			спШаблоны.ДобавитьЗначение(ИмяШаблона);
		КонецЕсли;	
		ИмяШаблона = ФС.НайтиСледующийФайл();
	КонецЦикла;	
КонецЕсли;	
// ...

2. Создаем подпапку по имени файла шаблона, и копируем туда файл на основании шаблона.
 //..
ИмяШаблонаКратко = спШаблоны.ПолучитьЗначение(спШаблоны.ТекущаяСтрока());
ИмяШаблонаКраткоБезРасширения = глИзвлечьИмяФайлаБезРасширения(ИмяШаблонаКратко);
ПутьКПапкеГотовых = КаталогИБ() + "Приказы\" + ИмяШаблонаКраткоБезРасширения + "\";
Если глСоздатьКаталог(ПутьКПапкеГотовых) = 0 Тогда
	Возврат;
КонецЕсли;	
		
ИмяШаблона = КаталогИБ()+"Приказы\\Шаблоны\"+ИмяШаблонаКратко;
ИмяФайла = ПутьКПапкеГотовых + ИмяШаблонаКраткоБезРасширения + " "
	+Формат(ТекущаяДата(), "ДГГГГММДД")+" "+СтрЗаменить(ТекущееВремя(), ":", "")+".doc";

Если ФС.СуществуетФайл(ИмяШаблона) = 0 Тогда
	Предупреждение("Шаблон "+ИмяШаблона+" не найден!");
	Возврат;
КонецЕсли;	

ФС.КопироватьФайл(ИмяШаблона, ИмяФайла, 1);
//..

Текст функций:
//-----------------------------------------------------
Функция глСоздатьКаталог(Знач Путь) Экспорт
	
	Пока Прав(Путь, 1) = "\" Цикл
		Путь = Сред(Путь, 1, СтрДлина(Путь) - 1);
	КонецЦикла;	
	
	// Проверим, возможно каталог существует
	Атрибуты = "";
	ФС.АтрибутыФайла(Путь, , Атрибуты);
	Если Сред(Атрибуты, 4, 1) = "1" Тогда
		Возврат 1;
	КонецЕсли;	
	
	спКСозданию = СоздатьОбъект("СписокЗначений");
	
	текПуть = Путь;
	врДлина = СтрДлина(Путь);
	Для к = -врДлина по -1 Цикл
		Если Сред(Путь, -к, 1) = "\" Тогда
			спКСозданию.ДобавитьЗначение(текПуть);
			текПуть = Лев(Путь, -к-1);
			
			// Проверяем наличие текущего уровня
			Атрибуты = "";
			ФС.АтрибутыФайла(текПуть, , Атрибуты);
			фЕстьТекПуть = ?(Сред(Атрибуты, 4, 1) = "1", 1, 0);
			
			Если фЕстьТекПуть = 0 Тогда
				Продолжить;
			КонецЕсли;	
			
			// Пытаемся создать с текущего уровня
			Для н = -спКСозданию.РазмерСписка() по -1 Цикл
				врПутьХ = спКСозданию.ПолучитьЗначение(-н);
				ФС.СоздатьКаталог(врПутьХ);
				Если н = - 1 Тогда
					Атрибуты = "";
					ФС.АтрибутыФайла(врПутьХ, , Атрибуты);
					Если Сред(Атрибуты, 4, 1) = "1" Тогда
						// Удачное создание с текущего уровня
						Возврат 1;
					КонецЕсли;	
				КонецЕсли;	
			КонецЦикла;	
		КонецЕсли;	
	КонецЦикла;	
	
	Предупреждение("Невозможно создать путь: "+РазделительСтрок+Путь, 4);
	Возврат 0;
	
КонецФункции

//-----------------------------------------------------
Функция глИзвлечьИмяФайла(ПолноеИмяФайла) Экспорт

	Файл = "";
	врДлина = СтрДлина(ПолноеИмяФайла);
	Для к = -врДлина по -1 Цикл
		Если Сред(ПолноеИмяФайла, -к, 1) = "\" Тогда
			Файл = Прав(ПолноеИмяФайла, врДлина+к);
			Прервать;
		КонецЕсли;	
	КонецЦикла;	
	
	Возврат(Файл);
КонецФункции

//-----------------------------------------------------
Функция глИзвлечьИмяФайлаБезРасширения(КраткоеИмяФайла) Экспорт

	Файл = "";
	врДлина = СтрДлина(КраткоеИмяФайла);
	Для к = -врДлина по -1 Цикл
		Если Сред(КраткоеИмяФайла, -к, 1) = "." Тогда
			Файл = Лев(КраткоеИмяФайла, -к-1);
			Прервать;
		КонецЕсли;	
	КонецЦикла;	
	
	Возврат(Файл);
КонецФункции


Все таки 1с это сила, даже если чего-то не хватает, всегда можно дописать.

Исправление.
Добавлена проверка на запрещенные символы и наличие в указанном пути файлов.
//-----------------------------------------------------
Функция глСоздатьКаталог(Знач Путь) Экспорт
	
	Пока Прав(Путь, 1) = "\" Цикл
		Путь = Сред(Путь, 1, СтрДлина(Путь) - 1);
	КонецЦикла;	
	
	Если СокрЛП(Путь) = "" Тогда
		Предупреждение("Невозможно создать пустой путь", 4);
		Возврат 0;
	КонецЕсли;	
	
	// Проверим, возможно каталог существует
	Если ФС.СуществуетФайл(Путь) = 1 Тогда
		Атрибуты = "";
		ФС.АтрибутыФайла(Путь, , Атрибуты);
		Если Сред(Атрибуты, 4, 1) = "1" Тогда
			Возврат 1;
		Иначе
			Предупреждение("Невозможно создать путь: "+РазделительСтрок+Путь
			+РазделительСтрок+"Так как существует одноименный файл.", 4);
			Возврат 0;
		КонецЕсли;
	КонецЕсли;	

	спКСозданию = СоздатьОбъект("СписокЗначений");
	
	врДлина = СтрДлина(Путь);
	// Проверка на запрещенные символы
	ЕстьБукваДиска = ?(Найти("abcdefghijklmnopqrstuvwxyz", Нрег(Лев(Путь, 1))) > 0, 1, 0);
	ЗапрещенныеСимволы = "/?|*<>:"""+РазделительСтрок+СимволТабуляции;
	Для к = 1 по врДлина Цикл
		Символ = Сред(Путь, к, 1);
		Если (Найти(ЗапрещенныеСимволы, Символ) > 0) или (КодСимв(Символ) < 32) Тогда
			Если не ((к = 2) и (Символ = ":") и (ЕстьБукваДиска = 1)) Тогда
				Предупреждение("Невозможно создать путь: "+РазделительСтрок+Путь
				+РазделительСтрок+"Так как использованы запрещенные символы.", 4);
				Возврат 0;
			КонецЕсли;
		КонецЕсли;	
	КонецЦикла;	
	// Основной цикл
	текПуть = Путь;
	Для к = -врДлина по -1 Цикл
		Если Сред(Путь, -к, 1) = "\" Тогда
			спКСозданию.ДобавитьЗначение(текПуть);
			текПуть = Лев(Путь, -к-1);
			
			// Проверяем наличие текущего уровня
			Если ФС.СуществуетФайл(текПуть) = 1 Тогда
				Атрибуты = "";
				ФС.АтрибутыФайла(текПуть, , Атрибуты);
				Если Сред(Атрибуты, 4, 1) = "0" Тогда
					Предупреждение("Невозможно создать путь: "+РазделительСтрок+Путь
					+РазделительСтрок+"Так как существует файл:"+РазделительСтрок+текПуть, 4);
					Возврат 0;
				КонецЕсли;
			Иначе
				Продолжить;
			КонецЕсли;	
			
			// Пытаемся создать с текущего уровня
			Для н = -спКСозданию.РазмерСписка() по -1 Цикл
				врПутьХ = спКСозданию.ПолучитьЗначение(-н);
				ФС.СоздатьКаталог(врПутьХ);
				Если н = - 1 Тогда
					Атрибуты = "";
					ФС.АтрибутыФайла(врПутьХ, , Атрибуты);
					Если Сред(Атрибуты, 4, 1) = "1" Тогда
						// Удачное создание с текущего уровня
						Возврат 1;
					Иначе
						Предупреждение("Невозможно создать путь: "+РазделительСтрок+Путь, 4);
						Возврат 0;
					КонецЕсли;	
				КонецЕсли;	
			КонецЦикла;	
		КонецЕсли;	
	КонецЦикла;	

	Предупреждение("Невозможно создать путь: "+РазделительСтрок+Путь, 4);
	Возврат 0;
	
КонецФункции
Функция очистки каталога от файлов. (Не подходит для вложенных каталогов.)
//-----------------------------------------------------
Процедура глОчиститьКаталог(Путь) Экспорт
	Попытка
		ФС.УстТекКаталог(Путь);
		ИмяФайла = ФС.НайтиПервыйФайл("*.*");
		Пока (ИмяФайла <> "") Цикл
			Если (ИмяФайла <> ".")
			и (ИмяФайла <> "..") Тогда
				ФС.УдалитьФайл(ИмяФайла);
			КонецЕсли;	
			ИмяФайла = ФС.НайтиСледующийФайл();
		КонецЦикла;	
	Исключение
	КонецПопытки;	
КонецПроцедуры

См. также

Библиотека процедур и функций для технологической платформы "1С: Предприятие 7.7"

Универсальные функции Платформа 1С v7.7 Россия Абонемент ($m)

В библиотеку собраны различные функции по работе с документами, журналами, типами данных, строками, датой и временем, таблицами значений, Excel, файлами, XML, JSON, Http-сервисами, SMTP серверами и т.п.

1 стартмани

22.12.2023    631    8    user706545_kseg1971    0    

4

1С 7.7 и новый 1С:Контрагент

Универсальные функции Платформа 1С v7.7 Конфигурации 1cv7 Россия Бесплатно (free)

Получение реквизитов контрагентов из 1С:Контрагент для старых конфигураций под 1с 7.7.

25.04.2022    1802    zhenyat    7    

6

Печать таблицы значений в 1С 7.7 при отладке

Универсальные функции Платформа 1С v7.7 Россия Бесплатно (free)

Функция выводит таблицу значений в табличный документ. (v7.7) Особенно полезно при отладке. Не нужно вносить изменения в код, вызываем функцию как вычисляемое выражение при останове. Если таблица обрабатывается в несколько этапов, можно вывести её после каждого и визуально проследить эволюцию.

30.06.2021    4371    Zoltan_Black    11    

2

Установка принтера по умолчанию для 1С 7.7

Универсальные функции Платформа 1С v7.7 Конфигурации 1cv7 Абонемент ($m)

Установка принтера по умолчанию в 1С 7.7. Обработка может быть полезна в том случае, когда нужно установить принтер по умолчанию, а доступа к рабочему столу нет (например, терминальный режим без рабочего стола или remoteApp)

1 стартмани

13.02.2019    13259    4    alsen    3    

3

Формирование строки json в 1С: 7.7

Универсальные функции Платформа 1С v7.7 Конфигурации 1cv7 1С:Комплексная 7.7 Абонемент ($m)

Предлагается набор функций 1с 7.7 для формирования строки json стандартными средствами.

1 стартмани

10.12.2018    10045    malovandrey    1    

17

Как создать индикатор в 1С:Предприятии 7.7

Универсальные функции Работа с интерфейсом Платформа 1С v7.7 Конфигурации 1cv7 Россия Абонемент ($m)

В статье дано описание создания индикатора на форме в среде разработки 1С:Предприятие 7.7 исключительно типовыми средствами.

1 стартмани

27.09.2016    18658    2    HAMMER_59    6    

2
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. CheBurator 3119 13.11.07 00:16 Сейчас в теме
хм.. как-то создание вложенных файлов красивше решается.. рекурсией...
а вариант
// Проверим, возможно каталог существует
Атрибуты = "";
ФС.АтрибутыФайла(Путь, , Атрибуты);
Если Сред(Атрибуты, 4, 1) = "1" Тогда
Возврат 1;
КонецЕсли;
..понравился
2. CheBurator 3119 13.11.07 00:18 Сейчас в теме
ага, все-таки я ее чуток подломал... ;-)
глСоздатьКаталог("c:\Еуые1\еуые2") при условии что еуые2 - существующий файл в папке Еуые1
tarasenkov; +1 Ответить
3. CheBurator 3119 13.11.07 00:28 Сейчас в теме
аналогично
глСоздатьКаталог("c:\Еуые1\eee*we")
+ еще Добился вывода сообщения "Невозможно создать путь:" - какой именно - не указано ;-)
tarasenkov; +1 Ответить
4. tarasenkov 340 13.11.07 07:42 Сейчас в теме
Вам бы только ломать :-)
Добавлена защита от взлома :-)
+ Спасибо за конструктивные замечания
5. CheBurator 3119 13.11.07 12:12 Сейчас в теме
Ну, вообще-то представляется более праивльным искать запрещенные символы в именах каталогов, а не наоборот.. потому как правило, вложенный путь каталогво больше 10 запрещенных символов... ;-) Это я так, побрюзжать...
Оставьте свое сообщение