Добавим на форму реквизит с типом КомпоновщикНастроекКомпоновкиДанных
Найдем отбор и перенесем его на форму
Чтобы отбор отображался компактно на форме у группы, в которой находится отбор, поставим поведение "Всплывающая"
Добавим в процедуру ПриСозданииНаСервере следующий код:
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
СхемаКомпоновкиДанных = РеквизитФормыВЗначение("Объект").ПолучитьМакет("Макет");
АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных, УникальныйИдентификатор);
ИсточникДоступныхНастроекКомпоновкиДанных = Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресВоВременномХранилище);
КомпоновщикНастроекКД.Инициализировать(ИсточникДоступныхНастроекКомпоновкиДанных);
КомпоновщикНастроекКД.ЗагрузитьНастройки(СхемаКомпоновкиДанных.НастройкиПоУмолчанию);
КонецПроцедуры
Создадим на форме команду "Загрузить" и добавим код:
&НаСервере
Процедура ЗагрузитьНаСервере()
СхемаКомпоновкиДанных = РеквизитФормыВЗначение("Объект").ПолучитьМакет("Макет");
НастройкиКомпоновки = КомпоновщикНастроекКД.ПолучитьНастройки();
КомпоновщикМакетаКомпоновкиДанных = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакетаКомпоновкиДанных.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);
ПроцессорВыводаРезультата = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ТЗ = Новый ТаблицаЗначений;
ПроцессорВыводаРезультата.УстановитьОбъект(ТЗ);
ПроцессорВыводаРезультата.Вывести(ПроцессорКомпоновки);
Объект.Товары.Очистить();
Для каждого СтрокаТЗ Из ТЗ Цикл
НовСтр = Объект.Товары.Добавить();
ЗаполнитьЗначенияСвойств(НовСтр,СтрокаТЗ);
КонецЦикла;
КонецПроцедуры
&НаКлиенте
Процедура Загрузить(Команда)
ЗагрузитьНаСервере();
КонецПроцедуры
Далее добавляем макет с типом "Схема компоновки данных". В набор данных добавим простенький запрос
В поля перенесем все данные, которые хотим видеть в результате
в отбор добавим отборы по умолчанию
В предприятии устанавливаем отбор, также можно добавить новые отборы через точку. Нажимаем кнопку загрузить.
Тестировал:
Платформа 1С:Предприятие 8.3 (8.3.18.1289).
Управление торговлей, редакция 11 (11.4.7.128).
