Неиспользуемые поля в конечных запросах построителя отчетов и СКД

14.04.14

Разработка - СКД

Оказывается, если в конечном запросе построителя (или СКД) не используются какие-то поля, то они вырезаются и из верхней подчиненной таблицы, что в некоторых случаях может привести к некорректным результатам

Работая с конфигурацией "Консолидация", вплотную столкнулся с одним механизмом работы построителя отчетов (т.к. в этой конфигурации все завязано на построителе).

Смысл в том, что если в конечном запросе построителя не используются какие-то поля, то они вырезаются и из верхней подчиненной таблицы, что в некоторых случаях может привести к некорректным результатам. Приведем пример двух запросов, которые вроде бы должны давать идентичные данные, но на практике данные разнятся.

Для примера возьмем справочник подразделений, у которого есть реквизит «Головное подразделение». Тестовая таблица выглядит так:

Запрос будет выглядеть следующим образом:

ВЫБРАТЬ
    Подразделения.ГоловноеПодразделение,
    Подразделения.Ссылка КАК Подразделение,
    1 КАК Количество
ПОМЕСТИТЬ Подр
ИЗ
    Справочник.Подразделения КАК Подразделения
ГДЕ
    НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)

СГРУППИРОВАТЬ ПО
    Подразделения.ГоловноеПодразделение,
    Подразделения.Ссылка
;
ВЫБРАТЬ
    Подр.ГоловноеПодразделение КАК ГоловноеПодразделение,
    СУММА(Подр.Количество) КАК КоличествоГоловного
ИЗ
    Подр КАК Подр

СГРУППИРОВАТЬ ПО
    Подр.ГоловноеПодразделение

По логике, данный запрос должен нам показать, сколько подразделений содержится в каждом из головных подразделений. Но на практике, выполнив данный запрос построителем, мы получим следующие данные:

Возникает резонный вопрос: «Что за … ?». Давайте проанализируем итоговый текст запроса, который формирует сам построитель. Мы увидим, что текст запроса будет следующим:

ВЫБРАТЬ
   Подразделения.ГоловноеПодразделение КАК ГоловноеПодразделение,
   1 КАК Количество
ПОМЕСТИТЬ Подр
ИЗ
   Справочник.Подразделения КАК Подразделения
ГДЕ
   НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)
 
СГРУППИРОВАТЬ ПО
   Подразделения.ГоловноеПодразделение
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Подр.ГоловноеПодразделение КАК ГоловноеПодразделение,
   СУММА(Подр.Количество) КАК КоличествоГоловного
ИЗ
   Подр КАК Подр
 
СГРУППИРОВАТЬ ПО
   Подр.ГоловноеПодразделение

Т.е. построитель, неиспользуемое поле «Подразделение» дополнительно убрал и из временной таблицы (видимо в целях оптимизации). Осталось выяснить, для всех ли временных таблиц такое происходит. Добавим в запрос промежуточную временную таблицу, в которой просто выберем результат предыдущей:

ВЫБРАТЬ
    Подразделения.ГоловноеПодразделение,
    Подразделения.Ссылка КАК Подразделение,
    1 КАК Количество
ПОМЕСТИТЬ Подр1
ИЗ
    Справочник.Подразделения КАК Подразделения
ГДЕ
    НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)

СГРУППИРОВАТЬ ПО
    Подразделения.ГоловноеПодразделение,
    Подразделения.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Подр1.ГоловноеПодразделение,
    Подр1.Подразделение,
    Подр1.Количество
ПОМЕСТИТЬ Подр
ИЗ
    Подр1 КАК Подр1
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Подр.ГоловноеПодразделение КАК ГоловноеПодразделение,
    СУММА(Подр.Количество) КАК КоличествоГоловного
ИЗ
    Подр КАК Подр

СГРУППИРОВАТЬ ПО
    Подр.ГоловноеПодразделение

Выполнив запрос, мы получим результат:

Т.е. мы получили верные логические результаты. Давайте посмотрим на запрос, который формирует построитель:

ВЫБРАТЬ
   Подразделения.ГоловноеПодразделение КАК ГоловноеПодразделение,
   Подразделения.Ссылка КАК Подразделение,
   1 КАК Количество
ПОМЕСТИТЬ Подр1
ИЗ
   Справочник.Подразделения КАК Подразделения
ГДЕ
   НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)
 
СГРУППИРОВАТЬ ПО
   Подразделения.ГоловноеПодразделение,
   Подразделения.Ссылка
;
 
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Подр1.ГоловноеПодразделение КАК ГоловноеПодразделение,
   Подр1.Количество КАК Количество
ПОМЕСТИТЬ Подр
ИЗ
   Подр1 КАК Подр1
;
 
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Подр.ГоловноеПодразделение КАК ГоловноеПодразделение,
   СУММА(Подр.Количество) КАК КоличествоГоловного
ИЗ
   Подр КАК Подр
 
СГРУППИРОВАТЬ ПО
   Подр.ГоловноеПодразделение

Получается, что построитель убирает неиспользуемые поля только из временных таблиц первого уровня, поэтому мы и получили другой результат.

Проделав эти же манипуляции со схемой компоновки данных, можно убедится, что и она работает абсолютно так же.

Вывод: Оптимизация это конечно хорошо, но иногда надо быть осторожным.

запрос построитель система компоновки данных СКД

См. также

Инструментарий разработчика Роли и права Запросы СКД Программист Руководитель проекта Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Платные (руб)

Инструменты для разработчиков 1С 8.3: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.

12000 руб.

02.09.2020    171913    964    403    

924

СКД Программист Платформа 1С v8.3 Система компоновки данных Бесплатно (free)

СКД – инструмент, на базе которого в современных конфигурациях реализованы практически все отчеты. СКД используется в динамических списках, печатных формах и универсальных механизмах. Если построить простейший отчет может каждый разработчик, то с нюансами знакомы далеко не все. Расскажем о неочевидных на первый взгляд приемах, способных значительно повысить качество отчетов.

24.12.2024    5839    Akcium    13    

41

Запросы СКД Программист Стажер Система компоновки данных Россия Бесплатно (free)

Часто при разработке отчетов в СКД возникает ситуация, когда не совсем понятно, почему отчет выводит не те данные, которые нужны, либо не выводит вовсе. Возникает потребность увидеть конечный запрос, который формирует СКД. Как это сделать, рассмотрим в этой статье.

15.05.2024    10690    implecs_team    6    

48

Инструментарий разработчика СКД Программист Платформа 1С v8.3 1C:Бухгалтерия Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    8064    59    obmailok    21    

80

Запросы СКД Программист Платформа 1С v8.3 Управляемые формы 1C:Бухгалтерия Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    3401    6    Yashazz    1    

34

СКД WEB-интеграция Программист Платформа 1С v8.3 1C:Бухгалтерия Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    11658    25    John_d    25    

126

СКД Программист Платформа 1С v8.3 Система компоновки данных 1C:Бухгалтерия Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    9147    PROSTO-1C    15    

69
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. artbear 1566 15.04.14 19:04 Сейчас в теме
2. wolfsoft 2421 16.04.14 09:06 Сейчас в теме
А если так?
ВЫБРАТЬ
            Подразделения.ГоловноеПодразделение,
            Подразделения.Ссылка КАК Подразделение,
            МАКСИМУМ(1) КАК Количество
ПОМЕСТИТЬ Подр
ИЗ
            Справочник.Подразделения КАК Подразделения
ГДЕ
            НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)
 
СГРУППИРОВАТЬ ПО
            Подразделения.ГоловноеПодразделение,
            Подразделения.Ссылка
Показать
3. andogskiy 16.04.14 10:25 Сейчас в теме
Что-то пример не совсем удачный.
Зачем тут вообще временные таблицы? Не проще ли сделать сразу такой запрос:
ВЫБРАТЬ
   Подразделения.ГоловноеПодразделение КАК ГоловноеПодразделение,
   (КОЛИЧЕСТВО РАЗЛИЧНЫХ Подразделения.Ссылка) КАК КоличествоГоловного
ИЗ
   Справочник.Подразделения КАК Подразделения
ГДЕ
   НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)
 
СГРУППИРОВАТЬ ПО
   Подразделения.ГоловноеПодразделение
Показать
4. Matveymc 150 16.04.14 10:39 Сейчас в теме
(3) andogskiy, Конечно проще. Пример взят максимально простой, чтоб показать ошибку
5. vardo 53 16.04.14 10:55 Сейчас в теме
В СКД можно сказать измернию что оно обязательное. Тогда будет все ок.
7. Matveymc 150 17.04.14 08:38 Сейчас в теме
(5) vardo, В конечном запросе два поля: "ГоловноеПодразделение" и "КоличествоГоловного". Поставив обоим в роли "Обязательное" проблема не решится (проверил только что, платформа 1С:Предприятие 8.2 (8.2.18.109)). Т.к. система убирает поле Подразделения.Ссылка, которое даже не участвует в конечном запросе
6. bulpi 217 16.04.14 14:49 Сейчас в теме
Никогда с таким не сталкивался, но, ИМХО, это не фича, а баг :) И во всех ли релизах он есть?
8. Matveymc 150 17.04.14 08:46 Сейчас в теме
(6) bulpi, ну на последней платформе (1С:Предприятие 8.3 (8.3.4.465)) ошибка сохраняется
9. nixel 1441 18.04.14 12:42 Сейчас в теме
(6) bulpi, это не баг.
Построитель, как и СКД переформировывает запрос на основании схемы/настроек построителя И/ИЛИ пользовательских настроек. Понимание механизмов работы инструментов и смысла свойств-галочек позволяет избежать таких ошибок.
Большинство таких "проблем" разруливается на уровне вкладки "Построитель/Компоновка данных" в конструкторе запросов.
Ну и чтение офф. литературы помогает, да.
10. cargobird 308 29.06.16 11:54 Сейчас в теме
Первый раз в жизни занимался "кощунством" - собирал временные таблицы в запросе построителя отчета обратно во вложенные, чтобы оптимизатор не резал поля очень нужной временной таблицы первого уровня....
11. cargobird 308 04.07.16 10:41 Сейчас в теме
Рано радовался...
Попался пример, в котором под одним пользователем одно из полей считается необязательным, и его построитель "режет", а под другим - не режет.
Права и прочее одинаковое, а тексты запроса по ПостроительОтчета.ПолучитьЗапрос() разные.
12. cargobird 308 04.07.16 12:00 Сейчас в теме
(11) cargobird, причем убиралось поле из конечного запроса, в других местах запроса этого поля не было.
Оказалось, что дело было в сохраненных через форму настройках построителя отчета.
Именно в момент применения настроек ПостроительОтчета.ПолучитьЗапрос() выдавал запрос уже без требуемого поля.
Сбросил настройку - текст запроса стал формироваться как надо.
13. olbu 04.05.17 15:25 Сейчас в теме
А как избежать удаления поля, ну кроме как, вывести его в конечный результат? Я так же заметил, что выставление "Обязательное" - все равно удаляет поле... Причем поле нужно для фильтрации в конечном результате...
14. dimon_upi 22.08.17 15:27 Сейчас в теме
В построителе обошелся таким подходом:
	МассивПолей = Новый Массив;
	МассивПолей.Добавить("Поле1");
	МассивПолей.Добавить("Поле2");
	МассивПолей.Добавить("Поле3");
	
	Для каждого ЭлементМассиваПолей из МассивПолей Цикл
		Если ПостроительОтчета.ВыбранныеПоля.Найти(ЭлементМассиваПолей) = неопределено Тогда
			ПостроительОтчета.ВыбранныеПоля.Добавить(ЭлементМассиваПолей);
		КонецЕсли;	
	КонецЦикла;	
Показать
15. AJIekceuT 15.04.22 11:15 Сейчас в теме
Приветствую, коллеги! Тоже бился как победить компоновщик. Мне нужно было из исходной таблицы остатков сделать сводку где участвуют только детальные записи остатков удовлетворяющие одному условию на ресурс (ВыручкаОстатки.НеДляПлановРГПОстаток = 0).

Если в исходную таблицу остатков вставить условия по измерениям друг на друга, то в сгруппированной таблице остатков самого первого уровня останутся только нужные данные:

ВЫБРАТЬ
	ВыручкаОстатки.Менеджер КАК Менеджер,
	СУММА(ВыручкаОстатки.ПодтвержденнаяОстаток) КАК ПодтвержденнаяОстаток
ПОМЕСТИТЬ ВТ
ИЗ
	РегистрНакопления.Выручка.Остатки(	, ) КАК ВыручкаОстатки
ГДЕ
	( ВыручкаОстатки.GUIDПозицииЗаказа = ВыручкаОстатки.GUIDПозицииЗаказа
				И ВыручкаОстатки.Заказ = ВыручкаОстатки.Заказ
				И ВыручкаОстатки.Проект = ВыручкаОстатки.Проект
				И ВыручкаОстатки.Город = ВыручкаОстатки.Город
				И ВыручкаОстатки.ТипРекламы = ВыручкаОстатки.ТипРекламы
				И ВыручкаОстатки.Позиция = ВыручкаОстатки.Позиция
				И ВыручкаОстатки.НеДляПлановРГПОстаток = 0)

СГРУППИРОВАТЬ ПО
	ВыручкаОстатки.Менеджер
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВТ.Менеджер КАК Менеджер,
	ВТ.ПодтвержденнаяОстаток КАК Остаток
ИЗ
	ВТ КАК ВТ
Показать
16. user1863362 26.11.24 08:38 Сейчас в теме
17. andadra 26.11.24 09:16 Сейчас в теме
Вот так будет работать

ВЫБРАТЬ
    Подразделения.ГоловноеПодразделение,
    1 КАК Количество
ПОМЕСТИТЬ Подр
ИЗ
    Справочник.Подразделения КАК Подразделения
ГДЕ
    НЕ Подразделения.ГоловноеПодразделение=ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)

СГРУППИРОВАТЬ ПО
    Подразделения.ГоловноеПодразделение,
    Подразделения.Ссылка
;
ВЫБРАТЬ
    Подр.ГоловноеПодразделение КАК ГоловноеПодразделение,
    СУММА(Подр.Количество) КАК КоличествоГоловного
ИЗ
    Подр КАК Подр

СГРУППИРОВАТЬ ПО
    Подр.ГоловноеПодразделение
Показать




Нужно поле убрать из выборки, но оставить группировку по нему, тогда оно не будет очищаться
Оставьте свое сообщение