gifts2017

Открытие консоли запросов из режима отладки

Опубликовал q_i в раздел Программирование - Инструментарий

Обработка позволяет из режима отладки (Конфигуратора) открыть консоль запросов в "1С:Предприятии", в которой будут установлены текст и параметры интересующего нас запроса.

Эта обработка - это синтез идей из публикации "Открытие консоли запросов при отладке из кода (Обычное приложение)" и  статьи "Хитрости отладки".

Саму задачу можно сформулировать следующим образом: нужна возможность из отладчика (Конфигуратора) открыть Консоль запросов в "1С:Предприятии" так, чтобы в этой Консоли запросов текст и параметры были заполнены текстом и параметрами интересующего нас запроса.

Для решения этой задачи будем использовать самую обычную Консоль запросов (не-генномодифицированную, без двойного дна).

Описание решения (для любопытных; нелюбопытные могут пропустить этот раздел).

Анализ кода обработки КонсольЗапросов.epf показал, что разработчики не предоставили нам никаких средств для внешнего управления ею: нет ни экспортных процедур, ни даже каких-либо реквизитов обработки, с помощью которых мы могли бы заставить Консоль запросов заполнить текст запроса и параметры так, как нам нужно. Ну что ж, значит будем работать через реквизиты формы. На мой взгляд, для этой цели лучше всего подходит дерево значений ДеревоЗапросов. Если добавить в него строку и заполнить значения в колонках "ТекстЗапроса", "ПараметрыЗапроса" и "СпособВыгрузки", а потом сделать строку активной, то текст запроса и параметры будут заполнены так как нам надо. Но есть одно но! По какой-то причине эти колонки дерева создаются в обработчике ПриОткрытии (хотя при этом колонка "Запрос" добавлена через редактор форм). Ну и ладно - значит будем получать форму обработки, открывать её (чтобы создались колонки дерева значений), а уже после этого будем добавлять свою строку в ДеревоЗапросов.

Ещё одну интересную идею я подсмотрел в комментариях к публикации про открытие консоли запросов. Идея состоит в том, что иногда имеет смысл открывать Консоль запросов в модальном режиме. Ну например, занимаемся мы отладкой кода, хотим посмотреть какой-нибудь запрос, текст которого генерируется программно и имеет кучу параметров. Тут было бы очень здорово оперативно открыть Консоль запросов в модальном режиме в "1С:Предприятии", выполнить этот запрос, "покрутить" параметры, посмотреть из-за каких условий не попадают нужные данные в результат запроса (или наоборот попадают лишние), закрыть Консоль запросов и продолжить отладку. Но тут есть маленькая трудность - при модальном открытии окна Консоли запросов мы не сможем добавить строку в ДеревоЗапросов описанным выше способом, потому что как только мы вызовем ОткрытьМодально(), выполнение нашего кода будет приостановлено до тех пор, пока мы не закроем модальное окно. Посмотрим ещё раз на код обработчика ПриОткрытии. Помимо всего прочего там есть вызов процедуры вЗагрузитьЗапросыИзФайла(), которая пытается прочитать запрос из файла, имя которого получает процедура вВосстановитьИмяФайла() из сохранённого в базе значения. А это значит, что если мы перед открытием модального окна подготовим дерево значений, которое по структуре будет совпадать с деревом ДеревоЗапросов, и сохраним его во временный файл, а потом имя этого файла с помощью вызова СохранитьЗначение("КонсольЗапросов_ИмяФайла", ИмяВременногоФайла) сохраним в базе, то Консоль запросов загрузит нужный нам текст запроса с параметрами из этого временного файла.

И наконец, последнее - это параметры запроса типа ТаблицаЗначений. Штатным образом в Консоли запросов нельзя задать таблицу значений в качестве значения параметра. Но в реальных запросах таблицы значений в качестве параметров пусть не часто, но всё-таки попадаются (например, Запрос.Текст = "ВЫБРАТЬ * ИЗ &ТЗ КАК ТЗ"). Решая данную задачу, я узнал, что означает загадочный флажок "В" в форме параметров запроса в Консоли запросов (до этого мне как-то особо не было до него дела). Оказывается, если установить этот флажок (на самом деле называется он "ЭтоВыражение"), то Консоль запросов в качестве значения параметра будет использовать результат вычисления выражения, заданного в "Значение параметра" (т.е. она возьмёт текст из "Значение параметра" и применит к нему функцию Вычислить(), а полученный результат будет использовать как значение параметра запроса). Вот так сервис! Ну что ж - тогда провернём ещё раз нашу махинацию с временными файлами. Все параметры запроса, которые имеют тип ТаблицаЗначений, с помощью обычного ЗначениеВФайл() будем сохранять во временные файлы, а в качестве значений таких параметров в Консоли запросов будем указывать "ЗначениеИзФайла(ИмяВременногоФайла)" и устанавливать это волшебный флажок "В".

Код модуля обработки

//////////////////////////////////////////////////
// Автор: q_i
// Лицензия: GPLv3
//////////////////////////////////////////////////

// Пример использования обработки для отладки запроса: 
// В режиме отладки вызываем диалог "Вычислить выражение..." (Shift+F9) и пишем выражение вида
// ВнешниеОбработки.Создать("(КаталогЭтойОбработки)\ОткрывашкаКонсолиЗапросов.epf").ОткрытьКонсольЗапросов(Запрос, "(КаталогКонсолиЗапросов)\КонсольЗапросов.epf", Истина)
//

// Функция открывает консоль запросов для отладки запроса.
//
Функция ОткрытьКонсольЗапросов(Запрос, ФайлКонсолиЗапросов = "", Модально = Истина) Экспорт

	Результат = Новый Структура("Успех, Сообщение", Ложь, "Неизвестная ошибка");
	
	ИмяФайлаКонсолиЗапросов = ФайлКонсолиЗапросов;
	Если ПустаяСтрока(ИмяФайлаКонсолиЗапросов) Тогда
		// по умолчанию считаем, что консоль запросов лежит в том же каталоге, что и эта обработка
		Файл = Новый Файл(ЭтотОбъект.ИспользуемоеИмяФайла);
	    ИмяФайлаКонсолиЗапросов = Файл.Путь + "КонсольЗапросов.epf";
	КонецЕсли;
	
	Попытка
		КонсольЗапросов = ВнешниеОбработки.Создать(ИмяФайлаКонсолиЗапросов);
	Исключение
		Результат.Успех		= Ложь;
		Результат.Сообщение	= "Не удалось создать обработку Консоль запросов: " + ОписаниеОшибки();
		Возврат Результат;
	КонецПопытки;	
	
	КомментарииКЗапросу = "";
	
	// скопируем параметры запроса в новую таблицу значений
	ФормаПараметров = КонсольЗапросов.ПолучитьФорму("ФормаПараметров");
	ТаблицаПараметров = ФормаПараметров.Параметры.СкопироватьКолонки();
	Для Каждого ТекПараметр Из Запрос.Параметры Цикл
		ТекИмя	= ТекПараметр.Ключ;
		ТекЗнач	= ТекПараметр.Значение;
		НоваяСтрока = ТаблицаПараметров.Добавить();
		НоваяСтрока.ИмяПараметра = ТекИмя;
		Если ТипЗнч(ТекЗнач) = Тип("Массив") Тогда
			// массивы преобразуем в списки значений
			СЗ = Новый СписокЗначений;
			СЗ.ЗагрузитьЗначения(ТекЗнач);
			ТекЗнач = СЗ;
		ИначеЕсли ТипЗнч(ТекЗнач) = Тип("ТаблицаЗначений") Тогда
			// таблицы значений сохраняем во временные файлы
			ИмяВремФайла = ПолучитьИмяВременногоФайла(".vt");
			ЗначениеВФайл(ИмяВремФайла, ТекЗнач);
			ТекЗнач = "ЗначениеИзФайла(""" + ИмяВремФайла + """)";
			НоваяСтрока.ЭтоВыражение = Истина;
			КомментарииКЗапросу = КомментарииКЗапросу + ?(ПустаяСтрока(КомментарииКЗапросу), "", Символы.ПС)
				+ "// ВНИМАНИЕ! Параметр """ + ТекИмя + """ имеет тип ТаблицаЗначений, поэтому сохранён в файл """ + ИмяВремФайла + """!";
		КонецЕсли; 
		НоваяСтрока.ЗначениеПараметра = ТекЗнач;
	КонецЦикла;	
	
	Форма = КонсольЗапросов.ПолучитьФорму("Форма");
	
	Если Модально Тогда
		ДеревоЗапросов = Форма.ДеревоЗапросов.Скопировать();
		ДеревоЗапросов.Строки.Очистить();
		// {{ повторяем действия из обработчика ПриОткрытии
		ДеревоЗапросов.Колонки.Добавить("ТекстЗапроса");
		ДеревоЗапросов.Колонки.Добавить("ПараметрыЗапроса");
		ДеревоЗапросов.Колонки.Добавить("СпособВыгрузки");
		// повторяем действия из обработчика ПриОткрытии }}
	Иначе	
		// открываем форму чтобы отработал обработчик ПриОткрытии
		Форма.Открыть();
		ДеревоЗапросов = Форма.ДеревоЗапросов;
	КонецЕсли; 	
	
	Если ДеревоЗапросов.Строки.Количество() > 0 
		И ДеревоЗапросов.Строки[0].Запрос = "Запросы" Тогда
	    СтрокаРодитель = ДеревоЗапросов.Строки[0];
	Иначе	
		СтрокаРодитель = ДеревоЗапросов;	
	КонецЕсли;
	ИмяЗапроса		= "Отладка " + ТекущаяДата();
	ТекстЗапроса	= Запрос.Текст;
	СтрокаЗапроса = СтрокаРодитель.Строки.Добавить();
	СтрокаЗапроса.Запрос			= ИмяЗапроса;
	СтрокаЗапроса.ТекстЗапроса		= ?(ПустаяСтрока(КомментарииКЗапросу), 
										ТекстЗапроса, 
										КомментарииКЗапросу + Символы.ПС + Символы.ПС + ТекстЗапроса);
	СтрокаЗапроса.ПараметрыЗапроса	= ТаблицаПараметров;
	СтрокаЗапроса.СпособВыгрузки	= 1; // список
	
	Если Модально Тогда
		// сохраняем сформированное ДеревоЗапросов во временный файл
		ИмяВремФайла = ПолучитьИмяВременногоФайла(".sel");
		ЗначениеВФайл(ИмяВремФайла, ДеревоЗапросов);
		Файл = Новый Файл(ИмяВремФайла);
		ИМЯЗНАЧ_ИМЯФАЙЛА	= "КонсольЗапросов_ИмяФайла";
		ИМЯЗНАЧ_ИМЯПУТИ		= "КонсольЗапросов_ИмяПути";
		ПредИмяФайла = ВосстановитьЗначение(ИМЯЗНАЧ_ИМЯФАЙЛА);
		ПредИмяПути	= ВосстановитьЗначение(ИМЯЗНАЧ_ИМЯПУТИ);
		БылиОшибки = Ложь;
		Попытка
			СохранитьЗначение(ИМЯЗНАЧ_ИМЯФАЙЛА, ИмяВремФайла);
			СохранитьЗначение(ИМЯЗНАЧ_ИМЯПУТИ,  Файл.Путь);
			// в обработчике ПриОткрытии консоль загрузит запросы из нашего файла
			Форма.ОткрытьМодально();
		Исключение
			Результат.Успех		= Ложь;
			Результат.Сообщение	= "Ошибка при модальном открытии формы Консоли запросов: " + ОписаниеОшибки();
			БылиОшибки = Истина;
		КонецПопытки;
		СохранитьЗначение(ИМЯЗНАЧ_ИМЯФАЙЛА, ПредИмяФайла);
		СохранитьЗначение(ИМЯЗНАЧ_ИМЯПУТИ,  ПредИмяПути);
		Если БылиОшибки Тогда
            Возврат Результат;
		КонецЕсли; 
	Иначе
		Форма.ЭлементыФормы.ДеревоЗапросов.ТекущаяСтрока = СтрокаЗапроса;	
	КонецЕсли; 

	Результат.Успех		= Истина;
	Результат.Сообщение	= "Консоль запросов открыта. Имя текущего запроса = " + ИмяЗапроса;
	Возврат Результат;
	
КонецФункции

Использование обработки

Обработка состоит всего из одной экспортной функции ОткрытьКонсольЗапросов(Запрос, ФайлКонсолиЗапросов = "", Модально = Истина).

Параметры этой функции:

  • Запрос - это объект Запрос, который нужно открыть в Консоли запросов.
  • ФайлКонсолиЗапросов - это полное имя файла Консоли запросов. Параметр необязательный. Если не указан, то обработка считает, что консоль запросов имеет имя "КонсольЗапросов.epf" и находится в том же каталоге, что и сама обработка.
  • Модально - указывает нужно ли открывать Консоль запросов в модальном режиме (Истина) или нет. Параметр также необязательный. По умолчанию - Истина (т.е. Консоль запросов открывается в модальном режиме).

 

Теперь о том, как использовать эту обработку.

В режиме отладки вызываем диалог "Вычислить выражение..." (Shift+F9), пишем выражение вида

  • ВнешниеОбработки.Создать("КаталогЭтойОбработки\ОткрывашкаКонсолиЗапросов.epf").ОткрытьКонсольЗапросов(Запрос, "КаталогКонсолиЗапросов\КонсольЗапросов.epf", Истина)

и нажимаем кнопку "Рассчитать". Если последний параметр Истина (или не задан), то Консоль запросов откроется в модальном режиме, и мы можем сразу перейти в "1С:Предприятие" и работать с открывшимся запросом. Если последний параметр Ложь, то Консоль запросов откроется в "1С:Предприятие" ПОСЛЕ того, как мы нажмём F5 ("Продолжить отладку").

В этом примере:

  • КаталогЭтойОбработки\ОткрывашкаКонсолиЗапросов.epf - это полное имя файла этой обработки.

Ещё примеры запуска:

  • ВнешниеОбработки.Создать("КаталогЭтойОбработки\ОткрывашкаКонсолиЗапросов.epf").ОткрытьКонсольЗапросов(Запрос) - откроет Консоль запросов, которая имеет имя "КонсольЗапросов.epf" и находится в каталоге "КаталогЭтойОбработки\".
  • ВнешниеОбработки.Создать("КаталогЭтойОбработки\ОткрывашкаКонсолиЗапросов.epf").ОткрытьКонсольЗапросов(Запрос,, Ложь) - то же самое, но Консоль запросов откроется в немодальном режиме.

 

Собственно и всё. Пожелания и замечания по делу приветствуются!

Скачать файлы

Наименование Файл Версия Размер
ОткрывашкаКонсолиЗапросов.epf.7z 35
.7z 3,29Kb
14.11.13
35
.7z 3,29Kb Скачать

См. также

Подписаться Добавить вознаграждение
Комментарии
1. Евгений Мадонов (madonov) 19.11.13 04:06
Очень часто приходится разбирать сложные запросы. Приходится отлавливать отладчиком текст запроса, значения всех параметров, вручную вносить все в консоль...
Большое спасибо за обработку!
2. Иван Иванов (Famza) 19.11.13 11:45
3. q_i 19.11.13 11:46
(1) madonov, рад что обработка понравилась! пользуйтесь на здоровье! ))
4. Андрей Овсянкин (Evil Beaver) 19.11.13 17:24
5. Андрей Акулов (DrAku1a) 20.11.13 02:18
Баян.
Уже давно реализовано как в ИР, так и в других обработках. У меня например: Отладчик запросов: Функция "Открыть из отладчика"
6. Юрий Осипов (yuraos) 20.11.13 05:57
(5) DrAku1a,
все мы боянисты, граф.
:)
ортодоксы считают, что на диске ИТС все давно есть
7. Юрий Осипов (yuraos) 20.11.13 06:09
(6)
Плюс за оригинальность идеи.
Я подобным образом при отладке открываю для просмотра "табличные объекты"
Подсистема ViewValues (просмотр "табличных" объектов).
8. Юрий Осипов (yuraos) 20.11.13 06:14
Немного критики:
не сильно красиво
на лету формировать список запросов
сохранять его в файле,
прописывать имя файла в настройках пользователя под нужным именем,
чтобы консоль его открыла при открытии формы.
9. Юрий Осипов (yuraos) 20.11.13 06:19
Можно сделать более изящно...подправив саму консоль

Предусмотрев например в модуле объекта обработки
экспортный метод формирующий новый список запроса
по объекту "Запрос"

и использовать подправленную консоль вместо "Открывашки"
10. Юрий Осипов (yuraos) 20.11.13 06:25
(9)
За основу разумно взять какую-нибудь из доработанных консолей запросов
которых довольно много на Инфостарте,
например мой скромный вариантик
Консоль запросов 1С + ADO
11. Андрей Акулов (DrAku1a) 20.11.13 07:41
(9) я описал именно это в (5)
12. Алексей Сергеев (students) 20.11.13 08:28
Давно уже все есть. зачем изобретать велосипед.
(7) Какая оригинальность? Человек просто не умеет пользоваться поиском.
13. sanek sanek_gk (sanek_gk) 20.11.13 09:49
Эта обработка полезна тем кто не умеет писать запросы ( или не знает что текст запроса смотрится через Запрос.текст а параметры Через Запрос.Параметры... Очень интересно если использовать её по назначению там где действительно сложно увидеть первоначальный Исходный полный запрос, например в процедуре расчета себестоимости где запрос собирается по 10 функциям или процедурами НО через менеджервременных таблиц данная обработка будет там полезна ? покажет что было в исходной ВТ из каких полей она состоит и каким запросом создавалась - чего то сомневаюсь. А вот там как раз было бы неплохо получить сразу всю картинку и не отлаживать хх минут собирая запросы кусками..
14. q_i 20.11.13 11:11
(5) DrAku1a, (10) yuraos, спасибо за ваши замечания.
Мне нужна была "открывашка" именно штатной 1с-вской консоли запросов, т.к. пользуюсь исключительно ею. Если вам удобнее пользоваться "прокачанными" консолями, то тогда, конечно, эта "открывашка" вам не нужна.
15. q_i 20.11.13 11:22
(13) sanek_gk, если все запросы собираются в одну большую простыню, то эта обработка поможет. Если же формирование запроса перемежается периодическими вызовами Запрос.Выполнить() чтобы заполнить соответствующие временные таблицы, то нет. Дело в том, что в стандартную консоль запросов можно передать только текст запроса и параметры, но не сам объект Запрос. О том, существуют ли в природе консоли запросов, которые могут помочь решить задачу отладки запроса с менеджером временных таблиц, я думаю, могут подсказать DrAku1a, yuraos или students.
16. q_i 20.11.13 11:32
(8) yuraos,
не сильно красиво
на лету формировать список запросов
сохранять его в файле,
прописывать имя файла в настройках пользователя под нужным именем,
чтобы консоль его открыла при открытии формы

Это вынужденный "костыль" для модального режима. В немодальном режиме консоль открывается несколько более "красиво": запрос с параметрами просто добавляется в существующее дерево запросов. Причём, если консолью при старте был открыт файл с запросами (.sel-файл), то новый запрос будет добавлен в дерево запросов этого файла с запросами.
17. Павел А (Pavean) 20.11.13 21:18
Работает только в обычном приложении?
18. Алекс Одинэсник (Alex1Cnic) 21.11.13 08:51
Интересная вещица, над попробовать! плюс однозначно!
19. q_i 21.11.13 11:31
(17) Pavean, да, эта открывашка для обычной ("не-управляемой") консоли запросов.
20. Владимир G (laduk) 22.11.13 10:27
Будет версия для "управляемой консоли ?
21. Сисой Сисой (Сисой) 22.11.13 12:59
Мне для анализа в общем-то не нужно, т.к. я со времен FoxPro гораздо быстрее понимаю запрос в виде текста, чем в окне конструктора, но у этой обработки может быть довольно толковое применение: быстрое внесение изменений в имеющийся запрос, проверка результата и если получилось, копирование текста запроса через буфер в Конфигуратор.

Пожалуй, включу ее в свою конфигурацию в глобальный модуль.
Автору зачот.
cleaner_it; +1 Ответить
23. q_i 23.11.13 21:42
(20)
Будет версия для "управляемой консоли ?

Пока такого в планах нет. Возможно, задумаюсь на этот счёт, когда перейду на управляемую консоль. Впрочем, есть надежда, что к тому времени кто-то другой сделает - тогда просто скачаю. )))
24. q_i 24.11.13 17:28
(22) tormozit, да кто ж спорит - если есть возможность вкрутить в конфигурацию подсистему ИР, то, конечно, она предоставляет несравнимо более широкие возможности. Это как самокат и автомобиль. Автомобиль и быстрее ездит, и уровень комфорта на порядки выше, но если нужно полететь куда-то далеко на самолёте, то самокат с собой ещё можно взять, а вот автомобиль сильно вряд ли.
25. Юрий Гуреев (Gureev) 27.11.13 14:32
Есть же запросник умеющий это и еще многое
http://infostart.ru/public/72969/
26. Zigfridish (Bassgood) 27.11.13 16:40
(0) Да, действительно все уже давно реализовано во многих "прокачанных" консолях запросов и рекомендую пользоваться именно ими, а не допиливать что-то свое к старой консоли с ИТС, которая уже морально устарела
27. q_i 27.11.13 17:35
(26) Zigfridish,
рекомендую пользоваться именно ими, а не допиливать что-то свое к старой консоли с ИТС
спасибо, я учту. я всегда учитываю рекомендации людей, которые лучше меня знают что мне нужно. ))