[Шпаргалка] Запрос остатков по LIFO FIFO партиям приобретения поступления товаров

18.02.20

Разработка - Запросы

+94 –

Запросом получаем остатки по партиям LIFO или FIFO.

Добрый день, коллеги!

Шпаргалка запроса остатки партий по LIFO / FIFO и нарастающий итог LIFO / FIFO

Предисловие

Текст, который мало кто читает

Запрос – Остатки по LIFO

Текст запроса "Остатки по LIFO и нарастающий итог"

//	Получаем таблицу номенклатуры по которой есть остатки
ВЫБРАТЬ
	СебестоимостьТоваровОстатки.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
	СУММА(СебестоимостьТоваровОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ врОстатки
ИЗ
	РегистрНакопления.СебестоимостьТоваров.Остатки(&ДатаОстатков, ) КАК СебестоимостьТоваровОстатки	

СГРУППИРОВАТЬ ПО
	СебестоимостьТоваровОстатки.АналитикаУчетаНоменклатуры.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
//	Получаем таблицу с оборотами в разрезе регистратора
ВЫБРАТЬ
	СебестоимостьТоваровОбороты.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
	СебестоимостьТоваровОбороты.Регистратор КАК Регистратор,
	СебестоимостьТоваровОбороты.Регистратор.МоментВремени КАК РегистраторМоментВремени,
	СебестоимостьТоваровОбороты.Период КАК Период,
	СУММА(СебестоимостьТоваровОбороты.КоличествоОборот) КАК КоличествоОборот
ПОМЕСТИТЬ врОборотРегистратор
ИЗ
	РегистрНакопления.СебестоимостьТоваров.Обороты(
			,
			&ДатаОстатков,
			Регистратор,
			АналитикаУчетаНоменклатуры.Номенклатура В
				(ВЫБРАТЬ
					врОстатки.Номенклатура
				ИЗ
					врОстатки КАК врОстатки)) КАК СебестоимостьТоваровОбороты
ГДЕ
	(СебестоимостьТоваровОбороты.Регистратор ССЫЛКА Документ.ПриобретениеТоваровУслуг
			ИЛИ СебестоимостьТоваровОбороты.Регистратор ССЫЛКА Документ.ВводОстатков)

СГРУППИРОВАТЬ ПО
	СебестоимостьТоваровОбороты.АналитикаУчетаНоменклатуры.Номенклатура,
	СебестоимостьТоваровОбороты.Регистратор,
	СебестоимостьТоваровОбороты.Регистратор.МоментВремени,
	СебестоимостьТоваровОбороты.Период
;

////////////////////////////////////////////////////////////////////////////////
//	Из-за специфики, убираем все строчки с минусами
ВЫБРАТЬ
	врОборотРегистратор.Номенклатура КАК Номенклатура,
	врОборотРегистратор.Регистратор КАК Регистратор,
	врОборотРегистратор.РегистраторМоментВремени КАК РегистраторМоментВремени,
	врОборотРегистратор.Период КАК Период,
	врОборотРегистратор.КоличествоОборот КАК КоличествоОборот
ПОМЕСТИТЬ врОборотРегистраторБезМинусов
ИЗ
	врОборотРегистратор КАК врОборотРегистратор
ГДЕ
	врОборотРегистратор.КоличествоОборот > 0
;

////////////////////////////////////////////////////////////////////////////////
//	Классика. Первая важная выборка - Нарастающий итог 
//	Объединяем одну таблицу с оборотом по номенклатуре и моменту времени саму с собой
ВЫБРАТЬ
	Документы.Номенклатура КАК Номенклатура,
	Документы.Регистратор КАК Регистратор,
	Документы.Период КАК Период,
	СУММА(ЕСТЬNULL(Движения.КоличествоОборот, 0)) КАК НарастающийИтог,
	МАКСИМУМ(Документы.КоличествоОборот) КАК КоличествоРегистратор
ПОМЕСТИТЬ врОстаткиНарастающийИтог
ИЗ
	врОборотРегистраторБезМинусов КАК Документы
		ЛЕВОЕ СОЕДИНЕНИЕ врОборотРегистраторБезМинусов КАК Движения
		ПО Документы.Номенклатура = Движения.Номенклатура
			И Документы.РегистраторМоментВремени > Движения.РегистраторМоментВремени

СГРУППИРОВАТЬ ПО
	Документы.Номенклатура,
	Документы.Регистратор,
	Документы.Период
;

////////////////////////////////////////////////////////////////////////////////
//	Вторая важная выборка - Формируем таблицу с остатками по партиям
ВЫБРАТЬ
	врОстаткиНарастающийИтог.Номенклатура КАК Номенклатура,
	врОстаткиНарастающийИтог.Регистратор КАК Регистратор,
	врОстаткиНарастающийИтог.Период КАК Период,
	врОстаткиНарастающийИтог.НарастающийИтог КАК НарастающийИтог,
	врОстатки.КоличествоОстаток КАК ИтогоОстаток,
	ВЫБОР
		КОГДА врОстаткиНарастающийИтог.НарастающийИтог < врОстатки.КоличествоОстаток
			ТОГДА ВЫБОР
					КОГДА врОстаткиНарастающийИтог.КоличествоРегистратор > врОстатки.КоличествоОстаток - врОстаткиНарастающийИтог.НарастающийИтог
						ТОГДА врОстатки.КоличествоОстаток - врОстаткиНарастающийИтог.НарастающийИтог
					ИНАЧЕ врОстаткиНарастающийИтог.КоличествоРегистратор
				КОНЕЦ
		ИНАЧЕ 0
	КОНЕЦ КАК КоличествоОстатокПартии,
	НАЧАЛОПЕРИОДА(врОстаткиНарастающийИтог.Период, ПОЛУГОДИЕ) КАК ПериодПолугодие,
	врОстаткиНарастающийИтог.КоличествоРегистратор КАК КоличествоРегистратор
ПОМЕСТИТЬ врОстаткиПартий
ИЗ
	врОстаткиНарастающийИтог КАК врОстаткиНарастающийИтог
		ЛЕВОЕ СОЕДИНЕНИЕ врОстатки КАК врОстатки
		ПО (врОстатки.Номенклатура = врОстаткиНарастающийИтог.Номенклатура)
;

////////////////////////////////////////////////////////////////////////////////
//	В конечной выборке исключаем строки с пустыми остатками по партиям - ФИНИШ
ВЫБРАТЬ
	врОстаткиПартий.Номенклатура КАК Номенклатура,
	врОстаткиПартий.Регистратор КАК Регистратор,
	врОстаткиПартий.Период КАК Период,
	врОстаткиПартий.ИтогоОстаток КАК ИтогоОстаток,
	врОстаткиПартий.НарастающийИтог КАК НарастающийИтог,
	врОстаткиПартий.КоличествоРегистратор КАК КоличествоРегистратор,
	врОстаткиПартий.КоличествоОстатокПартии КАК КоличествоОстатокПартии,
	врОстаткиПартий.ПериодПолугодие КАК ПериодПолугодие
ИЗ
	врОстаткиПартий КАК врОстаткиПартий
ГДЕ
	врОстаткиПартий.КоличествоОстатокПартии > 0

УПОРЯДОЧИТЬ ПО
	Номенклатура,	
	Период

Запрос – Остатки по FIFO

Достаточно поменять знак равенства и поменять упорядочивание, и мы получаем остатки по партиям FIFO.

Текст запроса "Остатки по FIFO и нарастающий итог"

ВЫБРАТЬ
	СебестоимостьТоваровОстатки.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
	СУММА(СебестоимостьТоваровОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ врОстатки
ИЗ
	РегистрНакопления.СебестоимостьТоваров.Остатки(&ДатаОстатков, ) КАК СебестоимостьТоваровОстатки

СГРУППИРОВАТЬ ПО
	СебестоимостьТоваровОстатки.АналитикаУчетаНоменклатуры.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	СебестоимостьТоваровОбороты.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
	СебестоимостьТоваровОбороты.Регистратор КАК Регистратор,
	СебестоимостьТоваровОбороты.Регистратор.МоментВремени КАК РегистраторМоментВремени,
	СебестоимостьТоваровОбороты.Период КАК Период,
	СУММА(СебестоимостьТоваровОбороты.КоличествоОборот) КАК КоличествоОборот
ПОМЕСТИТЬ врОборотРегистратор
ИЗ
	РегистрНакопления.СебестоимостьТоваров.Обороты(
			,
			&ДатаОстатков,
			Регистратор,
			АналитикаУчетаНоменклатуры.Номенклатура В
				(ВЫБРАТЬ
					врОстатки.Номенклатура
				ИЗ
					врОстатки КАК врОстатки)) КАК СебестоимостьТоваровОбороты
ГДЕ
	(СебестоимостьТоваровОбороты.Регистратор ССЫЛКА Документ.ПриобретениеТоваровУслуг
			ИЛИ СебестоимостьТоваровОбороты.Регистратор ССЫЛКА Документ.ВводОстатков)

СГРУППИРОВАТЬ ПО
	СебестоимостьТоваровОбороты.АналитикаУчетаНоменклатуры.Номенклатура,
	СебестоимостьТоваровОбороты.Регистратор,
	СебестоимостьТоваровОбороты.Регистратор.МоментВремени,
	СебестоимостьТоваровОбороты.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	врОборотРегистратор.Номенклатура КАК Номенклатура,
	врОборотРегистратор.Регистратор КАК Регистратор,
	врОборотРегистратор.РегистраторМоментВремени КАК РегистраторМоментВремени,
	врОборотРегистратор.Период КАК Период,
	врОборотРегистратор.КоличествоОборот КАК КоличествоОборот
ПОМЕСТИТЬ врОборотРегистраторБезМинусов
ИЗ
	врОборотРегистратор КАК врОборотРегистратор
ГДЕ
	врОборотРегистратор.КоличествоОборот > 0
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Документы.Номенклатура КАК Номенклатура,
	Документы.Регистратор КАК Регистратор,
	Документы.Период КАК Период,
	СУММА(ЕСТЬNULL(Движения.КоличествоОборот, 0)) КАК НарастающийИтог,
	МАКСИМУМ(Документы.КоличествоОборот) КАК КоличествоРегистратор
ПОМЕСТИТЬ врОстаткиНарастающийИтог
ИЗ
	врОборотРегистраторБезМинусов КАК Документы
		ЛЕВОЕ СОЕДИНЕНИЕ врОборотРегистраторБезМинусов КАК Движения
		ПО Документы.Номенклатура = Движения.Номенклатура
		
		//Об этом знаке равенства шла речь
			И Документы.РегистраторМоментВремени < Движения.РегистраторМоментВремени

СГРУППИРОВАТЬ ПО
	Документы.Номенклатура,
	Документы.Регистратор,
	Документы.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	врОстаткиНарастающийИтог.Номенклатура КАК Номенклатура,
	врОстаткиНарастающийИтог.Регистратор КАК Регистратор,
	врОстаткиНарастающийИтог.Период КАК Период,
	врОстаткиНарастающийИтог.НарастающийИтог КАК НарастающийИтог,
	врОстатки.КоличествоОстаток КАК ИтогоОстаток,
	ВЫБОР
		КОГДА врОстаткиНарастающийИтог.НарастающийИтог < врОстатки.КоличествоОстаток
			ТОГДА ВЫБОР
					КОГДА врОстаткиНарастающийИтог.КоличествоРегистратор > врОстатки.КоличествоОстаток - врОстаткиНарастающийИтог.НарастающийИтог
						ТОГДА врОстатки.КоличествоОстаток - врОстаткиНарастающийИтог.НарастающийИтог
					ИНАЧЕ врОстаткиНарастающийИтог.КоличествоРегистратор
				КОНЕЦ
		ИНАЧЕ 0
	КОНЕЦ КАК КоличествоОстатокПартии,
	НАЧАЛОПЕРИОДА(врОстаткиНарастающийИтог.Период, ПОЛУГОДИЕ) КАК ПериодПолугодие,
	врОстаткиНарастающийИтог.КоличествоРегистратор КАК КоличествоРегистратор
ПОМЕСТИТЬ врОстаткиПартий
ИЗ
	врОстаткиНарастающийИтог КАК врОстаткиНарастающийИтог
		ЛЕВОЕ СОЕДИНЕНИЕ врОстатки КАК врОстатки
		ПО (врОстатки.Номенклатура = врОстаткиНарастающийИтог.Номенклатура)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	врОстаткиПартий.Номенклатура КАК Номенклатура,
	врОстаткиПартий.Регистратор КАК Регистратор,
	врОстаткиПартий.Период КАК Период,
	врОстаткиПартий.ИтогоОстаток КАК ИтогоОстаток,
	врОстаткиПартий.НарастающийИтог КАК НарастающийИтог,
	врОстаткиПартий.КоличествоРегистратор КАК КоличествоРегистратор,
	врОстаткиПартий.КоличествоОстатокПартии КАК КоличествоОстатокПартии,
	врОстаткиПартий.ПериодПолугодие КАК ПериодПолугодие
ИЗ
	врОстаткиПартий КАК врОстаткиПартий
ГДЕ
	врОстаткиПартий.КоличествоОстатокПартии > 0

УПОРЯДОЧИТЬ ПО
	Номенклатура,
	
	//Данную сортировку изменил
	Период УБЫВ

Послесловие

Запросы тестировал на 1С:ERP 2.4.8.92, платформа 8.3.12.1714

Вариант использования запроса остатки по FIFO в отчёте с разрезом по полугодиям:

Всем удачного коддинга!

LIFO FIFO Нарастающий итог Запрос СКД ВычислитьВыражение

+94 –

См. также

Infostart Toolkit — Инструменты разработчика 1С 8.3

Инструментарий разработчика Роли и права Запросы СКД Программист Руководитель проекта Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Платные (руб)

Инструменты для разработчиков 1С 8.3: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.

15500 руб.

02.09.2020 184726 1029 403

968

Битва с призраками прошлого: ищем "битые" запросы после обновления релиза

Обновление 1С Запросы Программист Платформа 1С v8.3 1С:ERP Управление предприятием 2 Абонемент ($m)

Данный инструмент помогает анализировать доработанную конфигурацию после обновления на новый релиз и находить «битые» тексты запросов, в которых участвуют несуществующие в новом релизе метаданные.

2 стартмани

06.02.2025 2200 17 XilDen 26

Передача исполняемого запроса динамического списка с параметрами в консоль запросов

Запросы Программист Платформа 1С v8.3 Запросы 1C:Бухгалтерия Бесплатно (free)

В статье приведена удобная возможность отладки исполняемого запроса динамического списка.

03.12.2024 5733 artemusII 11

Шпаргалка по запросам

Запросы Программист Бесплатно (free)

Увидел cheatsheet по SQL и захотелось нарисовать подобное, но про запросы.

18.10.2024 13140 sergey279 18

Ловушка функции запроса АВТОНОМЕРЗАПИСИ()

Запросы Программист Платформа 1С v8.3 Запросы 1C:Бухгалтерия Бесплатно (free)

Столкнулся с интересной ситуацией, которую хотел бы разобрать, ввиду её неочевидности. Речь пойдёт про использование функции запроса АВТОНОМЕРЗАПИСИ() и проблемы, которые могут возникнуть.

11.10.2024 8220 XilDen 36

Механизм представлений в типовых конфигурациях 1С: Зарплата и управление персоналом, редакция 3.1

СКД Механизмы типовых конфигураций Запросы Программист Платформа 1С v8.3 1С:Зарплата и кадры государственного учреждения 3 1С:Зарплата и Управление Персоналом 3.x Россия Бесплатно (free)

Работая с типовыми отчетами в конфигурациях «Зарплата и управление персоналом, редакция 3», «Зарплата и кадры государственного учреждения, редакция 3» и подобных, в схемах компоновки данных можно встретить конструкции запросов, которые обращаются к некоторым виртуальным таблицам.

20.08.2024 3192 PROSTO-1C 0

Внутренняя жизнь ваших запросов PostgreSQL. Как и зачем «подглядывать» в подробности

Запросы Программист Запросы Бесплатно (free)

Отлаживая взаимодействие с базой данных, мы регулярно сталкиваемся с зависающими или подозрительно долго выполняющимися обращениями, негативно влияющими на производительность. О том, как в PostgreSQL выявить подозрительные запросы, основываясь на доступной о них информации, расскажем в статье.

16.08.2024 10801 user1840182 5

В помощь разработчику: преобразование табличного документа в запрос

Инструментарий разработчика Универсальные функции Запросы Программист Платформа 1С v8.3 1C:Бухгалтерия 1С:Бухгалтерия 3.0 1С:Зарплата и Управление Персоналом 3.x Бесплатно (free)

Внешняя обработка для создания запроса на основании табличных данных.

22.07.2024 7377 209 ixijixi 10

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. aximo 2306 31.01.20 11:22 Сейчас в теме

для полноты реализации задачи - запроса я бы добавил индексацию временных таблиц и их уничтожение.

2. D_e_X_T_e_R 576 31.01.20 12:10 Сейчас в теме

(1)индексацию согласен, а зачем уничтожение вт? Уничтожение же используют, когда менеджер временных таблиц задан в явном виде, а тут один пакет запросов идет.

3. aximo 2306 31.01.20 12:27 Сейчас в теме

(2) ну по-идее да - 1с-ка должна сама уничтожить все временные таблицы после выполнения запроса. но это не точно?
у меня вообще создалось впечатление, что товарищ автор написал данный запрос - ну максимум за 15-20 минут. Я писал подобные дела - могу сразу ответить - что без СКЛАДА (и он тут отсутствует так же) - это бессмысленная штука.... это то, что помню на память.

14. par_62 07.03.20 19:57 Сейчас в теме

(3)склад зачем с списании партий? Вряд ли включен учет партий по складам. Обычно как раз в разрезе организаций

4. rpgshnik 3856 31.01.20 13:25 Сейчас в теме

(1) с индексированием согласен 👍 было по номенклатуре, после чистки запроса пропало, поправлю, уничтожение перестал использовать

7. bugagashenka 203 03.02.20 08:05 Сейчас в теме

(1) индексация ВТ работает не всегда, или, порой, работает не так, как хотелось бы. Такие громкие заявления стоит проверять на конкретных примерах с конкретными данными, потому что в одном запросе может работать отлично, в другом не использоваться, а на построение индекса будет уходить время. Много раз такое встречал, поэтому очень осторожно отношусь и к ВТ и к ее индексации, особенно на больших данных.
На маленьких индексация больше вредит, чем помогает.

8. bugagashenka 203 03.02.20 08:08 Сейчас в теме

(1) про уничтожение ВТ. В запросе используются все ВТ близко к концу и транкейт их не даст ничего, кроме нагромождения в запросе.
Если бы запрос был, как в ЗУПе, пособирали в одном месте, посчитали, потом в другом месте, в третьем и изначальные данные уже были бы не нужны, а менеджер их будет держать в tempdb, тогда оправдано уничтожение.

5. aximo 2306 31.01.20 13:39 Сейчас в теме

я писал подобные запросы только значительно-значительно больше в рамках практической бухгалтерской задачи для УПП подбора партии для документа "Корректировки реализации" по новому законодательству.

так же я использовал поля - склады, подразделения.... и еще много чего там....

кроме того, не совсем понятно, почему автор не использует документ Ссылка ПЕРЕМЕЩЕНИЕ товаров наряду с поступлением и даже вводом начальных остатков. Тут я скорее прошу пояснения у автора - влияния перемещений на себестоимость товаров в ERP

ну как-то так....

6. rpgshnik 3856 31.01.20 15:58 Сейчас в теме

(5) конечно оригинал отчета намного сложнее, там собирается и себестоимость включая ТЗР на перемещения и производство. В данном запросе я лишь отразил получение остатков в разрезе ПТУ или ввода начальных остатков, забыл кстати оприходование добавить, в оригинале уже добавил :)

9. Pixar0000 06.02.20 00:31 Сейчас в теме

ребят, вы о чем?

Поставили задачу - разработать отчёт с необходимостью отразить остатки на складах в разрезе приобретения товаров по LIFO.

а чего возник такой вопрос? на "ходу" поменяли константы? или зачем такой отчет?

10. rpgshnik 3856 06.02.20 02:52 Сейчас в теме

(9) задачу ставил аналитик, ему ставил топ-менеджер. Я думаю у разработчика не должно возникать "вы о чем".

11. slavus2017 07.02.20 09:21 Сейчас в теме

У меня задача - в Рознице сделать отчет по партиям, в разрезе поставщиков, чтобы узнать, от кого товар прибыл и сколько товара было продано в тот или иной период времени.
Насколько я знаю, в типовой Рознице партионный учет не ведется. И нет выбора, какого именно товара, т.е. из какой партии и от какого поставщика продавец отпустил покупателю.
Тогда совсем непонятно, как мы точно можем быть уверены, что ушла именно эта партия, а не другая?

12. rpgshnik 3856 07.02.20 09:50 Сейчас в теме

(11) чтобы реально знать - нужно реально указывать, тому пример ЕГАИС, со второй этикеткой (или ручное отражение партии) в других случаях конечно не понятно, какая партия реально на складе, продавец берёт товар просто с полки.
В моём случае этот отчёт скорее требуется для некого анализа остатков по "партии" без явного указания такого учета для всей системы, но с принятием во внимание, что для заказчика отчета учёт остатков будет вестись по ФИФО или ЛИФО. От сюда и расчёт себестоимости остатков и т.п. Но на складе может лежать какая угодно партия.

13. Megaiff 11.02.20 01:21 Сейчас в теме

Ну как закладку оставил.

15. srtfin 01.03.23 10:51 Сейчас в теме

Большое человеческое спасибо... Взлетело на УНФ с заменой в запросе регистров.

Оставьте свое сообщение

E-mail:

Автор:

Дмитрий Котов (rpgshnik)

Рейтинг: 3856

Для получения уведомлений о новых публикациях автора подключите телеграм бот: Инфостарт бот

Публикация:

№ 1187402

Создание 31.01.20 09:33

Обновление 18.02.20 09:21

Статистика:

Просмотры 15994

Загрузки 0

Рейтинг 94

Комментарии 15

Характеристики:

Код открыт Да

Рубрики Запросы

Кому Программист ,
Стажер

Тип файла Нет файла

Платформа Платформа 1С v8.3 ,
Запросы

Конфигурация 1C:Бухгалтерия

Операционная система Не имеет значения

Страна Не имеет значения

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Бесплатно (free)