Программный запуск регламентированных бухгалтерских отчетов

04.12.20

Задачи пользователя - Менеджеры внешних отчетов

Программный запуск отчета Баланс или ОФР для получения значений его показателей.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование		По подписке [?]	Купить один файл
ПрограммныйЗапускРегламентированныйОтчетБухОтчетность.epf .epf 12,65Kb 18	18	Скачать (1 SM)	Купить за 1 850 руб.
ЗапускРегламентированныйОтчетБухОтчетностьВФоне.epf .epf 12,63Kb 1	1	Скачать (1 SM)	Купить за 1 850 руб.

Описание

Точно работает на Бухгалтерия предприятия, редакция 3.0 (3.0.82.34)

Обработки демонстрируют способ программного вызова регламентированной отчетности, для получения значений показателей строк Баланса и ОФР.

Затем эти показатели можно ещё и расшифровать по двойному щелчку (смотри скрин).

Навеяно отчетом ФинансовыйАнализ, который вызывает баланс динамически и выводит его показатели к себе в форму.

Создано на основе ОбщийМодуль.ИнтерфейсыВзаимодействияБро, в котором есть масса примеров вызова регламентированной отчетности из вне.

Предупреждение: данные формируются динамически, так, как если нажать кнопку "Заполнить" регламентированной отчетности. А не подтягиваются из сохраненных документов отчетности.

Реализовано 2 обработки:

1 ПрограммныйЗапускРегламентированныйОтчетБухОтчетность.epf

Работает в синхронном режиме. Использует метод РегламентированнаяОтчетностьПереопределяемый.ЗаполнитьОтчет. Весь код находится в форме обработки, он под спойлером.

Код обработки

&НаСервере
Функция ФормыБухОтчетностиДействующиеВВыбранныйПериод(ВсеДоступныеФормы, ДатаКонцаПериода)
	
	Результат = ВсеДоступныеФормы.СкопироватьКолонки();
	
	Для Каждого ДоступнаяФорма Из ВсеДоступныеФормы Цикл
		ДатаНачалаДействияФормы = ДоступнаяФорма.ДатаНачалоДействия;
		Если ДоступнаяФорма.ДатаКонецДействия = РегламентированнаяОтчетностьКлиентСервер.ПустоеЗначениеТипа(Тип("Дата")) Тогда
			ДатаКонцаДействияФормы = '20991231';
		Иначе
			ДатаКонцаДействияФормы = КонецДня(ДоступнаяФорма.ДатаКонецДействия);
		КонецЕсли;
		
		Если ДатаКонцаПериода <= ДатаКонцаДействияФормы
			И ДатаКонцаПериода >= ДатаНачалаДействияФормы Тогда
			
			НоваяФорма = Результат.Добавить();
			ЗаполнитьЗначенияСвойств(НоваяФорма, ДоступнаяФорма);
			
		КонецЕсли;
	КонецЦикла;
	
	Результат.Сортировать("ДатаКонецДействия Убыв");
	Возврат Результат;
	
КонецФункции

&НаСервере
Процедура ЗапуститьНаСервере()
	
	ИДОтчета = "РегламентированныйОтчетБухОтчетность";
	ОбъектОтчета = РегламентированнаяОтчетностьВызовСервера.ОтчетОбъект(ИДОтчета);
	
	УчетОтложенногоНалогаБалансовымМетодом = РегламентированнаяОтчетность.УчетОтложенногоНалогаБалансовымМетодом(Организация, СтандартныйПериод.ДатаОкончания);
	ВсеФормыОтчета = ОбъектОтчета.ТаблицаФормОтчета(УчетОтложенногоНалогаБалансовымМетодом);
	
	ДействующиеФормы = ФормыБухОтчетностиДействующиеВВыбранныйПериод(ВсеФормыОтчета, СтандартныйПериод.ДатаОкончания);
	Если ДействующиеФормы.Количество() = 0 Тогда
		Возврат;
	КонецЕсли;
	
	// Список действующих форм отсортирован по дате окончания действия. 
	// Заполняем отчет по самой поздней редакции, так же работает автоподстановка формы у Регламентированной отчетности.
	ФормаОтчета = ДействующиеФормы[0]["ФормаОтчета"];
	
	ПараметрыОтчета = Новый Структура;
	
	ПараметрыОтчета.Вставить("Организация", Организация);
	ПараметрыОтчета.Вставить("ГруппаОрганизаций", Новый Массив);
	ПараметрыОтчета.Вставить("мДатаНачалаПериодаОтчета", СтандартныйПериод.ДатаНачала);
	ПараметрыОтчета.Вставить("мДатаКонцаПериодаОтчета", СтандартныйПериод.ДатаОкончания);
	
	ПрименениеЕНВД = РегламентированнаяОтчетностьПереопределяемый.ПлательщикЕНВД(Организация, СтандартныйПериод.ДатаОкончания);
	ПараметрыОтчета.Вставить("ПрименениеЕНВД", ПрименениеЕНВД);
	
	ДеревоНастроекСтрокРасшифровки = Новый ДеревоЗначений;
	ДеревоНастроекСтрокРасшифровки.Колонки.Добавить("ИмяОбластиДопСтроки");
	
	ПараметрыОтчета.Вставить("СоставДополнительныхСтрокБаланс", ДеревоНастроекСтрокРасшифровки.Скопировать());
	ПараметрыОтчета.Вставить("СоставДополнительныхСтрокОПУ", ДеревоНастроекСтрокРасшифровки.Скопировать());
	
	ПараметрыОтчета.Вставить("СтруктураМногострочныхЧастей", Неопределено);
	
	ПараметрыОтчета.Вставить("ЗаполнятьБаланс",     Истина); // Бухгалтерский баланс.
	ПараметрыОтчета.Вставить("ЗаполнятьОФР",        Истина); // Отчет о финансовых результатах.
	ПараметрыОтчета.Вставить("ЗаполнятьОИК",        Ложь); // Отчет об изменениях капитала.
	ПараметрыОтчета.Вставить("ЗаполнятьОДДС",       Ложь); // Отчет о движении денежных средств.
	ПараметрыОтчета.Вставить("ЗаполнятьОЦИПС",      Ложь); // Отчет о целевом использовании средств
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения1", Ложь);
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения2", Ложь);
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения4", Ложь);
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения5", Ложь);
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения6", Ложь);
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения7", Ложь);
	ПараметрыОтчета.Вставить("ЗаполнятьПояснения8", Ложь);
	
	АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(Неопределено, Новый УникальныйИдентификатор);
	ПараметрыОтчета.Вставить("АдресВоВременномХранилище", АдресВоВременномХранилище);
	
	Если Справочники.Организации.ЭтоНекоммерческаяОрганизация(Организация) Тогда
		ПрефиксАвтозаполнения = "БалансНКО";
	Иначе
		ПрефиксАвтозаполнения = "Баланс";
	КонецЕсли;
	
	Если СтандартныйПериод.ДатаОкончания < КонецДня(Дата('2012-01-01')) Тогда
		ИдентификаторАвтозаполнения = ПрефиксАвтозаполнения;
		
	ИначеЕсли СтандартныйПериод.ДатаОкончания < КонецДня(Дата('2012-12-01')) Тогда
		ИдентификаторАвтозаполнения = СтрШаблон("%1_2012Кв1", ПрефиксАвтозаполнения);
		
	ИначеЕсли СтандартныйПериод.ДатаОкончания < КонецДня(Дата('2019-01-01')) Тогда
		ИдентификаторАвтозаполнения = СтрШаблон("%1_2012Кв4_3", ПрефиксАвтозаполнения);
		
	Иначе
		ИдентификаторАвтозаполнения = ПрефиксАвтозаполнения;
		
	КонецЕсли;
	
	Баланс = Новый Структура;
	Баланс.Вставить("ИдентификаторАвтозаполнения", ИдентификаторАвтозаполнения);
	
	ПараметрыОтчета.Вставить("СтруктураОтчета", Новый Структура("Баланс", Баланс));
	
	Контейнер = Новый Структура();
	Контейнер.Вставить("Баланс",        Новый Структура);
	Контейнер.Вставить("ОИК",           Новый Структура);
	Контейнер.Вставить("ОДДС",          Новый Структура);
	Контейнер.Вставить("ОЦИПС",         Новый Структура);
	Контейнер.Вставить("РасчетАктивов", Новый Структура);
	Контейнер.Вставить("Пояснения1",    Новый Структура);
	Контейнер.Вставить("Пояснения2",    Новый Структура);
	Контейнер.Вставить("Пояснения3",    Новый Структура);
	Контейнер.Вставить("Пояснения4",    Новый Структура);
	Контейнер.Вставить("Пояснения5",    Новый Структура);
	Контейнер.Вставить("Пояснения6",    Новый Структура);
	Контейнер.Вставить("Пояснения7",    Новый Структура);
	Контейнер.Вставить("Пояснения8",    Новый Структура);
	Контейнер.Вставить("Пояснения9",    Новый Структура);
	
	Если ФормаОтчета = "ФормаОтчета2011Кв1" 
		Или ФормаОтчета = "ФормаОтчета2011Кв3" 
		Или ФормаОтчета = "ФормаОтчета2011Кв4" Тогда
		
		ИмяСвойстваОФР = "ФормаОтчета";
		Контейнер.Вставить(ИмяСвойстваОФР, Новый Структура);
		
	Иначе
		
		ИмяСвойстваОФР = "ОФР";
		Контейнер.Вставить(ИмяСвойстваОФР, Новый Структура);
		
		ОФР = Новый Структура;
		ОФР.Вставить("ИмяМакета", "");
		ПараметрыОтчета.СтруктураОтчета.Вставить("ОФР", ОФР);
		ПараметрыОтчета.Вставить("СоставДополнительныхСтрокОФР", ДеревоНастроекСтрокРасшифровки.Скопировать());
		
	КонецЕсли;
	
	ПараметрыАвтозаполнения = Новый Структура;
	ПараметрыАвтозаполнения.Вставить("ПараметрыОтчета", ПараметрыОтчета);
	ПараметрыАвтозаполнения.Вставить("Контейнер",       Контейнер);
	ПараметрыАвтозаполнения.Вставить("ИмяСвойстваОФР",  ИмяСвойстваОФР);
		
	АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(Неопределено, Новый УникальныйИдентификатор);
	ПараметрыОтчета.АдресВоВременномХранилище = АдресВоВременномХранилище;
	
	РегламентированнаяОтчетностьПереопределяемый.ЗаполнитьОтчет(ИДОтчета, ФормаОтчета, ПараметрыОтчета, ПараметрыАвтозаполнения.Контейнер);
		
	ДанныеАвтозаполнения = ПолучитьИзВременногоХранилища(ПараметрыОтчета.АдресВоВременномХранилище);
	
	ПолученнаяСтруктураБаланса =  ДанныеАвтозаполнения.Контейнер.Баланс;
		
	Для Каждого Элемент ИЗ ПолученнаяСтруктураБаланса Цикл
		
		НС = Объект.Баланс.Добавить();
		ЗаполнитьЗначенияСвойств(НС,Элемент);
		
	КонецЦикла;	
	
	ПолученнаяСтруктураОФР =  ДанныеАвтозаполнения.Контейнер[ИмяСвойстваОФР];
	
	Для Каждого Элемент ИЗ ПолученнаяСтруктураОФР Цикл
		
		НС = Объект.ОФР.Добавить();
		ЗаполнитьЗначенияСвойств(НС,Элемент);
		
	КонецЦикла;	
	
	ТаблицаРасшифровки = ДанныеАвтозаполнения.ТаблицаРасшифровки;
	РегламентированнаяОтчетность.ПоместитьВКэш(ТаблицаРасшифровки, УникальныйИдентификатор,
			АдресВременногоХранилищаРасшифровки);
			
	Объект.ТаблицаРасшифровки.Загрузить(ДанныеАвтозаполнения.ТаблицаРасшифровки);
		

КонецПроцедуры

&НаКлиенте
Процедура Запустить(Команда)
	ЗапуститьНаСервере();
КонецПроцедуры

&НаКлиенте
Процедура Расшифровать(ИмяПоказателя)
	
	ПараметрыОтчета = Новый Структура();
	ПараметрыОтчета.Вставить("Организация",              Организация);
	ПараметрыОтчета.Вставить("мДатаНачалаПериодаОтчета", СтандартныйПериод.ДатаНачала);
	ПараметрыОтчета.Вставить("мДатаКонцаПериодаОтчета",  СтандартныйПериод.ДатаОкончания);
	ПараметрыОтчета.Вставить("АдресВременногоХранилищаРасшифровки", АдресВременногоХранилищаРасшифровки);
		
	ИДИменПоказателей = Новый Массив();
	ИДИменПоказателей.Добавить(ИмяПоказателя);
	
	РегламентированнаяОтчетностьКлиент.ОткрытьРасшифровкуОтчета(
		"РегламентированныйОтчетБухОтчетность", ФормаОтчета, ИДИменПоказателей, ПараметрыОтчета);
	
КонецПроцедуры

&НаКлиенте
Процедура БалансВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
	Расшифровать(Элемент.ТекущиеДанные.Ключ);
КонецПроцедуры

&НаКлиенте
Процедура ОФРВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
	Расшифровать(Элемент.ТекущиеДанные.Ключ);
КонецПроцедуры

2 ЗапускРегламентированныйОтчетБухОтчетностьВФоне.epf

Работает в асинхронном режиме. Использует параметр "СформироватьФормуОтчетаАвтоматически" формы ФормаОтчета2019Кв1 отчета РегламентированныйОтчетБухОтчетность. При получении вышеупомянутой формы срабатывает её метод ПриСозданииНаСервере, в котором вызывается автозаполнение формы. После заполнения формы обработка считывает результат заполнения из формы. Весь код находится в форме обработки, он под спойлером.

Код обработки

&НаКлиенте
Перем ФормаОтчетаРегламентированныйОтчетБухОтчетность;

&НаСервере
Функция ФормыБухОтчетностиДействующиеВВыбранныйПериод(ВсеДоступныеФормы, ДатаКонцаПериода)
	
	Результат = ВсеДоступныеФормы.СкопироватьКолонки();
	
	Для Каждого ДоступнаяФорма Из ВсеДоступныеФормы Цикл
		ДатаНачалаДействияФормы = ДоступнаяФорма.ДатаНачалоДействия;
		Если ДоступнаяФорма.ДатаКонецДействия = РегламентированнаяОтчетностьКлиентСервер.ПустоеЗначениеТипа(Тип("Дата")) Тогда
			ДатаКонцаДействияФормы = '20991231';
		Иначе
			ДатаКонцаДействияФормы = КонецДня(ДоступнаяФорма.ДатаКонецДействия);
		КонецЕсли;
		
		Если ДатаКонцаПериода <= ДатаКонцаДействияФормы
			И ДатаКонцаПериода >= ДатаНачалаДействияФормы Тогда
			
			НоваяФорма = Результат.Добавить();
			ЗаполнитьЗначенияСвойств(НоваяФорма, ДоступнаяФорма);
			
		КонецЕсли;
	КонецЦикла;
	
	Результат.Сортировать("ДатаКонецДействия Убыв");
	Возврат Результат;
	
КонецФункции


&НаСервере
Процедура ДозаполнитьПараметрыНаСервере(ПараметрыОтчета)
	
	ИДОтчета = "РегламентированныйОтчетБухОтчетность";
	ОбъектОтчета = РегламентированнаяОтчетностьВызовСервера.ОтчетОбъект(ИДОтчета);
	
	УчетОтложенногоНалогаБалансовымМетодом = РегламентированнаяОтчетность.УчетОтложенногоНалогаБалансовымМетодом(Объект.Организация, Объект.СтандартныйПериод.ДатаОкончания);
	ВсеФормыОтчета = ОбъектОтчета.ТаблицаФормОтчета(УчетОтложенногоНалогаБалансовымМетодом);
	
	ДействующиеФормы = ФормыБухОтчетностиДействующиеВВыбранныйПериод(ВсеФормыОтчета, Объект.СтандартныйПериод.ДатаОкончания);
	Если ДействующиеФормы.Количество() = 0 Тогда
		ФормаОтчета = "ФормаОтчета2019Кв1";
		Сообщить("Не определена действующая форма отчета, поэтому взята ФормаОтчета2019Кв1");
	Иначе	
		// Список действующих форм отсортирован по дате окончания действия. 
		// Заполняем отчет по самой поздней редакции, так же работает автоподстановка формы у Регламентированной отчетности.
		ФормаОтчета = ДействующиеФормы[0]["ФормаОтчета"];
	КонецЕсли;
	ПараметрыОтчета.Вставить("мВыбраннаяФорма", ФормаОтчета);
	
КонецПроцедуры

&НаКлиенте
Процедура Запустить(Команда)
	
	ОчиститьСообщения();
			
	ПараметрыОтчета = Новый Структура;
	ПараметрыОтчета.Вставить("Организация", Объект.Организация);
	ПараметрыОтчета.Вставить("мДатаНачалаПериодаОтчета", Объект.СтандартныйПериод.ДатаНачала);
	ПараметрыОтчета.Вставить("мДатаКонцаПериодаОтчета", Объект.СтандартныйПериод.ДатаОкончания);
	ПараметрыОтчета.Вставить("СформироватьФормуОтчетаАвтоматически",		Истина);
		
	ДозаполнитьПараметрыНаСервере(ПараметрыОтчета);
		
	// форма должна автоматически заполнится
	ФормаОтчетаРегламентированныйОтчетБухОтчетность = ПолучитьФорму("Отчет.РегламентированныйОтчетБухОтчетность.Форма." + ПараметрыОтчета.мВыбраннаяФорма,ПараметрыОтчета);
	
	РезультатЗапуска = ФормаОтчетаРегламентированныйОтчетБухОтчетность.СтруктураРеквизитовФормы.РезультатЗапускаАвтозаполненияПриСоздании;
	
	ОповещениеОЗавершении = Новый ОписаниеОповещения("ОбработатьЗавершениеАвтозаполненияВФоне", ЭтотОбъект);
	ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
	ДлительныеОперацииКлиент.ОжидатьЗавершение(РезультатЗапуска, ОповещениеОЗавершении, ПараметрыОжидания);
		
КонецПроцедуры

&НаСервере
Процедура ЗагрузитьПодготовленныеДанные(АдресРезультата)
	
	ДанныеАвтозаполнения = ПолучитьИзВременногоХранилища(АдресРезультата);
	
	ПолученнаяСтруктураБаланса =  ДанныеАвтозаполнения.Контейнер.Баланс;
	
	Объект.Баланс.Очистить();
	Для Каждого Элемент ИЗ ПолученнаяСтруктураБаланса Цикл
		
		НС = Объект.Баланс.Добавить();
		ЗаполнитьЗначенияСвойств(НС,Элемент);
		
	КонецЦикла;	
	
	ПолученнаяСтруктураОФР =  ДанныеАвтозаполнения.Контейнер.ОФР;
	
	Объект.ОФР.Очистить();
	Для Каждого Элемент ИЗ ПолученнаяСтруктураОФР Цикл
		
		НС = Объект.ОФР.Добавить();
		ЗаполнитьЗначенияСвойств(НС,Элемент);
		
	КонецЦикла;	
	
	ТаблицаРасшифровки = ДанныеАвтозаполнения.ТаблицаРасшифровки;
	РегламентированнаяОтчетность.ПоместитьВКэш(ТаблицаРасшифровки, УникальныйИдентификатор,
			АдресВременногоХранилищаРасшифровки);
			
	Объект.ТаблицаРасшифровки.Загрузить(ДанныеАвтозаполнения.ТаблицаРасшифровки);
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработатьЗавершениеАвтозаполненияВФоне(Результат,ВходящиеПараметры) Экспорт
		
	Если Результат <> Неопределено Тогда
		Если Результат.Статус = "Выполнено" Тогда
			
			ЗагрузитьПодготовленныеДанные(ФормаОтчетаРегламентированныйОтчетБухОтчетность.СтруктураРеквизитовФормы.АдресВоВременномХранилище);
						
		ИначеЕсли Результат.Статус = "Ошибка" Тогда
			ВызватьИсключение Результат.ПодробноеПредставлениеОшибки;
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура Расшифровать(ИмяПоказателя)
	
	ПараметрыОтчета = Новый Структура();
	ПараметрыОтчета.Вставить("Организация",              Объект.Организация);
	ПараметрыОтчета.Вставить("мДатаНачалаПериодаОтчета", Объект.СтандартныйПериод.ДатаНачала);
	ПараметрыОтчета.Вставить("мДатаКонцаПериодаОтчета",  Объект.СтандартныйПериод.ДатаОкончания);
	ПараметрыОтчета.Вставить("АдресВременногоХранилищаРасшифровки", АдресВременногоХранилищаРасшифровки);
		
	ИДИменПоказателей = Новый Массив();
	ИДИменПоказателей.Добавить(ИмяПоказателя);
	
	РегламентированнаяОтчетностьКлиент.ОткрытьРасшифровкуОтчета(
		"РегламентированныйОтчетБухОтчетность", ФормаОтчета, ИДИменПоказателей, ПараметрыОтчета);
	
КонецПроцедуры

&НаКлиенте
Процедура БалансВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
	Расшифровать(Элемент.ТекущиеДанные.Ключ);
КонецПроцедуры

&НаКлиенте
Процедура ОФРВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
	Расшифровать(Элемент.ТекущиеДанные.Ключ);
КонецПроцедуры

Реквизиты формы:

Реквизиты формы

Предыстория

Ко мне потребность формирования отчетности динамически перешла по наследству от ~~идущего к реке~~ предыдущего программиста. Он делал сводную отчетность для банка. А я исправляю:)

В его версии вызывалась непосредственно форма (одна из) отчета РегламентированныйОтчетБухОтчетность, её метод ЗаполнитьАвтоНаСервере, а затем ещё и метод ЗагрузитьПодготовленныеДанные(). Но я увидел, что есть другие способы - которые используются в самой конфигурации. Опробовал их и решил поделиться.

Сейчас работы над сводной отчетностью приостановлены, а при их возобновлении я собираюсь обсудить с бухгалтером вопрос актуальности динамически получаемых данных по сравнению с сохраненными.

РегламентированныйОтчетБухОтчетность ФормаОтчета2019Кв1 Регламентированная отчетность П000100115004

+8 –

См. также

Добавление внешнего отчета в информационную базу

Менеджеры внешних отчетов Программист Стажер Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Описание необходимых минимальных настроек внешнего отчета, позволяющих добавлять внешний отчет в информационную базу.

22.08.2024 1569 rslayer 7

Выгрузка дополнительных отчетов и обработок в папку с иерархией (Управляемые формы)

Менеджеры внешних отчетов Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Очень часто возникает необходимость сохранить в папку на локальном диске все дополнительные внешние отчеты и обработки из базы 1С. Данная обработка позволит сделать это быстро и с учетом внутренней иерархии и с проверкой результата выгрузки (Управляемые формы).

1 стартмани

25.04.2024 1412 16 Suker86 0

Пример добавления отчета в расширение в типовые конфигурации на БСП на примере УТ 11.5

Менеджеры внешних отчетов Программист Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Пример добавления отчета в расширение в типовые конфигурации на БСП на примере УТ 11.5, с добавлением в типовые меню отчетов.

1 стартмани

31.01.2024 4315 DarkPinch222 0

Пример выбора варианта отчета СКД

Менеджеры внешних отчетов СКД Программист Стажер Платформа 1С v8.3 Управляемые формы Система компоновки данных 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х Абонемент ($m)

Пример выбора варианта отчета СКД в обработке. Варианты отчета хранятся в Макетах обработки.

1 стартмани

29.12.2023 1333 5 vladimir_korshun 0

Менеджер отчетов

Менеджеры внешних отчетов Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Менеджер отчетов, это простой инструмент, который предназначен для организации доступа к отчетам и обработкам, как внешним так и встроенным в конфигурацию. Предоставление доступа реализовано как для пользователей, так и для пользовательских групп.

5 стартмани

04.09.2023 1122 3 serg1234 0

Расширение «Контрольные отчеты» для автоматизации проверки ведения учета в 1С:ERP 2х, 1С:КА 2.х

Менеджеры внешних отчетов Анализ учета Программист Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Комплексная автоматизация 2.х Платные (руб)

Расширение «Контрольные отчеты» для автоматизации процесса проверки ведения учета в ПП. Со списком ошибок могут работать ответственные пользователи. Помогает в процессе внедрения ПП находить нарушения в бизнес-процессах.

12000 руб.

08.08.2023 2066 3 1

Обработка для запуска обработок

Инструментарий разработчика Менеджеры внешних отчетов Программист Платформа 1С v8.3 Конфигурации 1cv8 1С:ERP Управление предприятием 2 Абонемент ($m)

При изменении и отладке внешней обработки приходится десятки раз заходить в Файл-Открыть и переоткрывать обработку. Данное решение значительно упрощает данную задачу.

1 стартмани

28.07.2023 5552 61 Serg2000mr 31