БСП, использование типового механизма 1с для запуска регламентных заданий с заранее подготовленными настройками.

Хороший механизм.
Одно но: в прикрепленной обработке заголовок процедуры Выполнить команду выглядит так:

Процедура ВыполнитьКоманду(ИдентификаторКоманды,ПараметрыКоманды,парам=Неопределено) Экспорт

А вызывается она из Модуля доп.отчеты и обработки так:
Если ПараметрыКоманды = Неопределено Тогда
ВнешнийОбъект.ВыполнитьКоманду(ИдентификаторКоманды);
Иначе
ВнешнийОбъект.ВыполнитьКоманду(ИдентификаторКоманды, ПараметрыКоманды);
КонецЕсли;

То есть если ПараметрыКоманды =Неопределено - возникает ошибка, надо заголовок писать так:

Процедура ВыполнитьКоманду(ИдентификаторКоманды,ПараметрыКоманды = Неопределено, парам = Неопределено) Экспорт

Я заказал обработку, почему она до сих пор не пришла ко мне на почту?

очень полезная статья

Добрый день!
Не могли бы, пожалуйста, подсказать как сохранить параметры для выполнения обработки в форме НастройкаПараметров, чтобы они использовались при выполнении Регламентной операции?

Подскажите, возможно ли сделать запуск внешней обработки по расписанию в отдельном сеансе с открытием формы внешней обработки, в которой будет выводится процесс выполнения обработки?

Описание процесса неполное и, соответственно, не корректное. То есть, если сделаете в точности как тут написано, работать не будет. Возможно, в обработке сделано нормально - не знаю. Польза от статьи лишь в том, что она рассказывает о существовании данного механизма в 1С. Скачайте БСП и посмотрите в демо базе. Там все корректно и работает.
Вот пример правильного модуля объекта:

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область ПрограммныйИнтерфейс

// Возвращает сведения о внешней обработке.
//
// Возвращаемое значение:
// Структура - Подробнее см. ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке().
//
Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
ПараметрыРегистрации.Информация = НСтр("ru = 'Обработка сервисных функций полнотекстового поиска. Используется для демонстрации возможностей подсистемы ""Дополнительные отчеты и обработки"".'");
ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
ПараметрыРегистрации.Версия = "2.4.1.1";

Команда = ПараметрыРегистрации.Команды.Добавить();
Команда.Представление = НСтр("ru = 'Обновить индекс полнотекстового поиска'");
Команда.Идентификатор = "ОбновитьИндекс";
Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
Команда.ПоказыватьОповещение = Истина;

Команда = ПараметрыРегистрации.Команды.Добавить();
Команда.Представление = НСтр("ru = 'Вывод ошибки'");
Команда.Идентификатор = "Исключение";
Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();

Команда = ПараметрыРегистрации.Команды.Добавить();
Команда.Представление = НСтр("ru = 'Управление полнотекстовым поиском'");
Команда.Идентификатор = "ОткрытиеФормы";
Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
Команда.ПоказыватьОповещение = Истина;

Описание = НСтр("ru = 'Для управления индексом полнотекстового поиска требуется установка привилегированного режима.'");
Разрешение = РаботаВБезопасномРежиме.РазрешениеНаИспользованиеПривилегированногоРежима(Описание);
ПараметрыРегистрации.Разрешения.Добавить(Разрешение);

Возврат ПараметрыРегистрации;
КонецФункции

// Обработчик серверных команд.
//
// Параметры:
// ИмяКоманды - Строка - Имя команды, определенное в функции СведенияОВнешнейОбработке().
// ПараметрыВыполнения - Структура - Контекст выполнения команды.
// * ДополнительнаяОбработкаСсылка - СправочникСсылка.ДополнительныеОтчетыИОбработки - Ссылка обработки.
// Может использоваться для чтения параметров обработки.
// Пример см. в комментарии к функции ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы().
//
Процедура ВыполнитьКоманду(Знач ИмяКоманды, Знач ПараметрыВыполнения) Экспорт
Если ИмяКоманды = "Исключение" Тогда
ВызватьИсключение НСтр("ru = 'Прикладной текст исключения'");
КонецЕсли;
Если ИмяКоманды = "ОткрытиеФормы" Тогда
ИмяКоманды = ОбщегоНазначенияКлиентСервер.СвойствоСтруктуры(ПараметрыВыполнения, "ИмяКоманды");
КонецЕсли;

// Общие действия перед началом выполнения команд.
УстановитьПривилегированныйРежим(Истина);

// Диспетчеризация обработчиков команд.
Если ИмяКоманды = "ОбновитьИндекс" Тогда
ПолнотекстовыйПоиск.ОбновитьИндекс(Ложь, Ложь);
ИначеЕсли ИмяКоманды = "ОчиститьИндекс" Тогда
ПолнотекстовыйПоиск.ОчиститьИндекс();
Иначе
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Команда ""%1"" не поддерживается обработкой ""%2""'"),
ИмяКоманды,
Метаданные().Представление());
КонецЕсли;

// Имитация длительной операции для демонстрации запуска фонового задания в клиент-серверном режиме.
Если Не ОбщегоНазначения.ИнформационнаяБазаФайловая() Тогда
ДатаОкончания = ТекущаяДатаСеанса() + 4;
Пока ДатаОкончания > ТекущаяДатаСеанса() Цикл
КонецЦикла;
КонецЕсли;

КонецПроцедуры

#КонецОбласти

#КонецЕсли