Наводим красоту: градиентная панель отборов

// Возвращает список значений с перечнем возможных значений отборов
//
// Параметры:
//  ИмяФормы - 	Строка - Имя подключаемой формы
// 
// Возвращаемое значение:
//  СписокЗначений 
//
Функция СписокЗначенийОтбора(ИмяФормы) Экспорт

	Если ИмяФормы = "Документ.РеализацияТоваровУслуг.Форма.ФормаСписка" Тогда
		Возврат Перечисления.ВидыОперацийРеализацияТоваров.СписокДоступныхЗначений();
	КонецЕсли;
	
КонецФункции

В данной функции необходимо настроить получение списка значений отбора в зависимости от имени подключаемой формы.

 Функции, отвечающие за наименования программно размещаемых элементов

• ИмяГруппыОтборов
• ИмяКомандыИзменитьОтбор
• ИмяКомандыНастроитьОтбор
• ИмяТаблицыДобавленныхЭлементов
• ПрефиксГруппыОтбора
• ИмяСпискаОтборов

Все имена содержат признак гпо_, чтобы имена элементов не пересекались с существующими. Если вдруг будет нарушена уникальность наименований, то необходимо изменить имена в этих функциях; в противном случае можно не изменять.

Настройка градиента:

// Начальный цвет градиента
// 
// Возвращаемое значение:
//   Цвет 
//
Функция НачальныйЦвет() Экспорт
	Возврат Новый Цвет(255, 215, 222);
КонецФункции

// Конечный цвет градиента
// 
// Возвращаемое значение:
//   Цвет 
//
Функция КонечныйЦвет() Экспорт
	Возврат Новый Цвет(182, 214, 244);
КонецФункции

Информация о размещении обычной группы форма, где будут размещаться элементы отбора:

// Информация о размещении панели отборов
//
// Параметры:
//  ИмяФормы - 	Строка - имя подключаемой формы
// 
// Возвращаемое значение:
//  Структура с ключами:
// 		* РодительскийЭлемент 	- Строка - родитель главной группы панели отбора (пустая строка, если разместить в корне формы)
// 		* ВставитьПеред 		- Строка - имя элемента, перед которым необходимо вставить группу
//
Функция ИнформацияОРазмещенииПанелиОтборов(ИмяФормы) Экспорт
	
	Результат = Новый Структура("РодительскийЭлемент, ВставитьПеред", "", "");
	
	Если ИмяФормы = "Документ.РеализацияТоваровУслуг.Форма.ФормаСписка" Тогда
    	Результат.Вставить("РодительскийЭлемент", Неопределено);
    	Результат.Вставить("ВставитьПеред", "ГруппаДополнительныеОтборы");
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

Если вдруг количество доступных значений отбора много, то их можно разместить в несколько строк. Настраивается индивидуально для каждой формы. Допустимое количество элементов отбора в одной строке настраивается тут:

// Количество элементов отбора в одной строке
//
// Параметры:
//  ИмяФормы - 	Строка - имя подключаемой формы
// 
// Возвращаемое значение:
//  Число 
//
Функция КоличествоОтборовВСтроке(ИмяФормы) Экспорт

	Если ИмяФормы = "Документ.РеализацияТоваровУслуг.Форма.ФормаСписка" Тогда
		Возврат 10;
	КонецЕсли;
	
	Возврат 0;
	
КонецФункции

Информация об имени динамического списка и пути к полю отбора для каждой формы:

// Информация об имени динамического списка и пути к полю отбора
//
// Параметры:
//  ИмяФормы - 	Строка - имя подключаемой формы
// 
// Возвращаемое значение:
//  Структура с ключами:
// 		* ИмяСписка - Строка - имя динамического списка
// 		* ИмяПоля 	- Строка - путь к полю, к которому применяется отбор 
//
Функция СписокПолеОтбора(ИмяФормы) Экспорт

	Результат = Новый Структура("ИмяСписка, ИмяПоля", "", "");
	
	Если ИмяФормы = "Документ.РеализацияТоваровУслуг.Форма.ФормаСписка" Тогда
		
    	Результат.Вставить("ИмяСписка"	, "Список");
    	Результат.Вставить("ИмяПоля"	, "Список.ВидОперации");
		
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

 Добавить событие ПриСозданииНаСервере (после)

&НаСервере
Процедура гпо_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	гпо_МодификацияФорм.МодифицироватьФормуСписка(ЭтотОбъект);	
КонецПроцедуры

Вставить код, приведенный ниже:

#Область СкопироватьКакЕсть

&НаСервере
Процедура ОбновитьОтборыНаСервере()
	
	ПолеСписок = гпо_МодификацияФормКлиентСерверПереопределяемый.СписокПолеОтбора(ИмяФормы);
	Количество = гпо_МодификацияФормКлиентСерверПереопределяемый.КоличествоОтборовВСтроке(ИмяФормы);
	гпо_МодификацияФорм.ОбновитьЭлементыОтбораТипов(ЭтотОбъект, Количество, ПолеСписок.ИмяПоля, ПолеСписок.ИмяСписка);
	
КонецПроцедуры

&НаКлиенте
Процедура гпо_ИзменитьОтбор(Команда)
	
	ИмяТаблицыЭлементов = гпо_МодификацияФормКлиентСерверПереопределяемый.ИмяТаблицыДобавленныхЭлементов();
	Префикс 			= гпо_МодификацияФормКлиентСерверПереопределяемый.ПрефиксГруппыОтбора();
	ИмяСписка 			= гпо_МодификацияФормКлиентСерверПереопределяемый.ИмяСпискаОтборов();
	
	ТекущаяГруппа 		= ЭтотОбъект.ТекущийЭлемент.Родитель.Имя;
	ИмяОтбора 			= СтрЗаменить(ТекущаяГруппа, Префикс, "");
	Строки 				= ЭтотОбъект[ИмяТаблицыЭлементов].НайтиСтроки(Новый Структура("Имя", ИмяОтбора));
	Значение 			= Строки[0].ЗначениеРеквизита;
	ТекЭлемент 			= ЭтотОбъект[ИмяСписка].НайтиПоЗначению(Значение);
	ТекЭлемент.Пометка 	= Не ТекЭлемент.Пометка;
	
	ОбновитьОтборыНаСервере();

КонецПроцедуры

&НаКлиенте
Асинх Процедура гпо_НастроитьОтбор(Команда)
	
	ИмяСписка = гпо_МодификацияФормКлиентСерверПереопределяемый.ИмяСпискаОтборов();
	Результат = Ждать ЭтотОбъект[ИмяСписка].ОтметитьЭлементыАсинх("Настройка панели отбора");
	
	Если Результат = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	ПодключитьОбработчикОжидания("гпо_ПриИзмененииОтбора", 0.1, Истина);

КонецПроцедуры

&НаКлиенте
Процедура гпо_ПриИзмененииОтбора()
	
	ОбновитьОтборыНаСервере();
	
КонецПроцедуры

#КонецОбласти // СкопироватьКакЕсть