gifts2017

Проблемы учёта по счёту ГТД в Бухгалтерии Предприятия 3.0

Опубликовал Дмитрий Конаков (dkonakov) в раздел Программирование - Практика программирования

После перехода с БП 2.0 на БП 3.0 я столкнулся с весьма неприятной проблемой. Программа перестала сообщать о незаполненных номерах ГТД в Реализации товаров и услуг. Проводка просто не формировалась по счёту ГТД без какого-либо сообщения. О методике решения я расскажу в этой публикации.

Задав вопросы на форумах и не получив ни одного ответа, опросил бухгалтеров, и была поставлена следующая задача. 

1. При проведении отображать информационное сообщение о том, что не заполнен номер ГТД, хотя должен.

2. При проведении отображать информационное сообщение о том, что не хватает остатка по текущему номеру ГТД.

Разумеется, можно использовать  http://infostart.ru/public/140232/ , но это спасёт, если не менять документы задним числом.

При перепроведении документов хотелось бы видеть такие ошибки.


Я открыл код БП 2.0, и вот что получилось.

1. Для БП 3.0 создаём общий модуль (на сервере).

Листинг:

Процедура ПроведениеДокументаСписанияПоСчетуГТД(Документ, ТаблицаПоТоварам, СодержаниеПроводки = "Списаны МПЗ") Экспорт
	
	ТоварыПоНомерамГТД = Новый ТаблицаЗначений;
	ТоварыПоНомерамГТД.Колонки.Добавить("Номенклатура");
	ТоварыПоНомерамГТД.Колонки.Добавить("НомерГТД");
	ТоварыПоНомерамГТД.Колонки.Добавить("СтранаПроисхождения");
	ТоварыПоНомерамГТД.Колонки.Добавить("Количество");
	
	ДатаДок = Документ.Дата;
	Организация = Документ.Организация;
	Проводки = Документ.Движения.Хозрасчетный;
	
	// Формирование параметров отбора для запроса.
	СписокНоменклатуры = Новый Массив;
	СписокНомеровГТД = Новый Массив;
	СписокСтранПроисхождения = Новый Массив;
	
	Для каждого СтрокаТЧ из ТаблицаПоТоварам Цикл
		
			 Если НеУказанНомерГТД(СтрокаТЧ.НомерГТД,СтрокаТЧ.СтранаПроисхождения) Тогда
	             ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Неверно заполнены данные по ГТД в строке "+СтрокаТЧ.НомерСтроки+"");
			 КонецЕсли;

		
		
		Если ЭтоИмпортныйТовар(СтрокаТЧ.СчетУчета, СтрокаТЧ.НомерГТД, СтрокаТЧ.СтранаПроисхождения) Тогда
	
			
			
			
			СписокНоменклатуры.Добавить(СтрокаТЧ.Номенклатура);
			СписокНомеровГТД.Добавить(СтрокаТЧ.НомерГТД);
			СписокСтранПроисхождения.Добавить(СтрокаТЧ.СтранаПроисхождения);
			
			ТоварПоНомеруГТД = ТоварыПоНомерамГТД.Добавить();
			ТоварПоНомеруГТД.Номенклатура = СтрокаТЧ.Номенклатура;
			ТоварПоНомеруГТД.НомерГТД = СтрокаТЧ.НомерГТД;
			ТоварПоНомеруГТД.СтранаПроисхождения = СтрокаТЧ.СтранаПроисхождения;
			ТоварПоНомеруГТД.Количество = СтрокаТЧ.Количество;
			
		КонецЕсли;
		
	КонецЦикла;
	
	Если СписокНоменклатуры.Количество() = 0 Тогда
		Возврат;
	КонецЕсли;

	Запрос = Новый Запрос(
	"ВЫБРАТЬ
	|	ХозрасчетныйОстатки.Субконто1 КАК Номенклатура,
	|	ХозрасчетныйОстатки.Субконто2 КАК НомерГТД,
	|	ХозрасчетныйОстатки.Субконто3 КАК СтранаПроисхождения,
	|	ХозрасчетныйОстатки.КоличествоОстатокДт КАК Количество
	|ИЗ
	|	РегистрБухгалтерии.Хозрасчетный.Остатки(
	|		&Период,
	|		Счет = &СчетУчетаНомеровГТД,
	|		&Видысубконто,
	|			Субконто1 В (&СписокНоменклатуры)
	|			И Субконто2 В (&СписокНомеровГТД)
	|			И Субконто3 В (&СписокСтранПроисхождения)
	|			И Организация = &Организация) КАК ХозрасчетныйОстатки");

	Запрос.УстановитьПараметр("Период", Документ.МоментВремени());
	Запрос.УстановитьПараметр("Организация", Организация);
	Запрос.УстановитьПараметр("СчетУчетаНомеровГТД", ПланыСчетов.Хозрасчетный.ГТД);
	Запрос.УстановитьПараметр("СписокНоменклатуры", СписокНоменклатуры);
	Запрос.УстановитьПараметр("СписокНомеровГТД", СписокНомеровГТД);
    //ОбщегоНазначения.УдалитьПовторяющиесяЭлементы(СписокСтранПроисхождения);
	ОбщегоНазначенияБПВызовСервера.УдалитьПовторяющиесяЭлементыМассива(СписокСтранПроисхождения);
	
	Запрос.УстановитьПараметр("СписокСтранПроисхождения", СписокСтранПроисхождения);
	ВидыСубконто = ПланыСчетов.Хозрасчетный.ГТД.ВидыСубконто.ВыгрузитьКолонку("ВидСубконто");
	Запрос.УстановитьПараметр("ВидыСубконто", ВидыСубконто);
	
	Остатки = Запрос.Выполнить();
	ВыборкаОстатков = Остатки.Выбрать();
	
	ТоварыПоНомерамГТД.Свернуть("Номенклатура,НомерГТД,СтранаПроисхождения", "Количество");
	СтруктураПоиска = Новый Структура("Номенклатура,НомерГТД,СтранаПроисхождения");
	
	ОтключитьКонтрольОстатков = Константы.ОтключитьКонтрольОтрицательныхОстатков.Получить();
	
	Для каждого ТоварПоНомеруГТД из ТоварыПоНомерамГТД Цикл
		
		СтруктураПоиска.Номенклатура = ТоварПоНомеруГТД.Номенклатура;
		СтруктураПоиска.НомерГТД = ТоварПоНомеруГТД.НомерГТД;
		СтруктураПоиска.СтранаПроисхождения = ТоварПоНомеруГТД.СтранаПроисхождения;
		
		УчетноеКоличество = 0;
		ВыборкаОстатков.Сбросить();
		Пока ВыборкаОстатков.НайтиСледующий(СтруктураПоиска) Цикл
			УчетноеКоличество = УчетноеКоличество + ВыборкаОстатков.Количество;
		КонецЦикла;
		
		КоличествоВПроводке = Мин(УчетноеКоличество, ТоварПоНомеруГТД.Количество);
		
		Если КоличествоВПроводке < ТоварПоНомеруГТД.Количество Тогда
			СтрокаНачалаСообщенияОбОшибке = "Для номенклатуры """+ СокрЛП(ТоварПоНомеруГТД.Номенклатура) + """ в табличной части ""Товары"" ";
			СтрокаСообщения = "по счету ГТД определен остаток "+УчетноеКоличество+" ед. "+ТоварПоНомеруГТД.Номенклатура+" из необходимых "+ТоварПоНомеруГТД.Количество+" ед.";
			ОбщегоНазначенияКлиентСервер.СообщитьПользователю(СтрокаНачалаСообщенияОбОшибке + СтрокаСообщения);
		КонецЕсли;
		
		КоличествоСписать = ?(ОтключитьКонтрольОстатков, ТоварПоНомеруГТД.Количество, КоличествоВПроводке);
		
		
		
	КонецЦикла;
	
КонецПроцедуры // ПолучитьОстаткиПоНомерамГТД()


Функция ЭтоИмпортныйТовар(СчетУчета, НомерГТД, СтранаПроисхождения) Экспорт

	Если НЕ ЗначениеЗаполнено(СтранаПроисхождения) или
		 СтранаПроисхождения = Справочники.СтраныМира.РОССИЯ или
		 НЕ ЗначениеЗаполнено(НомерГТД) Тогда
		 
		Результат = Ложь;
		
		ИначеЕсли СчетУчета.ПринадлежитЭлементу(ПланыСчетов.Хозрасчетный.ТоварыНаСкладах) или
		 СчетУчета = ПланыСчетов.Хозрасчетный.ТоварыНаСкладах или
		 
		 СчетУчета.ПринадлежитЭлементу(ПланыСчетов.Хозрасчетный.ТоварыВРозничнойТорговле) или
		 СчетУчета = ПланыСчетов.Хозрасчетный.ТоварыВРозничнойТорговле или
		 
		 СчетУчета.ПринадлежитЭлементу(ПланыСчетов.Хозрасчетный.ТоварыПринятыеНаКомиссию) или
		 СчетУчета = ПланыСчетов.Хозрасчетный.ТоварыПринятыеНаКомиссию или
		 
		 СчетУчета.ПринадлежитЭлементу(ПланыСчетов.Хозрасчетный.ТоварыВРозничнойТорговлеВПродажныхЦенахАТТ) или
		 СчетУчета = ПланыСчетов.Хозрасчетный.ТоварыВРозничнойТорговлеВПродажныхЦенахАТТ или
		 
		 СчетУчета.ПринадлежитЭлементу(ПланыСчетов.Хозрасчетный.ПокупныеИзделия) или
		 СчетУчета = ПланыСчетов.Хозрасчетный.ПокупныеИзделия Тогда

		Результат = Истина;

	Иначе
		Результат = Ложь;
	КонецЕсли;
	
	Возврат Результат;

КонецФункции


Функция НеУказанНомерГТД(НомерГТД, СтранаПроисхождения) Экспорт

	Если НЕ ЗначениеЗаполнено(СтранаПроисхождения) или
		 СтранаПроисхождения = Справочники.СтраныМира.РОССИЯ Тогда
		 
		Результат = Ложь;
		
	ИначеЕсли НЕ ЗначениеЗаполнено(НомерГТД) Тогда
		Результат = Истина;
		
	Иначе
		Результат = Ложь;
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

2. В конец обработки проведения добавляем вызов:

ОбщийМодуль.ПроведениеДокументаСписанияПоСчетуГТД(ЭтотОбъект,ЭтотОбъект.Товары, "Реализация услуг");

Разберем на примере:

В первой строке я умышленно указал ГТД с остатком 5 вместо 10

Во второй строке не указывал совсем.

После проведения результат отображается на рисунке.

 

 Вот таким образом мы решили проблему списания остатков по счёту ГТД.

Спасибо за внимание. Моя первая публикация, прошу прощения, если отнял ваше время :)

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Игорь Иванов (paybaseme) 19.01.16 12:43
Приветствую, коллега! Подход отличный при условии что ради этого конфигурация снимается с поддержки, со всеми вытекающими. У моих клиентов ни у одного такой аргумент как говорится "не покатил". Поэтому на свет появился вот такой отчет. Публикую не рекламы ради, а в свете всяческий лучей поддержки коллеге, столкнувшейся с такой особенностью!
2. Дмитрий Конаков (dkonakov) 19.01.16 14:13
(1) paybaseme, почему сразу "Снимается с поддержки"? Несколько сложнее обновлять, нужно хранить заметки о своих "внедрениях" =)
3. Алексей Ермилов (Alex_E) 19.01.16 14:25
(2) dkonakov, и нет возможности обновлять программу автоматом - т.е. буху нужно или звать кого-то или содержать "карманного" программиста или самому(-ой) научиться грамотно обновлять изменённую конфигурацию - для 80% клиентов это не айс - ибо мало заплатить за настройку, нужно ещё платить за обновления - а у нас кризис на дворе.....
Вообще решение этой задачи правильно включить в расширение - с обновлениями проблем уже будет меньше, но....мы же не ищем лёгких путей? :-)
4. Дмитрий Конаков (dkonakov) 19.01.16 15:30
(3) Alex_E, я штатный программист, я лишь поделился "быстрым решением" после перехода с 2.0 на 3.0. Раздел "Практика программирования" да и первый раз опубликовался :) не судите строго)
5. Иванов Иван (slauter77) 19.01.16 21:03
(4) dkonakov, "Подписки на события ?" - не ! не слышал! :)
6. Алексей Ермилов (Alex_E) 19.01.16 21:26
(4) dkonakov, это Вы не судите меня строго - просто Ваше решение - это показатель...)))))
7. Максим Анпилов (Mx00) 20.01.16 11:57
Сейчас появилась возможность использовать Расширения конфигурации - важно что при этом конфигурация остаётся неизменной, а логику проверки она вполне позволяет сделать, думаю на текущий момент решение с помощью Расширения самый оптимальный вариант :-)
8. Дмитрий Конаков (dkonakov) 21.01.16 08:57
(7) Mx00, спасибо за мнение. Я обязательно рассмотрю этот вариант и, если получится, опубликую :)
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа