gifts2017

Ускоренное заполнение документа УПП "Распределение материалов на выпуск"

Опубликовал Пикалев Николай (dabu-dabu) в раздел Обработки - Обработка документов

Обработка заполнения документа "Распределение материалов на выпуск". Для тех, кто устал ждать выполнения типовой. Работает на порядок быстрее, чем типовая.

У многих возникает проблема очень медленного заполнения документа Распределение материалов на выпуск.

Ситуация отягчается тем, что зачастую приходится перезаполнять документ по причине, например, неверно введенных первичных данных.

Предлагаемая обработка предназначена для автоматического заполнения закладки "Распределение материалов", работает на порядок быстрее типовой, что позволяет решить данную проблему.

Обработка распределяет указанные материалы на выпущенную продукцию пропорционально нормам списания по спецификациям. В случае, если материал не присутствует ни в одной спецификации, то его распределение производится пропорционально количеству выпуска, указанному на закладке "Продукция" без пересчета по единицам измерения.

Обработка должна работать на более-менее новых релизах УПП 1.3

Обработка не работает в следующих случаях:

  1. наличие формул в использованных спецификациях;
  2. наличие спецификаций с одновременным выпуском нескольких позиций готовой продукции;
  3. наличие режима "Автоподбор характеристик" в использованных спецификациях.

Если будут просьбы, постараюсь доработать обработку.

Обработка устанавливается как дополнительная обработка заполнения табличных частей.

Скачать файлы

Наименование Файл Версия Размер
Распределение материалов ускоренное 7
.epf 8,54Kb
02.03.15
7
.epf 1.0 8,54Kb Скачать

См. также

Вознаграждение за ответ
Сумма: 0 $m
Добавили:
Борис Рукавицын (rukawizin) (1.00 $m)
Подписаться Добавить вознаграждение
Комментарии
1. Борис Рукавицын (rukawizin) 20.03.15 18:10
К сожалению ничего не заполнилось. Быстро пробежалась и в таблицу "Распределение материалов" (3 закладка) ничего не попало. Пришлось заполнить старым методом.
В чем причина?
2. Пикалев Николай (dabu-dabu) 23.03.15 10:48
(1) rukawizin, Нужно смотреть ваши данные из первой и второй закладки. Проверьте, что верно заполнены данные таблицы:
1. Счета затрат БУ и НУ должны совпадать в 1-й и 2-й таблице.
2. Номенклатурные группы должны совпадать или на закладке Материалы ном. группа должна быть пустой.
3. Вид выпуска должен совпадать.

Если умеете пользоваться консолью запросов, то могу выложить текст запроса для анализа.
3. Борис Рукавицын (rukawizin) 12.04.15 15:57
Пожалуйста выложите текст запроса для анализа. Пока ничего не получилось.
Борис
4. Пикалев Николай (dabu-dabu) 14.04.15 15:23
(3) rukawizin, Запрос полностью идентичный, тому что в обработке, но с получением данных из ссылки на документ:
ВЫБРАТЬ
	ТабПродукции.Номенклатура,
	ТабПродукции.ХарактеристикаНоменклатуры,
	ТабПродукции.СерияНоменклатуры,
	ТабПродукции.Количество,
	ТабПродукции.НоменклатурнаяГруппа,
	ТабПродукции.Спецификация,
	ТабПродукции.Заказ,
	ТабПродукции.СчетЗатрат,
	ТабПродукции.СчетЗатратНУ,
	ТабПродукции.ВидВыпуска,
	ТабПродукции.ЕдиницаИзмерения,
	ТабПродукции.Коэффициент
ПОМЕСТИТЬ Продукция
ИЗ
	Документ.РаспределениеМатериаловНаВыпуск.Продукция КАК ТабПродукции
ГДЕ
	ТабПродукции.Ссылка = &Ссылка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ТабМатериалов.Номенклатура,
	ТабМатериалов.ХарактеристикаНоменклатуры,
	ТабМатериалов.СерияНоменклатуры,
	ТабМатериалов.Количество,
	ТабМатериалов.СтатьяЗатрат,
	ТабМатериалов.Заказ,
	ТабМатериалов.НоменклатурнаяГруппа,
	ТабМатериалов.СчетЗатрат,
	ТабМатериалов.СчетЗатратНУ,
	ТабМатериалов.ПодразделениеНЗП,
	ТабМатериалов.ПодразделениеОрганизацииНЗП,
	ТабМатериалов.ВидВыпуска,
	ТабМатериалов.ЕдиницаИзмерения,
	ТабМатериалов.Коэффициент,
	ТабМатериалов.НомерСтроки
ПОМЕСТИТЬ Материалы
ИЗ
	Документ.РаспределениеМатериаловНаВыпуск.Материалы КАК ТабМатериалов
ГДЕ
	ТабМатериалов.Ссылка = &Ссылка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Продукция.Спецификация,
	Продукция.Номенклатура КАК Продукция,
	Продукция.ХарактеристикаНоменклатуры КАК ХарактеристикаПродукции
ПОМЕСТИТЬ Спецификации
ИЗ
	Продукция КАК Продукция
ГДЕ
	Продукция.Спецификация <> ЗНАЧЕНИЕ(Справочник.СпецификацииНоменклатуры.ПустаяСсылка)

СГРУППИРОВАТЬ ПО
	Продукция.Спецификация,
	Продукция.Номенклатура,
	Продукция.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Спецификации.Спецификация,
	Спецификации.Продукция,
	Спецификации.ХарактеристикаПродукции,
	СпецификацииНоменклатурыВыходныеИзделия.Количество * СпецификацииНоменклатурыВыходныеИзделия.ЕдиницаИзмерения.Коэффициент КАК КоличествоВыпуска
ПОМЕСТИТЬ ДанныеСпецификации
ИЗ
	Спецификации КАК Спецификации
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ВыходныеИзделия КАК СпецификацииНоменклатурыВыходныеИзделия
		ПО (СпецификацииНоменклатурыВыходныеИзделия.Ссылка = Спецификации.Спецификация)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Материалы.Номенклатура,
	Материалы.ХарактеристикаНоменклатуры
ПОМЕСТИТЬ МатериалыИсп
ИЗ
	Материалы КАК Материалы

СГРУППИРОВАТЬ ПО
	Материалы.Номенклатура,
	Материалы.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ДанныеСпецификации.Спецификация,
	ДанныеСпецификации.Продукция,
	ДанныеСпецификации.ХарактеристикаПродукции,
	ДанныеСпецификации.КоличествоВыпуска,
	СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура,
	ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка) КАК ХарактеристикаНоменклатуры,
	СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК КоличествоКомплектующих,
	СпецификацииНоменклатурыИсходныеКомплектующие.Свойство,
	СпецификацииНоменклатурыИсходныеКомплектующие.ВариантАвтоподбора,
	СпецификацииНоменклатурыИсходныеКомплектующие.КлючСвязи
ПОМЕСТИТЬ КомплектующиеАвтоподбором
ИЗ
	ДанныеСпецификации КАК ДанныеСпецификации
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
		ПО ДанныеСпецификации.Спецификация = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка
			И (СпецификацииНоменклатурыИсходныеКомплектующие.ВидНорматива = ЗНАЧЕНИЕ(Перечисление.ВидыНормативовНоменклатуры.АвтоподборНоменклатуры))
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КомплектующиеАвтоподбором.Спецификация,
	КомплектующиеАвтоподбором.Продукция,
	КомплектующиеАвтоподбором.ХарактеристикаПродукции,
	КомплектующиеАвтоподбором.КоличествоВыпуска,
	КомплектующиеАвтоподбором.Номенклатура,
	КомплектующиеАвтоподбором.ХарактеристикаНоменклатуры,
	КомплектующиеАвтоподбором.КоличествоКомплектующих,
	КомплектующиеАвтоподбором.Свойство,
	КомплектующиеАвтоподбором.ВариантАвтоподбора,
	ЗначенияСвойствОбъектов.Значение КАК ЗначениеСвойства,
	КомплектующиеАвтоподбором.КлючСвязи
ПОМЕСТИТЬ КомплектующиеАвтоподборомЗначениеСвойства
ИЗ
	КомплектующиеАвтоподбором КАК КомплектующиеАвтоподбором
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
		ПО КомплектующиеАвтоподбором.ХарактеристикаПродукции = ЗначенияСвойствОбъектов.Объект
			И КомплектующиеАвтоподбором.Свойство = ЗначенияСвойствОбъектов.Свойство
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ДанныеСпецификации.Спецификация,
	ДанныеСпецификации.Продукция,
	ДанныеСпецификации.ХарактеристикаПродукции,
	СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура,
	СпецификацииНоменклатурыИсходныеКомплектующие.ХарактеристикаНоменклатуры,
	СпецификацииНоменклатурыИсходныеКомплектующие.Количество * СпецификацииНоменклатурыИсходныеКомплектующие.ЕдиницаИзмерения.Коэффициент / ДанныеСпецификации.КоличествоВыпуска КАК КоличествоНаЕдиницу
ПОМЕСТИТЬ КомплектующиеСпецификацийВсеБезАналогов
ИЗ
	ДанныеСпецификации КАК ДанныеСпецификации
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
		ПО ДанныеСпецификации.Спецификация = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка
			И (СпецификацииНоменклатурыИсходныеКомплектующие.ВидНорматива = ЗНАЧЕНИЕ(Перечисление.ВидыНормативовНоменклатуры.Номенклатура))

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ДанныеСпецификации.Спецификация,
	ДанныеСпецификации.Продукция,
	ДанныеСпецификации.ХарактеристикаПродукции,
	СпецификацииНоменклатурыИсходныеКомплектующиеУзла.Номенклатура,
	СпецификацииНоменклатурыИсходныеКомплектующиеУзла.ХарактеристикаНоменклатуры,
	СпецификацииНоменклатурыИсходныеКомплектующиеУзла.Количество * СпецификацииНоменклатурыИсходныеКомплектующиеУзла.ЕдиницаИзмерения.Коэффициент / ДанныеСпецификации.КоличествоВыпуска
ИЗ
	ДанныеСпецификации КАК ДанныеСпецификации
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующиеУзла
			ПО СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующиеУзла.Ссылка
		ПО ДанныеСпецификации.Спецификация = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка
			И (СпецификацииНоменклатурыИсходныеКомплектующие.ВидНорматива = ЗНАЧЕНИЕ(Перечисление.ВидыНормативовНоменклатуры.Узел))

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	КомплектующиеАвтоподборомЗначениеСвойства.Спецификация,
	КомплектующиеАвтоподборомЗначениеСвойства.Продукция,
	КомплектующиеАвтоподборомЗначениеСвойства.ХарактеристикаПродукции,
	КомплектующиеАвтоподборомЗначениеСвойства.ЗначениеСвойства,
	ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка),
	КомплектующиеАвтоподборомЗначениеСвойства.КоличествоКомплектующих / КомплектующиеАвтоподборомЗначениеСвойства.КоличествоВыпуска
ИЗ
	КомплектующиеАвтоподборомЗначениеСвойства КАК КомплектующиеАвтоподборомЗначениеСвойства
ГДЕ
	КомплектующиеАвтоподборомЗначениеСвойства.ВариантАвтоподбора = ЗНАЧЕНИЕ(Перечисление.ВариантыАвтоподбораНоменклатуры.ПолучитьИзСвойства)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	КомплектующиеАвтоподборомЗначениеСвойства.Спецификация,
	КомплектующиеАвтоподборомЗначениеСвойства.Продукция,
	КомплектующиеАвтоподборомЗначениеСвойства.ХарактеристикаПродукции,
	СпецификацииНоменклатурыАвтоподборНоменклатуры.Номенклатура,
	ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка),
	ВЫБОР
		КОГДА СпецификацииНоменклатурыАвтоподборНоменклатуры.Количество = 0
			ТОГДА КомплектующиеАвтоподборомЗначениеСвойства.КоличествоКомплектующих
		ИНАЧЕ СпецификацииНоменклатурыАвтоподборНоменклатуры.Количество
	КОНЕЦ * СпецификацииНоменклатурыАвтоподборНоменклатуры.ЕдиницаИзмерения.Коэффициент / КомплектующиеАвтоподборомЗначениеСвойства.КоличествоВыпуска
ИЗ
	КомплектующиеАвтоподборомЗначениеСвойства КАК КомплектующиеАвтоподборомЗначениеСвойства
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.АвтоподборНоменклатуры КАК СпецификацииНоменклатурыАвтоподборНоменклатуры
		ПО КомплектующиеАвтоподборомЗначениеСвойства.Спецификация = СпецификацииНоменклатурыАвтоподборНоменклатуры.Ссылка
			И КомплектующиеАвтоподборомЗначениеСвойства.КлючСвязи = СпецификацииНоменклатурыАвтоподборНоменклатуры.КлючСвязи
			И КомплектующиеАвтоподборомЗначениеСвойства.ЗначениеСвойства = СпецификацииНоменклатурыАвтоподборНоменклатуры.Значение
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КомплектующиеСпецификацийВсеБезАналогов.Спецификация,
	КомплектующиеСпецификацийВсеБезАналогов.Продукция,
	КомплектующиеСпецификацийВсеБезАналогов.ХарактеристикаПродукции,
	КомплектующиеСпецификацийВсеБезАналогов.Номенклатура,
	КомплектующиеСпецификацийВсеБезАналогов.ХарактеристикаНоменклатуры,
	КомплектующиеСпецификацийВсеБезАналогов.КоличествоНаЕдиницу
ПОМЕСТИТЬ КомплектующиеСпецификацийВсе
ИЗ
	КомплектующиеСпецификацийВсеБезАналогов КАК КомплектующиеСпецификацийВсеБезАналогов

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	КомплектующиеСпецификацийВсеБезАналогов.Спецификация,
	КомплектующиеСпецификацийВсеБезАналогов.Продукция,
	КомплектующиеСпецификацийВсеБезАналогов.ХарактеристикаПродукции,
	АналогиНоменклатуры.Аналог,
	АналогиНоменклатуры.ХарактеристикаАналога,
	МАКСИМУМ(КомплектующиеСпецификацийВсеБезАналогов.КоличествоНаЕдиницу / (АналогиНоменклатуры.Количество * АналогиНоменклатуры.ЕдиницаИзмерения.Коэффициент) * АналогиНоменклатуры.КоличествоАналога * АналогиНоменклатуры.ЕдиницаИзмеренияАналога.Коэффициент)
ИЗ
	КомплектующиеСпецификацийВсеБезАналогов КАК КомплектующиеСпецификацийВсеБезАналогов
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналогиНоменклатуры КАК АналогиНоменклатуры
		ПО КомплектующиеСпецификацийВсеБезАналогов.Номенклатура = АналогиНоменклатуры.Номенклатура
			И (АналогиНоменклатуры.ВидАналога = ЗНАЧЕНИЕ(Перечисление.ВидыАналогов.Комплектующая))
			И (АналогиНоменклатуры.Продукция = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка))
			И КомплектующиеСпецификацийВсеБезАналогов.ХарактеристикаНоменклатуры = АналогиНоменклатуры.ХарактеристикаНоменклатуры
			И (КомплектующиеСпецификацийВсеБезАналогов.Номенклатура <> АналогиНоменклатуры.Аналог
				ИЛИ КомплектующиеСпецификацийВсеБезАналогов.ХарактеристикаНоменклатуры <> АналогиНоменклатуры.ХарактеристикаАналога)

СГРУППИРОВАТЬ ПО
	КомплектующиеСпецификацийВсеБезАналогов.Спецификация,
	КомплектующиеСпецификацийВсеБезАналогов.Продукция,
	КомплектующиеСпецификацийВсеБезАналогов.ХарактеристикаПродукции,
	АналогиНоменклатуры.Аналог,
	АналогиНоменклатуры.ХарактеристикаАналога
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	МатериалыИсп.Номенклатура,
	МатериалыИсп.ХарактеристикаНоменклатуры,
	МАКСИМУМ(ВЫБОР
			КОГДА КомплектующиеСпецификацийВсе.Номенклатура ЕСТЬ NULL 
				ТОГДА ЛОЖЬ
			ИНАЧЕ ИСТИНА
		КОНЕЦ) КАК ЭтоКомплектующее
ПОМЕСТИТЬ МатериалыАнализИсп
ИЗ
	МатериалыИсп КАК МатериалыИсп
		ЛЕВОЕ СОЕДИНЕНИЕ КомплектующиеСпецификацийВсе КАК КомплектующиеСпецификацийВсе
		ПО МатериалыИсп.Номенклатура = КомплектующиеСпецификацийВсе.Номенклатура
			И МатериалыИсп.ХарактеристикаНоменклатуры = КомплектующиеСпецификацийВсе.ХарактеристикаНоменклатуры

СГРУППИРОВАТЬ ПО
	МатериалыИсп.Номенклатура,
	МатериалыИсп.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КомплектующиеСпецификацийВсе.Спецификация,
	КомплектующиеСпецификацийВсе.Продукция,
	КомплектующиеСпецификацийВсе.ХарактеристикаПродукции,
	КомплектующиеСпецификацийВсе.Номенклатура,
	КомплектующиеСпецификацийВсе.ХарактеристикаНоменклатуры,
	СУММА(КомплектующиеСпецификацийВсе.КоличествоНаЕдиницу) КАК КоличествоНаЕдиницу
ПОМЕСТИТЬ КомплектующиеСпецификаций
ИЗ
	КомплектующиеСпецификацийВсе КАК КомплектующиеСпецификацийВсе
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ МатериалыИсп КАК МатериалыИсп
		ПО (МатериалыИсп.Номенклатура = КомплектующиеСпецификацийВсе.Номенклатура)
			И (МатериалыИсп.ХарактеристикаНоменклатуры = КомплектующиеСпецификацийВсе.ХарактеристикаНоменклатуры)

СГРУППИРОВАТЬ ПО
	КомплектующиеСпецификацийВсе.Спецификация,
	КомплектующиеСпецификацийВсе.Продукция,
	КомплектующиеСпецификацийВсе.ХарактеристикаПродукции,
	КомплектующиеСпецификацийВсе.Номенклатура,
	КомплектующиеСпецификацийВсе.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Продукция.СчетЗатрат,
	Продукция.СчетЗатратНУ,
	Продукция.ВидВыпуска,
	Продукция.Заказ,
	Продукция.НоменклатурнаяГруппа,
	НЕОПРЕДЕЛЕНО КАК ЗаказВариации,
	ЗНАЧЕНИЕ(Справочник.НоменклатурныеГруппы.ПустаяСсылка) КАК НоменклатурнаяГруппаВариации,
	Продукция.Количество,
	Продукция.Номенклатура,
	Продукция.ХарактеристикаНоменклатуры,
	Продукция.СерияНоменклатуры,
	Продукция.Спецификация,
	Продукция.Коэффициент
ПОМЕСТИТЬ ВыпускВариацииАналитик
ИЗ
	Продукция КАК Продукция

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	Продукция.СчетЗатрат,
	Продукция.СчетЗатратНУ,
	Продукция.ВидВыпуска,
	Продукция.Заказ,
	Продукция.НоменклатурнаяГруппа,
	НЕОПРЕДЕЛЕНО,
	Продукция.НоменклатурнаяГруппа,
	Продукция.Количество,
	Продукция.Номенклатура,
	Продукция.ХарактеристикаНоменклатуры,
	Продукция.СерияНоменклатуры,
	Продукция.Спецификация,
	Продукция.Коэффициент
ИЗ
	Продукция КАК Продукция
ГДЕ
	Продукция.НоменклатурнаяГруппа <> ЗНАЧЕНИЕ(Справочник.НоменклатурныеГруппы.ПустаяСсылка)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	Продукция.СчетЗатрат,
	Продукция.СчетЗатратНУ,
	Продукция.ВидВыпуска,
	Продукция.Заказ,
	Продукция.НоменклатурнаяГруппа,
	Продукция.Заказ,
	ЗНАЧЕНИЕ(Справочник.НоменклатурныеГруппы.ПустаяСсылка),
	Продукция.Количество,
	Продукция.Номенклатура,
	Продукция.ХарактеристикаНоменклатуры,
	Продукция.СерияНоменклатуры,
	Продукция.Спецификация,
	Продукция.Коэффициент
ИЗ
	Продукция КАК Продукция
ГДЕ
	Продукция.Заказ <> НЕОПРЕДЕЛЕНО

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	Продукция.СчетЗатрат,
	Продукция.СчетЗатратНУ,
	Продукция.ВидВыпуска,
	Продукция.Заказ,
	Продукция.НоменклатурнаяГруппа,
	Продукция.Заказ,
	Продукция.НоменклатурнаяГруппа,
	Продукция.Количество,
	Продукция.Номенклатура,
	Продукция.ХарактеристикаНоменклатуры,
	Продукция.СерияНоменклатуры,
	Продукция.Спецификация,
	Продукция.Коэффициент
ИЗ
	Продукция КАК Продукция
ГДЕ
	Продукция.Заказ <> НЕОПРЕДЕЛЕНО
	И Продукция.НоменклатурнаяГруппа <> ЗНАЧЕНИЕ(Справочник.НоменклатурныеГруппы.ПустаяСсылка)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КомплектующиеСпецификаций.Продукция,
	КомплектующиеСпецификаций.ХарактеристикаПродукции,
	ВыпускВариацииАналитик.СерияНоменклатуры КАК СерияПродукции,
	КомплектующиеСпецификаций.Спецификация,
	КомплектующиеСпецификаций.Номенклатура,
	КомплектующиеСпецификаций.ХарактеристикаНоменклатуры,
	КомплектующиеСпецификаций.КоличествоНаЕдиницу * ВыпускВариацииАналитик.Количество * ВыпускВариацииАналитик.Коэффициент КАК Количество,
	ВыпускВариацииАналитик.НоменклатурнаяГруппа,
	ВыпускВариацииАналитик.Заказ,
	ВыпускВариацииАналитик.СчетЗатрат,
	ВыпускВариацииАналитик.СчетЗатратНУ,
	ВыпускВариацииАналитик.ВидВыпуска,
	ВыпускВариацииАналитик.ЗаказВариации,
	ВыпускВариацииАналитик.НоменклатурнаяГруппаВариации
ПОМЕСТИТЬ КомплектующиеПродукции
ИЗ
	ВыпускВариацииАналитик КАК ВыпускВариацииАналитик
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ КомплектующиеСпецификаций КАК КомплектующиеСпецификаций
		ПО ВыпускВариацииАналитик.Номенклатура = КомплектующиеСпецификаций.Продукция
			И ВыпускВариацииАналитик.ХарактеристикаНоменклатуры = КомплектующиеСпецификаций.ХарактеристикаПродукции
			И ВыпускВариацииАналитик.Спецификация = КомплектующиеСпецификаций.Спецификация
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КомплектующиеПродукции.Номенклатура,
	КомплектующиеПродукции.ХарактеристикаНоменклатуры,
	КомплектующиеПродукции.СчетЗатрат,
	КомплектующиеПродукции.СчетЗатратНУ,
	КомплектующиеПродукции.ВидВыпуска,
	КомплектующиеПродукции.ЗаказВариации,
	КомплектующиеПродукции.НоменклатурнаяГруппаВариации,
	СУММА(КомплектующиеПродукции.Количество) КАК Количество
ПОМЕСТИТЬ ИтогКомплектующихПродукции
ИЗ
	КомплектующиеПродукции КАК КомплектующиеПродукции

СГРУППИРОВАТЬ ПО
	КомплектующиеПродукции.СчетЗатратНУ,
	КомплектующиеПродукции.ВидВыпуска,
	КомплектующиеПродукции.Номенклатура,
	КомплектующиеПродукции.ХарактеристикаНоменклатуры,
	КомплектующиеПродукции.СчетЗатрат,
	КомплектующиеПродукции.ЗаказВариации,
	КомплектующиеПродукции.НоменклатурнаяГруппаВариации
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВыпускВариацииАналитик.СчетЗатрат,
	ВыпускВариацииАналитик.СчетЗатратНУ,
	ВыпускВариацииАналитик.ВидВыпуска,
	ВыпускВариацииАналитик.ЗаказВариации,
	ВыпускВариацииАналитик.НоменклатурнаяГруппаВариации,
	СУММА(ВыпускВариацииАналитик.Количество) КАК Количество
ПОМЕСТИТЬ ИтогиВыпускаВариацииАналитик
ИЗ
	ВыпускВариацииАналитик КАК ВыпускВариацииАналитик

СГРУППИРОВАТЬ ПО
	ВыпускВариацииАналитик.СчетЗатрат,
	ВыпускВариацииАналитик.СчетЗатратНУ,
	ВыпускВариацииАналитик.ВидВыпуска,
	ВыпускВариацииАналитик.ЗаказВариации,
	ВыпускВариацииАналитик.НоменклатурнаяГруппаВариации
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Материалы.Номенклатура КАК Номенклатура,
	Материалы.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
	Материалы.СерияНоменклатуры КАК СерияНоменклатуры,
	ВЫРАЗИТЬ(Материалы.Количество * КомплектующиеПродукции.Количество / ИтогКомплектующихПродукции.Количество КАК ЧИСЛО(15, 3)) КАК Количество,
	КомплектующиеПродукции.Заказ,
	Материалы.Заказ КАК ЗаказНЗП,
	Материалы.ЕдиницаИзмерения,
	Материалы.Коэффициент,
	КомплектующиеПродукции.Спецификация КАК Спецификация,
	КомплектующиеПродукции.НоменклатурнаяГруппа,
	Материалы.НоменклатурнаяГруппа КАК НоменклатурнаяГруппаНЗП,
	Материалы.СтатьяЗатрат,
	КомплектующиеПродукции.Продукция КАК Продукция,
	КомплектующиеПродукции.ХарактеристикаПродукции КАК ХарактеристикаПродукции,
	КомплектующиеПродукции.СерияПродукции КАК СерияПродукции,
	КомплектующиеПродукции.СчетЗатрат,
	КомплектующиеПродукции.СчетЗатратНУ,
	Материалы.ПодразделениеНЗП,
	Материалы.ПодразделениеОрганизацииНЗП,
	Материалы.ВидВыпуска,
	Материалы.НомерСтроки КАК НомерСтрокиТабМатериалы
ИЗ
	КомплектующиеПродукции КАК КомплектующиеПродукции
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Материалы КАК Материалы
		ПО КомплектующиеПродукции.Номенклатура = Материалы.Номенклатура
			И КомплектующиеПродукции.ХарактеристикаНоменклатуры = Материалы.ХарактеристикаНоменклатуры
			И КомплектующиеПродукции.СчетЗатрат = Материалы.СчетЗатрат
			И КомплектующиеПродукции.СчетЗатратНУ = Материалы.СчетЗатратНУ
			И КомплектующиеПродукции.ВидВыпуска = Материалы.ВидВыпуска
			И КомплектующиеПродукции.НоменклатурнаяГруппаВариации = Материалы.НоменклатурнаяГруппа
			И КомплектующиеПродукции.ЗаказВариации = Материалы.Заказ
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИтогКомплектующихПродукции КАК ИтогКомплектующихПродукции
		ПО КомплектующиеПродукции.Номенклатура = ИтогКомплектующихПродукции.Номенклатура
			И КомплектующиеПродукции.ХарактеристикаНоменклатуры = ИтогКомплектующихПродукции.ХарактеристикаНоменклатуры
			И КомплектующиеПродукции.СчетЗатрат = ИтогКомплектующихПродукции.СчетЗатрат
			И КомплектующиеПродукции.СчетЗатратНУ = ИтогКомплектующихПродукции.СчетЗатратНУ
			И КомплектующиеПродукции.ВидВыпуска = ИтогКомплектующихПродукции.ВидВыпуска
			И КомплектующиеПродукции.НоменклатурнаяГруппаВариации = ИтогКомплектующихПродукции.НоменклатурнаяГруппаВариации
			И КомплектующиеПродукции.ЗаказВариации = ИтогКомплектующихПродукции.ЗаказВариации

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	Материалы.Номенклатура,
	Материалы.ХарактеристикаНоменклатуры,
	Материалы.СерияНоменклатуры,
	ВЫРАЗИТЬ(Материалы.Количество * ВыпускВариацииАналитик.Количество / ИтогиВыпускаВариацииАналитик.Количество КАК ЧИСЛО(15, 3)),
	ВыпускВариацииАналитик.Заказ,
	Материалы.Заказ,
	Материалы.ЕдиницаИзмерения,
	Материалы.Коэффициент,
	ВыпускВариацииАналитик.Спецификация,
	ВыпускВариацииАналитик.НоменклатурнаяГруппа,
	Материалы.НоменклатурнаяГруппа,
	Материалы.СтатьяЗатрат,
	ВыпускВариацииАналитик.Номенклатура,
	ВыпускВариацииАналитик.ХарактеристикаНоменклатуры,
	ВыпускВариацииАналитик.СерияНоменклатуры,
	ВыпускВариацииАналитик.СчетЗатрат,
	ВыпускВариацииАналитик.СчетЗатратНУ,
	Материалы.ПодразделениеНЗП,
	Материалы.ПодразделениеОрганизацииНЗП,
	Материалы.ВидВыпуска,
	Материалы.НомерСтроки
ИЗ
	ВыпускВариацииАналитик КАК ВыпускВариацииАналитик
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИтогиВыпускаВариацииАналитик КАК ИтогиВыпускаВариацииАналитик
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Материалы КАК Материалы
				ВНУТРЕННЕЕ СОЕДИНЕНИЕ МатериалыАнализИсп КАК МатериалыАнализИсп
				ПО Материалы.Номенклатура = МатериалыАнализИсп.Номенклатура
					И Материалы.ХарактеристикаНоменклатуры = МатериалыАнализИсп.ХарактеристикаНоменклатуры
					И (НЕ МатериалыАнализИсп.ЭтоКомплектующее)
			ПО (Материалы.СчетЗатрат = ИтогиВыпускаВариацииАналитик.СчетЗатрат)
				И (Материалы.СчетЗатратНУ = ИтогиВыпускаВариацииАналитик.СчетЗатратНУ)
				И (Материалы.ВидВыпуска = ИтогиВыпускаВариацииАналитик.ВидВыпуска)
				И (Материалы.Заказ = ИтогиВыпускаВариацииАналитик.ЗаказВариации)
				И (Материалы.НоменклатурнаяГруппа = ИтогиВыпускаВариацииАналитик.НоменклатурнаяГруппаВариации)
		ПО ВыпускВариацииАналитик.СчетЗатрат = ИтогиВыпускаВариацииАналитик.СчетЗатрат
			И ВыпускВариацииАналитик.СчетЗатратНУ = ИтогиВыпускаВариацииАналитик.СчетЗатратНУ
			И ВыпускВариацииАналитик.ВидВыпуска = ИтогиВыпускаВариацииАналитик.ВидВыпуска
			И ВыпускВариацииАналитик.ЗаказВариации = ИтогиВыпускаВариацииАналитик.ЗаказВариации
			И ВыпускВариацииАналитик.НоменклатурнаяГруппаВариации = ИтогиВыпускаВариацииАналитик.НоменклатурнаяГруппаВариации

УПОРЯДОЧИТЬ ПО
	НомерСтрокиТабМатериалы
...Показать Скрыть