gifts2017

"Активы и пассивы" для Деньги 1.0

Опубликовал q_i в раздел Отчеты - Финансовые

Простенький отчёт "Активы и пассивы" для конфигурации 1С:Деньги редакция 1.0, который показывает активы и пассивы.

Для "самоделкиных":

1. Создаем отчет, в СКД добавляем запрос:

ВЫБРАТЬ
	КурсыВалютСрезПоследних.Валюта КАК Валюта,
	ВЫБОР
		КОГДА КурсыВалютСрезПоследних.Кратность <> 0
			ТОГДА КурсыВалютСрезПоследних.Курс / КурсыВалютСрезПоследних.Кратность
		ИНАЧЕ КурсыВалютСрезПоследних.Курс
	КОНЕЦ КАК Курс
ПОМЕСТИТЬ ВТ_Курсы
ИЗ
	РегистрСведений.КурсыВалют.СрезПоследних({(&Период)}, ) КАК КурсыВалютСрезПоследних

ИНДЕКСИРОВАТЬ ПО
	Валюта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	"АКТИВЫ" КАК Раздел,
	"Деньги" КАК Подраздел,
	ЛичныеФинансыОстатки.Счет,
	ВЫРАЗИТЬ(ЛичныеФинансыОстатки.Субконто1 КАК Справочник.КошелькиИСчета).ТипСчета КАК ГруппаСтатей,
	ЛичныеФинансыОстатки.Субконто1 КАК Статья,
	ЛичныеФинансыОстатки.Валюта,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток * ВТ_Курсы.Курс КАК СуммаНацЭквОстаток,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток * ВТ_Курсы.Курс / ВТ_КурсВалютыПересчета.Курс КАК СуммаВалПересчетаОстаток
ИЗ
	РегистрБухгалтерии.ЛичныеФинансы.Остатки(
			{(&Период)},
			Счет = ЗНАЧЕНИЕ(ПланСчетов.ЛичныеФинансы.ДоступныеДеньги)
				ИЛИ Счет = ЗНАЧЕНИЕ(ПланСчетов.ЛичныеФинансы.Накопления)
					И &ВключатьНакопления,
			&СубкКошелькиИСчета,
			) КАК ЛичныеФинансыОстатки
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Курсы КАК ВТ_Курсы
		ПО ЛичныеФинансыОстатки.Валюта = ВТ_Курсы.Валюта
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Курсы КАК ВТ_КурсВалютыПересчета
		ПО (ВТ_КурсВалютыПересчета.Валюта = &ВалютаПересчета)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	"АКТИВЫ",
	"Имущество",
	ЛичныеФинансыОстатки.Счет,
	ВЫРАЗИТЬ(ЛичныеФинансыОстатки.Субконто1 КАК Справочник.Имущество).Родитель,
	ЛичныеФинансыОстатки.Субконто1,
	ЛичныеФинансыОстатки.Валюта,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток * ВТ_Курсы.Курс,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток * ВТ_Курсы.Курс / ВТ_КурсВалютыПересчета.Курс
ИЗ
	РегистрБухгалтерии.ЛичныеФинансы.Остатки({(&Период)}, Счет = ЗНАЧЕНИЕ(ПланСчетов.ЛичныеФинансы.Имущество), &СубкИмущество, ) КАК ЛичныеФинансыОстатки
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Курсы КАК ВТ_Курсы
		ПО ЛичныеФинансыОстатки.Валюта = ВТ_Курсы.Валюта
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Курсы КАК ВТ_КурсВалютыПересчета
		ПО (ВТ_КурсВалютыПересчета.Валюта = &ВалютаПересчета)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ВЫБОР
		КОГДА ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток > 0
			ТОГДА "АКТИВЫ"
		ИНАЧЕ "ПАССИВЫ"
	КОНЕЦ,
	"Долги",
	ЛичныеФинансыОстатки.Счет,
	ЛичныеФинансыОстатки.Субконто1,
	ЛичныеФинансыОстатки.Субконто2,
	ЛичныеФинансыОстатки.Валюта,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток * ВТ_Курсы.Курс,
	ЛичныеФинансыОстатки.ВалютнаяСуммаОстаток * ВТ_Курсы.Курс / ВТ_КурсВалютыПересчета.Курс
ИЗ
	РегистрБухгалтерии.ЛичныеФинансы.Остатки({(&Период)}, Счет = ЗНАЧЕНИЕ(ПланСчетов.ЛичныеФинансы.Взаиморасчеты), &СубкКонтактыДокументыУчетаДолгов, ) КАК ЛичныеФинансыОстатки
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Курсы КАК ВТ_Курсы
		ПО ЛичныеФинансыОстатки.Валюта = ВТ_Курсы.Валюта
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Курсы КАК ВТ_КурсВалютыПересчета
		ПО (ВТ_КурсВалютыПересчета.Валюта = &ВалютаПересчета)

2. На вкладке Ресурсы добавляем поля ВалютнаяСуммаОстаток, СуммаНацЭквОстаток, СуммаВалПересчетаОстаток.

3. На вкладке Параметры задаем значения параметров:

СубкИмущество = ПланВидовХарактеристик.ВидыСубконто.Имущество,

СубкКошелькиИСчета = ПланВидовХарактеристик.ВидыСубконто.КошелькиИСчета,

СубкКонтактыДокументыУчетаДолгов = СписокЗначений{ПланВидовХарактеристик.ВидыСубконто.Контакты; ПланВидовХарактеристик.ВидыСубконто.ДокументыУчетаДолгов}

4. На вкладке Настройки добавляем группировки Раздел / Подраздел / Валюта / ГруппаСтатей / Статья, а в Выбранных полях выбираем ВалютнаяСуммаОстаток, СуммаНацЭквОстаток, СуммаВалПересчетаОстаток.

5. Сохраняем и запускаем.

Скачать файлы

Наименование Файл Версия Размер
AktivyPassivy.erf.7z 1
.7z 12,31Kb
03.10.16
1
.7z 12,31Kb Скачать

См. также

Подписаться Добавить вознаграждение
В этой теме еще нет сообщений.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа