gifts2017

Запрет редактирования проводок по определенным счетам

Опубликовал Александр Палий (duhh) в раздел Программирование - Практика программирования

Задача.  В финансовой службе часто сталкиваются с изменением проводок на счетах учета денежных средств задним числом. Необходимо запретить редактирование проводок по определенным счетам на определенную дату.

Решение задачи. 

Используемая конфигурация Инталев КМ6 (на самом деле неважно. Подход подойдет для любой конфигурации с Регистром бухгалтерии).

Создаем в конфигурации:

  1. Справочник для указания счетов и даты запрета (Сценарий - тонкость Инталева)
  2. Роль для изменения созданного справочника (по желанию)
  3. Подписку на событие для регистра бухгалтерии на событие перед записью. (Хозрасчетный также присутствует в источниках и отлично срабатывает, значит в обычной бухгалтерии тоже должно работать на ура) 
  4. Общий модуль. Со следующим содержанием. 
    Процедура Новард_РегистрБухгалтерииЗапретПроведенияПоСчетамПередЗаписью(Источник, Отказ, РежимЗаписи) Экспорт
    	
    	УстановитьПривилегированныйРежим(Истина);
    	
    	Попытка
    		ИмяРегистра     = Источник.Метаданные().Имя;
    		ЕстьСценарий    = Источник.Метаданные().Измерения.Найти("Сценарий") <> Неопределено;
    		ОтазВПроведении = Неопределено;
    		
    		//Проверить регистр до изменения
    		Набор = РегистрыБухгалтерии[ИмяРегистра].СоздатьНаборЗаписей();
    		Набор.Отбор.Регистратор.Установить(Источник.Отбор.Регистратор.Значение);
    		Набор.Прочитать();
    		
    		Если  Набор.Количество() > 0 Тогда
    			ОтазВПроведении = ПроверитьВозможностьИзменения(Набор, ЕстьСценарий);
    		КонецЕсли;
    		
    		//Проверить регистр после изменения
    		Если  Источник.Количество() > 0 и ОтазВПроведении = Неопределено Тогда
    			ОтазВПроведении = ПроверитьВозможностьИзменения(Источник, ЕстьСценарий);
    		КонецЕсли; 
    		
    		Если ОтазВПроведении <> Неопределено Тогда				
    			Отказ = Истина;
    			ТекстОтказа = "Проведение по счету "+ОтазВПроведении.Счет+" запрещено настройкой "+ОтазВПроведении.Ссылка;
    			Сообщить(ТекстОтказа,СтатусСообщения.Важное);
    			//ВызватьИсключение ТекстОтказа;
    		КонецЕсли;
    		
    	Исключение
    		Информация=ИнформацияОбОшибке();
    		ВызватьИсключение "Отмена проведения "+Источник+" не была выполнена:"+Символы.ПС+Информация.Описание;
    	КонецПопытки;
    	
    КонецПроцедуры
    
    Функция ПроверитьВозможностьИзменения(Источник, ЕстьСценарий)
    	
    	УстановитьПривилегированныйРежим(Истина);
    
    	ТаблицаПроводок = Источник.Выгрузить(,);
    	
    	Если Не ЕстьСценарий Тогда
    		ТаблицаПроводок.Колонки.Добавить("Сценарий",         Новый ОписаниеТипов("СправочникСсылка.Инт_Сценарии"));
    	КонецЕсли;	
    
    	ТаблицаПроводок.Свернуть("Период,Сценарий,СчетДТ,СчетКт");
    		
    	Запрос = Новый Запрос;
    	Запрос.Текст = "ВЫБРАТЬ
    	               |	Источник.Период,
    	               |	Источник.Сценарий,
    	               |	Источник.СчетДт,
    	               |	Источник.СчетКт
    	               |ПОМЕСТИТЬ ВТИсточник
    	               |ИЗ
    	               |	&Источник КАК Источник
    	               |;
    	               |
    	               |////////////////////////////////////////////////////////////////////////////////
    	               |ВЫБРАТЬ
    	               |	ВТИсточник.Период,
    	               |	ВТИсточник.СчетДт КАК Счет,
    	               |	ВТИсточник.Сценарий
    	               |ПОМЕСТИТЬ ВТСвернутыйИсточник
    	               |ИЗ
    	               |	ВТИсточник КАК ВТИсточник
    	               |
    	               |ОБЪЕДИНИТЬ
    	               |
    	               |ВЫБРАТЬ
    	               |	ВТИсточник.Период,
    	               |	ВТИсточник.СчетКт,
    	               |	ВТИсточник.Сценарий
    	               |ИЗ
    	               |	ВТИсточник КАК ВТИсточник
    	               |;
    	               |
    	               |////////////////////////////////////////////////////////////////////////////////
    	               |ВЫБРАТЬ
    	               |	Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Ссылка,
    	               |	Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Счет,
    	               |	Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Ссылка.ДатаВремяЗапрета
    	               |ИЗ
    	               |	Справочник.Новард_ДатыЗапретаПоСчетам.СчетаЗапрета КАК Новард_ДатыЗапретаПоСчетамСчетаЗапрета
    	               |		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТСвернутыйИсточник КАК ВТСвернутыйИсточник
    	               |		ПО Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Ссылка.ДатаВремяЗапрета > ВТСвернутыйИсточник.Период
    	               |			И Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Счет = ВТСвернутыйИсточник.Счет
    	               |			И (НЕ Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Ссылка.ПометкаУдаления)
    	               |			И Новард_ДатыЗапретаПоСчетамСчетаЗапрета.Ссылка.Сценарий = ВТСвернутыйИсточник.Сценарий";
    	
    	Запрос.УстановитьПараметр("Источник", ТаблицаПроводок);
    		
    	Результат = Запрос.Выполнить();
    	Выборка = Результат.Выбрать();
    	
    	Пока Выборка.Следующий() Цикл
    		Возврат Выборка;		
    	КонецЦикла;
    	
    	Возврат Неопределено;
    	
    КонецФункции	
p.s. Никаких изменений существующих объектов и модулей (снятие с поддержки не считается).

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Иван Ляхов (Alonarista) 11.09.15 09:08
ИМХО через регистр сведений будет работать быстрей, чем через справочник + при периодичном РСе можно без проблем устанавливать актуальность и активность запрета.
+ в конце можно переработать.
После выполнения запроса проверить его пустоту.
Если результат запроса не пустой - то отбирать результаты.
2. Александр Палий (duhh) 11.09.15 09:47
(1) Alonarista, Согласен, нужно всегда писать правильно, даже несмотря на то, что на фоне проведения эта проверка занимает менее процента.
3. Игорь Дзеса (Kamikadze) 11.09.15 10:03
А почему не регистр сведений?
mamanelli; Team leader; +2 Ответить 1
4. Александр Палий (duhh) 11.09.15 11:58
(3) Kamikadze, На моем количестве запретов по счетам, не даст значимого прироста в быстродействии. (1) уже ответил, согласен, правильней использовать регистр. вместо справочника.

5. Сергей Лямин (bydk) 19.09.15 13:19
Если ОтазВПроведении <> Неопределено Тогда 

ОтКаз? Опечатку поправьте...
6. Александр Палий (duhh) 20.09.15 01:01
(5) bydk, Действительно очепятался, и так шесть раз. Но так как на работоспособность алгоритма не влияет, оставлю как есть.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа