Добавление своих отборов в обработку по формированию заказов по потребностям

27.02.25

Разработка - Механизмы типовых конфигураций

В этой статье расскажу, как можно добавлять свои отборы в типовую обработку формирования заказов по потребностям с минимальными доработками.

Содержание

Постановка задачи
Макет МакетКомпоновкиДляСерверныхОтборов
Модуль менеджера обработки
Резюме

В ERP есть обработка по формированию заказов по потребностям, она регулярно используется для:

Формирования заказов на перемещение в соответствии со схемами обеспечения
Формирования заказов поставщику для пополнения ЦМС по поддержанию нормативных запасов.

Находится здесь.

Ввиду особенности учета и схем обеспечения часто приходится накладывать отборы перед формированием исходных данных.

Рис. 1

Часто бывает, что текущих отборов недостаточно. Предлагаю добавить свой.

Постановка задачи

Дана база ERP (на момент написания статьи версия - 2.5.17.155). Необходимо добавить новый отбор по дополнительным сведениям заказов на внутреннее потребление. Назовем его “Хороший заказ”. Зайдем в конфигуратор.

Обработка.

Рис. 2

Все, что нам потребуется:

поправить макет МакетКомпоновкиДляСерверныхОтборов
поправить модуль менеджера обработки

Править будем в расширении.

Макет МакетКомпоновкиДляСерверныхОтборов

Макет СКД. Отвечает за вывод всех доступных полей отборов Собственно поля отборов на рис. 1 – это отборы из компоновщика настроек этого макета.

В макете правим текст запроса, правки выделены комментарием
//Вставка
//КонецВставки

ВЫБРАТЬ
  Склады.Ссылка КАК Склад,
  ВЫРАЗИТЬ(NULL КАК Справочник.Склады) КАК СкладОтгрузкиЗаказа,
  ВЫРАЗИТЬ(NULL КАК Справочник.СтруктураПредприятия) КАК ПодразделениеПолучатель,
  ВЫРАЗИТЬ(NULL КАК Справочник.Номенклатура) КАК Номенклатура,
  СпрХарактеристика.Ссылка КАК Характеристика,
  СпрНазначение.Ссылка КАК Назначение,
  СпрНаправленияДеятельности.Ссылка КАК НаправлениеДеятельности,
  СпрПодразделение.Ссылка КАК Подразделение,
  СпрСпособыОбеспечения.Ссылка КАК СпособОбеспечения,
  СпрСегментНоменклатуры.Ссылка КАК СегментНоменклатуры,
  ВЫРАЗИТЬ(NULL КАК Перечисление.ТипыОбеспечения) КАК ТипОбеспечения,
  ВЫРАЗИТЬ(NULL КАК ЧИСЛО) КАК КодСтроки,
  ВЫРАЗИТЬ(NULL КАК ЧИСЛО) КАК РаспределеноНаСкладе,
  ВЫРАЗИТЬ(NULL КАК ЧИСЛО) КАК РаспределеноИзЗаказов,
  ВЫРАЗИТЬ(NULL КАК ЧИСЛО) КАК НеОбеспечено,
  ВЫРАЗИТЬ(NULL КАК ДАТА) КАК ДатаОтгрузки,
  ВЫРАЗИТЬ(NULL КАК ДАТА) КАК ДатаОтгрузкиЗаказа,
  СпрНазначение.Заказ КАК Заказ,
  //Вставка
    ВЫБОР
    КОГДА ДопСведенияЗаказ.Значение = ИСТИНА
      ТОГДА ИСТИНА
    ИНАЧЕ ЛОЖЬ
  КОНЕЦ КАК ХорошийЗаказ,
    //КонецВставки
  СпрСпособыОбеспечения.ИсточникОбеспеченияПотребностей КАК ИсточникОбеспечения,
  &ИспользуетсяОтборПоСегментуНоменклатуры КАК Параметр1,
  &ИспользоватьХарактеристикиНоменклатуры КАК Параметр2,
  &ИспользуетсяОтборПоЗаказам КАК Параметр3
{ВЫБРАТЬ
  Склад.* КАК Склад,
  СкладОтгрузкиЗаказа.* КАК СкладОтгрузкиЗаказа,
  Номенклатура.* КАК Номенклатура,
  Характеристика.* КАК Характеристика,
  Назначение.* КАК Назначение,
  НаправлениеДеятельности.* КАК НаправлениеДеятельности,
  Подразделение.* КАК Подразделение,
  ПодразделениеПолучатель.* КАК ПодразделениеПолучатель,
  СпособОбеспечения.* КАК СпособОбеспечения,
  СегментНоменклатуры.* КАК СегментНоменклатуры,
  ТипОбеспечения КАК ТипОбеспечения,
  ИсточникОбеспечения.* КАК ИсточникОбеспечения,
  КодСтроки КАК КодСтроки,
  Заказ.* КАК Заказ,
  //Вставка
  ХорошийЗаказ КАК ХорошийЗаказ,
  //КонецВставки
  ДатаОтгрузки КАК ДатаОтгрузки,
  ДатаОтгрузкиЗаказа КАК ДатаОтгрузкиЗаказа,
  РаспределеноНаСкладе КАК РаспределеноНаСкладе,
  РаспределеноИзЗаказов КАК РаспределеноИзЗаказов,
  НеОбеспечено КАК НеОбеспечено}
ИЗ
  Справочник.ХарактеристикиНоменклатуры КАК СпрХарактеристика,
  Справочник.Склады КАК Склады,
  Справочник.НаправленияДеятельности КАК СпрНаправленияДеятельности,
  Справочник.Назначения КАК СпрНазначение
  
    //Вставка
    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК ДопСведенияЗаказ
    ПО СпрНазначение.Заказ = ДопСведенияЗаказ.Объект
      И (ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(СпрНазначение.Заказ) = ТИП(Документ.ЗаказНаВнутреннееПотребление)
          ТОГДА ДопСведенияЗаказ.Свойство.Имя = "ХорошийЗаказ"
        ИНАЧЕ ЛОЖЬ
      КОНЕЦ),
     //КонецВставки
      
  Справочник.СтруктураПредприятия КАК СпрПодразделение,
  Справочник.СегментыНоменклатуры КАК СпрСегментНоменклатуры,
  Справочник.СпособыОбеспеченияПотребностей КАК СпрСпособыОбеспечения
{ГДЕ
  Склады.Ссылка.* КАК Склад,
  (ВЫРАЗИТЬ(NULL КАК Справочник.СтруктураПредприятия)) КАК ПодразделениеПолучатель,
  (ВЫРАЗИТЬ(NULL КАК Справочник.Номенклатура)).* КАК Номенклатура,
  СпрХарактеристика.Ссылка КАК Характеристика,
  СпрНазначение.Ссылка.* КАК Назначение,
  СпрНаправленияДеятельности.Ссылка.* КАК НаправлениеДеятельности,
  СпрПодразделение.Ссылка КАК Подразделение,
  СпрСпособыОбеспечения.Ссылка.* КАК СпособОбеспечения,
  СпрСегментНоменклатуры.Ссылка КАК СегментНоменклатуры,
  (ВЫРАЗИТЬ(NULL КАК Перечисление.ТипыОбеспечения)) КАК ТипОбеспечения,
  СпрНазначение.Заказ.* КАК Заказ,
  //Вставка
  (ВЫБОР
      КОГДА ДопСведенияЗаказ.Значение = ИСТИНА
        ТОГДА ИСТИНА
      ИНАЧЕ ЛОЖЬ
    КОНЕЦ) КАК ХорошийЗаказ,
   //КонецВставки
  СпрСпособыОбеспечения.ИсточникОбеспеченияПотребностей.* КАК ИсточникОбеспечения}

Во вкладке настройки добавляем новое поле в выбранные поля и в отбор (рис. 3)

В отборе ставим быстрый выбор (рис. 4).

Модуль менеджера обработки

В модуле менеджера правим всего 3 функции.

ВременнаяТаблицаОтборПоЗаказам()
ВременнаяТаблицаТоваровДляПоддержанияЗапаса()
ПолучитьЗапросСОтборамиКомпоновкиДанных()

Правки выделены комментарием
//Вставка
//КонецВставки.

ВременнаяТаблицаОтборПоЗаказам()

Правим текст запроса с упоминанием нового поля и условием в компоновке, чтобы по имени отборы мы могли его установить

&Вместо("ВременнаяТаблицаОтборПоЗаказам")
Функция Расш_ВременнаяТаблицаОтборПоЗаказам()
  
  //Результат = ПродолжитьВызов();
  
  МассивТекстов = Новый Массив;
  
  МассивТекстов.Добавить(
    "ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |  РеестрДокументов.Ссылка КАК Заказ
    |ПОМЕСТИТЬ ОтборПоЗаказам
    |ИЗ РегистрСведений.РеестрДокументов КАК РеестрДокументов
    //Вставка
    |  ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК ДопСведенияЗаказ
    |  ПО РеестрДокументов.Ссылка = ДопСведенияЗаказ.Объект
    |    И ВЫБОР 
    |    КОГДА ТипЗначения(РеестрДокументов.Ссылка) = Тип(Документ.ЗаказНаВнутреннееПотребление) 
    |      ТОГДА ДопСведенияЗаказ.Свойство.Имя = ""ХорошийЗаказ""
    |    ИНАЧЕ ЛОЖЬ КОНЕЦ
    //КонецВставки
    |ГДЕ
    |  &ИспользуетсяОтборПоЗаказам
    |{ГДЕ
    |  РеестрДокументов.Ссылка.* КАК Заказ,
    |  РеестрДокументов.НаправлениеДеятельности.* КАК НаправлениеДеятельности,
        //Вставка
    |  ВЫБОР КОГДА ДопСведенияЗаказ.Значение = ИСТИНА ТОГДА ИСТИНА ИНАЧЕ ЛОЖЬ КОНЕЦ КАК ХорошийЗаказ
        //КонецВставки
        }");
     
  //++ НЕ УТКА
  Если ПравоДоступа("Чтение", Метаданные.Документы.ЭтапПроизводства2_2) Тогда
    МассивТекстов.Добавить(
      "ВЫБРАТЬ
      |  ЭтапПроизводства2_2.Ссылка
      |ИЗ
      |  Документ.ЭтапПроизводства2_2 КАК ЭтапПроизводства2_2
      |ГДЕ
      |  &ИспользуетсяОтборПоЗаказам
      |{ГДЕ
      |  ЭтапПроизводства2_2.Распоряжение.* КАК Заказ,
      |  ЭтапПроизводства2_2.НаправлениеДеятельности.* КАК НаправлениеДеятельности}
      |
      |ОБЪЕДИНИТЬ ВСЕ
      |
      |ВЫБРАТЬ
      |  ЭтапПроизводства2_2.Ссылка
      |ИЗ
      |  Документ.ЭтапПроизводства2_2 КАК ЭтапПроизводства2_2
      |ГДЕ
      |  &ИспользуетсяОтборПоЗаказам
      |  И ЭтапПроизводства2_2.ПроизводствоНаСтороне
      |{ГДЕ
      |  ЭтапПроизводства2_2.ЗаказПереработчику.* КАК Заказ,
      |  ЭтапПроизводства2_2.НаправлениеДеятельности.* КАК НаправлениеДеятельности}");
  КонецЕсли;
  
  Если ПравоДоступа("Чтение", Метаданные.РегистрыСведений.СтруктураЗаказа) Тогда
    МассивТекстов.Добавить(
      "ВЫБРАТЬ РАЗЛИЧНЫЕ
      |  СтруктураЗаказа.ЗаказНаПроизводство
      |ИЗ
      |  РегистрСведений.СтруктураЗаказа КАК СтруктураЗаказа
      |ГДЕ
      |  &ИспользуетсяОтборПоЗаказам
      |{ГДЕ
      |  СтруктураЗаказа.ЗаказНаПроизводство.* КАК Заказ,
      |  СтруктураЗаказа.ЗаказНаПроизводство.НаправлениеДеятельности.* КАК НаправлениеДеятельности}");
  КонецЕсли;
  //-- НЕ УТКА
  
  Возврат СтрСоединить(МассивТекстов, ОбщегоНазначенияУТ.РазделительЗапросовВОбъединении());
  
КонецФункции

ВременнаяТаблицаТоваровДляПоддержанияЗапаса()

ВременнаяТаблицаТоваровДляПоддержанияЗапаса()

Добавляем поле с именем нашего отбора. Иначе система на стадии вывода таблицы товаров для поддержания запасов заругается на отсутствие поля с нашим именем

&Вместо("ВременнаяТаблицаТоваровДляПоддержанияЗапаса")
Функция Расш_ВременнаяТаблицаТоваровДляПоддержанияЗапаса()
	
	//Результат = ПродолжитьВызов();
	
	ТекстЗапроса =
	"ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	НоменклатураСегмента.Номенклатура    КАК Номенклатура,
	|	НоменклатураСегмента.Характеристика  КАК Характеристика
	|ПОМЕСТИТЬ ОтборПоСегментам
	|ИЗ
	|	РегистрСведений.НоменклатураСегмента КАК НоменклатураСегмента
	|		{ГДЕ
	|			НоменклатураСегмента.Номенклатура.*    КАК Номенклатура,
	|			НоменклатураСегмента.Характеристика.*  КАК Характеристика,
	|			НоменклатураСегмента.Сегмент.*         КАК СегментНоменклатуры}
	|ГДЕ
	|	&ИспользуетсяОтборПоСегментуНоменклатуры
	|ИНДЕКСИРОВАТЬ ПО
	|	Номенклатура,
	|	Характеристика
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|" + Справочники.ФорматыМагазинов.ТекстЗапросаВтФорматыСкладов(Ложь)
	+ РегистрыСведений.ТоварныеОграничения.ВременнаяТаблицаТоварыПоддерживаемогоЗапаса()
	+ "ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	Т.Номенклатура                       КАК Номенклатура,
	|	Т.Характеристика                     КАК Характеристика,
	|	Т.Склад                              КАК Склад,
	|
	|	СпрСпособ.Ссылка                     КАК СпособОбеспечения
	|
	|ПОМЕСТИТЬ ВтТовары
	|ИЗ
	|	ВтТоварыПоддерживаемогоЗапаса КАК Т
	|
	|		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпособыОбеспеченияПотребностей КАК СпрСпособ
	|		ПО &ПодстановкаОсновногоСпособаОбеспечения
	|
	//отборы компоновщика
	|{ГДЕ
	|	ЗНАЧЕНИЕ(Справочник.Назначения.ПустаяСсылка)              КАК Назначение,
	|	ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка)    КАК ПодразделениеПолучатель,
	|	ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка) КАК НаправлениеДеятельности,
	|	ВЫРАЗИТЬ(NULL КАК Справочник.Назначения).Заказ.*          КАК Заказ,
//Вставка
	|	ЛОЖЬ КАК ХорошийЗаказ
//КонецВставки
	|}
	|
	|{ГДЕ
	|	(ЕСТЬNULL(СпрСпособ.Ссылка,
	|		ЗНАЧЕНИЕ(Справочник.СпособыОбеспеченияПотребностей.ПустаяСсылка))).*           КАК СпособОбеспечения,
	|	ЕСТЬNULL(СпрСпособ.ТипОбеспечения, ЗНАЧЕНИЕ(Перечисление.ТипыОбеспечения.Покупка)) КАК ТипОбеспечения,
	|	ВЫРАЗИТЬ(
	|		ВЫБОР
	|			КОГДА СпрСпособ.Подразделение <> ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка) ТОГДА
	|				СпрСпособ.Подразделение
	|			ИНАЧЕ
	|				ЕСТЬNULL(Т.Склад.Подразделение,
	|					ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка))
	|		КОНЕЦ КАК Справочник.СтруктураПредприятия).*                                   КАК Подразделение,
	|	(ЕСТЬNULL(СпрСпособ.ИсточникОбеспеченияПотребностей, НЕОПРЕДЕЛЕНО)).*              КАК ИсточникОбеспечения}
	|
	|ИНДЕКСИРОВАТЬ ПО
	|	Номенклатура, Характеристика, Склад,
	|	СпособОбеспечения
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	|УНИЧТОЖИТЬ ВтФорматыСкладов;
	|
	|////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ ПЕРВЫЕ 1
	|	Т.Номенклатура                       КАК Номенклатура,
	|	Т.Характеристика                     КАК Характеристика,
	|	Т.Склад                              КАК Склад,
	|	Т.СпособОбеспечения                  КАК СпособОбеспечения
	|{ВЫБРАТЬ
	|	Номенклатура.*      КАК Номенклатура,
	|	Характеристика.*    КАК Характеристика,
	|	Склад.*             КАК Склад,
	|	СпособОбеспечения.* КАК СпособОбеспечения}
	|ИЗ
	|	ВтТовары КАК Т";
	
	ТекстЗапроса = РегистрыСведений.СхемыОбеспечения.ПодставитьСоединениеДляПолученияСпособаОбеспечения(
	ТекстЗапроса, "ПодстановкаОсновногоСпособаОбеспечения");
	
	Возврат ТекстЗапроса;
	
	
КонецФункции

ПолучитьЗапросСОтборамиКомпоновкиДанных()

Поскольку в нашем случае мы устанавливаем отбор по заказу (в данном случае по его свойствам), то в признак отбора по заказу добавляем и отбор с нашим именем

&Вместо("ПолучитьЗапросСОтборамиКомпоновкиДанных")
Функция Расш_ПолучитьЗапросСОтборамиКомпоновкиДанных(АдресСхемыКомпоновкиДанных, КомпоновщикНастроек, ИмяНабораДанных)
	
	//Результат = ПродолжитьВызов();
	
	СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемыКомпоновкиДанных);

	СегментыСервер.ВключитьОтборПоСегментуНоменклатурыВСКД(КомпоновщикНастроек);

	ОтборКомпоновки = КомпоновщикНастроек.ПолучитьНастройки().Отбор;
	
	ИспользуетсяОтборПоЗаказам = НайтиОтборРекурсивно(ОтборКомпоновки.Элементы, Новый ПолеКомпоновкиДанных("Заказ"))
	
//Вставка
ИЛИ НайтиОтборРекурсивно(ОтборКомпоновки.Элементы, Новый ПолеКомпоновкиДанных("ХорошийЗаказ"))
//КонецВставки
	
Или НайтиОтборРекурсивно(ОтборКомпоновки.Элементы, Новый ПолеКомпоновкиДанных("НаправлениеДеятельности"));

	КомпоновкаДанныхКлиентСервер.УстановитьПараметр(КомпоновщикНастроек, "ИспользуетсяОтборПоЗаказам", Истина, ИспользуетсяОтборПоЗаказам);

	КомпоновщикМакетаКомпоновкиДанных = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакетаКомпоновкиДанных.Выполнить(СхемаКомпоновкиДанных,
	КомпоновщикНастроек.ПолучитьНастройки(),,,, Ложь);

	Запрос = Новый Запрос(МакетКомпоновкиДанных.НаборыДанных[ИмяНабораДанных].Запрос);

	Для каждого ПараметрКомпоновки Из МакетКомпоновкиДанных.ЗначенияПараметров Цикл

		Запрос.УстановитьПараметр(ПараметрКомпоновки.Имя, ПараметрКомпоновки.Значение);

	КонецЦикла;
	ИспользоватьХарактеристикиНоменклатуры = ПолучитьФункциональнуюОпцию("ИспользоватьХарактеристикиНоменклатуры");
	Запрос.УстановитьПараметр("ИспользоватьХарактеристикиНоменклатуры", ИспользоватьХарактеристикиНоменклатуры);
	Возврат Запрос;

КонецФункции

Готово. Теперь в поле отборов появится новый отбор, работающий аналогично типовым.

Резюме

Аналогичным образом можно ставить и другие отборы. Пропишем плюсы и минусы фичи.

Достоинства:

Способ не требует вмешательства в основную конфигурацию и подходит для расширений
Гибкий отбор по механизму СКД. Вариативность по видам сравнения, вложенным полям
Простая и быстрая реализация

Недостатки:

В расширении в функциях используются директивы &Вместо

Автор: Иван К., разработчик 1С.

Вступайте в нашу телеграмм-группу Инфостарт

+6 –

См. также

Механизм представлений: как он работает и как его расширять

Механизмы типовых конфигураций Программист 1С v8.3 Бесплатно (free)

Каждый, кто работал с кадровыми отчетами в ЗУП, ERP или УХ, сталкивался с механизмом представлений – странным кодом запроса, где поля отображаются пустыми ссылками, а в названии временной таблицы есть слово «Представление». В статье разберем, что такое представления и как ими пользоваться. Больше не нужно ломать голову над тем, откуда и как правильно получать данные. Механизм представлений сделает это за вас.

08.07.2025 1602 user2012581 39

Замена поиска по первым символам на поиск по подстроке

Механизмы типовых конфигураций Программист Стажер 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Бесплатно (free)

В типовых решениях типа УТ, КА, ERP при вводе строк в поля ввода осуществляется поиск по первым символам. С помощью небольшой доработки (делается через расширение) можно организовать поиск по вхождению.

02.06.2025 558 lkey 0

Открытие нетиповых форм при начале работы системы в 1С:ERP 2.5

Работа с интерфейсом БСП (Библиотека стандартных подсистем) Механизмы типовых конфигураций Программист 1С v8.3 1C:ERP Бесплатно (free)

В этой статье я расскажу, как в конфигурации 1С:ERP 2.5 при начале работы системы настроить открытие своих нетиповых форм (в том числе и из внешних обработок). Данную методику можно использовать как на тонком клиенте, так и на мобильном или веб-клиенте, а также в мобильном приложении.

12.05.2025 2317 PROSTO-1C 1