gifts2017

Примечания в отчётах (вывод, хранение, изменение)

Опубликовал Иван Титов (Ibrogim) в раздел Программирование - Работа с интерфейсом

Эта микро статья о добавлении интерактива отчёту в виде возможности работы с примечаниями.

Например, у нас есть отчёт по заказам покупателей. Необходимо дать возможность пользователям добавлять, сохранять, изменять примечания для определённых заказов (в общем случае для любого объекта),

Будем хранить примечание в доп. свойстве заказа и пользоваться стандартным функционалом работы с примечаниями табличного документа.

1) Вывод примечаний

К сожалению, примечания нельзя вставить в уже выведенную область (поправьте меня, если я ошибаюсь)

Если вы выводите отчёт вручную (методом .Вывести() ), то проблем никаких нет, вставляем примечсание через свойство .Примечание.Текст . 

Однако у меня отчёт на СКД, поэтому пришлось немного исхитриться: пробежаться по выведенному ТД, получить для каждой строчки нужной группировки заказ (из расшифровки), вставить нужную ячейку с примечанием и удалить такую же без примечания.

Код будет примерно такой:

	 ПолеТабличногоДокумента=  ЭлементыФормы.Результат;
	 Свойство=ПроверитьСоздатьСвойство("Примечание");
	 НачальнаяВысота = ПолеТабличногоДокумента.ВысотаТаблицы; 	 
	 Для Счетчик = 1 по НачальнаяВысота Цикл
		 Область1 = ПолеТабличногоДокумента.ПолучитьОбласть(Счетчик,2,Счетчик,2);
		 ЗначениеРасшифровки="";
		 Попытка
			 ЗначениеРасшифровки = ДанныеРасшифровки.Элементы[Область1.ТекущаяОбласть.Расшифровка].ПолучитьПоля()[0].Значение;
		 Исключение
			 Продолжить;
		 КонецПопытки;
		 Если Не ТипЗНЧ(ЗначениеРасшифровки)=Тип("ДокументСсылка.ЗаказПокупателя") Тогда
			 Продолжить;  
		 КонецЕсли;
		 МенЗап=РегистрыСведений.ЗначенияСвойствОбъектов.СоздатьМенеджерЗаписи();
		 МенЗап.Объект= ЗначениеРасшифровки;
		 МенЗап.Свойство= Свойство;
		 МенЗап.Прочитать();
		 Если Не МенЗап.Выбран() Тогда
			 Продолжить;  
		 КонецЕсли;
		 ЗначениеПримечания= МенЗап.Значение;
		 
		 ОбластьКолонкиЯчейки = Область1.ТекущаяОбласть;
		 ОбластьКолонкиЯчейки.Примечание.Текст = ЗначениеПримечания;
		 
		 ОбластьКолонкиЯчейки.ПараметрРасшифровки="РасшифровкаЗаказа";
		 Область1.Параметры.РасшифровкаЗаказа= ЗначениеРасшифровки;
		 
		 ПолеТабличногоДокумента.ВставитьОбласть(ОбластьКолонкиЯчейки,ПолеТабличногоДокумента.Область(Счетчик,2,Счетчик,2),ТипСмещенияТабличногоДокумента.ПоГоризонтали);
		 ПолеТабличногоДокумента.УдалитьОбласть(ПолеТабличногоДокумента.Область(Счетчик,3,Счетчик,3),ТипСмещенияТабличногоДокумента.ПоГоризонтали);
		 
	 КонецЦикла;	

2) Добавление, удаление, редактирование примечаний и их сохранение в объекте

Будем использовать стандартный механизм работы с примечаниями ТД  (правой кнопкой мыши по ячейке, пункты "Вставить/Изменить примечание", "Удалить примечание" использовать не будем, считаем что изменение примечание на пустую строку это и есть его удаление)

Добавим форме реквизит "ТекущийЗаказ", при активизации ячейки, если она "нужная", то записываем в этот реквизит значение расшифровки.

Далее ПриИзмененииСодержимогоОбласти если область имеет тип "РисунокТабличногоДокумента" и заполнен "ТекущийЗаказ", то запишем в его доп. свойство примечание

Процедура РезультатПриАктивизацииОбласти(Элемент)   
	ЗначениеРасшифровки="";
	Попытка
	ЗначениеРасшифровки = ДанныеРасшифровки.Элементы[Элемент.ТекущаяОбласть.Расшифровка].ПолучитьПоля()[0].Значение;
    Исключение
	
	КонецПопытки;
	Если ТипЗНЧ(ЗначениеРасшифровки)=Тип("ДокументСсылка.ЗаказПокупателя") Тогда
		  ЭтаФорма.ТекущийЗаказ =ЗначениеРасшифровки;
	КонецЕсли;
КонецПроцедуры

Процедура РезультатПриИзмененииСодержимогоОбласти(Элемент, Область)
	Если Не ЗначениеЗаполнено(ЭтаФорма.ТекущийЗаказ) Тогда
		 Возврат;
	КонецЕсли;
	Если Не ТипЗНЧ(Область)=Тип("РисунокТабличногоДокумента") Тогда
		 Возврат;
	КонецЕсли;
	Свойство=ПроверитьСоздатьСвойство("Примечание");
	МенЗап=РегистрыСведений.ЗначенияСвойствОбъектов.СоздатьМенеджерЗаписи();
	МенЗап.Объект= ЭтаФорма.ТекущийЗаказ;
    МенЗап.Свойство= Свойство;
    МенЗап.Значение= Область.Текст;
	МенЗап.Записать();
КонецПроцедуры

Тут есть один нюанс: Если кроме примечаний вы хотите использовать расшифровку (например, переходить в заказ), то нужно обеспечить пользователю возможность переключать режим "ТолькоПросмотр", т.к. когда он истина, то работает расшифровка, но не работает управление примечаниями, а когда "ложь", то наоборот.

Я решил эту проблему добавлением на форму кнопки, переключающей этот режим

Процедура ДействияФормыДействие6(Кнопка)
	ПолеТабличногоДокумента=  ЭлементыФормы.Результат  ;
	ПолеТабличногоДокумента.ТолькоПросмотр=Не  ПолеТабличногоДокумента.ТолькоПросмотр;
КонецПроцедуры

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Иван Титов (Ibrogim) 09.11.16 15:09
Жду комментариев и конструктивной критики )
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа