Альтернативный способ задания расшифровки СКД-отчета

Публикация № 1151552

Разработка - Практика программирования

расшифровка СКД схема компоновки данных записать структура обработка

17
Задание расшифровки у отчета, выведенного с помощью СКД, как будто он был выведен традиционным способом. Изменения конфигурации при этом минимальны, создание формы у отчета не требуется, не нужно писать "простыни" кода.

Небольшой экскурс в историю

В доСКДшную эпоху расшифровка отчетов обычно делалась так: у ячейки задавалось имя параметра расшифровки, затем при формировании табличного документа можно было задать любое значение, которое будет записано в расшифровку конкретной ячейки. В качестве значения расшифровки обычно задавалась ссылка, если при расшифровке предполагалось просто открывать какой-то объект; либо объект Структура с набором каких-то значений, если предполагалось выполнение алгоритма, зависящего от ключей и значений структуры. С появлением СКД возможность записать объект Структура в расшифровку ячейки стандартным способом пропала, но я нашел способ как сделать это практически так же просто, как и при традиционном формировании табличных документов методом Вывести().

Основная идея

Схема следующая: при выводе отчета записываем в ячейки текст для создания структуры (по сути сериализируем структуру), а потом сформируем объект Структура постобработкой табличного документа (выполним десериализацию).

Теперь посмотрим как эту идею реализовать на практике.

Описание реализации

Представим следующую задачу: в отчете на СКД необходимо при расшифровке номенклатуры открывать веб-страницу с описанием данной номенклатуры. У номенклатуры есть ID, по которому можно сформировать ссылку для открытия в браузере. Работоспособность расшифровки не должна сбиваться при настройке вариантов отчета, поэтому привязываться к положению/наименованию колонки нельзя.

Сначала подготовим данные для структуры. Поля набора данных отчета:

В вычисляемых полях создадим представление номенклатуры, в которой кавычки будут заменены учетверенными кавычками

Функция СтрокаСУчетвереннымиКавычками() нужна для корректной сборки структуры в случае если в названии номенклатуры присутствуют кавычки

Функция СтрокаСУчетвереннымиКавычками(Текст) Экспорт
	
	Возврат СтрЗаменить(Текст, """", """""""""");
	
КонецФункции

На закладке Макеты создаем макет для вывода номенклатуры, заполнение ячейки устанавливаем "Шаблон", прописываем текст для создания структуры

Разберем строку для создания структуры

#Новый Структура(""УстанавливаемыйТекстЯчейки,ОткрытьНаПортале,НоменклатураID"", ""[НоменклатураПредставление]"", Истина, ""[НоменклатураID]"")

Символ # используется как часть маркера для сигнализирования процедуре постообработки о том, что данную ячейку необходимо обработать. В тексте создания структуры обязательно должен присутствовать ключ УстанавливаемыйТекстЯчейки - это тот текст, который будет установлен в ячейке после постобработки. В данном случае при постообработке текст в ячейке будет заменен на представление номенклатуры, а в расшифровку ячейки будет записана структура с ключами ОткрытьНаПортале=Истина и НоменклатураID=<ID номенклатуры>. Этих данных будет достаточно чтобы при обработке расшифровки определить что для данной ячейки нужно сформировать строку адреса и открыть ссылку в браузере.

Настройки вывода отчета абсолютно стандартны для отчетов на СКД:

 

Теперь необходимо в процедуре ПриКомпоновкеРезультата() программно вывести отчет и вызвать процедуру постобработки табличного документа:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	ДокументРезультат.Очистить();
	НастройкиОтчета = КомпоновщикНастроек.ПолучитьНастройки();
	_СКД.ВывестиОтчетВТабличныйДокументЧерезСхемуКомпоновкиДанных(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка, НастройкиОтчета, СхемаКомпоновкиДанных);
	
	_СКД.УстановитьРасшифровкуЯчеекТабличногоДокумента(ДокументРезультат);
	
КонецПроцедуры

Для программного вывода отчета на СКД я использую простенькую функцию в общем модуле _СКД:

Процедура ВывестиОтчетВТабличныйДокументЧерезСхемуКомпоновкиДанных(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка, НастройкиОтчета, СхемаКомпоновкиДанных) Экспорт
	
	СтандартнаяОбработка = Ложь;
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиОтчета, ДанныеРасшифровки);
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки, Истина);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновки, Истина);
	
КонецПроцедуры

В неё я передаю все параметры процедуры ПриКомпоновкеРезультата() и добавляю настройки отчета и схему компоновки данных. При необходимости можно вывести шапку и подвал отчета традиционным способом до/после процедуры ВывестиОтчетВТабличныйДокументЧерезСхемуКомпоновкиДанных().

Код процедуры _СКД.УстановитьРасшифровкуЯчеекТабличногоДокумента():

Процедура УстановитьРасшифровкуЯчеекТабличногоДокумента(ДокументРезультат) Экспорт
	
	ОграничениеОтладочныхСообщений = 10;
	Для НомерСтроки = 1 По ДокументРезультат.ВысотаТаблицы Цикл
		Для НомерКолонки = 1 По ДокументРезультат.ШиринаТаблицы Цикл
			ТекОбл = ДокументРезультат.Область(НомерСтроки, НомерКолонки);
			ТекстЯчейки = ТекОбл.Текст;
			Если СтрНачинаетсяС(ТекстЯчейки, "#Новый Структура(") Тогда
				ТекстРасшифровки = СокрЛП(Сред(ТекстЯчейки,2));
				Попытка
					СтруктураРасшифровки = Вычислить(Вычислить(""""+ТекстРасшифровки+""""));
				Исключение
					Если ОграничениеОтладочныхСообщений > 0 Тогда
						Если СтрНайти(ТекстРасшифровки, Символы.ПС) > 0 Тогда
							ОбщегоНазначенияКлиентСервер.СообщитьПользователю("В тексте создания структуры нельзя использовать символы переноса строки!");
						КонецЕсли;
						ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Не удалось преобразовать в структуру строку"+Символы.ПС+ТекстРасшифровки);
						ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ОписаниеОшибки());
						ОграничениеОтладочныхСообщений = ОграничениеОтладочныхСообщений - 1;
					КонецЕсли;
					Продолжить;
				КонецПопытки;
				Если ТипЗнч(СтруктураРасшифровки) = Тип("Структура") Тогда
					УстанавливаемыйТекстЯчейки = "";
					Если СтруктураРасшифровки.Свойство("УстанавливаемыйТекстЯчейки", УстанавливаемыйТекстЯчейки) Тогда
						СтруктураРасшифровки.Удалить("УстанавливаемыйТекстЯчейки");
					КонецЕсли;
					
					ТекОбл.Текст = УстанавливаемыйТекстЯчейки;
					ТекОбл.Расшифровка = СтруктураРасшифровки;
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
	КонецЦикла;
	
КонецПроцедуры

Код процедуры содержит процедуру из БСП ОбщегоНазначенияКлиентСервер.СообщитьПользователю(). При необходимости использования в конфигурациях без БСП, можно заменить её на Сообщить().  При неудачных попытках создать структуру из текста ячейки  процедура выводит 10 сообщений об ошибках (думаю 10 сообщений будет достаточно для отладки).

Собственно задача формирования отчета со структурами в расшифровках решена, осталось только прописать обработку расшифровки. В конфигурациях на БСП для этого можно использовать процедуру ОтчетыКлиентПереопределяемый.ОбработкаРасшифровки() модифицировав её в основной конфигурации либо в расширении.

Процедура ОбработкаРасшифровки(ФормаОтчета, Элемент, Расшифровка, СтандартнаяОбработка) Экспорт
	
	ИмяФормыОтчета = ФормаОтчета.ИмяФормы;
	
	Если СтрСравнить(ИмяФормыОтчета, "Отчет.ОстаткиТоваровНаСкладах.Форма") = 0 Тогда
		Если ТипЗнч(Расшифровка) = Тип("Структура") Тогда
			СтандартнаяОбработка = Ложь;
			ОткрытьНаПортале = Неопределено;
			НоменклатураID = Неопределено;
			Если Расшифровка.Свойство("ОткрытьНаПортале", ОткрытьНаПортале) И Расшифровка.Свойство("НоменклатураID", НоменклатураID) Тогда
				Если ОткрытьНаПортале И ЗначениеЗаполнено(НоменклатураID) Тогда
					//Формируем строку адреса используя НоменклатураID и запускаем браузер
					
				КонецЕсли;
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

Передача ссылок в структуре

В моем примере в расшифровке нет ссылок. Но передача их через текст не представляет трудности. Создадим в общем модуле _СКД функцию для получения ГУИДа ссылки:

Функция ГУИДСсылки(Ссылка) Экспорт
	
	Возврат Строка(Ссылка.УникальныйИдентификатор());
	
КонецФункции

Затем используем её в вычисляемых полях СКД, например передадим ГУИД склада

Добавим передачу ГУИДа склада в строке создания структуры:

#Новый Структура(""УстанавливаемыйТекстЯчейки,ОткрытьНаПортале,НоменклатураID,СкладГУИД"", ""[НоменклатураПредставление]"", Истина, ""[НоменклатураID]"", ""[СкладГУИД]"")

Восстанавливаем ссылку в обработке расшифровки.

СкладСсылка = _ВызовСервера.СсылкаПоГУИД("Справочник.Склады", Расшифровка.СкладГУИД);

Поскольку она выполняется на стороне клиента, используем для этого функцию в общем модуле с флажком "Вызов сервера". Для получения менеджера объекта используем функцию из БСП:

Функция СсылкаПоГУИД(ПолноеИмяОбъектаМетаданных, ГУИДСтрокой) Экспорт
	
	ОбъектМенеджер = ОбщегоНазначения.МенеджерОбъектаПоПолномуИмени(ПолноеИмяОбъектаМетаданных);
	Возврат	ОбъектМенеджер.ПолучитьСсылку(Новый УникальныйИдентификатор(ГУИДСтрокой));
	
КонецФункции

Тестовое окружение

Вышеприведенные алгоритмы проверялись на платформе 8.3.12.1855, в конфигурации с БСП.

17

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. VmvLer 11.11.19 09:36 Сейчас в теме
не осилил - бросил читать посередине.

постобработки, кучка кода - зачем? хотя дело вкуса.

когда мне необходимо по расшифровке на элемент запускать мулитьтик или видос с интернетов,
то я просто разрешал вызов функций общих модулей при компноновке и таки да
использовал макеты где относительно поля вызывал метод
РасшифроватьПолеИПоказатьВидосСКонями(П1, П2, Т1, ....)
в параметрах можно использовать поля, массивы, тз и прочие прелести функций СКД, можно и в структуру преобразовать параметры используя также функции общих модулей и вычисляемые поля.

Короче, в СКД и модуле компоновки практически никакого кода, никакой постобработки и вся прелесть вызова кина с конями заключена где-то в закромах общих модулей.
milov.aleksey; A_Max; +2 Ответить
2. timeforlive 11 11.11.19 12:40 Сейчас в теме
(1), Тоже думаю, что лучше святой КОД написать, чем колупаться с СКД.
СКД великий и могучий, но не нужно все дырки им затыкать :)
3. lmnlmn 54 11.11.19 13:17 Сейчас в теме
Это сложный одноразовый костыль который кроме самого автора вряд ли кто-то будет понимать и применять.
Полагаю что использование расшифровки для данной задачи проще и понятнее. При программной обработке расшифровки можно много чего понаделать. К примеру, получить имена и значения полей по строке отчета и хоть ядерным реактором управлять
&НаСервере
Процедура РезультатОбработкаРасшифровкиНаСервере(НомерСтрокиТабДок);
    ДанныеРасшифр = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);
    
    Для Сч = 1 По Результат.ШиринаТаблицы Цикл
        Поля = ДанныеРасшифр.Элементы[Результат.Область(НомерСтрокиТабДок, Сч).Расшифровка].ПолучитьПоля();
        
        Для Каждого Поле из Поля Цикл
            Сообщить("Имя поля: " + Поле.Поле + ", Значение: " + Поле.Значение);
        КонецЦикла
    КонецЦикла;
КонецПроцедуры
Показать
4. nocer 11.11.19 23:18 Сейчас в теме
Автор тут показал что не нужно вычислять поле для которого нужна расшифровка, когда стандартные простыни кода на процедуру обработки расшифровки не подходят
Если группировки отчёта поменяют, как вы будете вычислять в каком поле теперь номенклатура? Для скд это головная боль, которая возникла в следствии ее универсальности
5. achernobrovin 14.11.19 09:36 Сейчас в теме
6. dimonb123 14.11.19 09:38 Сейчас в теме
Не осилил и не понял, зачем такая куча кода.
Можно же просто записать ИД номенклатуры в расшифровку и потом обработать расшифровку в ручном режиме. У нас так несколько отчетов работает.
7. Quantum81 14.11.19 10:04 Сейчас в теме
На той неделе решал аналогичную задачу.
Не осилил заполнение ДанныеРасшифровки в процедуре ПриКомпоновкеРезультата своими данными.
Т.к. мне туда нужно было поместить два массива ссылок для каждой ячейки.

Коллеги, а это возможно?

Мне пришлось делать аналог типовому механизму. При компоновке создавать свое соответствие данных. В ячеку помещать ключ соответствия. Само соответствие помещать во временное хранилище, а при расшифровке вытаскивать и обрабатывать (открывать другой отчет с двумя параметрами массивами.)
8. dimonb123 14.11.19 11:40 Сейчас в теме
(7) Ну можно же сделать два вычисляемых поля, которые будут этими массивами ссылок и поля запихнуть в расшифровку
Quantum81; +1 Ответить
9. Quantum81 14.11.19 13:21 Сейчас в теме
(8) в ощущениям это сработало бы.
Оставьте свое сообщение

См. также

Полезные процедуры и функции для программиста 160

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Практика программирования Универсальные функции

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    11506    HostHost    23       

Вакансия Программист, аналитик, эксперт 1С Промо

Приглашаем к сотрудничеству квалифицированных специалистов 1С из любых регионов, готовых работать в удаленном режиме, а также с возможностью при необходимости выезда к заказчику.

СКД. Отчеты с картинками 189

Статья Программист Нет файла v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Работа с интерфейсом

Решение популярных кейсов с картинками в отчетах на СКД.

25.09.2019    6727    YPermitin    24       

Cashback 35% при покупке 1С лицензий на счет INFOSTART.RU с 27.11 по 04.12 Промо

Оформляете заказ на 1С лицензии или конфигурации. Получаете 35% от стоимости на счет в профиле INFOSTART.RU. Выбираете сервисы и продукты на сумму кэшбэка.

СКД не только для отчетов 144

Статья Программист Нет файла v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

СКД позволяет получать данные из информационной базы не только для вывода в отчеты, но и для других целей. Пример такого использования рассматривается в настоящей статье.

18.09.2019    9066    YPermitin    31       

Перенос данных УТ 10.3 => УТ 11 / КА 2 / ERP 2 (ЕРП 2) (документы, остатки и справочная информация из "1С:Управление торговлей, ред. 10.3" в УТ 11 / КА 2 / ERP 2). Обновлен до УТ 10.3.56.х, УТ 11.4.10.х, КА 2.4.10.х и ERP 2.4.10.х! Промо

Уже более 100 компаний приобрели перенос и выполнили переход на УТ 11 / КА 2 / ERP 2 с помощью нашей разработки! Обработка перехода с УТ 10.3 на УТ 11 / КА 2 / ERP 2 позволяет перенести не только остатки на указанную дату (как типовой перенос), но и все возможные документы за выбранный период. При выходе новых релизов этих программ оперативно выпускаем обновление обработки. Предоставляем техническую поддержку. Можем сделать бесплатный тестовый перенос!

29700 руб.

Агрегатные функции СКД, о которых мало кто знает 353

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    15415    ids79    44       

Три костыля. Сказ про фокусы в коде 124

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    10468    YPermitin    69       

1СПАРК РИСКИ. Сервис оценки благонадежности контрагентов. Промо

СПАРК помогает предотвратить мошенничество со стороны компаний и предпринимателей, благодаря актуальным сведениям о компаниях и системе выявления факторов риска.Сервис позволяет управлять налоговыми рисками и комплексно оценивать благонадежность контрагентов.

Отслеживание выполнения фонового задания 143

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    12595    ids79    16       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 261

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    17795    ids79    31       

Перенос данных БП 3.0 => УТ 11 / КА 2 / ERP 2 (ЕРП) (перенос остатков, документов и справочной информации из "1С:Бухгалтерия предприятия 8", ред.3.0). Обновлено до БП 3.0.73.х, УТ 11.4.10.х, КА 2.4.10.х., ERP 2.4.10.х! Промо

Переносятся документы за выбранный период, справочная информация и остатки по счетам бух. учета в программу УТ 11 / КА 2 / ЕРП 2 (ERP). Переносятся все возможные виды операций ввода остатков на нужную дату. Есть отбор по периоду переноса документов и фильтр по организации, доступен выбор даты ввода остатков. Если нужно переносить что-то дополнительно, то обычно бесплатно добавляем это в перенос . Смотрите видеодемонстрацию со звуком - советами по переносу и рекомендациями настройки программ.

29700 руб.

Фоновое выполнение кода в 1С - это просто 124

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    12689    avalakh    21       

1С:Предприятие через Интернет. 1С:Fresh Промо

Ведение бухгалтерского и налогового учет, сдача отчетности, управление бизнесом из любой точки мира. Привычные программы «1С» через Интернет без приобретения коробочных программ.

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 141

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    15958    ids79    8       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 155

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    13505    ids79    27       

Перенос данных БП 2.0 => УТ 11 / КА 2 / ERP 2 (перенос остатков, документов и справочников из "1С:Бухгалтерия предприятия 8", ред. 2.0 в "1С:Управление торговлей 8", ред.11 / КА 2 / ERP 2). Обновлено до УТ 11.4.10.х, КА 2.4.10.х, ERP 2.4.10.х! Промо

Перенос позволяет загрузить в УТ 11 / КА 2 / ERP 2 документы за выбранный период, справочную информацию и остатки по счетам бух. учета. Переносятся остатки денежных средств, взаиморасчетов, остатки товаров и материалов на складах. Переносятся девятнадцать основных видов документов за выбранный период и вся нормативно-справочная информация. Есть фильтр по организации. Если нужно переносить что-то дополнительно, то обычно бесплатно дорабатываю правила (перед покупкой согласуйте необходимые доработки).

29700 руб.

Регистры сведений. За кулисами 129

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    10532    YPermitin    12       

"Меньше копипаста!", или как Вася универсальную процедуру писал 183

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    9307    SeiOkami    49       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

Создание отчетов с помощью СКД - основные понятия и элементы 216

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    23624    ids79    17       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 179

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    13571    dmurk    134       

Перенос данных КА 1.1 => ERP 2 (ЕРП) (обработка переноса документов, остатков и справочной информации из "1С:Комплексная автоматизация, ред. 1.1" в "1С:ERP Управление предприятием, ред 2"). Обновлен до КА 1.1.115.х и ERP 2.4.10.х Промо

Обработка позволяет переносить из КА 1.1 в ERP 2 документы за выбранный период и остатки. Типовая обработка от фирмы 1С документы не переносит. Также исправлены ошибки типовой обработки. При выходе новых релизов обновление высылается бесплатно в течение года. Разработка будет полезна фирмам-франчайзи, которые периодически выполняют такой перенос данных для заказчиков. Вы можете один раз приобрести обработку переноса, и потом бесплатно получать обновления в случае выхода новых релизов конфигураций 1С.

29700 руб.

Регистры накопления. Структура хранения в базе данных 178

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    21029    YPermitin    27       

Выполнение внешней обработки в фоновом задании 149

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    12924    Eret1k    23       

Очный семинар по регулярному менеджменту Александра Фридмана "Вы или Хаос", 12 декабря 2019 г. , Санкт-Петербург Промо

Семинар по регулярному менеджменту от Александра Фридмана для собственников, первых лиц и топов. Технология управленческого планирования, комплексного управления временем и другими ресурсами, выполнением поручений, делами, информацией, контактами (встречи-звонки-почта).

от 11000 до 29000 рублей

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    7312    m-rv    2       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    9871    m-rv    16       

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

О расширениях замолвите слово... 195

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    18864    ellavs    125       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 202

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    15096    ellavs    83       

Перенос документов, остатков и справочников КА 1.1 => КА 2 / УТ 11. Обновлено до КА 2.4.10.х и УТ 11.4.10.х! Промо

Более 130 компаний выполнили переход на КА 2 или УТ 11 с помощью нашей разработки! Позволяет перенести не только остатки и справочники (как типовая обработка), но и документы за нужный период времени. Предоставляем техподдержку, оперативно исправляем замечания, выпускаем обновления при выходе новых релизов программ 1С. Вы можете проверить разработку до покупки: сделаем бесплатный тестовый перенос из вашей базы КА 1.1 и предоставим доступ к базе-результату через веб-клиент!

29700 руб.

Трюки с внешними источниками данных 166

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    15839    YPermitin    52       

Добавление отчетов в типовые конфигурации 1С 208

Статья Программист Нет файла v8::УФ v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем)

Описание различных способов добавления общих и контекстных отчетов в конфигурации 1С, построенные на базе БСП. Основные моменты и нюансы.

07.03.2019    28515    ids79    37