Паттерн "Стратегия". Пример реализации

Для использования шаблона «Стратегия» нам потребуется:
* Класс контекста. Поскольку конкретные реализации алгоритмов требуемого действия / результата (по сути стратегии) недоступны вызывающей стороне (клиенту) напрямую, необходима точка взаимодействия, с помощью которой клиент может устанавливать стратегию выполнения, инициировать запуск стратегии. В процессе взаимодействия класс-контекст делегирует выполнение алгоритма конкретному классу-стратегии (вызывает выбранную клиентом реализацию).

* Общий интерфейс. Соглашение, содержащее описание методов (без реализации) которые должны быть реализованы в классах конкретных стратегий. Требуется для того, чтобы класс-контекст «не задумывался» о том, какая стратегия будет вызвана, т.к. все стратегии содержат методы, описанные в интерфейсе.

* Классы-реализации конкретных стратегий. Это объекты, в которых содержатся реализованные методы-стратегии, описанные в общем интерфейсе (п.2.). Данные методы вызываются, когда класс-контекст делегирует продолжение выполнение алгоритма классу реализации конкретной стратегии.

Способ применения:

1. Вызывающая сторона (клиент) выбирает стратегию выполнения алгоритма путем создания экземпляра класса-реализации конкретной стратегии. 

2. Клиент обращается к классу контексту:

2.1 Сообщает классу-контексту, какую стратегию нужно выполнить. Для этого у класса-контекста должен присутствовать метод, сохраняющий ссылку на экземпляр выбранной стратегии из п.1 в реквизит класса-контекста.

2.2 Вызывает метод класса-контекста, инициирующий запуск выполнения стратегии. В этот момент класс-контекст «пробрасывает» вызов от клиента в метод класса реализации выбранной стратегии.

3. Для смены стратегии клиент создает экземпляр другого класса-реализации и обращается к классу-контексту как в п.2
Схема взаимодействия выглядит следующим образом:

Для понимания приведу пример из жизни. Мне понадобилось подстричься. Рассматриваю отзывы на стилистов из ближайшей парикмахерской и выбираю определенного мастера по стрижке. Придя в парикмахерскую, сообщаю администратору, что хочу подстричься у выбранного мной мастера. Администратор проводит меня в зал к определенному мастеру. Я усаживаюсь в кресле, и стилист принимается за работу. Закончив, я понимаю, что не мешало бы и подравнять бороду. Но у текущего мастера закончилась рабочая смена, и мне приходится выбрать другого стилиста.  Определившись с парикмахером, подхожу к администратору, сообщаю, что хочу подровнять бороду у другого выбранного стилиста. Меня снова отводят в зал к выбранному парикмахеру, усаживают в кресло, и мастер выполняет стрижку бороды.

С точки зрения паттерна стратегии в описанной ситуации присутствуют следующие составляющие:

* Класс контекст. В качестве точки взаимодействия выступает администратор парикмахерской. Ему я сообщаю, какого мастера выбрал и прошу оказать мне услугу по стрижке. Далее администратор усаживает меня в кресло к выбранному мастеру и делегирует продолжение оказания услуги парикмахеру.

* Общий интерфейс. Все стилисты парикмахерской обладают навыком стрижки. Поэтому администратор, провожая клиента на стрижку, не задумывается, умеет ли стричь выбранный клиентом парикмахер.

* Конкретные реализации стратегии. В качестве стратегий в данном случае выступают стилисты парикмахерской. Все они умеют стричь, но каждый по-своему уникально. Кто-то держит ножницы в левой руке, кто-то в правой. Одни парикмахеры предпочитают большую часть работы выполнять машинкой, другие - ножницами и т.д.

* Выбор стратегии. Выбирая определенного стилиста, я выбирал стратегию.

* Взаимозаменяемость. Когда закончилась смена первого стилиста, для стрижки бороды я выбрал другого работающего стилиста. О своем выборе я сообщил администратору и попросил оказать услугу по стрижке бороды.

Получается следующая схема взаимодействия:

Думаю, становится очевидным, что все описание шаблона проектирования «Стратегия» было приведено с использованием понятий объектно-ориентированного программирования. Классы, интерфейсы, экземпляры класса – все эти понятия далеки от мира 1с. Но ничто не мешает нам выделить суть составляющих паттерна «Стратегия» и правильно их применить. Тогда с точки зрения механизма паттерна «Стратегия» нам понадобится:
1. Точка взаимодействия – объект, с которым будет взаимодействовать вызывающая сторона. Через точку взаимодействия клиент будет передавать информацию о выбранной стратегии выполнения и инициировать запуск алгоритма стратегии. Точкой взаимодействия может быть, например, общий модуль.

2. Соглашение по реализации методов стратегий. В соглашении должны быть перечислены и описаны методы, обязательные к реализации в конкретных стратегиях. Такое соглашение можно оформить в документации и в описании модуля точки взаимодействия.

3. Объекты, реализующие конкретные стратегии. Это объекты, содержащие методы из соглашения п.2, к которым будет переходить управление в момент делегирования вызова от точки взаимодействия. Объекты реализации конкретных стратегий должны содержать все методы из соглашения. Такими объектами-стратегиями могут быть, например, общие модули, модули-менеджеры объектов.
 
Тогда применение паттерна «Стратегия» можно описать так:

• Клиент обращается к точке взаимодействия, передав информацию о выбранной стратегии и входные параметры алгоритма выполнения стратегии.
   
• В точке взаимодействия на основании полученной информации о стратегии управление передается объекту-реализации – вызывается метод объекта-реализации, описанный в соглашении по реализации алгоритмов стратегий. Параметры от клиента «пробрасываются» в этот метод.

В качестве клиента может быть любое место конфигурации (модуль объекта, модуль менеджера, общий модуль и т.д.), из которого можно «дотянуться» до точки взаимодействия.

Пример

В качестве примера использования шаблона проектирования «Стратегия» рассмотрим следующую задачу: необходимо создать алгоритм расчета математического выражения суммы, разности, умножения и деления для двух чисел (такой же пример рассматривается в статье на википедии). Задачу будем решать на пустой конфигурации.
Исходя из описанных условий, можно выделить схожие алгоритмы – это расчет суммы, разности, произведения и частного двух чисел. На вход функциям поступают два числа, а в результате расчета возвращается другое число.  Таким образом, есть четыре стратегии:

• Сумма
• Разность
• Умножение
• Деление

Создадим серверные общие модули, в которые в последующем поместим алгоритмы расчета математического выражения:

Общие модули «Сумма», «Разность», «Умножение», «Деление» - это объекты, реализующие конкретные стратегии.

Далее нам потребуется соглашение по реализации методов стратегии - во всех ранее созданных общих модулях обязательно должна присутствовать функция «РезультатВыражения» с двумя числовыми параметрами, возвращающая числовое значение. Вставим заготовку в созданные ранее общие модули:

#Область СлужебныйПрограммныйИнтерфейс

// Параметры:
//  ПервоеЧисло	 - Число
//  ВтороеЧисло	 - Число
// 
// Возвращаемое значение:
//   - Число
//
Функция РезультатВыражения(ПервоеЧисло, ВтороеЧисло) Экспорт
	
	
КонецФункции

#КонецОбласти

Теперь опишем алгоритмы расчета во вставленной заготовке для каждой стратегии.

#Область СлужебныйПрограммныйИнтерфейс

// Параметры:
//  ПервоеЧисло	 - Число
//  ВтороеЧисло	 - Число
// 
// Возвращаемое значение:
//   - Число - результат сложения первого и второго числа
//
Функция РезультатВыражения(ПервоеЧисло, ВтороеЧисло) Экспорт
	
	Сообщение = Новый СообщениеПользователю;
	Сообщение.Текст = НСтр("ru = 'Вызов стратегии Сумма'");
	Сообщение.Сообщить();
	
	РезультатВыражения = ПервоеЧисло + ВтороеЧисло;
	
	Возврат РезультатВыражения;
	
КонецФункции

#КонецОбласти

#Область СлужебныйПрограммныйИнтерфейс

// Параметры:
//  ПервоеЧисло	 - Число - уменьшаемое
//  ВтороеЧисло	 - Число - вычитаемое
// 
// Возвращаемое значение:
//   - Число - разность первого и второго числа
//
Функция РезультатВыражения(ПервоеЧисло, ВтороеЧисло) Экспорт
	
	Сообщение = Новый СообщениеПользователю;
	Сообщение.Текст = НСтр("ru = 'Вызов стратегии Разность'");
	Сообщение.Сообщить();
	
	РезультатВыражения = ПервоеЧисло - ВтороеЧисло;
	
	Возврат РезультатВыражения;
	
КонецФункции

#КонецОбласти

#Область СлужебныйПрограммныйИнтерфейс

// Параметры:
//  ПервоеЧисло	 - Число
//  ВтороеЧисло	 - Число
// 
// Возвращаемое значение:
//   - Число - произведение первого и второго числа
//
Функция РезультатВыражения(ПервоеЧисло, ВтороеЧисло) Экспорт
	
	Сообщение = Новый СообщениеПользователю;
	Сообщение.Текст = НСтр("ru = 'Вызов стратегии Умножение'");
	Сообщение.Сообщить();
	
	РезультатВыражения = ПервоеЧисло * ВтороеЧисло;
	
	Возврат РезультатВыражения;
	
КонецФункции

#КонецОбласти

#Область СлужебныйПрограммныйИнтерфейс

// Параметры:
//  ПервоеЧисло	 - Число - делимое 
//  ВтороеЧисло	 - Число - делитель
// 
// Возвращаемое значение:
//   - Число - частное первого числа от второго 
//
Функция РезультатВыражения(ПервоеЧисло, ВтороеЧисло) Экспорт
	
	Сообщение = Новый СообщениеПользователю;
	Сообщение.Текст = НСтр("ru = 'Вызов стратегии Деление'");
	Сообщение.Сообщить();
	
	РезультатВыражения = ПервоеЧисло / ВтороеЧисло;
	
	Возврат РезультатВыражения;
	
КонецФункции

#КонецОбласти

#Область ПрограммныйИнтерфейс

// Возвращает результат выбранной математической
// операции двух чисел
//
// Параметры:
//  Операция	 - Строка - математическое выражение. 
//				   Допустимые значения: "Сумма", "Разность",
//				   "Умножение", "Деление".
//
//  ПервоеЧисло	 - Число
//  ВтороеЧисло	 - Число
// 
// Возвращаемое значение:
//   - Число - результат математической операции первого и второго числа
//
Функция РезультатМатематическойОперации(Операция, ПервоеЧисло, ВтороеЧисло) Экспорт
	
	// 1. Получим объект-реализации стратегии математической операции (общий модуль)
	МодульРеализацииРасчета = Вычислить(Операция);
	
	// 2. Делегируем выполнение расчета объекту-реализации конкретной стратегии
	РезультатОперации = МодульРеализацииРасчета.РезультатВыражения(ПервоеЧисло, ВтороеЧисло);
	
	Возврат РезультатОперации;
	
КонецФункции

#КонецОбласти

#Область ПрограммныйИнтерфейс

// Вычисляет результат выбранной математической
// операции двух чисел. Выражение указывается в 
// реквизите "МатематическаяОперация"; 
// параметры - в реквизитах "ПервоеЧисло", "ВтороеЧисло";
// результат вычисления помещается в реквизит "Результат"
//
Процедура РасчитатьРезультатМатематическогоВыражения() Экспорт
	
	Результат = МатематическиеВыражения.РезультатМатематическойОперации(МатематическаяОперация,
					ПервоеЧисло, ВтороеЧисло);
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура РассчитатьВыражение(Команда)
	
	Если НЕ ЗначениеЗаполнено(Объект.МатематическаяОперация) Тогда
		ПоказатьПредупреждение(, НСтр("ru = 'Необходимо выбрать математическую операцию'"), 20);
		Возврат;
	КонецЕсли;
	
	Если Объект.МатематическаяОперация = "Деление" И Объект.ВтороеЧисло = 0 Тогда
		ПоказатьПредупреждение(, НСтр("ru = 'Деление на 0 недопустимо'"), 20);
		Возврат;
	КонецЕсли;
	
	РассчитатьВыражениеНаСервере();
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаСервере
Процедура РассчитатьВыражениеНаСервере()
	
	ОбработкаОбъект = РеквизитФормыВЗначение("Объект");
	ОбработкаОбъект.РасчитатьРезультатМатематическогоВыражения();
	
	ЗначениеВРеквизитФормы(ОбработкаОбъект, "Объект");
	
КонецПроцедуры

#КонецОбласти