gifts2017

Преобразование даты в текст в запросе

Опубликовал Вячеслав Балюнов (BalyunovVV) в раздел Программирование - Практика программирования

Иногда в запросе необходимо вывести дату в текстовом формате, к сожалению, штатными средствами запроса это сделать невозможно. Предлагаю свой вариант решения проблемы

Идея простая: создаем 2 временных таблицы, одну - содержащую числа от 0 до 99 и их строковые представления, вторую - числа от 1900 до 2099 и их строковые представления. Соединяем при помощи левого соединения нашу таблицу дат и эти таблицы:

ВЫБРАТЬ
	0	КАК Число,
	"0"	КАК Текст
ПОМЕСТИТЬ Десяток
ОБЪЕДИНИТЬ ВЫБРАТЬ 1,"1"
ОБЪЕДИНИТЬ ВЫБРАТЬ 2,"2"
ОБЪЕДИНИТЬ ВЫБРАТЬ 3,"3"
ОБЪЕДИНИТЬ ВЫБРАТЬ 4,"4"
ОБЪЕДИНИТЬ ВЫБРАТЬ 5,"5"
ОБЪЕДИНИТЬ ВЫБРАТЬ 6,"6"
ОБЪЕДИНИТЬ ВЫБРАТЬ 7,"7"
ОБЪЕДИНИТЬ ВЫБРАТЬ 8,"8"
ОБЪЕДИНИТЬ ВЫБРАТЬ 9,"9";

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Цифра1.Число*10	 + Цифра2.Число КАК Число,
	Цифра1.Текст	 + Цифра2.Текст КАК Текст
ПОМЕСТИТЬ Сотня
ИЗ
	Десяток КАК Цифра1
	ЛЕВОЕ СОЕДИНЕНИЕ
	Десяток КАК Цифра2
	ПО ИСТИНА;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	1900 + Число КАК Число,
	"19" + Текст КАК Текст
ПОМЕСТИТЬ Годы
ИЗ Сотня
ОБЪЕДИНИТЬ
ВЫБРАТЬ
	2000 + Число,
	"20" + Текст
ИЗ Сотня;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	РТУ.Дата					КАК Дата,
	Дни.Текст+"."+Месяцы.Текст+"."+Годы.Текст	КАК Текст
ИЗ
	Документ.РеализацияТоваровУслуг КАК РТУ
	ЛЕВОЕ СОЕДИНЕНИЕ Сотня КАК Дни		ПО ДЕНЬ(РТУ.Дата)=Дни.Число
	ЛЕВОЕ СОЕДИНЕНИЕ Сотня КАК Месяцы	ПО МЕСЯЦ(РТУ.Дата)=Месяцы.Число
	ЛЕВОЕ СОЕДИНЕНИЕ Годы			ПО ГОД(РТУ.Дата)=Годы.Число

Или в компактном виде

SELECT 0 Ч,"0"Т INTO Д UNION SELECT 1,"1"UNION SELECT 2,"2"UNION SELECT
3,"3"UNION SELECT 4,"4"UNION SELECT 5,"5"UNION SELECT 6,"6"UNION SELECT
7,"7"UNION SELECT 8,"8"UNION SELECT 9,"9";SELECT Ц1.Ч*10+Ц2.Ч Ч,Ц1.Т+
Ц2.Т Т INTO С ИЗ Д Ц1 LEFT JOIN Д Ц2 ON TRUE;SELECT 1900+С.Ч Ч,"19"+С.Т
Т INTO Г ИЗ С UNION SELECT 2000+С.Ч Ч,"20"+С.Т Т ИЗ С;

ВЫБРАТЬ
	РТУ.Дата		КАК Дата,
	Ц1.Т+"."+Ц2.Т+"."+Ц3.Т	КАК Текст
ИЗ
	Документ.РеализацияТоваровУслуг КАК РТУ
	ЛЕВОЕ СОЕДИНЕНИЕ С КАК Ц1 ПО ДЕНЬ(РТУ.Дата)=Ц1.Ч
	ЛЕВОЕ СОЕДИНЕНИЕ С КАК Ц2 ПО МЕСЯЦ(РТУ.Дата)=Ц2.Ч
	ЛЕВОЕ СОЕДИНЕНИЕ Г КАК Ц3 ПО ГОД(РТУ.Дата)=Ц3.Ч

Недостаток:  диапазон допустимых дат 1900-2099 годы.  Этот недостаток можно устранить соединив с годами 2 таблицы:

ВЫБРАТЬ
	0	КАК Число,
	"0"	КАК Текст
ПОМЕСТИТЬ Десяток
ОБЪЕДИНИТЬ ВЫБРАТЬ 1,"1"
ОБЪЕДИНИТЬ ВЫБРАТЬ 2,"2"
ОБЪЕДИНИТЬ ВЫБРАТЬ 3,"3"
ОБЪЕДИНИТЬ ВЫБРАТЬ 4,"4"
ОБЪЕДИНИТЬ ВЫБРАТЬ 5,"5"
ОБЪЕДИНИТЬ ВЫБРАТЬ 6,"6"
ОБЪЕДИНИТЬ ВЫБРАТЬ 7,"7"
ОБЪЕДИНИТЬ ВЫБРАТЬ 8,"8"
ОБЪЕДИНИТЬ ВЫБРАТЬ 9,"9";

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Цифра1.Число*10	 + Цифра2.Число КАК Число,
	Цифра1.Текст	 + Цифра2.Текст КАК Текст
ПОМЕСТИТЬ Сотня
ИЗ
	Десяток КАК Цифра1
	ЛЕВОЕ СОЕДИНЕНИЕ
	Десяток КАК Цифра2
	ПО ИСТИНА;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	РТУ.Дата							КАК Дата,
	Дни.Текст+"."+Месяцы.Текст+"."+СотниЛет.Текст+Годы.Текст	КАК Текст
ИЗ
	Документ.РеализацияТоваровУслуг КАК РТУ
	ЛЕВОЕ СОЕДИНЕНИЕ Сотня КАК Дни		ПО ДЕНЬ(РТУ.Дата)=Дни.Число
	ЛЕВОЕ СОЕДИНЕНИЕ Сотня КАК Месяцы  	ПО МЕСЯЦ(РТУ.Дата)=Месяцы.Число
	ЛЕВОЕ СОЕДИНЕНИЕ Сотня КАК СотниЛет	ПО ВЫРАЗИТЬ(ГОД(РТУ.Дата)/100 КАК ЧИСЛО(2))=СотниЛет.Число
	ЛЕВОЕ СОЕДИНЕНИЕ Сотня КАК Годы		ПО ГОД(РТУ.Дата)-СотниЛет.Число*100=Годы.Число

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Сергей Семченков (BigClock) 19.02.15 14:30
Может, проще писать код так, чтобы выполнять преобразование Дата->Строка вне запроса?
2. Андрей Кондратенко (Kondratenko.as) 19.02.15 14:54
А зачем вам нужна была дата в виде строки в запросе?
3. davmat (cargobird) 19.02.15 15:29
Все в запросе для СКД безусловно хорошо, только область применения тоже пока представляю весьма смутно.
4. Сергей (ildarovich) 19.02.15 16:06
А вот еще один вариант в стиле "минимализма"
ВЫБРАТЬ
	  ПОДСТРОКА("0123456789", ЧАС(ДобавитьКДате(&Дата, МИНУТА, 6 * День(&Дата))) + 1, 1)
	+ ПОДСТРОКА("0123456789", МИНУТА(ДобавитьКДате(&Дата, МИНУТА, 6 * День(&Дата))) / 6 + 1, 1)
	+ "/"
	+ ПОДСТРОКА("0123456789", ЧАС(ДобавитьКДате(&Дата, МИНУТА, 6 * Месяц(&Дата))) + 1, 1)
	+ ПОДСТРОКА("0123456789", МИНУТА(ДобавитьКДате(&Дата, МИНУТА, 6 * Месяц(&Дата))) / 6 + 1, 1)
	+ "/"
	+ ПОДСТРОКА("0123456789", ЧАС(ДобавитьКДате(&Дата, МИНУТА, 6 * (Год(&Дата) - 1900))) + 1, 1)
	+ ПОДСТРОКА("0123456789", МИНУТА(ДобавитьКДате(&Дата, МИНУТА, 6 * (Год(&Дата) - 1900))) / 6 + 1, 1)
...Показать Скрыть
Предполагается, что параметр &Дата время не содержит. Если это не так, запись будет подлиннее
ВЫБРАТЬ
	ПОДСТРОКА("0123456789", ЧАС(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0), МИНУТА, 6 * ДЕНЬ(&Дата))) + 1, 1) 
	+ ПОДСТРОКА("0123456789", МИНУТА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0), МИНУТА, 6 * ДЕНЬ(&Дата))) / 6 + 1, 1) 
	+ "/" 
	+ ПОДСТРОКА("0123456789", ЧАС(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0), МИНУТА, 6 * МЕСЯЦ(&Дата))) + 1, 1) 
	+ ПОДСТРОКА("0123456789", МИНУТА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0), МИНУТА, 6 * МЕСЯЦ(&Дата))) / 6 + 1, 1) 
	+ "/" 
        + ПОДСТРОКА("0123456789", ЧАС(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0), МИНУТА, 6 * (ГОД(&Дата) - 1900))) + 1, 1) 
	+ ПОДСТРОКА("0123456789", МИНУТА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0), МИНУТА, 6 * (ГОД(&Дата) - 1900))) / 6 + 1, 1)
...Показать Скрыть
scape; rtnm; +2 Ответить 3
5. Яков Коган (Yashazz) 19.02.15 19:32
Во, я так и знал, что придёт Ильдарович и покажет, как это на самом деле надо делать в 5-6 строк, просто и изящно) Спасибо!
BigClock; +1 Ответить
6. Вячеслав Балюнов (BalyunovVV) 19.02.15 19:46
(2) Kondratenko.as,
Да был такой случай, надо было в отчете чтобы дата являлась частью строки, поэтому дата выводилась через шаблон а не через параметр, поэтому форматирование в ячейке на нее не действовало. А дата была со временем и это время никак не удавалось убрать.
Может придумаете еще какой способ, но у меня так получилось.
7. Вячеслав Балюнов (BalyunovVV) 19.02.15 19:54
(4) ildarovich,
А вообще интересна идея использовать "подстроку" в виде некоего переключателя, или преобразователя числа в последовательность символов.
вместо нескольких КОГДА ТОГДА
спасибо за идею!
8. Сергей Вн (EmpireSer) 20.02.15 12:54
(4) ildarovich,
А где данный пост в "Минимализмы"? А то искать Ваши гениальные и простые решения по всему форуму - тяжко...
9. Сергей Вн (EmpireSer) 20.02.15 13:57
(4) ildarovich,
Кстати, а зачем учёт 1900 года? Мне кажется так лучше будет:
ВЫБРАТЬ
	ПОДСТРОКА("0123456789", ДЕНЬ(&Дата) / 10 + 1, 1) 
	+ ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, 6 * ДЕНЬ(&Дата))) / 6 + 1, 1)
	+ "/"
	+ ПОДСТРОКА("0123456789", МЕСЯЦ(&Дата) / 10 + 1, 1) 
	+ ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, 6 * МЕСЯЦ(&Дата))) / 6 + 1, 1)
	+ "/"
	+ ПОДСТРОКА("0123456789", ГОД(&Дата) / 1000 + 1, 1)
	+ ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, 6 * ГОД(&Дата) / 100)) / 6 + 1, 1)
	+ ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, 6 * ГОД(&Дата) / 10)) / 6 + 1, 1)
	+ ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, 6 * ГОД(&Дата))) / 6 + 1, 1)
...Показать Скрыть
ildarovich; +1 Ответить 1
10. Сергей (ildarovich) 20.02.15 15:56
(9) EmpireSer, да, согласен. Со старшей цифрой так хорошо получается. То, что взяли секунду - значит уловили саму суть. Секунда лучше всего, но длиннее в записи. У меня еще есть вариант с вложенным запросом - чуть покороче по числу символов.
(8) Я сейчас думаю, не сделать ли вторую часть минимализмов (Минимализмы-2), а то до последнего далеко листать в таком длинном тексте. Еще не решил окончательно. А задачи и решения пока коплю.
11. Сергей Вн (EmpireSer) 20.02.15 17:54
(10) ildarovich,
Да я долго втягивался в эту логику. А секунду взял из-за возможного уменьшения математических действий ядром СУБД.

Может вам в минимализмы добавить пункт "Интересное" и там просто перечислить ссылки на Ваши примеры решений к чужим публикациям?
По хорошему Ваши идеи должны в БСП попасть :-)
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа