gifts2017

1С: 7.7. Функции-обертки, функторы, отложенный вызов, карринг параметров на примере функции чтения табличных данных

Опубликовал Рожков Дмитрий (rozhkovdmitriy) в раздел Программирование - Практика программирования

Человек, работающий в 1С, в силу своей практики и опыта может нуждаться в средствах программирования, в 1С не представленных. В публикации описаны средства отложенного вызова функций, каринга параметров, композиции и др., в основе которых лежит вызов функции посредством функции Шаблон. Несмотря на простоту, созданный за несколько лет работы в 1С 7.7 набор функций обрел мощь, достаточную для лаконичной реализации указанных целей.

Рассмотрение темы предлагается начать "от обратного".

Вниманию читателя предлагается вызов функции чтения табличных данных (xls,csv)

Функция мПрочитатьВходнойФайл(пКонтекстДокумента, пФайлЗагрузки, пРольАгентскойСхемы)
	лРасшФормы = глРасшФормы(пКонтекстДокумента.Форма);
	лТаблица = глСчитатьТабличныеДанные(пФайлЗагрузки
		, глСписок_("Признак-итога", 2, "ВидЗатрат", 6,"Счет", 6, "Сумма", 11, "Объект", 4, "РольАгентСхемы", 1)
		, глСписок_(
			  "Сумма", глСписок("->", глСписок("глЗаменить", "\.", "", ",", "."), глСписок("Число"))
			, "Объект", глСписок("->>", глСписок("глЭлементСправочника", "СПП"))
			, "ВидЗатрат", глСписок("->>", глСписок("глЭлементСправочника", "IBSВидыЗатрат"))
			, "Счет", глСписок("->>", глСписок("глЭлементСправочника", "IBSВидыЗатрат"), глСписок("глВызов_", глСписок("Реквизит", "БухСчет")))
			, "РольАгентСхемы", глСписок("->>", глСписок("глЗнач", пРольАгентскойСхемы))
			) 
		, глСписок_("Признак-итога", глСписок("ПустоеЗначение"))
		, глСписок("мНоваяСтрокаДокументаОстатки", пКонтекстДокумента)
		, 4);
КонецФункции // ПрочитатьВходнойФайл

Функция мПрочитатьВходнойФайл вызывается из документа "Ввод остатков" конфигурации БУ. При вызове происходит передача контекста документа, который используется для заполнения табличной части вызывающего документа содержимым excel или csv файла.

Таким образом, функция мПрочитатьВходнойФайл  дублируется в нескольких внешних обработках, реализуя множество способов построения документа "Ввод остатков" через интерфейсную функцию мПрочитатьВходнойФайл, каждая из которых производит чтение, преобразование и проверку разнородных табличных данных (паттерн "Строитель")

Используемая функция глСчитатьТабличныеДанные является реализацией паттерна стратегия. Производится чтение произвольного файла табличных данных, указание целевых полей, функций проебразования, проверки и конечной обработки строки данных исходя из целесообразности решаемой бизнес-функции, строка, с которой следует начинать чтение.

Предлагается рассмотреть используемые функции-обертки подробней. Сначала фигурирующие в мПрочитатьВходнойФайл и далее те, что находятся "под капотом"

глСписок

Функция глСписок( пЗнач1 = "дефолт",  пЗнач2 = "дефолт",  пЗнач3 = "дефолт", ..., пЗнач43 = "дефолт") Экспорт

Функция глСписок является оберткой для создания объекта "СписокЗначений" в одну строку, также поддерживается хранение типизированных пустых значений.

Пример:
лСписок = глСписок(1, 2, 4, "stuf stuf stuf",, ПолучитьПустоеЗначение("Справочник.Номенклатура"));

глСписок_

Функция глСписок_(знач пСтрока1 = 0, пЗнач1 = "дефолт",  знач пСтрока2 = 0, пЗнач2 = "дефолт", ..., знач пСтрока43 = 0, пЗнач43 = "дефолт") Экспорт

Функция глСписок является оберткой для создания объекта "СписокЗначений" в одну строку. Дополнительно указываются строковые представления хранимых в списке значений.

Пример:
лСписок = глСписок_("фамилия", "Рожков", "имя", "Дмитрий",  "отчество", "Сергеевич", "возраст", 30)

глВызов_

Функция глВызов_(знач пФунктор, знач пАргумент, знач пВКонец = 0)

Реализует отложенный вызов функции, переданной в первом параметре. На второй позиции передается аргумент, располагающийся в вызываемом функторе в качестве первого параметра по умолчанию. Если  пВКонец не равно нулю, то пАргумент будет размещен в конце списка параметров пФуктор.

Функтор

Функтором в представленной организации исполнительной среды является объект типа "СписокЗначений", на первой позиции которого хранится строковое наименование вызываемой функции, в оставшейся части списка поочередно размещаются параметры указанной на первой позиции функции. Вызов алгоритмов обработки любых коллекций ("СписокЗначений", "ТаблицаЗначений", файл excel, "Справочник.ХХХ" и др.) подразумевает передачу в обобщенный алгоритм функтора и дальнейшую последовательную подстановку в него i-того элемента коллекции по аналогии с функциями стандартной библиотеки высокоуровневых языков foreach, accumulate, map_reduce, sort, filter, transform, search и др. Как правило, производится подстановка на вторую позицию в списке, сразу после имени функции, при вызове подставленное значение окажется на первой позиции списка аргументов функции. Почти во всех таких абстракциях присутствует вызов глВызов_. Например функция глВызов (без знака подчеркивания) реализована при её помощи.

глВызов

Функция глВызов(знач пФунктор) Экспорт
	Перем лРезульт;
	Если ТипЗначенияСтр(пФунктор) <> "СписокЗначений" Тогда
		Возврат пФунктор;
	КонецЕсли;
	Шаблон("[глПрисвоить(лРезульт, " + глРазвернутьФунктор(пФунктор,, "пФунктор", 1) + ")]");
	Возврат лРезульт;
КонецФункции // глВызов
Функция глРазвернутьФунктор(пФунктор, знач пПервыеАргументы = "", знач пИмяФунктора, знач пБезСкобок = 0) Экспорт
    лРазмер = пФунктор.РазмерСписка();
    
    лНаимФункц = пФунктор.ПолучитьЗначение(1);
    
    Если "->" = лНаимФункц Тогда 
        пФунктор.УстановитьЗначение(1, "Композиция");
    КонецЕсли;

    Если "->>" = лНаимФункц Тогда 
        пФунктор.УстановитьЗначение(1, "Композиция_");
    КонецЕсли;
    
    лВызовУсловия = ?(пБезСкобок <> 0, "", "[") + пФунктор.ПолучитьЗначение(1) + "(" + пПервыеАргументы
                        + ?(лРазмер > 1, ?(ПустаяСтрока(пПервыеАргументы) = 0, ", ", ""), "");
    лАргументы = глСписок();
    Если пФунктор.РазмерСписка() > 1 Тогда
        пФунктор.Выгрузить(лАргументы, 2);
    КонецЕсли;

    Возврат лВызовУсловия + глРазвернутьАргументы(лАргументы, пИмяФунктора, 1) + ")" + ?(пБезСкобок <> 0, "", "]");
КонецФункции // глРазвернутьФунктор
Функция глРазвернутьАргументы(знач пСписок, знач пИмяСписка, знач пСмещение = 0) Экспорт
	лРазмер = пСписок.РазмерСписка();
	лСтрВызова = "";
	Для ит = 1 по лРазмер Цикл
		лСтрока = "";
		лЗначение = глЗначениеСписка(пСписок, ит, лСтрока);
		лСтрВызова = лСтрВызова +  ", " + ?(НепустоеЗначение(лЗначение) = 0, "Пуст(""" + лСтрока + """)"
			, Шаблон("глЗначениеСписка([пИмяСписка], [ит + пСмещение])"));
	КонецЦикла;
	Возврат Сред(лСтрВызова, 3);
КонецФункции // глРазвернутАргументы

Функция глВызов производит "развертывание" функтора в строковое представление, интерпретируемое впоследствии вызовом Шаблон

Шаблон("[глПрисвоить(лРезульт, " + глРазвернутьФунктор(пФунктор,, "пФунктор", 1) + ")]");

Считается, что аргументы функтора, как и её название, хранятся в переменной пФунктор. Исходя из этого знания происходит развертывание. В глРазвернутьФунктор передается не только его содержание, но и наименование переменной, представленное в контексте исполнения. После работы функций глРазвернутьФунктор и глРазвернутьАргументы в контексте глВызов оказывается пригодная для выполнения в Шаблоне строка вызова. Например, подстановка в табло операций развёртывания функторов даст следующие результаты:

глРазвернутьФунктор(глСписок("ок", "Привет мир!!!"),, "пФунктор", 1)  = ок(глЗначениеСписка(пФунктор, 2))
глРазвернутьФунктор(глСписок("->>", глСписок("глЭлементСправочника", "СтавкиНДС", "V1")),, "пФунктор", 1) 
	= Композиция_(глЗначениеСписка(пФунктор, 2))

Композиция, Композиция_ ("->", "->>")

Функция Композиция создана исключительно для "заворачивания" и хранения её в функторе. Прямой вызов этой функции вне функций обхода коллекций нецелесообразен.

Отложенный вызвов функций Композиция ("->") и Композиция_ ("->>") подразумевает уже упомянутую передачу в них в качестве первого аргумента i-го элемента коллекции. Функция композиция производит последовательное выполнение функторов переданных в качестве параметров. На вход первого функтора подается i-й элемент обрабатываемой в текущий момент коллекции.

Композиция ("->") отличается от Композиция_ ("->>") тем, что в первом случае переданный начальный параметр всегда размещается как первый аргумент цепочки функторов, а во втором как последний. Очень редко может понадобиться размещение входного параметра в цепочке функторов на иной позиции - для этого следует использовать функции глСместАргСлева(Справа). Сказанное наглядно иллюстрирует исходный код функции композиция и пример.

Функция Композиция(знач пИскомое, знач пф1 = 0, знач пф2 = 0, знач пф3 = 0, знач пф4 =0, знач пф5 = 0) Экспорт
	лРезультат = пИскомое;
	лФункторы = глСписок();
	Если пф1 <> 0 Тогда лФункторы.ДобавитьЗначение(пф1); КонецЕсли;
	Если пф2 <> 0 Тогда лФункторы.ДобавитьЗначение(пф2); КонецЕсли;
	Если пф3 <> 0 Тогда лФункторы.ДобавитьЗначение(пф3); КонецЕсли;
	Если пф4 <> 0 Тогда лФункторы.ДобавитьЗначение(пф4); КонецЕсли;
	Если пф5 <> 0 Тогда лФункторы.ДобавитьЗначение(пф5); КонецЕсли;
	
	лРазмер = лФункторы.РазмерСписка();
	Для ит = 1 по лРазмер Цикл
		лФунктор = лФункторы.ПолучитьЗначение(ит);
		Если лФунктор = 0 Тогда Прервать; КонецЕсли; 
		лРезультат = глВызов(глВставитьВСписок(лФунктор, лРезультат, 2));
	КонецЦикла;
	Возврат лРезультат;
КонецФункции // Композиция

Пример:

Установлено, что в справочнике "СПП" по коду "test-test-test" хранится строка, в которой среди прочего мусора хранится дата ("Элемент справочника СПП - дата х . 17.09.2015 --"), которую необходимо изъять и преобразовать в тип Дата:

глВызов_(
    глСписок("->>"
        , глСписок("глЭлементСправочника", "СПП")
        , глСписок("Строка")
        , глСписок("глСместАргСправа" // сместить аргумент справа в указанную позицию (1)
            , глСписок("глЗаменить", ".*(\d{2}\.\d{2}\.\d{2,4}).*", "$1"), 1)
        , глСписок("Дата"))
    , "test-test-test") = 17.09.15

Таким образом происходит "отложенный" (при вызове из Табло отложенный совсем чуть-чуть) вызов цепочки функций глЭлементСправочника,Строка,глЗаменить,Дата. Пример является надуманным и в реальной практике такие сложные вызовы встречаются примерно никогда и скорее вредны с точки зрения возможности поддержания кода коллегами. Оптимальным решением является обработка коллекций при помощи несложных простых или более сложных составных функторов на основе композиции.

В заключение

Поводом для статьи послужили несколько причин.

К сожалению, некоторые разработчики на 1С и не только придерживаются в своей практике принципа простоты, считая что для создания хороших програм достаточно операторов Если...ИначеЕсли...Иначе...Тогда, Для..Цикл..КонецЦикла. Практика показала, что исходные коды, созданые без применения минимальных абстракций, стремятся в к высоким величинам по показателям длина кода функции и вложенность условий. Любовь к ремеслу вызывает стремление показать заинтересованному читателю, что можно писать на 1С лаконичней, интересней и продуктивней.

Синтаксис 1С не предоставляет указанных абстракций, так сильно облегчающих жизнь программиста.

Нежелание хоронить результат своей работы ...

Весь описанный функционал сохранен в приложенном к публикации zip архиве, буду безмерно рад, если кому-нибудь пригодится.

Еще примеры:

Объединение списков периодов

В примере рассматривается объединение списков периодов, являющихся списком троек хранящих начальную и конечную даты. Период также характеризуется вещественным коэффициентом, применяемым в вычислениях на списке периодов. В простейшем случае коэффициент периода равен единице. При объединении списка периодов производится удаление дублей по пересекающимся участкам с последующей сортировкой.

Функция глОбъединитьСпискиПериодов(знач пА, знач пБ, знач пМетодУчетаКоэфПересеч = 1) Экспорт
	лРазнАБ = глРазностьСписковПериодов(пА, пБ);
	лРазнБА = глРазностьСписковПериодов(пБ, пА);
	лПересАБ = глПересеченияСписковПериодов(пА, пБ, пМетодУчетаКоэфПересеч);
	лОбъединение = глСортироватьСписокЗначений(глОбъединитьСписки(глОбъединитьСписки(лРазнАБ, лРазнБА), лПересАБ), глСписок("глПериодРаньше"));

        //... обработка коэффициентов
КонецФункции
Функция глПериодРаньше(знач пВрПер1, знач пВрПер2) Экспорт
	Возврат ?(пВрПер1.ПолучитьЗначение(1) < пВрПер2.ПолучитьЗначение(1), 1, 0);
КонецФункции // глПериодРаньше

Обход справочника, копирование стажей

Рассмотрено копирование стажей по всему справочнику сотрудников при помощи вызова глОбходСправочника. Стажи хранятся в отдельном подчиненном сотрудникам справочнике.

глФильтрСправочника("Сотрудники"
	, глСписок("глСкопироватьСтажи", Перечисление.ВидСтажа.ВОтрасли, 1, 0.85, Перечисление.ВидСтажа.МММ),,,0);
Функция глСкопироватьСтажи(знач пСотрудник, знач пВидСтажаИЗ, знач пРучнСтажиИз, знач пКоэф, знач пВидСтажаВ, знач пОчист = 0) Экспорт ...

По типу стажа источника выбираются записи с указанным, если он задан, коэффициентом из соответсвующего справочника. Система разделяет стажи ручные и производные (вычиляемые из других), поэтому дополнительно указывается производить ли поиск ручных записей в справочнике стажей или же принять производные стажи по указанному типу. Производится копирование записей по указанному источнику в справочник стажей по целевому типу с возможностью предварительной очистки.

Фильтр списка сотрудников

Интересный пример выборки сотрудников с достаточным стажем и не перерботавших более полугода после возраста права гос. пенсии для назначения негосударственной пенсии.

Возврат глФильтрСпискаПоИ(лСостав
	, глСписок("->", глСписок("СтажГазпромРКСПриУвольнении"), глСписок("больше", 14))
	, глСписок("НеПереработал"));

Фильтр таблицы, получение строк таблицы по типу документа

Пример заключается в фильтрации строчек таблицы значений, имеющей колонку "Документ", по типу "НачислениеОтпуска".  Сразу оговорюсь, что большие возможности по работе с таблицами нам открывает индексированная таблица. Однако, при некритических требованиях к производительности подобные конструкции вполне жизнеспособны.

Функция ПечатьРасходов_ФСС_НС(знач пРасходыЗаСчет_ФСС_НС)
	лТаблица = глТаблица("4ФСС_Расходы_ФССНС");
	лТаблица.Вывести();
	
        // ... предварительная подготовка

	лРасходыЗаСчет_ФСС_НС = глФильтрТаблциы(пРасходыЗаСчет_ФСС_НС, глСписок("Композиция"
			, глСписок("глЗначениеКолонки", "Документ")
			, глСписок("глВидДокумента")
			, глСписок("равно", "НачислениеОтпуска")));
  
       // ... обработка отфильтрованной таблицы
КонецФункции

https://yadi.sk/d/2SrdDsVGj9T7y

Скачать файлы

Наименование Файл Версия Размер Кол. Скачив.
Конфигурация, содержащая весь описанный набор функций
.zip 291,75Kb
18.09.15
4
.zip 291,75Kb 4 Скачать

См. также

Подписаться Добавить вознаграждение

Комментарии

1. MaxDavid (MaxDavid) 17.09.15 14:59
К сожалению, некоторые разработчики на 1С и не только придерживаются в своей практике принципа простоты, считая что для создания хороших програм достаточно операторов Если...ИначеЕсли...Иначе...Тогда, Для..Цикл..КонецЦикла.
Простота обуславливает низкий порог вхождения и, как следствие, массовость, что для 1С актуальнее красоты и продуктивности кода.

Но подход интересный, на досуге посмотрю ))
2. Сергей (Che) Коцюра (CheBurator) 17.09.15 23:08
Приведите плиз не пример самих функций а пару кусков кода с использованием этих возможностей/функций для текущей работы
3. Рожков Дмитрий (rozhkovdmitriy) 18.09.15 09:12
(2) CheBurator, добавил несколько примеров
4. Владислав Чинючин (vcv) 18.09.15 13:00
Подход интересный. Но боюсь, быстродействие будет сильно страдать.
Возврат глФильтрСпискаПоИ(лСостав
, глСписок("->", глСписок("СтажГазпромРКСПриУвольнении"), глСписок("больше", 14))
, глСписок("НеПереработал"));

Если уж пользуетесь активно функцией Шаблон, то почему бы не сделать более простой синтаксис?
Что-то типа такого:
глФильтрСпискаЗначений(лСписок,"($.СтажГазпромРКСПриУвольнении>14)И($.НеПереработал=1)")

где $ обозначает текущий объект перебираемой коллекции.
5. Рожков Дмитрий (rozhkovdmitriy) 18.09.15 14:33
(4) vcv, Спасибо за интерес к теме

Подход интересный. Но боюсь, быстродействие будет  сильно страдать.


Думаю что страдает, незначительно. Профилировщик на мегаотчетах каких либо значимых процентов на подобных запусках не показывал. Как показала практика, проседание происходит не в местах применения функторов в шаблонах.

Если уж пользуетесь активно функцией Шаблон, то почему бы не сделать более простой синтаксис?
Что-то типа такого:

глФильтрСпискаЗначений(лСписок,"($.СтажГазпромРКСПриУвольнении>14)И($.НеПереработал=1)")


Я согласен с Вами, vcv, предложенный вид хорош и вполне себе реализуем для фильтра коллекции, но к сожалению не вписывается во всё разнообразие возможных вызовов.

Предложенная строка заработает в Шаблоне если на лету будет создан некий КОП (класс определенный пользователем), перенаправляющий вызовы через точку, а все остальные возможные аргументы, с учетом своих позиций в целевой функции, будут сохранены в объекте класса до своего вызова(И они тоже должны быть указаны в строке шаблона). Вопрос, позиции аргумента, в которую передается текущий элемент тоже открыт, его надо будет прописать в строке шаблона и элегантно распарситься не превратившись в дополнительный язык запросов 7.7 :). Как реализовать композицию и шифтинг, возвращаемого параметра на другую позицию?

Рождается больше вопросов чем ответов. Прошу меня поправить, если я во всем и не прав :)

глФильтрСпискаЗначений(лСписок,"($.СтажГазпромРКСПриУвольнении(прм1, прм2..., прмN)>14)И($.НеПереработал(прм1, прм2..., прмN)=1)")

Идея использования функторов, для лаконичного представления кода не нова, как и все парадигмы, которые я попросту попытался перенести в 1С без изменений, вероятно вы знаете про это.

Существующие реализации:

c++ (https://en.cppreference.com/w/cpp/utility/functional) ,
lisp (http://clojuredocs.org/clojure.core/sort)
javascript,actionscript - там нет явной подстановки операторов, зато лямбда-функции создаются на лету (http://javascript.ru/Function)

p.s. Были мысли перевести вызов функций на ВыполнитьФункцию объекта "Сервис" из FormEx, но что-то мне тогда помешало

Спасибо!
6. Brr (brr) 18.09.15 14:59
Вместо строки, с возможными опечатками, завести переменную, например, глСкопироватьСтажи = "глСкопироватьСтажи".

Вот и передача функции параметром.

Костыль конечно.
7. bulpi bulpi (bulpi) 18.09.15 22:02
Как то Грибоедов написал "Горе от ума". Само произведение плевенькое, но название зачетное. Очень подходит для таких вот "произведений". Особенно доставляет поддержка таких вот конфигураций после ухода автора. Если бы проклятия обладали материальной силой, Вам, автор, пришлось бы очень плохо. Долго бы болели и умерли нехорошей смертью.
8. Владислав Чинючин (vcv) 19.09.15 12:41
(7) bulpi, Проблема с поддержкой есть. Во многом она объясняется прямолинейностью мышления среднего 1Сника, не воспринимающего приёмов программирования, распространённых в других языках. Но проблему с поддержкой это не облегчает.
Мне больше не нравится проблема с проверкой кода. Синтаксический контроль в 7.7 и так прост и туп как доска, а тут у его еще и отбирают возможность проверить имя функции и количество параметров.
Я вот недавно занялся противоположным (в некоторой степени) вопросом. Как проверить еще что-нибудь в дополнение к синтаксическому контролю. Первый вариант прост и туп, но уже помог выловить ряд потенциально проблемных мест в большом рабочем проекте.
9. Рожков Дмитрий (rozhkovdmitriy) 21.09.15 06:20
(7) bulpi, "горе от ума", вы правы, крыть нечем :)
10. Рожков Дмитрий (rozhkovdmitriy) 21.09.15 06:25
(8) vcv, добрый день, использую прототипирование в табло чтобы проверять работоспособность написанного, всегда "проваливаюсь" в функцию по ctrl-Enter чтобы посмотреть количество параметров.
11. Котэ Пруидзе (kote) 21.09.15 11:09
Идея хорошая.
Но реализация - плохая..

И не то, что бы у Вас плохая - не знаю, можно ли удобнее сделать в 1С.. убогость языка, конечно, убивает. Особенно после того, как пощупаешь python или ruby - хочеться более гибкого языка.
autotrade; +1 Ответить
12. Рожков Дмитрий (rozhkovdmitriy) 22.09.15 07:49
13. Brr (brr) 22.09.15 10:39
По конфигурации. Вроде как рекомендуется 1с++ грузить первой.
14. MaxDavid (MaxDavid) 22.09.15 20:31
Впечатление двойственное, честно говоря. Можно, конечно, попытаться и Лисп реализовать на 1С, но... но...
Я сам одно время думал, как средствами 1С реализовать нечто похожее на мою юношескую любовь - Forth ))
15. Антон Рощин (wolfsoft) 23.09.15 09:12
(8) vcv,
Во многом она объясняется прямолинейностью мышления среднего 1Сника, не воспринимающего приёмов программирования, распространённых в других языках.


Нет, она объясняется тем, что обычные заказчики не хотят оплачивать специалиста стоимостью 200к в месяц. Плюсанул к "горю от ума", ибо приходилось иногда разгребать такие витиеватые коды, мама не горюй... причём за счёт заказчика...

PS: Особенно нравится одна самописная конфа - судя по коду, её явно писали люди, которые программировали до этого на фокспро, а тут заказчик потребовал написать конфу на 1с. 1с при этом они первый раз увидели, в результате чего нагромоздили такого, за что их периодически хочется побить. А самое грустное, что заказчик уже привык к такому и другого видеть не желает, поневоле приходится продолжать в том же духе.. ))
16. Антон Рощин (wolfsoft) 23.09.15 09:14
Ну, а так в целом, как разминка для ума, конечно, интересно :) В принципе, если функция работает и хорошо задокументирована, то почему бы и нет. Просто использовать её, не вникая в реализацию.
17. Петр Самчук (Frogger1971) 23.09.15 09:44
самое главное в публикации начинается после
- "продвинутый" код 1С 7.7
18. Рожков Дмитрий (rozhkovdmitriy) 23.09.15 14:29
Спасибо за критику, друзья!

В оправдание своего решения позволю себе процитировать самого себя.

Пример является надуманным и в реальной практике такие сложные вызовы встречаются примерно никогда и скорее вредны с точки зрения возможности поддержания кода коллегами. Оптимальным решением является обработка коллекций при помощи несложных простых или более сложных составных функторов на основе композиции.


Замечу также, что в неумелых руках и обычный синтаксис 1С превращается в кучу макарон, как и стремление накрутить функтор посложней и повложенней.
Знание меры позволит писать приятней и эффективней и радовать своих коллег, простыми и лаконичными решениями.

Нет, она объясняется тем, что обычные заказчики не хотят оплачивать специалиста стоимостью 200к в месяц. Плюсанул к "горю от ума", ибо приходилось иногда разгребать такие витиеватые коды, мама не горюй... причём за счёт заказчика...


Если бы я был заказчиком, я бы тоже с осторожностью относился к *витиеватым* кусочкам кода соискателей. Ключевым словом, уважаемый woflsoft, является "витиеватые коды". Сам перелопатил, тонны такого кода, в зарплатной конфигурации, написанного тёмными силами, работающими в не менее тёмных застенках компании 1С и кода, написанного за счет моего предприятия, именитыми аутсорсинговыми компаниями-подрядчиками. Надеюсь вы не будете оппонировать отложенным вызовам и возьмете их на вооружение при сохранении требования отсутствия витиеватости.

В принципе, если функция работает и хорошо задокументирована, то почему бы и нет.


Спасибо, так и есть, берем и пользуемся. Документация в шапках функций. Мои коллеги, их двое, не используют предложенные механизмы, но и по голове мне тоже не стучат, вполне себе могут править мои куски.
Более того, при обсуждении всплыл например такой вопрос - "Что проще, отложенные вызовы или прямые запросы из 1С++". И то и другое - инструмент. В первом случае надо иметь опыт работы с функторами на одном из ЯП высокого уровня, в другом - иметь опыт работы с SQL
19. aspirator 23 (aspirator23) 26.09.15 14:34
Поддержу автора. Мне такой подход ближе, чем километровые "портянки" из простых, а главное повторяющихся конструкций в коде. Которые да, легче поддерживать, но как то не вызывают чувства гармонии. Хотя, пожалуй, гармония мало подходит к коду. Но однотипные функции в разных местах - это уж точно не то чем стоит гордиться.
20. MaxDavid (MaxDavid) 26.09.15 19:56
(19) aspirator23, видите ли, в чем дело. Фикси всегда доделывают конфу в соответствии со своими представлениями о красоте кода. Это нормально, их не в чем упрекнуть. Беда в том, что рано или поздно появляется человек, которому во всей этой красоте приходится разбираться. Даже топикстартер, при всем моем уважении и при всей его пунктуальности, допустил как минимум одну ошибку в документировании функций. Будь вы на месте руководителя, стали бы вы оплачивать приходящему 1Снику время, затраченное на вникание в красоту стороннего кода? ))
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа