Хранение файлов в томах на диске (для УПП 1.3)

03.10.18

Задачи пользователя - Адаптация типовых решений

Доработка типовой УПП 1.3 в плане хранения присоединенных файлов вне базы данных

Скачать файлы

Наименование Файл Версия Размер
Все обработки от wowik на infostart.ru до 01.10.2018
.zip 59,98Kb
25
.zip 59,98Kb 25 Скачать

Часто возникает необходимость хранить присоединенные файлы где-нибудь на сетевом диске, чтобы как-то сократить рост размера базы.
К большому сожалению, приходится изобретать велосипед, т.к. в УПП 1.3 (заметьте, версия продается и поддерживается) НЕТ! хранения файлов вне базы.
Да, эта возможность уже реализована в УПП 1.3 для электронных документов, а все остальное по-прежнему хранится в базе.

"Допилок" этой функциональности много, есть и платные. Предлагаю свой варинат велосипеда. Версия рабочая, проверялась на УПП 1.3.72.3.

 

Побежали!

Включим хранение файлов в томах на диске

 

Добавим в справочник "ХранилищеДополнительнойИнформации" два реквизита:

ИмяФайлаВТоме (тип "Строка(50)")

НомерВерсии (тип "Число(10)")

 

 

 

В модуле объекта справочника "ХранилищеДополнительнойИнформации" пишем код (реквизит "Хранилище" очистим, а данные сохраним на диск). Использована типовая процедура "ФайловыеФункции.ДобавитьНаДиск", которая позволит также контролировать размер файла и запишет в имя файла на диске версию:

Процедура ПередЗаписью(Отказ)
	
	//+wowik
	Если ФайловыеФункции.ПолучитьТипХраненияФайлов() <> Перечисления.ТипыХраненияФайлов.ВИнформационнойБазе Тогда
		Если Хранилище.Получить() <> Неопределено Тогда // когда помечается элемент на удаление, то хранилище пустое
			Если не ЗначениеЗаполнено(ИмяФайлаВТоме) Тогда
				ИмяФайлаВТоме = Строка(Новый УникальныйИдентификатор);
				НомерВерсии = 1;
			Иначе			
				НомерВерсии = НомерВерсии + 1; //будем сохранять версии файлов на всякий случай
			КонецЕсли;
			
			Если Этотобъект.ВидДанных = Перечисления.ВидыДополнительнойИнформацииОбъектов.Файл Тогда
				РасширениеФайла = СтрЗаменить(Прав(ИмяФайла,4),".","");
				ДвоичныеДанныеФайла = Хранилище.Получить();
			Иначе			
				РасширениеФайла = "bmp";
				ВременныйФайл = ПолучитьИмяВременногоФайла(РасширениеФайла);
				Картинка = Хранилище.Получить();
				Картинка.Записать(ВременныйФайл); 
				ДвоичныеДанныеФайла = Новый ДвоичныеДанные(ВременныйФайл);
			КонецЕсли;
			
			ПутьКФайлуВТоме = ИмяФайлаВТоме+"."+РасширениеФайла;
			
			РазмерФайла = ДвоичныеДанныеФайла.Размер(); 
			
			ФайловыеФункции.ДобавитьНаДиск(
			ДвоичныеДанныеФайла,
			ПутьКФайлуВТоме,
			"", //ссылка на том, все равно она обнуляется в процедуре ДобавитьНаДиск
			1,
			НомерВерсии,
			ИмяФайлаВТоме,
			РасширениеФайла,
			РазмерФайла,
			Ложь,
			ТекущаяДата()
			);
			
			//хранилище элемента очищаем 
			Хранилище = Неопределено;  
		КонецЕсли;
	КонецЕсли;
	//-wowik
	
КонецПроцедуры

Далее в каком-либо общем модуле (в моем случае общий модуль "wowikОбщийМодуль") добавляем функцию:

Функция ПолучитьДвоичныеДанныеФайлаВХранилище(ХранилищеДополнительнойИнформацииСсылка, ВернутьХранилищеЗначения = Ложь) Экспорт
	
	Если ФайловыеФункции.ПолучитьТипХраненияФайлов() = Перечисления.ТипыХраненияФайлов.ВИнформационнойБазе Тогда
		Если ВернутьХранилищеЗначения Тогда
			Возврат ХранилищеДополнительнойИнформацииСсылка.Хранилище;
		Иначе
			Возврат ХранилищеДополнительнойИнформацииСсылка.Хранилище.Получить();
		КонецЕсли;
	Иначе
		Запрос = Новый Запрос;
		Запрос.Текст = 
		"ВЫБРАТЬ
		|	ТомаХраненияФайлов.Ссылка
		|ИЗ
		|	Справочник.ТомаХраненияФайлов КАК ТомаХраненияФайлов
		|ГДЕ
		|	ТомаХраненияФайлов.ПометкаУдаления = &ПометкаУдаления
		|
		|УПОРЯДОЧИТЬ ПО
		|	ТомаХраненияФайлов.ПорядокЗаполнения";
		
		Запрос.УстановитьПараметр("ПометкаУдаления", Ложь);
		Выборка = Запрос.Выполнить().Выбрать();
		
		Если Выборка.Количество() = 0 Тогда
			ВызватьИсключение(НСтр("ru = 'Нет ни одного тома для размещения файла.'"));
		КонецЕсли;
		
		Пока Выборка.Следующий() Цикл 			
			СсылкаНаТом = Выборка.Ссылка;			
			ПутьКТому = ФайловыеФункции.ПолныйПутьТома(СсылкаНаТом);
			ИмяФайлаВТоме = ХранилищеДополнительнойИнформацииСсылка.ИмяФайлаВТоме;
			Если ЗначениеЗаполнено(ИмяФайлаВТоме) Тогда
				НайденныеФайлы = НайтиФайлы(ПутьКТому,"*"+ИмяФайлаВТоме+"*",Истина);
				Если НайденныеФайлы.Количество() > 0 Тогда
					//получить последнюю версию файла. Предполагается что файлы беспорядочно отсортированы
					ПолучитьФайлСНомером = 1;
					ИндексНайденногоФайла = 0;
					Для Каждого НайденныйФайл из НайденныеФайлы Цикл
						 НомерВерсии = Число(СтрЗаменить(Прав(НайденныйФайл.ИмяБезРасширения,2),".",""));						 
						 Если НомерВерсии >= ПолучитьФайлСНомером Тогда
							 ПолучитьФайлСНомером = НомерВерсии;
							 ФайлВТоме = НайденныйФайл;
						 КонецЕсли; 						 
					КонецЦикла;
					     
					ПутьКФайлуЛокальный = ПолучитьИмяВременногоФайла(ФайлВТоме.Расширение);
					КопироватьФайл(ФайлВТоме.ПолноеИмя, ПутьКФайлуЛокальный); //открыть картинку из локального диска быстрее получится, чем по сети открыть				
					Если ВернутьХранилищеЗначения Тогда
						Возврат Новый ХранилищеЗначения(Новый ДвоичныеДанные(ПутьКФайлуЛокальный));
					Иначе
						Возврат Новый Картинка(ПутьКФайлуЛокальный);
					КонецЕсли;
				КонецЕсли;
			Иначе
				Если ВернутьХранилищеЗначения Тогда
					Возврат Новый ХранилищеЗначения(Неопределено);
				Иначе
					Возврат Новый Картинка;
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;		
	КонецЕсли;
	
КонецФункции

Далее ищем глобальным поиском выражение "Хранилище.Получить()":

в большинстве случаев замена проста:

...

                //мТекущееОсновноеИзображение = ОсновноеИзображение.Хранилище.Получить(); //wowik
                мТекущееОсновноеИзображение = wowikОбщийМодуль.ПолучитьДвоичныеДанныеФайлаВХранилище(ОсновноеИзображение); //wowik

...

            //ЭлементКартинки.Картинка = ОсновноеИзображение.Хранилище.Получить(); //wowik
            ЭлементКартинки.Картинка = wowikОбщийМодуль.ПолучитьДвоичныеДанныеФайлаВХранилище(ОсновноеИзображение); //wowik

...

Но в некоторых случаях сложнее, например в процедуре "ОтображениеИзображения()" формы "ФормаИзображения" справочника "ХранилищеДополнительнойИнформации":

Процедура ОтображениеИзображения()

	//+wowik
	Если Хранилище.Получить() = Неопределено Тогда
 		Если ФайловыеФункции.ПолучитьТипХраненияФайлов() = Перечисления.ТипыХраненияФайлов.ВИнформационнойБазе Тогда
			ЭлементыФормы.ПолеИзображения.Картинка = Новый Картинка();
		Иначе
			Если НЕ ЗначениеЗаполнено(ИмяФайлаВТоме) Тогда 
				ЭлементыФормы.ПолеИзображения.Картинка = Новый Картинка();
			Иначе
				КартинкаВТоме = wowikОбщийМодуль.ПолучитьДвоичныеДанныеФайлаВХранилище(Ссылка);
				ЭлементыФормы.ПолеИзображения.Картинка = КартинкаВТоме;
				Хранилище = Новый ХранилищеЗначения(КартинкаВТоме);
			КонецЕсли;
		КонецЕсли;
		Возврат;
	КонецЕсли;

	Если ВидДанных = Перечисления.ВидыДополнительнойИнформацииОбъектов.Изображение Тогда
		ЭлементыФормы.ПолеИзображения.Картинка = Хранилище.Получить();
	Иначе
		ЭлементыФормы.ПолеИзображения.Картинка = Новый Картинка();
	КонецЕсли; 
	 //-wowik
	 
КонецПроцедуры

 

Отображение картинок поправили, теперь переходим к сохранению и открытию внешних файлов:

 

в общем модуле "РаботаСФайлами" исправляем:

...

//СохранитьФайл(СтруктураПараметров, СсылкаФайл.ИмяФайла, СсылкаФайл.Хранилище, СпособПерезаписи); //wowik            
СохранитьФайл(СтруктураПараметров, СсылкаФайл.ИмяФайла, wowikОбщийМодуль.ПолучитьДвоичныеДанныеФайлаВХранилище(СсылкаФайл,Истина), СпособПерезаписи); //wowik
...

//ДанныеФайла = СсылкаФайл.Хранилище; //wowik
ДанныеФайла = wowikОбщийМодуль.ПолучитьДвоичныеДанныеФайлаВХранилище(СсылкаФайл,Истина);//wowik

...

в общем модуле "ФайловыеФункции" ставим "попытку":  

Попытка //wowik
 // Установим время изменения файла таким, как оно стоит в текущей версии
ФайлНаДиске = Новый Файл(ПолноеИмяФайлаСПутем);
ФайлНаДиске.УстановитьВремяИзменения(ВремяИзменения);
ФайлНаДиске.УстановитьТолькоЧтение(Истина);
Исключение
КонецПопытки;

Возможно, еще где-то придется что-то закомментировать. Далее все решается отладкой уже в конфигурации.

И все.  Спасибо. Удачного внедрения!

См. также

Табличная часть в доп. реквизитах и формирование таблиц в шаблоне docx для 1С:ДО 3.0

Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Платные (руб)

Расширение конфигурации для «1С:Документооборот КОРП», редакция 3.0. позволяет: 1.использовать произвольные табличные части в качестве дополнительных реквизитов к документу; 2 использовать произвольные табличные части в шаблонах в формате docx для автоматического заполнения таблиц.

29400 руб.

29.06.2023    4371    8    4    

16

Расширение для 1С:УНФ. Автоматическое снятие резервов в Заказах покупателей

Логистика, склад и ТМЦ Адаптация типовых решений Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Мы доработали УНФ, чтобы она автоматически отменяла старые резервы и не мешала эффективно продавать.

7200 руб.

02.08.2023    2897    4    0    

19

Создать на основании - своя кнопка (БСП). Проблема двух подменю Создать на основании

БСП (Библиотека стандартных подсистем) Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 Бесплатно (free)

Понадобилось в подменю "Создать на основании" добавить свою команду, которая открывает обработку. В процессе доработок появилась проблема двух подменю "Создать на основании". В статье о том, как решились проблемы.

01.03.2024    1114    dimanich70    6    

13

Доработка отчета "Связанные документы" (структура подчиненности) для вывода объектов из любого расширения

Адаптация типовых решений Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Доработка типового отчета "Связанные документы" позволяет просто и быстро расширять состав объектов для построения структуры подчиненности документов, используя объекты основной конфигурации и любых расширений.

1 стартмани

27.10.2023    1933    13    avmartynov    10    

43

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2020    21    progmaster    7    

3
Вознаграждение за ответ
Показать полностью
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. cool.vlad4 2 05.06.16 15:33 Сейчас в теме
а в вашей версии УПП есть модули ПрисоединенныеФайлы, ПрисоединенныеФайлыКлиент?(скорее всего есть) Имхо через него все проще можно было сделать. там уже готовые функции все есть.(т.е. через БСП это сделать)
2. wowik 884 05.06.16 22:05 Сейчас в теме
(1) cool.vlad4, сделайте, опубликуйте свой вариант, чё пальцы гнуть)
evgeniy_1c; user1320061; 1Cynep4eJIoBek; Trancer64; +4 2 Ответить
3. cool.vlad4 2 05.06.16 22:10 Сейчас в теме
(2) а я где-то пальцы гнул?
vano-ekt; bohdan-k; Мах; Irwin; pss1985; kild; AlexKoso; CSiER; Рамзес; waol; sulfur17; +11 1 Ответить
4. Ivon 673 08.06.16 12:26 Сейчас в теме
Механизм интересен, но хранение в файловых шарах имеет свои минусы, порой очень существенные. Я бы делал хранение в отдельной БД - и бекапить проще и безопасность данных выше.
5. thelans 30 08.06.16 14:05 Сейчас в теме
На сколько я знаю в MS SQL есть возможность хранить файлы, сохранённые в поле BLOB, на диске. В 1С дорабатывать при этом ничего не надо, а выставить соответствующие настройки СУБД.
6. Xershi 1473 08.06.16 19:49 Сейчас в теме
(5) thelans, что то новенькое. Где про это почитать подробнее?
13. CSiER 35 14.06.16 07:21 Сейчас в теме
(6) Xershi, рискну предположить, что речь идет про filestream - но структурой бд "рулит" 1С (как в этом случае быть при реструктуризациях, триггерах и прочих мелочах с данными - тоже интересно).
14. cool.vlad4 2 15.06.16 01:06 Сейчас в теме
(6) Xershi, c 2008 sql server filestream как верно выше заметили и с 2012 filetables появились, котороые позволяют делать таблицы, связывать их с папкой, где можно будет работь уже с файлами привычными операциями. технология крутая, но как ее связать с 1С (какой профит от этого получить) , я не знаю. в принципе хранения в томах из БСП имхо достаточно для 1С, может ошибаюсь, поправьте.
7. webester 26 09.06.16 06:00 Сейчас в теме
(5)(6)Угу очень интересно, как это работает.
9. SuhoffGV 09.06.16 17:06 Сейчас в теме
(5) thelans, Только выгрузка в DT и бэкап средствами СУБД быстрее от этого не станут. А если хранить файлы в ФС то выгрузка в dt будет намного быстрее.
romankoav; +1 Ответить
8. kosmo0 107 09.06.16 08:58 Сейчас в теме
В подобных случаях у меня зачастую возникает вопрос - неужели люди не создают тестовые базы для всяких безобразий? (причем чтобы и пользователи могли изменения и/или новинки потестить).

К чему весь разговор. Тестовые базы зачастую это загруженная сохраненка рабочей БД. И в этом случае тестовая база может легко и непринужденно что-нибудь сотворить с сохраненными файлами рабочей БД. Так что не помешало бы сделать маленький механизм контроля какой БД с файлами можно работать, а какой - нет (либо только смотреть, но не менять).
KAV2; Krio2; ph33l; NazarovV; +4 Ответить
10. SuhoffGV 09.06.16 17:11 Сейчас в теме
(8) kosmo0, Создают. У меня в базе есть константа "СтрокаСоединенияСРабочейБазой". И процедура общего модуля "ЭтоРабочаяБаза()" которая проверяет совпадает ли строка соединения текущей базы с значением константы. Если совпадает, то база считается рабочей и критичный функционал работает нормально.

Но к сожалению хранение файлов во внешних каталогах пока не написали, но уже назрело. Бэкап средствами СУБД идет 80 минут. Только из-за файлов в базе.
11. Xershi 1473 09.06.16 17:14 Сейчас в теме
(10) SuhoffGV, а каков их объем? У нас 40 гигов на ссд за 130 сек бекапит.
15. SuhoffGV 21.06.16 17:13 Сейчас в теме
(11) Xershi, 40Гб только дамп сжатый а gzip занимает. База в postgresql на 300Gb SAS дисках. Размер самой базы по данным pg_admin - 65Gb. Из них чуть более 32,2Гб в виде файлов в базе.
12. vshish 149 10.06.16 03:12 Сейчас в теме
Все хорошо и вроде бы правильно, но. Как писал в [1] да есть Присоединенные файлы, и есть еще некоторые подводные камни.
Я о них знаю потому, что сам делал такую доработку. Вот она http://infostart.ru/public/411416/
и вообще этот метод работает и на КА 1.1 и на УТ 10.3 и на УПП 1.3 правда с релиза как появился механизм электронного обмена документами.
16. qapex 67 23.06.16 09:45 Сейчас в теме
добрый день, сервер 1с на linux, с правами на linux настроили, файлы записывает на шару, а при открытии выдает ошибку. По коду получилось, что ПолучитьФайлы() возвращает пустой массив и дальше код не отрабатывает. Получается, что ПолучитьФайлы() работает от клиента (и пути, и права), а запись файлов через сервер (и пути, и права под которыми сервер 1с запущен). А путь предполагается использовать один и тот же?
17. wowik 884 23.06.16 21:29 Сейчас в теме
(16) qapex, ПолучитьФайлы() - что за процедура?
22. alen-s 12.12.16 08:49 Сейчас в теме
(16)
У Вас получилось решить эту проблему?
18. qapex 67 24.06.16 06:58 Сейчас в теме
извините, НайтиФайлы()
19. wowik 884 24.06.16 20:34 Сейчас в теме
(18) qapex, ну вообще должно работать, если папка открыта для сети и обращаетесь через "\\". Не знаю в чем дело.
20. Himikuda 22.07.16 07:56 Сейчас в теме
Всё работает класс) Огромное спасибо! хоть база пухнуть не будет. Только есть нюанс, имена файлов не корректно отображаются (набор символов) зато читаются., может кто то подскажет как это возможно поправить?
21. vovan_matveev 12 15.09.16 01:53 Сейчас в теме
Спасибо, wowik!
Статья очень помогла.

Я ограничился только тем что храню только присоединенные файлы (которые добавляются и отображаются через формы справочника Хранилище дополнительной информации)
таким образом я ограничился только первой частью статьи (доработка справочника Хранилище дополнительной информации и общий модуль), последней чстью (сохранение и открытие внешних файлов).

А вместо объемной средней части (где подмена функций во всех ссылках на "Хранилище.Получить()" я ограничился изменением одной функции модуля формы в справочнике Хранилище дополнительной информации.

В моем случае в базе уже были картинки хранящиеся внутри базы. поэтому мне было важно отображать и старый файлы и новые файлы из тома.

// Процедура показывает картинку текущей строки таблицы Изображения
//
// Параметры: 
//  Элемент - элемент формы, Изображения
//
// Возвращаемое значение:
//  Нет.
//
Процедура ПоказатьКартинкуТекущейСтроки(Элемент)

	Если Элемент.ТекущиеДанные = Неопределено Тогда
		ЭлементыФормы.ПолеИзображения.Картинка = Новый Картинка();
		Возврат;
	КонецЕсли;

	//Проверка на новую строку, если новая то не обновляем изображение.
	Если НЕ Элемент.ТекущаяСтрока.Пустая() Тогда
		//Изменения на основе wowik
		ТекущаяКартинка = Элемент.ТекущиеДанные.Ссылка.Хранилище.Получить();
		Если  ТекущаяКартинка = Неопределено Тогда
			ТекущаяКартинка = ОбщийМодульРМ.ПолучитьДвоичныеДанныеФайлаВХранилище(Элемент.ТекущиеДанные.Ссылка);
		КонецЕсли;
		//--Изменения на основе wowik
		ЭлементыФормы.ПолеИзображения.Картинка = ?(ТекущаяКартинка <> Неопределено, ТекущаяКартинка, Новый Картинка());
	КонецЕсли;
	
	ОбновитьКнопкиОсновногоИзображения(ЭлементыФормы.Изображения.ТекущаяСтрока);

КонецПроцедуры
Показать
toypaul; vlad636; +2 Ответить
29. vlad636 4 10.04.20 05:20 Сейчас в теме
Спасибо, помогла статья для сильно измененной КА 1.1. Сделал как в (21)
23. alen-s 29.12.16 12:59 Сейчас в теме
24. n0ther 09.02.17 13:45 Сейчас в теме
Почему в справочник не добавлен реквизит Том с типом ТомаХраненияФайлов? Так же быстрее и проще, чем перебирать все тома.
25. wowik 884 03.04.17 11:40 Сейчас в теме +10 $m
(24)
ее и проще, чем перебирать все тома.

это уже бантики)
26. albertik88 10 04.05.17 07:00 Сейчас в теме
Добрый день, у меня упп версии 1.3.5.1 - она полностью доработана и абсолютно не обновляется...у меня вообще отсутствует вкладка электронные документы в настройках программы...а сейчас возникла необходимость хранение файлов вне базы...если есть возможность скинь мне базу cf, или выложи в облако...буду очень признателен и благодарен! zakievar@mail.ru
27. pss1985 3 03.05.18 05:20 Сейчас в теме
я у себя такое как-то реализовывал, но еще добавил права на открытие файла. Создал таб часть "Пользователи" с реквизитами Пользователь и право записи, право чтения. Если в ней есть пользователь, то дается право на осуществление действий с этим файлом. Бывают случаи, когда надо некоторым пользователям запретить открытие и изменение файла.
user1320061; 1Cynep4eJIoBek; alen-s; +3 Ответить
28. KOVRUS 23 20.02.20 12:30 Сейчас в теме
Очень помогла статься, сделал в сильно измененной Ут 10.3
30. evgeniy_1c 07.07.20 17:20 Сейчас в теме
Спасибо. Очень интересный вариант, заработал.
И на паре позиций попробовал, при перезаписи хранилища доп информации автоматом зачищается хранилище и создаётся внешний файл. (Не нужно каких-то костылей с переносом придумывать.
Но думаю лучше использовать имя файла
ИмяФайлаВТоме = СокрЛП(Строка(ТипЗнч(ЭтотОбъект.Объект)))+"_"+СокрЛП(Строка(ЭтотОбъект.Объект.Код))+"_"+Строка(Новый УникальныйИдентификатор)

добавляет тип объекта и его код для более быстрой идентификации на диске.
Режим совместимости "Версия 8.2.13"
31. evgeniy_1c 09.07.20 09:10 Сейчас в теме
(30)
Если имя файла в томе делать по такому способу (длинное название получается, не забыть поменять в длину строки "ИмяФайлаВТоме" по умолчанию 50, этого не хватит в некоторых случаях.
И чтобы совсем исключить форсмажор, то конечно не красиво, но лучше вначале имени файла указать УИД, а потом комментарии объекта и кода. И да, если вложение не справочника, а документа, то там должен быть НЕ ЭтотОбъект.Объект.Код, а ЭтотОбъект.Объект.Номер.

А так ещё раз по всем моментам прошёлся, гениально) Только у вас будет количество версий больше 99, то при получении файла это нужно поправлять. Или опять-таки в справочнике "Хранилище доп информации" есть реквизит с номером версии (при перезаписи элемента, номер прибавляется), то по факту можно искать файл тогда ИмяФайлаВТоме + "."+НомерВерсии

И поправил сохранение разрешения не картинки и возможного расширения более 4х символов

			НомерСимволаПередРасширениемФайла = СтрНайти(ЭтотОбъект.ИмяФайла,".","СКонца");
            Если Этотобъект.ВидДанных = Перечисления.ВидыДополнительнойИнформацииОбъектов.Файл Тогда
                РасширениеФайла = СтрЗаменить(Прав(ИмяФайла,4),".","");
				Если НомерСимволаПередРасширениемФайла > 0 Тогда
					РасширениеФайла = Прав(Строка(ЭтотОбъект.ИмяФайла), Строка(СтрДлина(ЭтотОбъект.ИмяФайла)) - НомерСимволаПередРасширениемФайла);					
				КонецЕсли;				
                ДвоичныеДанныеФайла = Хранилище.Получить();
			Иначе				
				РасширениеФайла = "bmp";
				Если НомерСимволаПередРасширениемФайла > 0 Тогда
					РасширениеФайла = Прав(Строка(ЭтотОбъект.ИмяФайла), Строка(СтрДлина(ЭтотОбъект.ИмяФайла)) - НомерСимволаПередРасширениемФайла);					
				КонецЕсли;
                ВременныйФайл = ПолучитьИмяВременногоФайла(РасширениеФайла);
                Картинка = Хранилище.Получить();
                Картинка.Записать(ВременныйФайл); 
                ДвоичныеДанныеФайла = Новый ДвоичныеДанные(ВременныйФайл);
            КонецЕсли;
Показать
32. MasI 9 22.07.20 17:10 Сейчас в теме
Большое спасибо, отличная доработка))
33. Max7788 26.08.22 17:27 Сейчас в теме
А если файлы уже хранятся в УПП можно их как-то после настройки в каталог переместить?
Оставьте свое сообщение