gifts2017

Вывод печатных форм с запросом данных в форму "Печать документов" из подсистемы БСП "Печать".

Опубликовал Александр Лопатин (lopatin) в раздел Программирование - Практика программирования

Все не раз видели, как в типовых конфигурациях, построенных на основе БСП (Библиотека стандартных подсистем), печатные формы, построенные на основе Табличного документа, выводятся в специальную форму "ПечатьДокументов". Эта форма входит в состав подсистемы "Печать" из БСП. При разработке своих печатных форм, иногда необходимо запросить у пользователя дополнительные данные необходимые для печати. Тут встает вопрос, как в этом случае вывести печатную форму в форму "Печать документа". В этой статье я рассмотрю, как реализовать вывод печатной формы в упомянутую форму из подсистемы "Печать", в случае если мы хотим перед выводом печатной формы запросить у пользователя дополнительные данные. Здесь будут рассмотрены два случая: когда реализуется печатная форма с использованием подсистемы "Дополнительные отчеты и обработки" и когда печатная форма добавляется в конфигурацию в режиме конфигуратора, т.е. вносятся изменения в типовую конфигурацию.

Форма "ПечатьДокументов" предоставляет некоторые дополнительные функции при работе с печатными формами, такие как:

  • кнопка печати на принтер, непосредственно в форме;
  • указание количества копий, печатной формы;
  • редактирование сформированной печатной формы;
  • возможность сохранения печатной формы в различные форматы данных(Excel, Word, PDF и др.);
  • отправка печатной формы по электронной почте;
  • удобная работа с комплектом документов.

Эта форма сейчас используется фирмой 1С во всех типовых конфигурациях для вывода печатных форм документов и элементов справочников. И конечно же нам, при разработке своих печатных форм, чтобы не выходить за рамки принятой практики, следует так же выводить свои печатные формы используя предоставляемые инструменты.

При использовании стандартных методов добавления печатных форм подсистема "Печать" все сделает за нас и выведет печатную форму, как надо. Например:

  1. При добавлении команды печати в документ с использованием подсистемы "Печать", нам необходимо в процедуре ДобавитьКомандыПечати описать команду печати с указанием менеджера печати, в котором реализована прцоедура Печать;
  2. При создании Дополнительной обработки, нам необходимо, в модуле объекта обработки в функции СведенияОВнешнейОбработке, описать команду с типом использования Вызов серверного метода и тут же реализовать процедуру Печать, которая определенным образом реализует вызов формирования печатной формы.
В подобных случаях, как я уже сказал, подсистема печать выведет сформированную нами печатную форму сама, как нужно. Подобные способы подразумевают непосредственное формирование печатной формы, т.е. передали объекты для печати в процедуру печать, сформировали табличный документ и вывели на экран.

А что если перед началом формирования табличного документа, необходимо запросить у пользователя какие-то данные? Т.е. нам необходимо показать форму. В этом случае стандартный порядок формирвоания печатной формы нарушается и нам надо думать, как же передать нашу печатную форму в форму "ПечатьДокументов".

В этом случае возможны две ситуации:
  1. Когда печатная форма создается с изменение конфигурации;
  2. Когда печатная форма создается без изменения конфигурации, т.е. используетя подсистема "Дополнительные отчеты и обработки".

Создаем печатную форму добавляя её через конфигуратор.

Первый вариат. Через создание обработки с командой.

Этот вариант предусматривает, добавление обработки непосредственно в Объекты метаданных:

Рассмотрим вариант, когда нам необходимо реализовать печатную форму определенного объекта, например, элемента справочника. Для этого нам необходимо поработать в четырех местах обработки:

  1. Создать команду, которая будет вызывать форму нашей печатной формы;
  2. Создать саму форму;
  3. Создать макет печатной формы;
  4. Внести изменения в модуль менеджера обработки.
Создаем команду
 
 
Указываем в свойствах команды:
  • Группу где хотим, чтобы команда отображалась в форме;
  • Тип параметра, это как раз тот справочник или документ, печатную форму которого мы делаем;
  • Режим использования параметра - Множественный. Чтобы можно было выводить печатных формы, сразу по нескольким выбранным в списке элементам.
 В модуле команды открываем форму обработки передавая её выбранные элементы справочника, для которых необходимо сформировать печатные формы. Не будем тут мудровствовать лукаво и слегка подправим типовой код, который подставляется платформой в процедуру обрабокти команды:
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
	//Вставить содержимое обработчика.
	ПараметрыФормы = Новый Структура("ДанныеДляПечати", ПараметрКоманды);
	ОткрытьФорму("Обработка.ПечатнаяФорма.Форма", ПараметрыФормы, ПараметрыВыполненияКоманды.Источник, ПараметрыВыполненияКоманды.Уникальность, ПараметрыВыполненияКоманды.Окно, ПараметрыВыполненияКоманды.НавигационнаяСсылка);
КонецПроцедуры
Параметр процедуры ПараметрКоманды, как раз и содержит выбранные нами элементы для печати.
 
Создаем форму
 
Добавим в обработку форму, создадим реквизит формы типа СписокЗначений и необходые для нас реквизиты для ввода дополнительных параметров для печатной формы:
 
 
Я добавил на форму реквизиты:
 
ДанныеДляПечати - тип СписокЗначений;
КоличествоСтрок - тип Число.
 
Мой пример, будет чисто демонстрационный, поэтому условно определимся, что моя цель вывести в печатную строку представления выбранного элемента и то количество строк, которое мы выберем в качестве дополнительного параметра на форме.
 
Переходим в модуль формы и пишем следующий код:
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	ДанныеДляПечати.ЗагрузитьЗначения(Параметры.ДанныеДляПечати);
КонецПроцедуры

&НаКлиенте
Процедура Печать(Команда)
	УправлениеПечатьюКлиент.ВыполнитьКомандуПечати(	"Обработка.ПечатнаяФорма",		//Менеджер печати
							"ПечатнаяФорма",			//Идентификатор
							ПолучитьОбъектыДляПечати(),		//Объекты печати
							ЭтотОбъект,				//Владелец формы - форма из которой вызывается печать
							ПолучитьПараметрыПечати());		//Параметры печати - произвольные параметры для передачи в менеджер печати
КонецПроцедуры

&НаСервере
Функция ПолучитьОбъектыДляПечати()
	Массив = ДанныеДляПечати.ВыгрузитьЗначения();
	Возврат Массив;
КонецФункции

&НаСервере
Функция ПолучитьПараметрыПечати()
	
	ПараметрыПечати = Новый Структура;
	
	ПараметрыПечати.Вставить("ЗаголовокФормы", "Печатная форма");					//Один из параметров, для формы "Печать документа".
													//Указывает заголовок формы вывода печатной формы.

	//Тут добавляем наши параметры, которые мы хотим дополнительно передать в менеджер печати.
	ПараметрыПечати.Вставить("КоличествоСтрок", КоличествоСтрок);	
	
	Возврат ПараметрыПечати;
	
КонецФункции
Определяем процедуру ПриСозданииНаСервере и в ней считываем из параметра, который мы передали из команды при открытии формы, список объектов для которых надо формировать печатную форму.
 
Создаем в форме команду Печать и пишем её обработчик, в котором вызываем функцию общего модуля УправлениеПечатьюКлиент.ВыполнитьКомандуПечати, задаем необходимые параметры этой функции, а именно:
  • Менеджер печати - имя объекта в модуле менеджера, которого определена функция Печать, формирующая нашу печатную форму;
  • Идентификатор - идентификатор печатной формы, которую необходимо напечатать. По этому идентификатору, мы будем в функции Печать модуля менеджера выбирать, какую печатную форму необходимо напечатать;
  • Объекты печати - это непосредтвенно те объекты для которых формируются печатные формы;
  • Владелец формы;
  • Параметры печати - сюда мы формируем и передаем структуру с параметрами печати, тут же мы передаем наши дополнительные параметры, которые мы запросили у пользователя в форме обработки.
Собственно, вызывая функцию ВыполнитьКомандуПечати из формы обработки, мы решаем нашу задачу вывода печатной формы в форму "ПечатьДокументов". Дальше подсистема "Печать" выполнит стандартные действия и доведет выполнение до процедуры Печать, которую мы должны определить в модуле менеджере нашей обработки.
 
Создаем макет печатной формы
 
Тут все просто, не будем здесь останавливаться. Скажу лишь, что необходимо соблюсти стиль именования макета, предусмотренный подсистемой "Печать": ПФ_MXL_<Имя печатной формы> - для макетов типа Табличный документ.
 
Вносим изменения в модуль менеджера обработки
 
С этого момента мы выполняем стандартные действия по разработки печатных форм с использованием подсистемы "Печать" из БСП.
 
Добавляем в модуль менеджера следующий код:
 
Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "ПечатнаяФорма") Тогда
        УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм,
        													 "ПечатнаяФорма",
        													 НСтр("ru = 'Печатная форма'"),
        													 НапечататьМакет(МассивОбъектов, ПараметрыПечати),,
															 "Обработка.ПечатнаяФорма.ПФ_MXL_ПечатнаяФорма",);
    КонецЕсли;
КонецПроцедуры

&НаСервере
Функция НапечататьМакет(МассивОбъектов, ПараметрыПечати)

	                                               	
	ТабличныйДокумент = Новый ТабличныйДокумент;	//Создаем табличный документ
	
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	//ПЕРЕОПРЕДЕЛЯЕМАЯ ЧАСТЬ МОДУЛЯ
	//
	//Тут формируем нашу печатную форму
	
	Макет = ПолучитьМакет("ПФ_MXL_ПечатнаяФорма");
	
		
	Для каждого Объект Из МассивОбъектов Цикл
		
		ОбластьШапка = Макет.ПолучитьОбласть("Шапка");
		ОбластьОбъект = Макет.ПолучитьОбласть("Объект");
		
		
		ТабличныйДокумент.Вывести(ОбластьШапка);
		
		ОбластьОбъект.Параметры["Объект"] = Объект;
		
		ТабличныйДокумент.Вывести(ОбластьОбъект);
		
		Для Сч = 1 По ПараметрыПечати["КоличествоСтрок"] Цикл
			
			ОбластьСтрока = Макет.ПолучитьОбласть("Строка");
			ОбластьСтрока.Параметры["Строка"] = Сч;
			ТабличныйДокумент.Вывести(ОбластьСтрока);
			
		КонецЦикла;
		
		ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
	
	КонецЦикла;
	
	//ПЕРЕОПРЕДЕЛЯЕМАЯ ЧАСТЬ МОДУЛЯ
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	
	Возврат ТабличныйДокумент;						//Возвращаем табличный документ
КонецФункции

Второй вариант. Через реализацию команды печати.

Этот вариант, очень похож на первый по реализации печати. Отличие его в способе создания команды, которая будет выводиться в интерфейс и запускать нашу печать.

В этом случае при определении команды печати мы так же задействуем подсистему "Печать" из БСП. Вместо того, чтобы определять команду для открытия обработки в самой обработке, нам необходимо перейти в модуль менеджера, того объекта, в который мы хотим добавить печатную форму, и задать описание команды печати в процедуре ДобавитьКомандыПечати(КомандыПечати):

Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт
	
	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "ПечатнаяФорма";
	КомандаПечати.Представление = НСтр("ru = 'Печать печатной формы'");
	КомандаПечати.Обработчик = "ОбщийМодульПечатнаяФорма.ОбработкаКомандыПечатиПечатнойФормы";
	КомандаПечати.Порядок = 100;

КонецПроцедуры

Здесь мы добавляем на все формы справочника(напоминаю, что мы работаем со справочником контрагенты), команду печати с названием "Печать печатной формы". И вот здесь главный момент, который надо учесть. На форму можно добавить два вида команд:

1. Вызов процедуры Печать из модуля менеджера;

2. Вызов клиентского метода.

Вот именно вызов клиентского метода нам и нужен. Клиентский метод позволит нам вызвать форму обработки, в которой мы перед печатью запросим у пользователя необходимые нам данные.

Чтобы реализовать такой вызов, необходимо при определении команды, задать для неё Обработчик(см. код выше). В Обработчик команды передается строка, содержащая путь к клиентской функции, т.е. путь к Экспортной функции общего модуля на клиенте. Именно эта функция будет вызвана, при нажатии на команду печати, которую мы добавляем на формы.

Как вы понимаете, чтобы это все заработало, необходимо создать этот самый ОбщийМодуль и определить Экспортную функцию. Поэтому пишем в нашем общем модуле следующий код:

Функция ОбработкаКомандыПечатиПечатнойФормы(ПараметрыПечати) Экспорт

	//Вставить содержимое обработчика.
	ПараметрыФормы = Новый Структура("ДанныеДляПечати", ПараметрыПечати.ОбъектыПечати);
	ОткрытьФорму("Обработка.ПечатнаяФорма.Форма", ПараметрыФормы);
	
КонецФункции

Здесь мы делаем тоже самое, что и при первой реализации, открываем форму печатной формы, только теперь наши ДанныеДляПечати, будут содержаться в параметре переданном функции ПараметрыПечати, а точнее в его поле ОбъектыПечати.

После того, как мы открыли форму обработки, все действия аналогичны первому варианту.

Реализацию подобного варианта можно найти в типовых конфигурациях, в механизмах связанных с печатью согласия на обработку персональных данных.

Создаем дополнительную обработку.

А что если, это не наша конфигурация и она на поддержке? Да и вообще мы не хотим лезть в конфигурацию и править её?

В этом случае нам необходимо воспользоватья подсистемой "Дополнительные отчеты и обработки" из БСП.

При таком варианте решения, нам необходимо писать код, только в двух местах и все они находятся в нашей будущей дополнительной обработке:

1. Модуль объекта обработки;

2. Модуль формы обработки.

В модуле объекта пишем следующий код:

////////////////////////////////////////////////////////////////////////////////
// ПРОГРАММНЫЙ ИНТЕРФЕЙС

#Область ПрограммныйИнтерфейс

// Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
	
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиПечатнаяФорма();
	ПараметрыРегистрации.Версия = "1.0";
	
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Внешняя печатная форма с предварительным запросом данных'");
	НоваяКоманда.Идентификатор = "ВнешняяПечатнаяФорма";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	НоваяКоманда.ПоказыватьОповещение = Истина;
	НоваяКоманда.Модификатор = "ПечатьMXL";
	
	Возврат ПараметрыРегистрации;
	
КонецФункции
		
Процедура Печать(ДанныеПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "ВнешняяПечатнаяФорма") Тогда
        УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм,
        													 "ВнешняяПечатнаяФорма",
        													 НСтр("ru = 'Экзаменационная ведомость'"),
        													 НапечататьМакет(ДанныеПечати),,);
    КонецЕсли;
КонецПроцедуры

&НаСервере
Функция НапечататьМакет(ДанныеПечати)

	ПараметрыПечати = ДанныеПечати[0].Значение; 	//Получает параметры печати из первого элемента СпискаЗначения
	МассивОбъектов = ДанныеПечати.Скопировать(); 	//Копируем список значений
	МассивОбъектов.Удалить(0);						//Удаляем линий скопирвоанный элемент, содержащий ПараметрыПечати
	                                               	
	ТабличныйДокумент = Новый ТабличныйДокумент;	//Создаем табличный документ
	
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	//ПЕРЕОПРЕДЕЛЯЕМАЯ ЧАСТЬ МОДУЛЯ
	//
	//Тут формируем нашу печатную форму
	
	Макет = ПолучитьМакет("Макет");
	
		
	Для каждого Объект Из МассивОбъектов Цикл
		
		ОбластьШапка = Макет.ПолучитьОбласть("Шапка");
		ОбластьОбъект = Макет.ПолучитьОбласть("Объект");
		
		
		ТабличныйДокумент.Вывести(ОбластьШапка);
		
		ОбластьОбъект.Параметры["Объект"] = Объект;
		
		ТабличныйДокумент.Вывести(ОбластьОбъект);
		
		Для Сч = 1 По ПараметрыПечати["КоличествоСтрок"] Цикл
			
			ОбластьСтрока = Макет.ПолучитьОбласть("Строка");
			ОбластьСтрока.Параметры["Строка"] = Сч;
			ТабличныйДокумент.Вывести(ОбластьСтрока);
			
		КонецЦикла;
		
		ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
	
	КонецЦикла;
	
	//ПЕРЕОПРЕДЕЛЯЕМАЯ ЧАСТЬ МОДУЛЯ
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	
	Возврат ТабличныйДокумент;						//Возвращаем табличный документ
КонецФункции
#КонецОбласти

Здесь две функции и одна процедура.

Стандартная функция для Дополнительной обработки СведенияОВнешнейОбработке(), без неё система не поймет, что это дополнительная обработка. Здесь важным моментом является, указание того, что команда реализуемая в данной обработке имеет тип Открытие формы. Т.е. мы будем открывать форму, как нам и нужно. Дальше следует определение процедуры Печать и функции, которая непосредственно формирует наш табличный документ.

Тут нужно обратить внимание на то, что команда печать в этом случае должна содержать только 4 параметра, а не 5 как это при привычном определение команды печати в модуле менеджера. В данном случае отсутвует параметр для передачи Параметров печати. Поэтому нам придетя проявить изобретательность, чтобы передать помимо самих объектов, для которых формируется печатная форма, но так же и параметры которые мы запрашиваем у пользователя в форме.

И так мы определили дополнительную обработку, команда из которой будет открывать форму обработк. Поэтому следующим шагом создаем форму обработки.

В этой форме нам необходимо создать три реквизита для сохранения значений, которые нам понадобятся в дальнейшем. Назовем эти реквизиты следующим образом:

ДополнительнаяОбработкаСсылка - тип СправочникСсылка.ДополнительныеОтчетыИОбработки

ИдентификаторКоманды - тип Строка

ОбъектыНазначения - тип СписокЗначений

 

В модуле этой формы пишем следующий код:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	//При создании на сервере запомним стандартные параметры передаваемые подсистемой ДополнительныеОтчетыИОбработки
	ДополнительнаяОбработкаСсылка = Параметры.ДополнительнаяОбработкаСсылка;
	ИдентификаторКоманды = Параметры.ИдентификаторКоманды;
	ОбъектыНазначения.ЗагрузитьЗначения(Параметры.ОбъектыНазначения);
	
КонецПроцедуры
	
&НаКлиенте
Процедура Печать(Команда)
	
	// Получим ключ уникальности открываемой формы.
	КлючУникальности = Строка(Новый УникальныйИдентификатор);
		
	//Определение и заполнение стандартных параметров для общей формы ПечатьДокументов
	ПараметрыОткрытия = Новый Структура("ИсточникДанных, ПараметрыИсточника");
	ПараметрыОткрытия.ИсточникДанных     = ДополнительнаяОбработкаСсылка;
	ПараметрыОткрытия.ПараметрыИсточника = Новый Структура("ИдентификаторКоманды, ОбъектыНазначения");
	ПараметрыОткрытия.ПараметрыИсточника.ИдентификаторКоманды = ИдентификаторКоманды;
	
	//Объекты для печати и параметры вводимые в форме обработке 
	//будем передавать через параметр ПараметрыИсточника.ОбъектыНазначения
	ПараметрыОткрытия.ПараметрыИсточника.ОбъектыНазначения = ПолучитьОбъектыНазначенияИПараметрыПечати();
	
	ОткрытьФорму("ОбщаяФорма.ПечатьДокументов", ПараметрыОткрытия, ВладелецФормы, КлючУникальности);
	
КонецПроцедуры

&НаСервере
Функция ПолучитьОбъектыНазначенияИПараметрыПечати()
	
	ДанныеПечати = ОбъектыНазначения.Скопировать();
	
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	//ПЕРЕОПРЕДЕЛЯЕМАЯ ЧАСТЬ МОДУЛЯ
	//
	//Тут создаем структуру ПараметрыПечати и заполняем её теми параметрами, 
	//которые необходимо передать в функцию печать
	
	ПараметрыПечати = Новый Структура;
	ПараметрыПечати.Вставить("КоличествоСтрок", КоличествоСтрок);
	ДанныеПечати.Вставить(0, ПараметрыПечати);
	
	//ПЕРЕОПРЕДЕЛЯЕМАЯ ЧАСТЬ МОДУЛЯ
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	
	Возврат ДанныеПечати;
	
КонецФункции

В процедуре ПриСозданииНаСервере, заполняем наши три реквизита, которые мы создали для хранения параметров передаваемых в форму обработки.

Дальше определяем обработчик кнопки печать на форме. В этом обработчике нам необходимо самим открыть форму "Печать документов", для этого необходимо подготовить ПараметрыОткрытия определенной структуры. В этой структуре, как минимум должны быть определены два поля:

ИсточникДанных - ссылка на нашу дополнительную обработку в справочнике Дополнительных обработок и отчетов. Этот параметр мы сохранили из параметров формы, при создании на сервере;

ПараметрыИсточника, которые включают в себя ИдентификаторКоманды и ОбъектыНазначения:

ИдентификаторКоманды - так же сохранили при создании на сервере, это идентификатор, той команды, которая вызвала форму нашей обработки. Поэтому идентификатору, мы будем определять, что нам необходимо печатать в процедуре Печать в модуле объекта.

ОбъектыНазначения - именно в этом поле нам необходимо передать массив объектов, для которых формируется печатная форма, а так же параметры, запрашиваемые у пользователя в форме.

Как я определяю объекты назначения, можно увидеть в функции ПолучитьОбъектыНазначенияИПараметрыПечати. Здесь я копирую наши объекты назначения из реквизита формы, на место элемента массива с индексом 0, я вставляю наши параметры печати.

В дальнейшем массив определенный таким образом будет передан из формы "Печать документов", в качестве первого параметра процедуры Печать модуля объекта, которую мы определили ранее.

Если вернуться к определению модуля объекта обработки и посмотреть на функцию НапечататьМакет, в первых трех строках функции можно увидеть, как я вытаскиваю из переданных данных в процедуру Печать наши параметры и объекты и дальше с ними работаю.

Такие манипуляции с параметром ОбъектыНазначения, обусловленны спецификой вызова процедуры Печать модуля объекта. Вы можете сами отследить, как передаются параметры и выполняются вызовы функций, открыв модуль формы ПечатьДокументов.

Результат.

В итоге таких манипуляций, мы получим три команды на форме, из которой мы хотим выводить печатную форму:

Нумерация команд, соответствует порядку вариантов реализации.

Все эти команды будут выполнять одинаковые действия:

Показывать форму запроса дополнительных параметров

 

Выводить в форму "Печать документов" сформированные печатные форм. Как раз то, чего мы и добивались:

 

P.S. В качестве шаблонов, для реализации своих печатных форм с запросом дополнительных параметров, выгружаю обе обработки, которые учавствуют во всех трех способах формирования печатной формы.

Скачать файлы

Наименование Файл Версия Размер Кол. Скачив.
Печатная форма для встраивания в конфигурацию
.epf 7,75Kb
29.03.16
3
.epf 7,75Kb 3 Скачать
Печатная форма реализованная в виде дополнительной обработки
.epf 9,61Kb
29.03.16
9
.epf 9,61Kb 9 Скачать

См. также

Подписаться Добавить вознаграждение
В этой теме еще нет сообщений.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа