Загрузка из EXCEL в 1С. Чтение файла XLSX средствами 1С. ЧтениеXML

Публикация № 225624

Разработка - Практика программирования

1C Предприятие Импорт Загрузка Чтение ЧтениеXML Microsoft MS Excel LibreOffice OpenOffice dbf dBase xml mxl ActiveX ADO ADODB Windows

165
ПРАКТИЧЕСКОЕ ПОСОБИЕ РАЗРАБОТЧИКА: Метод "NativeXLSX" (ЧтениеXML).
Обрабатываются данные EXCEL типов: "Строка", "Число", "Дата" ("Время"), "Булево", "Процент".

В данной статье приведен функционал, с помощью которого в обработке
"Импорт из EXCEL и др.источников (xls,xlsx,ods,sxc,dbf,mxl,csv,sql) в 1С": //infostart.ru/public/120961/
производится считывание данных из файлов табличного типа *.xlsx средствами 1С (метод "NativeXLSX").

19.09.2014. Уточненная редакция.

Метод позволяет обрабатывать
данные EXCEL типов: "Строка", "Число", "Дата" ("Время"), "Булево", "Процент".


Методы загрузки из внешнего источника:
- Метод "MS ADO" (Чтение файлов xls, xlsx средствами Microsoft ADO): //infostart.ru/public/163640/
- Метод "MS EXCEL" (Чтение файлов xls, xlsx с картинками средствами Microsoft Office): //infostart.ru/public/163641/
- Метод "LO CALC" (Чтение файлов xls, xlsx, ods, sxc с картинками средствами LibreOffice): //infostart.ru/public/163642/
- Метод "NativeXLSX" (Чтение файлов xlsx с картинками средствами 1С. ПостроительDOM): //infostart.ru/public/300092/
- Метод "NativeXLSX". Предыдущий вариант (Чтение файлов xlsx средствами 1С. ЧтениеXML):
//infostart.ru/public/225624/
- Метод "Excel1C" (Загрузка на платформе 8.3.6 с картинками. Чтение файлов xls, xlsx, ods): //infostart.ru/public/341855/
- Список листов файла: //infostart.ru/public/163724/


Публикаций на тему загрузки из EXCEL - множество, но
"
— Вам билетёр нужен?
— Был нужен, да уже взяли.
— Может и я на что сгожусь?
— Может и сгодишься, если скалиться не будешь ...
"
"НЕУЛОВИМЫЕ МСТИТЕЛИ" (1966).


Публикации других авторов:

"XLSX средствами 1С":
1cmax: Чтение файлов *.xlsx средствами 1С 8.2 (Управляемые формы) в т.ч. Веб-клиент: //infostart.ru/public/142187
Abadonna: Чтение файлов *.xlsx средствами 1С 8.2: //infostart.ru/public/139556
Dzenn: Загрузка файлов Excel XLSX через XML: //infostart.ru/public/205359
webstep: Чтение документа Excel 2007 без офиса, без ВК: //infostart.ru/public/202023
Душелов: Чтение/Запись документа Excel 2007 без офиса, без ВК. (с примером для 7.7, 8.1 и 8.2 на управляемых формах): //infostart.ru/public/19139
"Другое: чтение/редактирование XML":
anig99: "Однопальцевое" чтение XML для 8.2: //infostart.ru/public/84254
Lokiy: Парсинг, преобразование, редактирование XML: //infostart.ru/public/198131
onec.developer: Редактор XML на управляемых формах 8.2: //infostart.ru/public/201077
Yashazz: Просмотр xml-файлов: //infostart.ru/public/203514
Душелов: Создание документа Word 2007: //infostart.ru/public/16215
"Не 1С, но полезно":
iddqd: akXmlEdit - v1.5.0.7 редактор XML: //infostart.ru/public/15464


&НаКлиенте
Процедура ПриОткрытии(Отказ)
    ФайлEXCEL= "D:\Товар.xlsx";
    ИмяНомерЛиста = Новый Структура ("ИмяЛиста, НомерЛиста","Alfa1", 1);
    СтрокаЗаголовка = 1;
    НачСтрока = 0;
    КонСтрока = 0;
    КолвоСтрокExcel = 0;
    ЗагрузитьМетодом_NativeXLSX_НаСервере(ФайлEXCEL, ИмяНомерЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel);
КонецПроцедуры

&НаСервере
Процедура ЗагрузитьМетодом_NativeXLSX_НаСервере(ФайлEXCEL, ИмяНомерЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel)
    ТаблицаРезультат = ЗагрузитьМетодом_NativeXLSX(ФайлEXCEL, ИмяНомерЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel);
КонецПроцедуры

// Метод "NativeXLSX" (ЧтениеXML).
// Преобразует текст формата XML (файл типа XLSX) в таблицу значений,
// при этом колонки таблицы формируются на основе описания в XML.
//
// Параметры:
//      ФайлEXCEL - Полное имя файла (путь к файлу с именем файла и расширением)
//      ИмяНомерЛиста - Структура Имя и Номер выбранного листа файла EXCEL.
//      СтрокаЗаголовка (по умолчанию = 1) - Номер строки EXCEL, в которой расположены заголовки колонок.
//          Не используется.
//      В обработке 1-я строка анализируется для сопоставления колонок EXCEL с реквизитами 1С (справочники, докуметны, регистры).
//      НачСтрока (по-умолчанию = 0) - Номер начальной строки, начиная с которой считываются данные из EXCEL.
//      КонСтрока (по-умолчанию = 0) - Номер конечной строки, которой заканчиваются считываемые данные из EXCEL.
//          Если НачСтрока=0 и КонСтрока=0, то считывается вся таблица, находящаяся на листе EXCEL.
//      КолвоСтрокExcel - Количество строк на листе "ИмяЛиста" EXCEL. Возвращается в вызываемую процедуру.
//
// Возвращаемые значения:
//      ТаблицаРезультат - Результат считывания с листа "ИмяНомерЛиста" EXCEL.
//
&НаСервере
Функция ЗагрузитьМетодом_NativeXLSX(Знач ФайлEXCEL, Знач ИмяНомерЛиста, Знач СтрокаЗаголовка = 1, Знач НачСтрока = 0, Знач КонСтрока = 0, КолвоСтрокExcel = 0)
    Перем ZIPКаталог, ФайлИмяЛиста, ФайлНомерЛиста, КолвоКолонокEXCEL, НомерСтроки, НомерКолонки, ИмяКолонки, ИндексКолонки, ШиринаКолонки, ДлинаСтроки;
    Перем МассивИменКолонокXLSX, МассивSharedStrings, МассивNumFmtId, СоответствиеNumFmtIdFormatCode;
    Перем
SheetX,ЗначениеЯчейки, ТипЗначения, ФорматЯчейки, ФорматСтиля;
    Перем ТаблицаРезультат, НоваяСтрока;
   
    ФайлНомерЛиста  = ИмяНомерЛиста.НомерЛиста;
    ФайлНомерЛиста = ?(ФайлНомерЛиста = 0, 1, ФайлНомерЛиста);
   
    ZIPКаталог = КаталогВременныхФайлов() + "XLSX\";
    Если НЕ ПредварительнаяОбработкаФайлаXLSX(ФайлEXCEL, ZIPКаталог) Тогда
        Возврат Новый ТаблицаЗначений;
    КонецЕсли;
   
    СоответствиеNumFmtIdFormatCode = Новый Соответствие;
    МассивNumFmtId = ИзвлечьДанныеИзФайла_StylesXML(ZIPКаталог, СоответствиеNumFmtIdFormatCode);
   
    МассивSharedStrings = ИзвлечьДанныеИзФайла_SharedStringsXML(ZIPКаталог);
   
    SheetX = Новый ЧтениеXML;
    SheetX.ОткрытьФайл(ZIPКаталог + "XL\WorkSheets\Sheet" + ФайлНомерЛиста + ".xml");
   
    МассивИменКолонокXLSX = ПолучитьМассивИменКолонокНаЛистеXLSX(SheetX);
    КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
   
    // Создание результирующей таблицы, в которую будут записываться считанные из EXCEL данные.
    ТаблицаРезультат = Новый ТаблицаЗначений;
    // Формирование колонок результирующей таблицы.
    // "НомерСтроки" - для наглядности и удобства.
    // В зависимости от разрабатываемой обработки.
    // "Сопоставлено" - может быть другим.
    // Здесь же могут быть добавлены другие колонки, не формируемые из содержимого файла EXCEL.
    ТаблицаРезультат.Колонки.Добавить("НомерСтроки", Новый ОписаниеТипов("Число"), "№", 4);
    ТаблицаРезультат.Колонки.Добавить("Сопоставлено", Новый ОписаниеТипов("Булево"), "Сопоставлено", 1)
;
    ТаблицаРезультат.Колонки.Добавить("УровеньГруппировки", Новый ОписаниеТипов(
"Число"), "Гр", 2); // Группировка строк в файле EXCEL.
    Для ит = 1 ПО КолвоКолонокExcel Цикл
        ИмяКолонки = "N" + ит;
        Колонка = ТаблицаРезультат.Колонки.Добавить(ИмяКолонки);
    КонецЦикла;
   
    SheetX = Новый ЧтениеXML;
    SheetX.ОткрытьФайл(ZIPКаталог + "XL\WorkSheets\Sheet" + ФайлНомерЛиста + ".xml");
   
    ЭтоНачалоДанных = Ложь;
    // Считать очередной узел XML.
    Пока SheetX.Прочитать() Цикл
        Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ЭтоНачалоДанных = Истина;
            Прервать;
        КонецЕсли;
    КонецЦикла;
    Если НЕ ЭтоНачалоДанных Тогда
        Возврат Новый ТаблицаЗначений;
    КонецЕсли;
   
    // Считать очередной узел XML.
    НомерСтроки = 0;
    Пока SheetX.Прочитать() Цикл
        Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
            Прервать;   // Окончание данных.
        КонецЕсли;
        Если ВРег(SheetX.Имя) = "ROW" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            НомерСтроки = НомерСтроки + 1;
            Если НЕ НачСтрока = 0 И НЕ НомерСтроки = 1 И НомерСтроки < НачСтрока Тогда
                Продолжить;
            КонецЕсли;
            НоваяСтрока = ТаблицаРезультат.Добавить();
            НоваяСтрока.НомерСтроки = НомерСтроки
;
            НоваяСтрока.УровеньГруппировки = SheetX.ЗначениеАтрибута("outlineLevel");

            Пока SheetX.Прочитать() Цикл    // Считаем колонки строки EXCEL.
                Если ВРег(SheetX.Имя) = "ROW" Тогда
                    Прервать;
                КонецЕсли;
                Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
                    Прервать;   // Окончание данных.
                КонецЕсли;
                Если ВРег(SheetX.Имя) = "C" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                    ТипЗначения = SheetX.ЗначениеАтрибута("t");
                    ФорматЯчейки = SheetX.ЗначениеАтрибута("s");
                    ИмяКолонки = SheetX.ЗначениеАтрибута("r");
                    ИмяКолонкиБезЦифр = ЗаменитьОдниСимволыДругими("0123456789", ИмяКолонки, "");
                    ИндексКолонки = МассивИменКолонокXLSX.Найти(ИмяКолонкиБезЦифр)+1;
                    SheetX.Прочитать();
                    Если ВРег(SheetX.Имя) = "V"  ИЛИ ВРег(SheetX.Имя) = "F" Тогда   // "V" - Значение, "F" - Формула.
                        Если ВРег(SheetX.Имя) = "F" Тогда
                            Пока НЕ ВРег(SheetX.Имя) = "V" Цикл
                                SheetX.Прочитать();
                            КонецЦикла;
                        КонецЕсли;
                        SheetX.Прочитать();
                        Если ВРег(SheetX.Имя) = "#TEXT" Тогда
                            ЗначениеЯчейки = SheetX.Значение;
                            ФорматСтиля = "";
                            Если (НЕ ФорматЯчейки = "" И НЕ ФорматЯчейки = Неопределено) Тогда
                                Попытка
                                    ИндексФормата = Число(ФорматЯчейки);
                                    ФорматСтиля = СоответствиеNumFmtIdFormatCode.Получить(МассивNumFmtId[ИндексФормата]);
                                Исключение
                                    ФорматСтиля = "";
                                КонецПопытки;
                            КонецЕсли;
                            Если ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
                                Если ТипЗначения = Неопределено ИЛИ ВРег(ТипЗначения) = "N" ИЛИ ВРег(ТипЗначения) = "B" Тогда
                                    Попытка
                                        Значение1 = Число(ЗначениеЯчейки);
                                    Исключение
                                        Значение1 = ЗначениеЯчейки;
                                    КонецПопытки;
                                    ЗначениеЯчейки = Значение1;
                                    Если (ФорматСтиля = "" ИЛИ ФорматСтиля = Неопределено) Тогда
                                        // ФорматСтиля = Неопределено - Атрибут "s" отсутствует.
                                        // MS Office (2010) может не формировать в xml-файле описание стиля форматирования для ячейки.
                                        // LibreOffice (4.1.5) формирует в xml-файле необходимые описания стиля форматирования ячейки.
                                        // Сообщить("Не определен стиль форматирования для кода " + ФорматЯчейки + " значения " + ЗначениеЯчейки);
                                    КонецЕсли;
                                   
                                    Если ТипЗнч(ЗначениеЯчейки) = Тип("Строка")
                                        И (Найти(ЗначениеЯчейки, "E-") > 0 ИЛИ Найти(ЗначениеЯчейки, "E+") > 0) Тогда
                                        ЗначениеЯчейки = ПолучитьЧислоВСтепениИзСтроковогоЗначения(ЗначениеЯчейки);
                                    КонецЕсли;
                                   
                                    Если ТипЗнч(ЗначениеЯчейки) = Тип("Число") Тогда
                                        // ПРОЦЕНТ.
                                        Если ЭтоПроцентXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = Окр(ЗначениеЯчейки * 100, 3);
                                        // БУЛЕВО.
                                        ИначеЕсли ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = Булево(ЗначениеЯчейки);
                                        // ВРЕМЯ.
                                        ИначеЕсли ЭтоВремяXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = КонвертироватьЧислоXLSXвДатуВремя(ЗначениеЯчейки);
                                        // ДАТА.
                                        ИначеЕсли ЭтоДатаXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = КонвертироватьЧислоXLSXвДату(ЗначениеЯчейки);
                                        // ЧИСЛО.
                                        ИначеЕсли ТипЗначения = Неопределено
                                            ИЛИ ( ЭтоЧислоXLSX(ЗначениеЯчейки, ФорматСтиля)
                                            И НЕ ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля)
                                            И НЕ ЭтоВремяXLSX(ЗначениеЯчейки, ФорматСтиля)
                                            И НЕ ЭтоДатаXLSX(ЗначениеЯчейки, ФорматСтиля) )
                                            Тогда
                                            // Без преобразования.
                                        Иначе
                                            // Прочие форматы.
                                        КонецЕсли;
                                       
                                    Иначе
                                       
                                        Сообщить("Не удалось преобразовать значение к ""числовому""(процент, время, дата, число) типу.");
                                       
                                    КонецЕсли;
                                   
                                ИначеЕсли ВРег(ТипЗначения) = "S" Тогда
                                   
                                    // МассивSharedStrings может быть пустым.
                                    Попытка
                                        ЗначениеЯчейки = СокрЛП(МассивSharedStrings[Число(SheetX.Значение)]);
                                    Исключение
                                        ЗначениеЯчейки = "";
                                    КонецПопытки;
                                   
                                ИначеЕсли ВРег(ТипЗначения) = "STR" Тогда
                       
                                    Если ТипЗнч(ЗначениеЯчейки) = Тип("Строка") Тогда
                                        ЗначениеЯчейки = СокрЛП(ЗначениеЯчейки);
                                    КонецЕсли;
                       
                                КонецЕсли;
                            КонецЕсли;
                           
                            ИмяКолонки = "N"+ИндексКолонки;
                            НоваяСтрока[ИмяКолонки] = ЗначениеЯчейки;
                            // Используется при формировании таблицы на форме обработки.
                            ШиринаКолонки = ТаблицаРезультат.Колонки[ИмяКолонки].Ширина;
                            ДлинаСтроки = СтрДлина(СокрЛП(ЗначениеЯчейки));
                            ТаблицаРезультат.Колонки[ИмяКолонки].Ширина = ?(ШиринаКолонки < ДлинаСтроки, ДлинаСтроки, ШиринаКолонки);
                           
                        КонецЕсли;
                    КонецЕсли;
                КонецЕсли;
            КонецЦикла;
            Если ((НЕ КонСтрока = 0 И (НомерСтроки + 1) > КонСтрока)
                ИЛИ (НЕ КолвоСтрокExcel = 0  И (НомерСтроки + 1) > КолвоСтрокExcel)) Тогда
                Прервать;   // Окончание диапазона считываемых данных.
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
   
    // Завершение работы.
    // Закрытие Объектов.
    SheetX.Закрыть();
   
    УдалитьКолонкиСНулевойШириной(ТаблицаРезультат);
   
    Возврат ТаблицаРезультат;
   
КонецФункции

&НаСервере
Функция ПредварительнаяОбработкаФайлаXLSX(ФайлEXCEL, ZIPКаталог)
    Перем Файл;
   
    Файл = ПолучитьОбъектФайл(ФайлEXCEL);
    Если Файл = Неопределено Тогда
        Сообщить("Невозможно загрузить данные, т.к. невозможно открыть для чтения файл:
        |" + ФайлEXCEL);
        Возврат Ложь;
    КонецЕсли;
   
    Если НЕ ВРег(Файл.Расширение) = ".XLSX" Тогда
        Сообщить("Файл с расширением " + Файл.Расширение +" не поддерживается методом NativeXLSX:
        |" + ФайлEXCEL);
        Возврат Ложь;
    КонецЕсли;
   
    Если НЕ РаспаковатьXLSXвКаталогВременныхФайлов(ФайлEXCEL, ZIPКаталог) Тогда
        Сообщить("Ошибка распаковки файла.
        |Возможно каталог временных файлов занят.
        |" + ФайлEXCEL);
        Возврат Ложь;
    КонецЕсли;
   
    Возврат Истина;
   
КонецФункции

&НаСервере
Функция ПолучитьОбъектФайл(Знач ФайлEXCEL)
    Перем Файл;
   
    Если НЕ ЗначениеЗаполнено(ФайлEXCEL) Тогда
        Возврат Неопределено;
    КонецЕсли;
   
    Файл = Новый Файл(ФайлEXCEL);
    Если НЕ ФайлСуществуетИДоступен(Файл.ПолноеИмя) Тогда
        Сообщить("Файл не существует/не доступен:
        |" + ФайлEXCEL);
        Возврат Неопределено;
    КонецЕсли;
   
    Возврат Файл;
   
КонецФункции

&НаСервере
Функция ФайлСуществуетИДоступен(ПолноеИмяФайла)
    Перем Файл;
   
    Файл = Новый Файл(ПолноеИмяФайла);
    Если НЕ Файл.Существует() Тогда
        Возврат Ложь;
    КонецЕсли;
   
    // Проверка: Занят ли файл другим процессом?
    Если НЕ ВРег(Файл.Расширение) = ".DBF" Тогда
        Попытка
            ПереместитьФайл(Файл.ПолноеИмя,Файл.ПолноеИмя);
        Исключение
            Сообщить("Файл не доступен:
            |" + Файл.ПолноеИмя);
            Возврат Ложь;
        КонецПопытки;
    КонецЕсли;
   
    Возврат Истина;
   
КонецФункции

&НаСервере
Функция РаспаковатьXLSXвКаталогВременныхФайлов(ФайлEXCEL, ZIPКаталог)
    Перем ZIPФайл;
   
    Попытка
        УдалитьФайлы(ZIPКаталог);
       
        ZIPФайл = Новый ЧтениеZipФайла;
        ZIPФайл.Открыть(ФайлEXCEL);
        ZIPФайл.ИзвлечьВсе(ZIPКаталог, РежимВосстановленияПутейФайловZIP.Восстанавливать);
        Возврат Истина;
    Исключение
        Возврат Ложь;
    КонецПопытки;
   
    Возврат Истина;
   
КонецФункции

&НаСервере
Функция ИзвлечьДанныеИзФайла_StylesXML(ZIPКаталог, СоответствиеNumFmtIdFormatCode)
    Перем Файл, Styles;
    Перем МассивNumFmtId, ит;
   
    МассивNumFmtId = Новый Массив;
    СоответствиеNumFmtIdFormatCode = Новый Соответствие;
   
    Файл = Новый Файл(ZIPКаталог + "XL\Styles.xml");
    Если НЕ Файл.Существует() Тогда
        Возврат МассивNumFmtId;
    КонецЕсли;
   
    Styles = Новый ЧтениеXML;
    Styles.ОткрытьФайл(Файл.ПолноеИмя);
   
    Пока Styles.Прочитать() Цикл
        Если ВРег(Styles.Имя) = ВРег("numFmt") И Styles.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            СоответствиеNumFmtIdFormatCode.Вставить(Styles.ЗначениеАтрибута("numFmtId"), ВРег(Styles.ЗначениеАтрибута("formatCode")));
        КонецЕсли;
        Если ВРег(Styles.Имя) = ВРег("cellXfs") Тогда
            Пока Styles.Прочитать() Цикл
                Если ВРег(Styles.Имя) = ВРег("xf") И Styles.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                    МассивNumFmtId.Добавить(Styles.ЗначениеАтрибута("numFmtId"));
                КонецЕсли;
            КонецЦикла;
        КонецЕсли;
    КонецЦикла;
   
    // Завершение работы.
    // Закрытие Объектов.
    Styles.Закрыть();

    // Проверка сопоставления кодов массива и соответствия.
    // MS Office может не формировать в xml-файле описание стиля форматирования для ячейки.
    // LibreOffice формирует в xml-файле необходимые описания стиля форматирования ячейки.
    Для Каждого ит ИЗ МассивNumFmtId Цикл
        Если СоответствиеNumFmtIdFormatCode.Получить(ит) = Неопределено Тогда
            Если ит = "0" Тогда    // Стандарт для числа (Целое число).
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "GENERAL");
            ИначеЕсли ит = "9" ИЛИ ит = "10" Тогда    // Форматы для % ("0%", "0.00%").
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "0%");
            ИначеЕсли ит = "14" ИЛИ ит = "16" Тогда    // Форматы для даты.
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "DD.MM.YYYY");
            ИначеЕсли ит = "45" ИЛИ ит = "46" ИЛИ ит = "47" Тогда    // Форматы для времени.
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "HH:MM:SS");
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
   
    Возврат МассивNumFmtId;
   
КонецФункции

&НаСервере
Функция ИзвлечьДанныеИзФайла_SharedStringsXML(ZIPКаталог)
    Перем Файл, SharedStrings;
    Перем МассивSharedStrings;
   
    // Если в файле EXCEL не содержится значений, имеющих тип "СТРОКА", то файл "SharedStrings.xml" не формируется.
   
    МассивSharedStrings = Новый Массив;
   
    Файл = Новый Файл(ZIPКаталог + "XL\SharedStrings.xml");
    Если НЕ Файл.Существует() Тогда
        Возврат МассивSharedStrings;
    КонецЕсли;
   
    SharedStrings = Новый ЧтениеXML;
    SharedStrings.ОткрытьФайл(Файл.ПолноеИмя);
   
    Пока SharedStrings.Прочитать() Цикл
        Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
            МассивSharedStrings.Добавить(SharedStrings.Значение);
        КонецЕсли;
    КонецЦикла;
   
    // Завершение работы.
    // Закрытие Объектов.
    SharedStrings.Закрыть();
   
    Возврат МассивSharedStrings;
   
КонецФункции

&НаСервере
Функция ПолучитьМассивИменКолонокНаЛистеXLSX(SheetX)
    Перем ДиапазонДанных, ДиапазонКолонок, ПерваяКолонка, ПоследняяКолонка, НомерПервойК, НомерПоследнейК;
    Перем Подсчет, ИмяКолонки;
    Перем МассивИменКолонокXLSX, КолвоКолонокEXCEL;
    
    МассивИменКолонокXLSX = Новый Массив;
    
    Подсчет = Ложь;
    // Считать очередной узел XML.
    Пока SheetX.Прочитать() Цикл
        // DIMENSION.
        Если ВРег(SheetX.Имя) = "DIMENSION" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ДиапазонДанных     = SheetX.ПолучитьАтрибут("ref");
            ДиапазонКолонок = ЗаменитьОдниСимволыДругими("0123456789", ДиапазонДанных, "");
            ПерваяКолонка     = Лев(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") - 1);
            ПоследняяКолонка= Сред(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") + 1);
            НомерПервойК    = НомерКолонкиДесятичный(ПерваяКолонка);
            НомерПоследнейК    = НомерКолонкиДесятичный(ПоследняяКолонка);
        КонецЕсли;
        // Подсчет по 1-ой строке.
        Если ВРег(SheetX.Имя) = "ROW" Тогда
            Если SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                // Начало отсчета.
                Подсчет = Истина;
            ИначеЕсли SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
                // Окончание отсчета.
                Прервать;
            КонецЕсли;
        КонецЕсли;
        Если Подсчет И ВРег(SheetX.Имя) = "C" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ИмяКолонки = SheetX.ПолучитьАтрибут("r");
            ИмяКолонки = ЗаменитьОдниСимволыДругими("0123456789", ИмяКолонки, "");
            МассивИменКолонокXLSX.Добавить(ИмяКолонки);
        КонецЕсли;
    КонецЦикла;
    
    КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
    Если НЕ НомерПоследнейК = Неопределено Тогда
        Если КолвоКолонокEXCEL < НомерПоследнейК Тогда
            Сообщить("Строка заголовков колонок (1-я строка) заполнена не полностью:
            |К-во колонок строки меньше объявленной: " + КолвоКолонокEXCEL + "<" + НомерПоследнейК);
            ДополнитьМассивИменКолонокXLSX(НомерПоследнейК, МассивИменКолонокXLSX);
        ИначеЕсли КолвоКолонокEXCEL > НомерПоследнейК Тогда
            Сообщить("Строка заголовков колонок (1-я строка) содержит больше колонок, чем объявлено:
            |К-во колонок строки больше объявленной:" + КолвоКолонокEXCEL + ">" + НомерПоследнейК);
        КонецЕсли;
    КонецЕсли;
        
    Возврат МассивИменКолонокXLSX;
    
КонецФункции

&НаСервере
Функция НомерКолонкиДесятичный(ИмяКолонкиXLSX)
    Перем Латиница, ДлинаНомера, Поз, ит;
    Перем НомерКолонки;
    
    Латиница = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";    // 26.
    ДлинаНомера = СтрДлина(ИмяКолонкиXLSX);
    НомерКолонки = 0;
    Для ит = 1 ПО ДлинаНомера Цикл
        Поз = Найти(Латиница, Сред(ИмяКолонкиXLSX, (ДлинаНомера + 1 - ит), 1));
        НомерКолонки = НомерКолонки + Поз * Pow(26, ит - 1);
    КонецЦикла;
    
    Возврат НомерКолонки;
    
КонецФункции

&НаСервере
Процедура ДополнитьМассивИменКолонокXLSX(Знач КолвоКолонокExcel, МассивИменКолонокXLSX, Индекс = - 1)
    Перем Алфавит, ит, Буква;
    
    Алфавит = РазложитьСтрокуВМассивПодстрок("A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z", ",");
    
    Если МассивИменКолонокXLSX.Количество() >= КолвоКолонокExcel Тогда
        Возврат;
    КонецЕсли;
    
    Если Индекс > Алфавит.Количество() - 1 Тогда
        Возврат;
    КонецЕсли;
    
    Буква = ?(Индекс = -1, "", Алфавит[Индекс]);
    Для ит = 0 ПО Алфавит.Количество() - 1 Цикл
        Если МассивИменКолонокXLSX.Найти(Буква + Алфавит[ит]) = Неопределено Тогда
            МассивИменКолонокXLSX.Добавить(Буква + Алфавит[ит]);
        КонецЕсли;
        Если МассивИменКолонокXLSX.Количество() >= КолвоКолонокExcel Тогда
            Возврат;
        КонецЕсли;
    КонецЦикла;
    
    Если МассивИменКолонокXLSX.Количество() > КолвоКолонокExcel Тогда
        Возврат;
    Иначе
        Индекс = Индекс + 1;
        ДополнитьМассивИменКолонокXLSX(КолвоКолонокExcel, МассивИменКолонокXLSX, Индекс);
    КонецЕсли;
    
    Возврат;
    
КонецПроцедуры

// Функция "расщепляет" строку на подстроки, используя заданный
//      разделитель. Разделитель может иметь любую длину.
//      Если в качестве разделителя задан пробел, рядом стоящие пробелы
//      считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
//      игнорируются.
//      Например,
//      РазложитьСтрокуВМассивПодстрок(",один,,,два", ",") возвратит массив значений из пяти элементов,
//      три из которых - пустые строки, а
//      РазложитьСтрокуВМассивПодстрок(" один   два", " ") возвратит массив значений из двух элементов
//
//  Параметры:
//      Стр -           строка, которую необходимо разложить на подстроки.
//                      Параметр передается по значению.
//      Разделитель -   строка-разделитель, по умолчанию - запятая.
//
//  Возвращаемое значение:
//      массив значений, элементы которого - подстроки
//
&НаСервере
Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",")
    
    МассивСтрок = Новый Массив();
    Если Разделитель = " " Тогда
        Стр = СокрЛП(Стр);
        Пока 1 = 1 Цикл
            Поз = Найти(Стр, Разделитель);
            Если Поз = 0 Тогда
                МассивСтрок.Добавить(СокрЛП(Стр));
                Возврат МассивСтрок;
            КонецЕсли;
            МассивСтрок.Добавить(СокрЛП(Лев(Стр, Поз - 1)));
            Стр = СокрЛ(Сред(Стр, Поз));
        КонецЦикла;
    Иначе
        ДлинаРазделителя = СтрДлина(Разделитель);
        Пока 1 = 1 Цикл
            Поз = Найти(Стр, Разделитель);
            Если Поз = 0 Тогда
                Если (СокрЛП(Стр) <> "") Тогда
                    МассивСтрок.Добавить(СокрЛП(Стр));
                КонецЕсли;
                Возврат МассивСтрок;
            КонецЕсли;
            МассивСтрок.Добавить(СокрЛП(Лев(Стр,Поз - 1)));
            Стр = Сред(Стр, Поз + ДлинаРазделителя);
        КонецЦикла;
    КонецЕсли;
   
КонецФункции

&НаСервере
Функция ЭтоЧислоXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ( ВРег(ФорматСтиля) = "GENERAL"
        ИЛИ ВРег(ФорматСтиля) = "STANDARD"
        ИЛИ Найти(ФорматСтиля, "0") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоПроцентXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ( Найти(ФорматСтиля, "%") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля)
   
    Если (ЗначениеЯчейки = 0 ИЛИ ЗначениеЯчейки = 1)
        И Найти(ВРег(ФорматСтиля), "ИСТИНА") > 0 ИЛИ Найти(ВРег(ФорматСтиля), "ЛОЖЬ") > 0
        ИЛИ Найти(ВРег(ФорматСтиля), "TRUE") > 0 ИЛИ Найти(ВРег(ФорматСтиля), "FALSE") > 0
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоДатаXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ЗначениеЯчейки = Цел(ЗначениеЯчейки) И
        ( Найти(ФорматСтиля, "DD") > 0
        ИЛИ Найти(ФорматСтиля, "MM") > 0
        ИЛИ Найти(ФорматСтиля, "YY") > 0
        ИЛИ Найти(ФорматСтиля, "QQ") > 0
        ИЛИ Найти(ФорматСтиля, "WW") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоВремяXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ЗначениеЯчейки < 1 И
        ( Найти(ФорматСтиля, "HH:") > 0
        ИЛИ Найти(ФорматСтиля, "[HH]:") > 0
        ИЛИ Найти(ФорматСтиля, "[H]:") > 0
        ИЛИ Найти(ФорматСтиля, "MM:") > 0
        ИЛИ Найти(ФорматСтиля, ":SS") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция КонвертироватьЧислоXLSXвДату(Знач Число)
    Перем Дата1900, Разница, ДатаРезультат;
   
    Дата1900 = Дата("19000101");
   
    Разница = Число - 2;    // EXCEL ошибочно считает 1900-й год високосным.
    Разница = ?(Разница < 0, 0, Разница);
   
    ДатаРезультат = Дата1900 + Разница * 24 * 60 * 60;
   
    Возврат ДатаРезультат;
   
КонецФункции

&НаСервере
Функция КонвертироватьЧислоXLSXвДатуВремя(Знач Число)
    Перем КВоСекунд;
    Перем ВремяРезультат;
   
    // 0,0000115740740740741 = 1 сек.
    // 1                     = 24 часа 00 мин 00 сек.
   
    Если ТипЗнч(Число) = Тип("Число") Тогда
        КВоСекунд = Число * 100000 / 1.15740740740741;
        КВоСекунд = Окр(КВоСекунд);
    Иначе
        Сообщить("Ошибка определения значения типа ""Время"".");
    КонецЕсли;
   
    ВремяРезультат = Дата("19000101000000") + КВоСекунд;
   
    Возврат ВремяРезультат;
   
КонецФункции

&НаСервере
Функция ПолучитьЧислоВСтепениИзСтроковогоЗначения(Знач ЗначениеЯчейки)
    Перем Поз1Е, Степень;
    Перем Значение;
   
    Если Найти(ЗначениеЯчейки, "E-") > 0 Тогда
        Поз1Е = Найти(ЗначениеЯчейки, "E-");
        Степень = Сред(ЗначениеЯчейки, Поз1Е+2);
        Значение = Лев(ЗначениеЯчейки, Поз1Е-1);
        Попытка
            Степень = Число(Степень);
            Значение = Число(Значение) / Pow(10, Степень);
        Исключение
            Значение = ЗначениеЯчейки;
        КонецПопытки;
    ИначеЕсли Найти(ЗначениеЯчейки, "E+") > 0 Тогда
        Поз1Е = Найти(ЗначениеЯчейки, "E+");
        Степень = Сред(ЗначениеЯчейки, Поз1Е+2);
        Значение = Лев(ЗначениеЯчейки, Поз1Е-1);
        Попытка
            Степень = Число(Степень);
            Значение = Число(Значение) * Pow(10, Степень);
        Исключение
            Значение = ЗначениеЯчейки;
        КонецПопытки;
    Иначе
        Значение = ЗначениеЯчейки;
    КонецЕсли;
   
    Возврат Значение;
   
КонецФункции

&НаСервере
Функция ЗаменитьОдниСимволыДругими(ЗаменяемыеСимволы, Строка, СимволыЗамены)
    Результат = Строка;
    Для НомерСимвола = 1 По СтрДлина(ЗаменяемыеСимволы) Цикл
        Результат = СтрЗаменить(Результат, Сред(ЗаменяемыеСимволы, НомерСимвола, 1), Сред(СимволыЗамены, НомерСимвола, 1));
    КонецЦикла;
    Возврат Результат;
КонецФункции

&НаСервере
Процедура УдалитьКолонкиСНулевойШириной(ТаблицаРезультат)
    Перем МассивПустыхКолонок;
    // Найдем пустые колонки.
    МассивПустыхКолонок = Новый Массив;
    Для Каждого Колонка ИЗ ТаблицаРезультат.Колонки Цикл
        Если Колонка.Ширина = 0 Тогда
            МассивПустыхКолонок.Добавить(Колонка.Имя);
        КонецЕсли;
    КонецЦикла;
    // Удалим пустые колонки.
    Для Каждого ПустаяКолонка ИЗ МассивПустыхКолонок Цикл
        ТаблицаРезультат.Колонки.Удалить(ПустаяКолонка);
    КонецЦикла;
КонецПроцедуры

МА! С уважением к сообществу МА!


165

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Рейтинг
8. sergnik 06.11.13 12:33 Сейчас в теме
(5) Eugeneer,
Позволю себе с вами не согласиться.
Сама публикация не то чтобы сильно заинтересовала, но была в топе, и я сюда зашел.
Просмотрел остальные 5 публикаций автора, о которых вы написали

Каждая публикация описывает совсем разные методы обработки информации,
поэтому это не выжимание из воздуха.
Кроме того, весь код выложен прямо в публикации, не нужно качать "кота в мешке" чтобы оценить работу
кода. Уже за одно это автору - ОГРОМНЕЙШИЙ ПЛЮС

Быть может, у Вас личная неприязнь к автору? ))
user687869_ip.kolotei; Knych; HitGroove; CratosX; Alex_IT; StepByStep; +6 Ответить 1
9. CagoBHuK 31 06.11.13 14:56 Сейчас в теме
Для тех, кто хочет сделать действительно красивое решение: открываете XML XSLX файла и с помощью XSLT преобразуете в сериализованный табличный документ. А дальше - обычная рассериализация с помощью фабрики XDTO. Никакого геморроя и лишнего текста. Все будет работать штатными средствами.
SoNiKa; quNas; nSpirit2; i.kovtun; zarucheisky; StepByStep; +6 Ответить 2
46. 7OH 32 05.09.14 01:53 Сейчас в теме
Ни на что не претендую.
Добавил:
1. чистку временного каталога за собой
2. выбор листа
Переделал:
1. Определение колонок (не по первой строке, а по служебным данным "DIMENSION\ref" )
2. Имена колонок - немного подправил аглоритм - вылетало часто.
3. Сорри - но обычных формах - переделать не сложно.
Прикрепленные файлы:
ЗагрузкаXLSX.erf
Ponommax; quNas; StepByStep; Glk; +4 Ответить 3
56. MishaHD 28 05.11.14 07:32 Сейчас в теме
Update :) Написал хвалебный комментарий, а потом нашел косяк. В представленных выше процедурах когда мы формируем МассивSharedStrings из файла SharedStrings.xml не учитывается то, что может встречаться значение "пустая строка". То есть условие
Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
не будет отрабатывать. Соответственно если в файле SharedStrings.xml встретилась пустая строка, то начинаю "плыть" индексы массива МассивSharedStrings, а за ними "плывет" результирующая таблица.

Написал следующий костыль, может кому полезно будет:

Вот это:
Пока SharedStrings.Прочитать() Цикл
        Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
            МассивSharedStrings.Добавить(SharedStrings.Значение);
        КонецЕсли;
    КонецЦикла;


Меняем на это:
ФлагСтрокаЗаписана = Ложь;
    
	Пока SharedStrings.Прочитать() Цикл
		Если ВРег(SharedStrings.Имя) = "SI" и SharedStrings.ТипУзла = ТипУзлаXML.НачалоЭлемента тогда
			ФлагСтрокаЗаписана = Ложь;
		КонецЕсли;
		
        Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
            МассивSharedStrings.Добавить(SharedStrings.Значение);
			ФлагСтрокаЗаписана = Истина;
		КонецЕсли;
		
		Если ВРег(SharedStrings.Имя) = "SI" и SharedStrings.ТипУзла = ТипУзлаXML.КонецЭлемента и не ФлагСтрокаЗаписана тогда
			//встретили пустую строку!
			 МассивSharedStrings.Добавить("");
		КонецЕсли;
		
    КонецЦикла;
Показать


Спасибо за процедуры, приятно что все нормально отлажено и работает (как выяснилось кроме некоторых косяков))). Небольшое пожелание, бы бы удобно если бы колонки именовались из заголовочных данных (например если указываем что заголовок - это строка №1).
It-developer; InShallaH; [4EPHbIYY_KOT]; Glk; +4 Ответить 4
4. TheGrr 139 03.11.13 12:23 Сейчас в теме
(3) Eugeneer, а вы в каждой публикации, касающейся загрузки из Excel, будете обсирать автора? :) Уже ведь даже не смешно. Я прекрасно понимаю, что это Ваша вотчина. Но я лично за то, чтобы различных решений одной задачи было много и разных, в т.ч. и бесплатных ;)
yuraskas; quNas; StepByStep; +3 Ответить 1
1. Evgen.Ponomarenko 542 01.11.13 18:50 Сейчас в теме
Мега зачетно! В копилку готовых решений на пожизненно! )))
StepByStep; +1 Ответить
2. peterxx 19 01.11.13 20:59 Сейчас в теме
Очень неплохо, а то внешние компоненты - кот в мешке, ADO - бывает лень возиться и т.п.
StepByStep; +1 Ответить
6. Yashazz 2854 05.11.13 12:46 Сейчас в теме
Ну, пущай будет, как оглавление. А то и правда, неохота иной раз лазить да искать.

(5) Кое в чём склонен согласиться.
StepByStep; +1 Ответить
7. Pavl0 86 06.11.13 10:27 Сейчас в теме
Замечательно! Утащил к себе, проверю на досуге.
StepByStep; +1 Ответить 1
14. Abadonna 3833 07.11.13 06:20 Сейчас в теме
(5)
А тут мы видим банальное выжимание рейтинга. Ведь те кто первую публикацию скачал будут еще ставить рейтинги в других пяти. Это очевидно)))

Нет, Евген, тут ты как раз не прав! Плюсуют/качают только то, что на виду. Не будут еще ставить рейтинги в других пяти, за редчайшими исключениями. По личному опыту;)..
P.S. Давным-давно, хохмы ради, я опубликовал свою же обработку под другим ником. Как попёрли плюсы! А самое интересное: продолжали плюсовать даже после того, как я написал, что это шутка и указал первоисточник. Продолжали!
StepByStep; +1 Ответить
24. mvgfirst 4 20.01.14 13:28 Сейчас в теме
Кто нибудь тестировал это на практических данных?
Значения ячеек с формулами полностью игнорируются при использовании этого метода.
Вернее не метода а если скопировать приведенный исходный код.

Без допиливания руками - никак не обойтись.
35. Glk 15.04.14 14:36 Сейчас в теме
// ЧИСЛО.
                                        Если Прав(ЗначениеЯчейки, 5) = "E-003" Тогда
                                            УдалитьПоследнийСимволВСтроке(ЗначениеЯчейки, 5);
                                            Попытка
                                                ЗначениеЯчейки = Число(ЗначениеЯчейки);
                                            Исключение
                                            КонецПопытки;
                                            // ЧИСЛО.
                                        ИначеЕсли Прав(ЗначениеЯчейки, 3) = "E-3" Тогда
                                            УдалитьПоследнийСимволВСтроке(ЗначениеЯчейки, 3);
                                            Попытка
                                                ЗначениеЯчейки = Число(ЗначениеЯчейки);
                                            Исключение
                                            КонецПопытки;
Показать

Обрезать обрезали, а поделить на 1000 забыли.
StepByStep; +1 Ответить 1
40. StepByStep 3256 03.09.14 13:57 Сейчас в теме
(38) Glk,
03.09.2014. Новая редакция.
41. Glk 03.09.14 16:39 Сейчас в теме
ИндексКолонки = ?(ИндексКолонки = Неопределено, КоличествоСлужебныхКолонок-1, ИндексКолонки+КоличествоСлужебныхКолонок-1);

Непонятно, зачем тут КоличествоСлужебныхКолонок-1, если имя колонки никак от количества служебных не зависит.
У меня добавляется еще одна служебная колонка с уровнем группировки для загрузки иерархических справочников номенклатуры от поставщиков, возможно стоит ее добавить и в вашу обработку для универсальности.
НоваяСтрока.УровеньГруппировки=SheetX.ЗначениеАтрибута("outlineLevel");


StepByStep; +1 Ответить 1
43. Glk 04.09.14 12:47 Сейчас в теме
(42)
Он отсутствует, если нет собственно группировки в текущей строке, но это не мешает загружать его для остальных. А если определить колонку как
ТаблицаРезультат.Колонки.Добавить("УровеньГруппировки", Новый ОписаниеТипов("Число"), "Гр", 4);

то даже проверку на Неопределено делать не приходится - само в 0 преобразуется.
StepByStep; +1 Ответить 2
10. Nick_Godspeed 06.11.13 15:14 Сейчас в теме
(5) Eugeneer, не ревнуйте :)
Как верно подметил (8) только за открытый код, да плюс за такую всестороннюю проработку вопроса автор заслужил хоть сто постов по одному вопросу.
11. LexSeIch 203 06.11.13 16:34 Сейчас в теме
Мир этому дому!
Мне нравиться, когда код публикуется в статье. Автору плюс.
12. StepByStep 3256 06.11.13 18:36 Сейчас в теме
(7) Pavl0,
Если не затруднит - отпишитесь, пожалуйста, о результатах.
13. StepByStep 3256 06.11.13 18:47 Сейчас в теме
(9) CagoBHuK,
ПРЕКРАСНО. Существует еще способ.
15. Abadonna 3833 07.11.13 07:09 Сейчас в теме
16. StepByStep 3256 07.11.13 10:45 Сейчас в теме
(15) Abadonna,
Упоминание об этой работе встречал. Страница была недоступна. Причина - неизвестна.
А вообще, хорошая мысль, сделать подборку ссылок по вопросу "Загрузки из EXCEL ..." от разных авторов в разных "ракурсах".
Соберу - выложу.
17. StepByStep 3256 07.11.13 13:30 Сейчас в теме
07.11.2013.
Добавлены ссылки на публикации других авторов.
Если что-то не увидел, не обессудьте.
18. soap 56 07.11.13 15:45 Сейчас в теме
Интересно. Оч хор что код прямо в статье.
Автору плюс
19. Abadonna 3833 07.11.13 16:55 Сейчас в теме
(0) В тексте поправь
Импирически:
-Эмпирически ;)
20. StepByStep 3256 07.11.13 20:35 Сейчас в теме
(19) Abadonna,
СПАСИБО. "Велик и Могуч Русский язык".
21. RainyAugust22 234 08.11.13 06:37 Сейчас в теме
Плюсую. Взял на заметку.
22. zspr 22 15.11.13 15:01 Сейчас в теме
Автору большое спасибо
Прикрепленные файлы:
25. StepByStep 3256 30.01.14 13:02 Сейчас в теме
(24) mvgfirst,
СПАСИБО.
Действительно так. Надо "допилить".
26. StepByStep 3256 01.02.14 14:18 Сейчас в теме
(24) mvgfirst,
01.02.2014.
Изменена функция ЗагрузитьМетодом_1CXML().
Дополнена считыванием значений из ячеек, содержащих формулы.
27. Al-X 05.02.14 10:48 Сейчас в теме
+ Актуально-то как !!! Жлобы, не хотят офис покупать !! ))))
28. smilebringer 26.02.14 12:05 Сейчас в теме
Эмпирическая догадка не верна, любое целое, дробное число, процент, время, и другие числовые форматы будут интерпретироваться как дата. Строковые значения будут верно обрабатываться.
29. igyo 104 27.02.14 10:08 Сейчас в теме
Косяк если в колонке будет пустая ячейка, смещаются колонки тогда... :(
30. StepByStep 3256 27.02.14 16:56 Сейчас в теме
(28) smilebringer,
СПАСИБО.
Строки, числа, даты читаются.
Процент, время - посмотрю, подправлю.
31. StepByStep 3256 27.02.14 16:58 Сейчас в теме
(29) igyo,
Это проверялось.
В смысле одна или несколько пустых ячеек в колонке или вся колонка пустая?
Если можно - файл выложите, пожалуйста.
32. StepByStep 3256 01.03.14 23:16 Сейчас в теме
01.03.2014 г. Обновление.
(28) smilebringer, (29) igyo,
СПАСИБО за указанные неточности.
Доработал.
Если обнаружите неточности - напишите, пожалуйста.
33. spaminfostart 15 05.03.14 16:47 Сейчас в теме
и тут спрошу про 255 столбцов... таки не обрабатывает такие файлы?
34. smilebringer 11.03.14 13:43 Сейчас в теме
Тебе бы еще такие вещи вынести на git или другую систему контроля версий, тебе тогда и сообщество укажет, где что поправить, может и свой вариант кто-то предложит. А так изменение читать тяжело и поэтому лениво :)
36. StepByStep 3256 20.08.14 15:46 Сейчас в теме
37. nSpirit2 20.08.14 15:07 Сейчас в теме
Меня очень нервирует способ объявление переменных взятый явно из Делфи. Ну а так полностью согласен с (9) CagoBHuK все намного проще :)
38. Glk 23.08.14 01:13 Сейчас в теме
(36) Кстати, пришлось еще добавить аналогичную конструкцию для
Прав(ЗначениеЯчейки, 3) = "E-2"
, регулярно попадалось в присылаемых нам файликах.
39. StepByStep 3256 27.08.14 21:02 Сейчас в теме
(38) Glk,
Скоро будет новая редакция. В ней будет и Е-..., Е+... и др.
42. StepByStep 3256 03.09.14 22:43 Сейчас в теме
(41) Glk,
ИндексКолонки = ?(ИндексКолонки = Неопределено, КоличествоСлужебныхКолонок-1, ИндексКолонки+КоличествоСлужебныхКолонок-1);
СПАСИБО.

Атрибут "outlineLevel" может отсутствовать, например, если файл создан в MS EXCEL.
При сохранении в LibreOffice - он есть.
44. StepByStep 3256 04.09.14 15:22 Сейчас в теме
45. StepByStep 3256 04.09.14 15:32 Сейчас в теме
47. StepByStep 3256 05.09.14 13:44 Сейчас в теме
(46) 7OH,
Определение колонок (не по первой строке, а по служебным данным "DIMENSION\ref"

Сталкнулся с несоответствием служебных данных и реальных колонок - поэтому по 1-ой строке "по факту".
Имена колонок - немного подправил аглоритм - вылетало часто

Если не сложно опишите пример.
СПАСИБО.
48. StepByStep 3256 05.09.14 17:14 Сейчас в теме
(46) 7OH,
Не заполненная/не полностью заполненная 1-я строка ?
49. 7OH 32 06.09.14 15:30 Сейчас в теме
(47)
в первой строке шапка документа в виде
Склад : техника
ответственный: Пупкин
и тут пошла шапка колонок
итого он определяет всего 2 колонки и при попытке считывания на шапке вываливается с ошибкой
а так в DIMENSION вроде красиво лежит весь диапазон - спеациально ставил спрва снизу подальше одну букву - подхватывало
50. StepByStep 3256 10.09.14 13:53 Сейчас в теме
51. Drizer2000 13 24.09.14 15:57 Сейчас в теме
Эх описал бы кто преимущество, того или иного метода, я не читал все статьи автора, может где и есть. Например, мне нужно загружать в базу из экселя прайсы поставщиков. Прайсы могут содержать до 10 тыс строк, вот и думаю какой бы метод использовать. Сейчас сделано классичеси через ОЛЕ,но относительно медленно идет загрузка.
52. jobkostya1c8 24.09.14 16:19 Сейчас в теме
Ставлю "плюс" за подборку решений. Все равно для разных задач приходится свое писать. В одной из нехороших обработок по загрузке основных средств лучшего решения чем вручную указание пользователем номеров колонок не было.
53. Drizer2000 13 24.09.14 20:54 Сейчас в теме
А кто знает какой используется метод для обработки указанной вот по этой ссылке:
http://infostart.ru/public/21810/
54. SinglCOOLer 210 26.09.14 14:08 Сейчас в теме
все бы вроде не плохо, но часть данных колонок почему то берется с нужно листа, а часть с другого
55. SinglCOOLer 210 26.09.14 14:34 Сейчас в теме
Если делаешь лист 1 и единственным, то перестает путать и грузит корректно
57. StepByStep 3256 25.11.14 23:20 Сейчас в теме
(54), (55) SinglCOOLer,
В ранних версиях обработки "Импорт (загрузка) из внешнего источника (Excel,LibreOffice,SQL,DBF,MXL) в 1С 8.2/8.3: Розница,УТ,БП,КА. /РОССИЯ,УКРАИНА,БЕЛАРУСЬ/" http://infostart.ru/public/120961/ описанный метод использовался и корректно брал данные с необходимого листа.
58. StepByStep 3256 25.11.14 23:21 Сейчас в теме
(56) MishaHD,
Рекомендую обратить внимание на "Загрузка из EXCEL в 1С. Чтение файла XLSX средствами 1С. ПостроительDOM" http://infostart.ru/public/300092/
59. MishaHD 28 21.12.14 08:33 Сейчас в теме
(58) спасибо за совет. В принципе допилил то, что в этом посте выложено под свои нужды, все работает без косяков
60. jobkostya1c8 28.01.15 13:41 Сейчас в теме
Вопрос граждане по отказоустойчивости при чтении из Excel. Тут есть сервер 1С (вроде 64 битный без установленного на нем офисного пакета. Соответственно на нем нет зарегистрированного объекта COMОбъект "Excel.Application". Как раз смотрели недавнюю статью Настройка DCOM компоненты "Excel.Application" на 64-битном сервере приложений 1С
Суть вопроса в чем. Мне прислали такое техническое мнение корпорации Майкрософт:
Корпорация Microsoft на сегодняшний день не рекомендует производить и не поддерживает автоматизацию программ из пакета Microsoft Office с помощью автоматических, неинтерактивных клиентских приложений или компонентов (включая ASP, DCOM и службы NT), поскольку при запуске в этом окружении программы пакета Office могут работать нестабильно или зависать.

Насчет при запуске в этом окружении программы пакета Office могут работать нестабильно или зависать частично согласен. Методы закрытия работают плохо и висят на сервере о чем писали.
Что народ скажед по поводу данного мнения? Не хотелось бы вступать в админские споры. Если загрузка хотя бы периодическая под контролем оператора? Насколько это критично. В чем получается преимущество ADO? В том что не надо пакет офисный ставить (я про уклон в лицензионную политику)? Или еще есть преимущества (про скорость и прочие радости излишне).
61. jobkostya1c8 28.01.15 14:17 Сейчас в теме
Насчет "универсального ADO" как-то начал обработку чтения xls в тонком клиенте для БП 3.0 с анализом ошибок. Предполагалось сделать универсальной с ведением протокола ошибок на сервере с передачей на клиент.
Сразу предупреждаю, данную обработку запускать осторожно чтоб не повредить данные. Тут выкладываю только с целью сравнения и отладки технологии по чтению из екселя с помощью ADO.
По крайней мере лист начинает читать без всяких настроек ADO и локального Екслея (на компе только Libre office).
Код чтения (главное, метод ADODBConnection.Open(); срабатывает:
// Инициализация основного объекта ADODB.Connection. Открытие соединения.
		ADODBConnection = Новый COMОбъект("ADODB.Connection");		
		ADODBConnection.ConnectionString =  СonnectionString;
		
		ADODBConnection.Provider = "Microsoft.Jet.OLEDB.4.0"; //????? ставился САМ MSSQL -		
		ADODBConnection.Open();
		// Импирически определенный параметр для правильного определения количества строк листа.
		ADODBConnection.CursorLocation = 3;    // По-умолчанию 2.
		
	ТекстЗапроса = "SELECT * FROM [" + ИмяЛиста + "$]";
	
	// Создание Recordset. Дочерний объект ADODBConnection. Набор записей по запросу.
	
		ADODBRecordset = Новый COMОбъект("ADODB.Recordset");
		ADODBRecordset.Open(ТекстЗапроса, ADODBConnection);
		
		// Проверка заполненности листа.
		Если (ADODBRecordset.EOF ИЛИ ADODBRecordset.BOF) Тогда
			КолвоСтрокExcel = 0;
			ДобавитьВЛогНаСервере("Лист екселя " + ИмяЛиста + ": не содержит данных (вообще)!");
			
			// Завершение работы.
			// Закрытие Объектов.
			ADODBRecordset.Close();
			ADODBConnection.Close();
			ADODBRecordset   = Неопределено;
			ADODBConnection = Неопределено;
			
			Возврат;
		КонецЕсли;
		
		// Импирически определенные параметры для правильного определения количества строк листа.
		ADODBRecordset.AbsolutePage     = 1;
		ADODBRecordset.AbsolutePosition = 1;
		
	// Параметр, возвращаемый в вызывающую процедуру.
	КолвоСтрокExcel = ADODBRecordset.RecordCount + 1;    // (+1) - учет Строки-Заголовока, которая "съедается".
	КолвоКолонокExcel = ADODBRecordset.Fields.Count;
	
	// Проверка заполненности листа.
	Если КолвоСтрокExcel <= 2 Тогда
		КолвоСтрокExcel = 0;
		 ДобавитьВЛогНаСервере("Лист екселя " + ИмяЛиста + ": не содержит данных (строк)!");
		
		// Завершение работы.
		// Закрытие Объектов.
		ADODBRecordset.Close();
		ADODBConnection.Close();
		ADODBRecordset   = Неопределено;
		ADODBConnection = Неопределено;
		
		Возврат;
	КонецЕсли;
Показать

обработка прилагается
Прикрепленные файлы:
ЗагрузкаВБухгалтерию3.epf
62. Petrony 20.08.15 16:53 Сейчас в теме
Также не распознаются ячейки с Дата+Время.
Поскольку Дата+Время - это не целое число, которое больше 1, то оно не распознается ни процедурой ЭтоДатаXLSX() ни процедурой ЭтоВремяXLSX
В принципе, можно из функции ЭтоДатаXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля) убрать проверку на то, что значение ячейки - целое число. Или отдельно создать функцию.
63. XelOla 15 18.10.15 00:39 Сейчас в теме
(46) 7OH, будет ли это работать в обычном приложении?
Что еще можно использовать для работы с Эксель без установленного Офиса?
64. StepByStep 3256 15.11.15 19:31 Сейчас в теме
(60) kostyaomsk, (61) kostyaomsk,
См. Загрузка из EXCEL в 1С. MS ADODB.Connection : http://infostart.ru/public/163640/
65. StepByStep 3256 15.11.15 19:32 Сейчас в теме
66. StepByStep 3256 15.11.15 19:36 Сейчас в теме
(63) XelOla,
будет ли это работать в обычном приложении?
Что еще можно использовать для работы с Эксель без установленного Офиса?

Да, будет.
См. также
Методы загрузки из внешнего источника:
- Метод "MS ADO" (Чтение файлов xls, xlsx средствами Microsoft ADO): http://infostart.ru/public/163640/
- Метод "NativeXLSX" (Чтение файлов xlsx с картинками средствами 1С. ПостроительDOM): http://infostart.ru/public/300092/
- Метод "Excel1C" (Загрузка на платформе 8.3.6 с картинками. Чтение файлов xls, xlsx, ods): http://infostart.ru/public/341855/

При установленном бесплатном LibreOffice:
- Метод "LO CALC" (Чтение файлов xls, xlsx, ods, sxc с картинками средствами LibreOffice): http://infostart.ru/public/163642/
67. [4EPHbIYY_KOT] 37 09.02.16 10:31 Сейчас в теме
(56) MishaHD, ещё бы автор это подправил - вообще был бы зачёт. А то без разбора кода пооткрывали файлики, плывёт всё жестко. Даже с соседних листов данные берёт :)
68. InShallaH 50 27.02.17 18:00 Сейчас в теме
(56)
Ты просто сделал мой день :)
69. vladismi 161 12.10.17 16:41 Сейчас в теме
70. It-developer 20 13.04.18 17:09 Сейчас в теме
71. It-developer 20 18.04.18 17:52 Сейчас в теме
Все хорошо, но у меня был косяк, когда ничего не было в заголовке - происходило смещение колонок. Помогло исправить изменение функции ПолучитьМассивИменКолонокНаЛистеXLSX_Новый. Не все в ней нужно, но суть, думаю, понятна

Функция ПолучитьМассивИменКолонокНаЛистеXLSX_Новый(SheetX)
    Перем ДиапазонДанных, ДиапазонКолонок, ПерваяКолонка, ПоследняяКолонка, НомерПервойК, НомерПоследнейК;
    Перем Подсчет, ИмяКолонки;
    Перем МассивИменКолонокXLSX, КолвоКолонокEXCEL;
    
    МассивИменКолонокXLSX = Новый Массив;
    
    Подсчет = Ложь;
    // Считать очередной узел XML.
    Пока SheetX.Прочитать() Цикл
        // DIMENSION.
        Если ВРег(SheetX.Имя) = "DIMENSION" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ДиапазонДанных     = SheetX.ПолучитьАтрибут("ref");
            ДиапазонКолонок = ЗаменитьОдниСимволыДругими("0123456789", ДиапазонДанных, "");
            ПерваяКолонка     = Лев(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") - 1);
            ПоследняяКолонка= Сред(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") + 1);
            НомерПервойК    = НомерКолонкиДесятичный(ПерваяКолонка);
            НомерПоследнейК    = НомерКолонкиДесятичный(ПоследняяКолонка);
        КонецЕсли;
    КонецЦикла;
	
	к = НомерПервойК;
	Пока к <= НомерПоследнейК Цикл
		МассивИменКолонокXLSX.Добавить(ИмяКолонкиПоНомеру(к));
		к = к + 1;
	КонецЦикла;	
    
    КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
    Если НЕ НомерПоследнейК = Неопределено Тогда
        Если КолвоКолонокEXCEL < НомерПоследнейК Тогда
            Сообщить("Строка заголовков колонок (1-я строка) заполнена не полностью:
            |К-во колонок строки меньше объявленной: " + КолвоКолонокEXCEL + "<" + НомерПоследнейК);
            ДополнитьМассивИменКолонокXLSX(НомерПоследнейК, МассивИменКолонокXLSX);
        ИначеЕсли КолвоКолонокEXCEL > НомерПоследнейК Тогда
            Сообщить("Строка заголовков колонок (1-я строка) содержит больше колонок, чем объявлено:
            |К-во колонок строки больше объявленной:" + КолвоКолонокEXCEL + ">" + НомерПоследнейК);
        КонецЕсли;
    КонецЕсли;
        
    Возврат МассивИменКолонокXLSX;
    
КонецФункции

Функция ИмяКолонкиПоНомеру(НомерКолонки)
	
	Латиница = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";    // 26.
	
	Если НомерКолонки <= 26 Тогда
		Возврат Сред(Латиница, НомерКолонки, 1)
	Иначе
		Возврат Сред(Латиница, Цел((НомерКолонки-1)/26), 1) + Сред(Латиница, НомерКолонки - 26*Цел((НомерКолонки-1)/26), 1)
	КонецЕсли;	
	
КонецФункции
Показать
72. AlexeyPapanov 12.09.18 23:36 Сейчас в теме
Коллеги, я одного не догоню.

Колонки смешиваются по непонятному принципу. Т.е. они не идут в ТЗ в таком порядке как они были в эксель-файле.
Я хочу дать юзеру возможность видеть на форме всю ТЗ результата.

Мне надо взять нужные колонки из ТЗ результата загрузки.
А как я ее выведу, если колонки в неведомом мне порядке идут.
Прикрепленные файлы:
73. fanlexa 2 28.09.18 10:24 Сейчас в теме
Всем доброго дня. С выше указанными доработками, все отлично работает, за что всем огромное спасибо! Но у меня вот какая проблема, при выгрузке из клиент банка(сбербанк) в формате excel, файлы выгруженные на разных компах имеют почему-то разную структуру xml файлов, т.е. на одних компах файлы выгружается с "правильной " структурой и в заголовке файла sheet1.xml: "<?xml version="1.0" encoding="UTF-8" standalone="true"?>

-<worksheet xmlns:x14ac="http://schemas.microsoft.com/office/spreadsheetml/2009/9/ac" mc:Ignorable="x14ac" xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006" xmlns:r="http://schemas.openxmlformats.org/officeDocument/2006/relationships" xmlns="http://schemas.openxmlformats.org/spreadsheetml/2006/main">",

а в НЕ правильных файлах: "<?xml version="1.0" encoding="UTF-8"?>

-<worksheet xmlns:r="http://schemas.openxmlformats.org/officeDocument/2006/relationships" xmlns="http://schemas.openxmlformats.org/spreadsheetml/2006/main">", кроме того у них разная структура папок внутри. Но если "не правильный файл" открыть в excel, и просто нажать сохранить, то его структура становится правильной и читается нормально... не понимаю как победить пока, может кто уже сталкивался?
74. fanlexa 2 28.09.18 14:04 Сейчас в теме
Пока ждал проверку модератерами сам починил, может кому пригодится:

1.
Функция ПолучитьМассивИменКолонокНаЛистеXLSX(SheetX)
	//Возврат МассивИменКолонокXLSX;
	Перем ДиапазонДанных, ДиапазонКолонок, ПерваяКолонка, ПоследняяКолонка, НомерПервойК, НомерПоследнейК;
	Перем Подсчет, ИмяКолонки;
	Перем МассивИменКолонокXLSX, КолвоКолонокEXCEL;
	
	МассивИменКолонокXLSX = Новый Массив;
	
	Подсчет = Ложь;
	// Считать очередной узел XML.
	Пока SheetX.Прочитать() Цикл
		// DIMENSION.
		Если ВРег(SheetX.Имя) = "DIMENSION" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
			ДиапазонДанных     = SheetX.ПолучитьАтрибут("ref");
			//{[+](фрагмент добавлен), 
			Если СтрДлина(ДиапазонДанных) = 2 Тогда
				ДиапазонДанных = ДиапазонДанных + ":ZZ";
			КонецЕсли; 
			//} 
			ДиапазонКолонок = ЗаменитьОдниСимволыДругими("0123456789", ДиапазонДанных, "");
			ПерваяКолонка     = Лев(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") - 1);
			ПоследняяКолонка= Сред(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") + 1); 			
			НомерПервойК    = НомерКолонкиДесятичный(ПерваяКолонка);
			НомерПоследнейК    = НомерКолонкиДесятичный(ПоследняяКолонка);
		КонецЕсли;
	КонецЦикла;
	
	к = НомерПервойК;
	Пока к <= НомерПоследнейК Цикл
		МассивИменКолонокXLSX.Добавить(ИмяКолонкиПоНомеру(к));
		к = к + 1;
	КонецЦикла;    
	
	КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
	Если НЕ НомерПоследнейК = Неопределено Тогда
		Если КолвоКолонокEXCEL < НомерПоследнейК Тогда
			Сообщить("Строка заголовков колонок (1-я строка) заполнена не полностью:
			|К-во колонок строки меньше объявленной: " + КолвоКолонокEXCEL + "<" + НомерПоследнейК);
			ДополнитьМассивИменКолонокXLSX(НомерПоследнейК, МассивИменКолонокXLSX);
		ИначеЕсли КолвоКолонокEXCEL > НомерПоследнейК Тогда
			Сообщить("Строка заголовков колонок (1-я строка) содержит больше колонок, чем объявлено:
			|К-во колонок строки больше объявленной:" + КолвоКолонокEXCEL + ">" + НомерПоследнейК);
		КонецЕсли;
	КонецЕсли;
	
	Возврат МассивИменКолонокXLSX;
	
КонецФункции
Показать


2.

Функция ЗагрузитьМетодом_NativeXLSX(Знач ФайлEXCEL, Знач ИмяНомерЛиста, Знач СтрокаЗаголовка = 1, Знач НачСтрока = 0, Знач КонСтрока = 0, КолвоСтрокExcel = 0)
	Перем ZIPКаталог, ФайлИмяЛиста, ФайлНомерЛиста, КолвоКолонокEXCEL, НомерСтроки, НомерКолонки, ИмяКолонки, ИндексКолонки, ШиринаКолонки, ДлинаСтроки;
	Перем МассивИменКолонокXLSX, МассивSharedStrings, МассивNumFmtId, СоответствиеNumFmtIdFormatCode;
	Перем SheetX,ЗначениеЯчейки, ТипЗначения, ФорматЯчейки, ФорматСтиля;
	Перем ТаблицаРезультат, НоваяСтрока;
	
	ФайлНомерЛиста  = ИмяНомерЛиста.НомерЛиста;
	ФайлНомерЛиста = ?(ФайлНомерЛиста = 0, 1, ФайлНомерЛиста);
	
	ZIPКаталог = КаталогВременныхФайлов() + "XLSX\";
	Если НЕ ПредварительнаяОбработкаФайлаXLSX(ФайлEXCEL, ZIPКаталог) Тогда
		Возврат Новый ТаблицаЗначений;
	КонецЕсли;
	
	СоответствиеNumFmtIdFormatCode = Новый Соответствие;
	МассивNumFmtId = ИзвлечьДанныеИзФайла_StylesXML(ZIPКаталог, СоответствиеNumFmtIdFormatCode);
	
	МассивSharedStrings = ИзвлечьДанныеИзФайла_SharedStringsXML(ZIPКаталог);
	
	SheetX = Новый ЧтениеXML;
	SheetX.ОткрытьФайл(ZIPКаталог + "XL\WorkSheets\Sheet" + ФайлНомерЛиста + ".xml");
	
	МассивИменКолонокXLSX = ПолучитьМассивИменКолонокНаЛистеXLSX(SheetX);
	КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
	
	// Создание результирующей таблицы, в которую будут записываться считанные из EXCEL данные.
	ТаблицаРезультат = Новый ТаблицаЗначений;
	// Формирование колонок результирующей таблицы.
	// "НомерСтроки" - для наглядности и удобства.
	// В зависимости от разрабатываемой обработки.
	// "Сопоставлено" - может быть другим.
	// Здесь же могут быть добавлены другие колонки, не формируемые из содержимого файла EXCEL.
	ТаблицаРезультат.Колонки.Добавить("НомерСтроки", Новый ОписаниеТипов("Число"), "№", 4);
	ТаблицаРезультат.Колонки.Добавить("Сопоставлено", Новый ОписаниеТипов("Булево"), "Сопоставлено", 1);
	ТаблицаРезультат.Колонки.Добавить("УровеньГруппировки", Новый ОписаниеТипов("Число"), "Гр", 2); // Группировка строк в файле EXCEL.
	Для ит = 1 ПО КолвоКолонокExcel Цикл
		ИмяКолонки = "N" + ит;
		Колонка = ТаблицаРезультат.Колонки.Добавить(ИмяКолонки);
	КонецЦикла;
	
	SheetX = Новый ЧтениеXML;
	SheetX.ОткрытьФайл(ZIPКаталог + "XL\WorkSheets\Sheet" + ФайлНомерЛиста + ".xml");
	
	ЭтоНачалоДанных = Ложь;
	// Считать очередной узел XML.
	Пока SheetX.Прочитать() Цикл
		Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
			ЭтоНачалоДанных = Истина;
			Прервать;
		КонецЕсли;
	КонецЦикла;
	Если НЕ ЭтоНачалоДанных Тогда
		Возврат Новый ТаблицаЗначений;
	КонецЕсли;
	
	// Считать очередной узел XML.
	НомерСтроки = 0;
	Пока SheetX.Прочитать() Цикл
		Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
			Прервать;   // Окончание данных.
		КонецЕсли;
		Если ВРег(SheetX.Имя) = "ROW" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
			НомерСтроки = НомерСтроки + 1;
			Если НЕ НачСтрока = 0 И НЕ НомерСтроки = 1 И НомерСтроки < НачСтрока Тогда
				Продолжить;
			КонецЕсли;
			НоваяСтрока = ТаблицаРезультат.Добавить();
			НоваяСтрока.НомерСтроки = НомерСтроки;
			НоваяСтрока.УровеньГруппировки = SheetX.ЗначениеАтрибута("outlineLevel");
			Пока SheetX.Прочитать() Цикл    // Считаем колонки строки EXCEL.
				Если ВРег(SheetX.Имя) = "ROW" Тогда
					Прервать;
				КонецЕсли;
				Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
					Прервать;   // Окончание данных.
				КонецЕсли;
				Если ВРег(SheetX.Имя) = "C" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
					ТипЗначения = SheetX.ЗначениеАтрибута("t");
					ФорматЯчейки = SheetX.ЗначениеАтрибута("s");
					ИмяКолонки = SheetX.ЗначениеАтрибута("r");
					ИмяКолонкиБезЦифр = ЗаменитьОдниСимволыДругими("0123456789", ИмяКолонки, "");
					ИндексКолонки = МассивИменКолонокXLSX.Найти(ИмяКолонкиБезЦифр)+1;
					SheetX.Прочитать();
					Если ВРег(SheetX.Имя) = "V"  ИЛИ ВРег(SheetX.Имя) = "F" ИЛИ ВРег(SheetX.Имя) = "IS" Тогда   // "V" - Значение, "F" - Формула.  "IS" - добавлено для формата файла из сбербанка
						Если ВРег(SheetX.Имя) = "F" Тогда
							Пока НЕ ВРег(SheetX.Имя) = "V" Цикл
								SheetX.Прочитать();
							КонецЦикла;
						КонецЕсли;
						//{[+](фрагмент добавлен)
						Если ВРег(SheetX.Имя) = "IS" Тогда 						
							Пока НЕ ВРег(SheetX.Имя) = "T" Цикл
								SheetX.Прочитать();
							КонецЦикла;
						КонецЕсли;
						//} 
						SheetX.Прочитать();
						Если ВРег(SheetX.Имя) = "#TEXT" Тогда
							ЗначениеЯчейки = SheetX.Значение;
							ФорматСтиля = "";
							Если (НЕ ФорматЯчейки = "" И НЕ ФорматЯчейки = Неопределено) Тогда
								Попытка
									ИндексФормата = Число(ФорматЯчейки);
									ФорматСтиля = СоответствиеNumFmtIdFormatCode.Получить(МассивNumFmtId[ИндексФормата]);
								Исключение
									ФорматСтиля = "";
								КонецПопытки;
							КонецЕсли;
							Если ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
								Если ТипЗначения = Неопределено ИЛИ ВРег(ТипЗначения) = "N" ИЛИ ВРег(ТипЗначения) = "B" Тогда
									Попытка
										Значение1 = Число(ЗначениеЯчейки);
									Исключение
										Значение1 = ЗначениеЯчейки;
									КонецПопытки;
									ЗначениеЯчейки = Значение1;
									Если (ФорматСтиля = "" ИЛИ ФорматСтиля = Неопределено) Тогда
										// ФорматСтиля = Неопределено - Атрибут "s" отсутствует.
										// MS Office (2010) может не формировать в xml-файле описание стиля форматирования для ячейки.
										// LibreOffice (4.1.5) формирует в xml-файле необходимые описания стиля форматирования ячейки.
										// Сообщить("Не определен стиль форматирования для кода " + ФорматЯчейки + " значения " + ЗначениеЯчейки);
									КонецЕсли;
									
									Если ТипЗнч(ЗначениеЯчейки) = Тип("Строка")
										И (Найти(ЗначениеЯчейки, "E-") > 0 ИЛИ Найти(ЗначениеЯчейки, "E+") > 0) Тогда
										ЗначениеЯчейки = ПолучитьЧислоВСтепениИзСтроковогоЗначения(ЗначениеЯчейки);
									КонецЕсли;
									
									Если ТипЗнч(ЗначениеЯчейки) = Тип("Число") Тогда
										// ПРОЦЕНТ.
										Если ЭтоПроцентXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
											ЗначениеЯчейки = Окр(ЗначениеЯчейки * 100, 3);
											// БУЛЕВО.
										ИначеЕсли ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
											ЗначениеЯчейки = Булево(ЗначениеЯчейки);
											// ВРЕМЯ.
										ИначеЕсли ЭтоВремяXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
											ЗначениеЯчейки = КонвертироватьЧислоXLSXвДатуВремя(ЗначениеЯчейки);
											// ДАТА.
										ИначеЕсли ЭтоДатаXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
											ЗначениеЯчейки = КонвертироватьЧислоXLSXвДату(ЗначениеЯчейки);
											// ЧИСЛО.
										ИначеЕсли ТипЗначения = Неопределено
											ИЛИ ( ЭтоЧислоXLSX(ЗначениеЯчейки, ФорматСтиля) 
											И НЕ ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля)
											И НЕ ЭтоВремяXLSX(ЗначениеЯчейки, ФорматСтиля)
											И НЕ ЭтоДатаXLSX(ЗначениеЯчейки, ФорматСтиля) )
											Тогда
											// Без преобразования.
										Иначе
											// Прочие форматы.
										КонецЕсли;
										
									Иначе
										
										Сообщить("Не удалось преобразовать значение к ""числовому""(процент, время, дата, число) типу.");
										
									КонецЕсли;
									
								ИначеЕсли ВРег(ТипЗначения) = "S" Тогда
									
									// МассивSharedStrings может быть пустым.
									Попытка
										ЗначениеЯчейки = СокрЛП(МассивSharedStrings[Число(SheetX.Значение)]);
									Исключение
										ЗначениеЯчейки = "";
									КонецПопытки;
									
								ИначеЕсли ВРег(ТипЗначения) = "STR" ИЛИ ВРег(ТипЗначения) = "INLINESTR" Тогда //{[+](фрагмент добавлен) 
									
									Если ТипЗнч(ЗначениеЯчейки) = Тип("Строка") Тогда
										ЗначениеЯчейки = СокрЛП(ЗначениеЯчейки);
									КонецЕсли;
									
								КонецЕсли;
							КонецЕсли;
							
							ИмяКолонки = "N"+ИндексКолонки;
							НоваяСтрока[ИмяКолонки] = ЗначениеЯчейки;
							// Используется при формировании таблицы на форме обработки.
							ШиринаКолонки = ТаблицаРезультат.Колонки[ИмяКолонки].Ширина;
							ДлинаСтроки = СтрДлина(СокрЛП(ЗначениеЯчейки));
							ТаблицаРезультат.Колонки[ИмяКолонки].Ширина = ?(ШиринаКолонки < ДлинаСтроки, ДлинаСтроки, ШиринаКолонки);							
						КонецЕсли;								
					КонецЕсли;
				КонецЕсли;
			КонецЦикла;
			Если ((НЕ КонСтрока = 0 И (НомерСтроки + 1) > КонСтрока)
				ИЛИ (НЕ КолвоСтрокExcel = 0  И (НомерСтроки + 1) > КолвоСтрокExcel)) Тогда
				Прервать;   // Окончание диапазона считываемых данных.
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;
	
	// Завершение работы.
	// Закрытие Объектов.
	SheetX.Закрыть();
	
	УдалитьКолонкиСНулевойШириной(ТаблицаРезультат);
	
	Возврат ТаблицаРезультат;
	
КонецФункции
Показать



Фишка в том, что сбербанк когда выгружает свои данные в excel, сами данные выгружает не в отдельный файл xl\sharedStrings.xml - как положено, а напрямую в файл xl\worksheets\sheet1.xml, хотя там должны хранится только индексы на данные в файле xl\sharedStrings.xml ))))))))
75. user1114234 26.04.19 09:51 Сейчас в теме
Почему может писать, чтo:
Файл не существует/не доступен:
D:\Товар.xlsx
Хотя файл там. Пробовал разные директории, даже файл пустым делал. Всё равно не хочет видеть
76. Petrony 26.04.19 13:30 Сейчас в теме
(75) Если у вас клиент-сервер, то возможно, загрузка у вас происходит на сервере и тогда файл должен быть там, а не на локальном компьютере. И наоборот. Если нужно выбрать файл на локальном компьютере, а прочитать на сервере, помещайте во временное хранилище.
Оставьте свое сообщение

См. также

Агрегатные функции СКД, о которых мало кто знает 316

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    9935    ids79    42       

Отслеживание выполнения фонового задания 133

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    8200    ids79    14       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 241

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    10320    ids79    24       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 134

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования Разработка

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    8661    ids79    24       

"Меньше копипаста!", или как Вася универсальную процедуру писал 170

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    6196    SeiOkami    48       

Создание отчетов с помощью СКД - основные понятия и элементы 192

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    17361    ids79    16       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 176

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    11498    dmurk    134       

Регистры накопления. Структура хранения в базе данных 174

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    17194    YPermitin    27       

Выполнение внешней обработки в фоновом задании 147

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    9806    Eret1k    22       

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    4792    m-rv    2       

Преобразование EXCEL в таблицу значений без COM и других извращений 208

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Загрузка и выгрузка в Excel

Получение таблицы значений из excel в 1С v8, без COM, внешних источников данных и т.д. EXCELВТаблицуЗначений() - За 10 строчек кода! Реализация протестирована на 1С 8.3.12.1714 (x64).

18.04.2019    12054    9    Eret1k    43       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    7323    m-rv    16       

О расширениях замолвите слово... 191

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    16315    ellavs    122       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 200

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    12677    ellavs    83       

RabbitMQ + Конвертация Данных 3.0 178

Статья Системный администратор Программист Бизнес-аналитик Руководитель проекта Нет файла v8 КД Бесплатно (free) Внешние источники данных Обмен через XML Интеграция Перенос данных из 1C8 в 1C8

Предлагаем ознакомиться с хронологией проекта, проследить ход мыслей от снятия потребностей до реализации, и решить, удалось ли проектной команде найти оптимальное архитектурное решение под конкретный кейс заказчика путем совмещения двух известных, но до сих пор не пересекавшихся технологий, и получилось ли сложить плюсы и устранить минусы каждой из них.

21.03.2019    13748    barelpro    82       

Трюки с внешними источниками данных 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    12793    YPermitin    52       

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 162

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    15417    ids79    9       

Копирование числовых ячеек из 1С в Excel 26

Статья Системный администратор Программист Нет файла v8 1cv8.cf Windows Бесплатно (free) Загрузка и выгрузка в Excel Администрирование данных 1С

Решение проблемы, когда значения скопированных ячеек из табличных документов 1С в Excel воспринимаются последним как текст, т.е. без дополнительного форматирования значений невозможно применить арифметические операции. Поводом для публикации послужило понимание того, что целое предприятие с более сотней активных пользователей уже на протяжении года мучилось с такой, казалось бы на первый взгляд, тривиальной проблемой. Варианты решения, предложенные специалистами helpdesk, обслуживающими данное предприятие, а так же многочисленные обсуждения на форумах, только подтвердили убеждение в необходимости описания способа, который позволил мне качественно и быстро справиться с ситуацией.

15.01.2019    10412    itriot11    21       

Запись одной книги Excel на нескольких листах средствами 1С (без внешних компонент) 139

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Загрузка и выгрузка в Excel

Пользователи часто просят сохранить им стопиццот отчетов в один файл Excel, чтобы отчеты были в одном файле. Ну или клиент хочет счет, накладную и счет-фактуру получить в одном документе. 1С умеет это делать без всяких там COM-объектов. Давайте разберемся, куда нажимать и что крутить.

14.01.2019    11670    starik-2005    23       

EnterpriseData – часть 2. Процесс выгрузки данных 127

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    12687    ids79    27       

Новый подход к обмену данными EnterpriseData 203

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    21361    ids79    72       

Программное заполнение пользовательских параметров и отборов СКД 135

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Публикация представляет из себя краткие примеры того, как можно заполнять параметры СКД программно так, чтобы все параметры и отборы были доступны в быстрых настройках и в обычных (типовых) настройках параметров и отборов СКД.

13.11.2018    19559    Unk92    18       

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С 126

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    20795    ids79    40       

Вспомогательные инструкции в коде 1С 104

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    20413    tormozit    100       

Произвольный код в фоновом режиме 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Задача: реализовать выполнение произвольного кода в фоновом режиме без изменения конфигурации, т.е. во внешней обработке.

03.09.2018    14555    nikita0832    41       

Основные понятия и механизмы оптимизации клиент-серверного взаимодействия в 1C 144

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы Практика программирования

У многих начинающих 1С программистов часто возникают вопросы про клиент-серверное взаимодействие в 1С и чтобы разобраться в непростых механизмах платформы, необходимо понять, что же такое контекст, для чего предназначены директивы компиляции, что представляют собой контекстные/внеконтекстные вызовы и как наиболее оптимально описывать прикладные задачи в модулях управляемых форм.

23.08.2018    21204    Rain88    42       

Из Excel в 1С запросом 33

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Загрузка и выгрузка в Excel

... ну, конечно, не прям так типовым языком запросов, а расширенным языком запросов. Речь пойдет о том, как "залить" данные в таблицы 1С и не пилить при этом бесконечного количества наколеночных обработок.

14.08.2018    13513    m-rv    5       

Повышаем эффективность разработки правил обмена 123

Статья Программист Нет файла v8 КД ОС Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    19282    olegtymko    47       

Введение в механизм представлений в ЗУП ред. 3 153

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Бесплатно (free) Практика программирования

В нашей организации на первом же телефонном собеседовании на должность разработчика по ЗУП ред. 3 вас обязательно спросят о том, что такое "Представления".

04.06.2018    24309    xrrg    82       

Как сделать запрос на изменение данных 75

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    21151    m-rv    21       

Строим графы средствами 1С (без GraphViz) 42

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Множество статей на Инфостарте описывают, как работать с компонентой GraphViz, чтобы построить ориентированный граф. Но практически нет материалов, как работать с такими графами средствами 1С. Сегодня я расскажу, как красиво строить графы с минимальным пересечением. Нам этот метод пригодился для отрисовки алгоритмов в БИТ.Финансе, т.к. типовой механизм не устраивал. Еще это может быть полезно для визуализации различных зависимостей: расчета себестоимости, графы аффилированности компаний и т.д. Надеюсь, эта статья поможет сделать мир 1С красивее и гармоничней:) Итак, поехали...

23.05.2018    16940    slozhenikin_com    19       

Распределение расходов пропорционально продажам 9

Статья Программист Пользователь Нет файла v8 v8::ОУ УТ10 УУ Финансовый учет и бюджетирование (FRP) Учет доходов и расходов Бесплатно (free) Практика программирования

Финансовая модель. Распределение административных расходов по подразделениям пропорционально продажам за месяц. Дополнительные реквизиты против бизнес-процессов!

13.05.2018    11312    Rustig    9       

Минимализмы 3 351

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    35526    ildarovich    44       

Шаблон для загрузки из Excel 6

Инструменты и обработки Системный администратор Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Загрузка и выгрузка в Excel

Шаблон для загрузки любых данных из Excel. На выходе вы получаете таблицу как в Excel (столбцы A,B,C...) и делаете с ней что хотите. Подходит для любых УФ.

2 стартмани

07.02.2018    6348    22    Коленкин Илья    5       

Этюды по программированию. Взаимодействие с Microsoft Word 109

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Часто приходится заниматься созданием сложных документов Word с таблицами, вложенными фрагментами, хитрым оформлением и прочими радостями жизни. Это - попытка как-то структурировать полученный опыт, чтобы не приходилось перерывать ворох старых обработок в поисках крупиц истины. Надеюсь, эта статья будет полезна и Вам.

11.12.2017    25811    milkers    23       

Метод формирования движений в типовых регистрах нетиповыми регистраторами 31

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    21286    itriot11    34       

1С: Конвертация данных 3. Инструкции и примеры. EnterpriseData (универсальный формат обмена) 720

Статья Программист Нет файла v8 КД Бесплатно (free) Перенос данных из 1C8 в 1C8 Практика программирования Обмен через XML

Что такое КД3? Как начать использовать? Полезные дополнения к документации. Что нужно исправить в типовых обработках и конфигурации. Как изменить правила обмена не снимая конфигурацию с поддержки. Как отлаживать правила обмена?

19.11.2017    137409    MaxS    251       

Заполнение данных по ИНН контрагента с помощью альтернативного сервиса огрн.онлайн 131

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Код для заполнения данных по ИНН контрагента из ЕГРЮЛ с сайта огрн.онлайн.

01.11.2017    22659    slava_1c    49       

Программные перечисления, ч.2: приемы кэширования при разработке 66

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    21030    unichkin    17       

Разбираемся с настройками компоновки данных 159

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Краткая шпаргалка по программной работе с настройками СКД

29.10.2017    24005    json    9       

Работа с Excel 288

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Загрузка и выгрузка в Excel

Собрал различные полезности для работы с Excel из 1С. Иногда приходится форматировать документ Excel программно из 1С. Так вот, чтобы не искать постоянно на просторах интернета как сделать левое выравнивание в ячейке Excel из 1С и т.п. решил опубликовать это...

23.10.2017    24621    arakelyan    39       

Добавление команд печати в конфигурациях на БСП 2.4.3 (в частности, в самописных документах в Бухгалтерии 3.0 после релиза 3.0.52.35) 143

Статья Программист Нет файла v8 v8::БУ БП3.0 Россия Бесплатно (free) Печатные формы документов Практика программирования БСП (Библиотека стандартных подсистем)

В статье https://infostart.ru/public/237013/ пользователя nick max рассматривался список действий для подключения команд печати в Бухгалтерии 3.0, работающей на БСП 2.3.6. В новом релизе Бухгалтерии 3.0.52.35 от 15.09.2017г. стала использоваться БСП 2.4.3, из-за чего произошли изменения в процедурах общих модулей, связанных с механизмом печати, и в процедурах их вызова в формах документов и в формах списков. Рассмотрим их.

18.09.2017    46707    bugtester    43       

Отказ от работы с временными файлами при работе с двоичными данными или Потоки как простая замена ADODB.Stream и временным файлам 127

Статья Программист Нет файла v8 Россия Бесплатно (free) Практика программирования

В платформе начиная с версии 3.8.9 (как я понял по документации) появился расширенный функционал средств работы с двоичными данными. Если раньше простой и очевидный способ преобразования данных строился на использовании временных файлов, то теперь благодаря новым средствам можно уйти от их использования.

12.09.2017    18196    vardeg    31