gifts2017

Что такое буквы в 1С

Опубликовал Alexander Speshilov (speshuric) в раздел Программирование - Практика программирования

Некоторые особенности и неочевидные моменты использования символов в 1С.

Что такое буквы в 1С.

Скрипт приведенный ниже демонстрирует следующие особенности работы с символами в 1С:

  • Символ/КодСимвола работают в диапазоне -1..65535, причем Символ(-1) - строка без символов
  • Скрипт ищет все символы "пустые строки". Некоторые из этих строк отображаются как непустые.
  • Скрипт показывает, какие символы являются "буквами" для языка 1С - это полезно для написания обфускаторов и для проверок самописных парсеров языка 1С (собственно для проверки лексического генератора и написан этот скрипт).
  • Скрипт показывает допустимость символов для XML. Это важно, потому что сервер и клиент 1С в управляемых формах общаются через XML, поэтому при попытке передать недопустимый символ возникнет ошибка времени выполнения. Если при загрузке данных из внешних источников это не учитывать, то может возникнуть ситуация, когда 1С будет всегда падать при открытии, например, справочника.
  • Демонстрируется, что строка в 1С не является null-terminated. В скрипте не демонстрируется, но упомянуто, что ТекстовыйДокумент не умеет корректно работать со строками, содержащими Символ(0)

Сам скрипт проверялся в управляемых формах:


&НаКлиенте
Процедура ВыполнитьТест(Команда)

   
РезультатТеста = Новый Массив;
   
СтруктураДляПроверкиБукв = Новый Структура;
   
Начало = -2;
   
Конец = 65540;

    Для
Сч = Начало По Конец Цикл

        Если
Сч % 1024 = 0 Тогда
           
Состояние("Символ № " + Строка(Сч));
           
ОбработкаПрерыванияПользователя();
        КонецЕсли;

       
СимволПоКоду = Символ(Сч);
       
СтруктураРезультат = Новый Структура(
           
"Номер, Символ, ЭтоСимвол, ПустаяСтрока, ЭтоБуква, ДопустимыйСимволыXML, КорректнаяКонкатенация");
       
РезультатТеста.Добавить(СтруктураРезультат);
       
СтруктураРезультат.Номер = Сч;
       
СтруктураРезультат.Символ = СимволПоКоду;

       
//Проверка 1 - Это символ?
        //Демонстрируется, что Символ/КодСимвола работают в диапазоне -1..65535, причем Символ(-1) - строка без символов
       
КодПоСимволу = КодСимвола(СимволПоКоду);
        Если
КодПоСимволу<>Сч Тогда
           
СтруктураРезультат.ЭтоСимвол = Ложь;
            Продолжить;
        Иначе
           
СтруктураРезультат.ЭтоСимвол = Истина;
        КонецЕсли;

       
//Проверка 2 - Это пустая строка?
        //Неочевидный момент - некоторые "пустые строки" вполне имеют графическое непустое отображение
       
СтруктураРезультат.ПустаяСтрока = ПустаяСтрока(СимволПоКоду);

       
//Проверка 3 - Это буква?
        //Буквой считаем символ, который может быть именем поля в структуре. Таких букв достаточно много.
       
ТекущееЗначение = "";
        Попытка
            Если
СтруктураДляПроверкиБукв.Свойство(СимволПоКоду, ТекущееЗначение) Тогда
               
//Заодно сохраняем все "одинаковые" буквы, максимальное количество - 4:Θθϑe2;
               
СтруктураДляПроверкиБукв[СимволПоКоду] = ТекущееЗначение + СимволПоКоду;
            Иначе
               
СтруктураДляПроверкиБукв.Вставить(СимволПоКоду, СимволПоКоду);
            КонецЕсли;
           
СтруктураРезультат.ЭтоБуква = Истина;
        Исключение
           
СтруктураРезультат.ЭтоБуква = Ложь;
        КонецПопытки;

       
//Проверка 4 - Допустимые символы XML. Строки с недопустимыми символами нельзя передать с сервера или на сервер.
        //При получении данных из любых сторонних источников, перез записью их в БД крайне желательно их проверять на то,
        //что они смогут потом быть прочитанными. 
       
СтруктураРезультат.ДопустимыйСимволыXML = (НайтиНедопустимыеСимволыXML(СимволПоКоду) = 0);

       
//Проверка 5 - корректность конкатенации
        //- очевидно, что для символа с кодом -1 конкатенация не работает (это пустая строка длины 0)
        //- менее очевидно, что символы кода 0 успешно конкатенируются. Только ТекстовыйДокумент об этом, к сожалению, не знает
       
ДлиннаяСтрока = СимволПоКоду + СимволПоКоду + СимволПоКоду + СимволПоКоду + СимволПоКоду;
       
СтруктураРезультат.КорректнаяКонкатенация = (СтрДлина(ДлиннаяСтрока) = 5);

    КонецЦикла;

   
//1. в текстовый документ нельзя вывести "нулевой символ"
    //2. Выводим "честно" - последовательно по строкам и колонкам, чтобы не привлекать дополнительные механизмы
   
ТабличныйДокумент = Новый ТабличныйДокумент;
   
СчКолонок = 1;
    Для каждого
КлючИЗначениеСтруктураРезультат Из СтруктураРезультат Цикл
       
ТабличныйДокумент.Область(1, СчКолонок, 1, СчКолонок).Текст = КлючИЗначениеСтруктураРезультат.Ключ;
       
СчКолонок = СчКолонок + 1;
    КонецЦикла;
   
ТабличныйДокумент.Область(1, СчКолонок, 1, СчКолонок).Текст = "АналогичныеСимволы";
   
ТабличныйДокумент.Область(1, СчКолонок + 1, 1, СчКолонок + 1).Текст = "КоличествоАналогов";
   
СчСтрок = 2;
    Для каждого
СтруктураРезультат Из РезультатТеста Цикл

        Если
СчСтрок % 1024 = 0 Тогда
           
Состояние("Строка № " + Строка(СчСтрок));
           
ОбработкаПрерыванияПользователя();
        КонецЕсли;

       
СчКолонок = 1;
        Для каждого
КлючИЗначениеСтруктураРезультат Из СтруктураРезультат Цикл
           
ТабличныйДокумент.Область(СчСтрок, СчКолонок, СчСтрок, СчКолонок).Текст КлючИЗначениеСтруктураРезультат.Значение;
           
СчКолонок = СчКолонок + 1;
        КонецЦикла;
        Если
СтруктураРезультат.ЭтоБуква = Истина Тогда
           
ТабличныйДокумент.Область(СчСтрок, СчКолонок, СчСтрок, СчКолонок).Текст = СтруктураДляПроверкиБукв[СтруктураРезультат.Символ];
           
ТабличныйДокумент.Область(СчСтрок, СчКолонок + 1, СчСтрок, СчКолонок + 1).Текст = СтрДлина(СтруктураДляПроверкиБукв[СтруктураРезультат.Символ]);
        КонецЕсли;
       
СчСтрок = СчСтрок + 1;

    КонецЦикла;
   
ТабличныйДокумент.Показать();

КонецПроцедуры

Скрипт пробегает по всем символам и просто выводит на экран табличный документ с результатами.

 

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Александр (TrinitronHome) 20.05.13 20:07
спасибо большое за статью, очень полезный материал для меня
2. Virikus 22.05.13 12:32
Для проверки обмена через XML будет полезно. Спасибо.
3. Родин Родновер (dr.vatson) 27.05.13 19:51
Скрипт пробегает по всем символам и просто выводит на экран табличный документ с результатами

выводит ошибки или вносит исправления?
4. Vlad (KillHunter) 27.05.13 20:03
Отличная статья. Спасибо!
5. Alexander Speshilov (speshuric) 27.05.13 21:26
(3) Не понял. Куда вносить исправления? Просто тупо выводит сформированную табличку с колонками. И всё.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа