Необходимость задавать исполняемый код в пользовательском режиме появляется не так уж и редко. Для этого создано множество инструментов - универсальные регламентные задания, консоли кода, динамические подписки на события и т.д. С помощью этих инструментов можно создавать код, содержащий запросы, и хорошо бы иметь возможность вызывать для этих запросов конструктор. Более того, во всем известных "Инструментах разработчика" уже есть решение этой задачи для обычных форм с применением библиотеки регулярных выражений (внешней библиотеки, подключаемой как COM-объект).
Мы же рассмотрим решение исключительно средствами 1С, которое вы сможете легко встраивать в свои формы, и которое будет подходить как для обычной, так и для управляемой формы (в толстом клиенте). Следующая иллюстрация показывает, чего мы хотим добиться от нашего алгоритма:
То есть нам необходимо получить возможность работать с запросами в коде аналогичную той, что дает Конфигуратор - открывать существующий запрос, изменять его, и затем возвращать измененный запрос в код на языке 1С с форматированием и сохранением позиции курсора. Эта задача сложна лишь потому, что у поля тестового документа 1С мало методов для работы с текстом и их придется "изобретать" самостоятельно.
Сначала опишем алгоритм на человеческом языке, а затем перейдем к реализации алгоритма на языке платформы.
Нам нужно:
1) Определить позицию курсора в поле текстового документа на форме.
2) Извлечь текст до курсора и после курсора.
3) В тексте, расположенном до курсора, найти открывающую запрос кавычку. В тексте расположенном после курсора найти первую несдвоенную кавычку от начала строки, это будет закрывающая кавычка.
4) Отделить текст запроса, расположенный между открывающей и закрывающей кавычками. А также выделить код, расположенный до начала запроса и после него.
5) Преобразовать код запроса таким образом, чтобы он нормально воспринимался конструктором запроса. Вместо двойных кавычек подставить одинарные, убрать символы вертикальной черты. После чего передать полученный текст в конструктор.
6) После закрытия конструктора сделать обратное преобразование полученного из него кода запроса. Добавить отступы и привести его к виду, который будет нормально воспринят интерпретатором языка 1С.
7) Соединить новый код запроса с текстом, который раньше располагался до и после текста запроса. Загрузить полученный код в поле формы и восстановить позицию курсора.
Теперь перейдем к поэтапной реализации этого алгоритма на языке 1С. Для демонстрации выберем обычную форму. Для управляемой формы код будет отличаться всего несколькими строками, и он также есть в прикрепленном к этой публикации файле. Пусть поле текстового документа на нашей форме имеет имя "Поле".
1) Упростим процесс кодирования введением дополнительных переменных и определим текущую позицию курсора. Позицию курсора запишем в переменные НачалоСтроки и НачалоКолонки. Значение переменной НачалоСтроки в ходе алгорима менять не будем. Оно понадобится в конце для восстановления позиции курсора:
//БЛОК №1 - ИНИЦИАЛИЗАЦИЯ ПЕРЕМЕННЫХ
ЭлементПоля = ЭлементыФормы.Поле;
Кавычка = """";
ДвойнаяКавычка = """""";
ЗаменаДляДвойнойКавычки = Строка(Новый УникальныйИдентификатор);
КоличествоСтрок = ЭлементПоля.КоличествоСтрок();
НачалоСтроки = 0;
НачалоКолонки = 0;
КонецСтроки = 0;
КонецКолонки = 0;
ЭлементПоля.ПолучитьГраницыВыделения(НачалоСтроки, НачалоКолонки, КонецСтроки, КонецКолонки);
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НачалоКолонки, Началостроки, НачалоКолонки);
2) Определим текст, расположенный до курсора и после него. Для этого поле текстового документа дает нам только одну возможность - устанавливать границы выделения и получать выделенный текст. Далее нам придется искать открывающую и закрывающую запрос кавычку. Сильной помехой в этом могут оказаться двойные кавычки. Чтобы избежать лишнего кода по обработке двойных кавычек используем следующий прием. Временно заменим все двойные кавычки на уникальную строку. Обратную замену будем проводить в конце алгоритма, при получении нового кода:
//БЛОК №2 - ОПРЕДЕЛЕНИЕ ТЕКСТА ДО КУРСОРА И ПОСЛЕ КУРСОРА
ЭлементПоля.УстановитьГраницыВыделения(1, 1, Началостроки, НачалоКолонки);
ТекстДоКурсора = ЭлементПоля.ВыделенныйТекст;
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НачалоКолонки, КоличествоСтрок+1, 1);
ТекстПослеКурсора = ЭлементПоля.ВыделенныйТекст;
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НачалоКолонки, Началостроки, НачалоКолонки);
//гарантируем отсутствие в тексте двойных кавычек
ТекстДоКурсора = СтрЗаменить(ТекстДоКурсора, ДвойнаяКавычка, ЗаменаДляДвойнойКавычки);
//в тексте после курсора необходимо оставить первую кавычку, если сразу после нее идет двойная
//случай подряд идущих кавычек в количестве более 5-ти штук обрабатывать не будем
ТекстПослеКурсора = СтрЗаменить(Лев(ТекстПослеКурсора, 1) +
СтрЗаменить(Сред(ТекстПослеКурсора, 2), ДвойнаяКавычка, ЗаменаДляДвойнойКавычки), ДвойнаяКавычка, ЗаменаДляДвойнойКавычки) ;
3) Двигаясь по строке кода, расположенного до курсора, находим открывающую запрос кавычку. Поскольку мы избавились от двойных кавычек, то найти ее несложно. Нужно просто найти кавычку, которая не была закрыта следующей за ней. Правда, нужно учитывать, что кавычки в комментариях надо пропустить, перемещаясь сразу к концу строки, а также то, что курсор сам мог находиться внутри двойной кавычки в строке запроса:
//БЛОК №3 - ИЩЕМ ПОЗИЦИЮ ОТКРВАЮЩЕЙ И ЗАКРЫВАЮЩЕЙ КАВЫЧКИ ДЛЯ СТРОКИ ЗАПРОСА
ПозицияОткрывающейКавычки = 0;
ПозицияЗакрывающейКавычки = 0;
ВСтроке = Ложь;
КавычкиЕсть = Ложь;
ПозицияПредыдущейКавычки = 0;
ПоизцияПоследнейКавычки = 0;
Позиция = 1;
ДлинаТекстаДоКурсора = СтрДлина(ТекстДоКурсора);
//ИЩЕМ ОТКРЫВАЮЩУЮ КАВЫЧКУ
Пока Позиция <= ДлинаТекстаДоКурсора Цикл
ТекущийСимвол = Сред(ТекстДоКурсора, Позиция, 1);
ПредыдущийСимвол = " ";
Если Позиция > 1 Тогда
ПредыдущийСимвол = Сред(ТекстДоКурсора, Позиция-1, 1);
КонецЕсли;
Если ТекущийСимвол = Кавычка Тогда
ВСтроке = НЕ ВСтроке;
ПозицияПредыдущейКавычки = ПоизцияПоследнейКавычки;
ПоизцияПоследнейКавычки = Позиция;
КавычкиЕсть = Истина;
КонецЕсли;
//Обработка комментария - начало
Если НЕ ВСтроке И ПредыдущийСимвол = "/" И ТекущийСимвол = "/" Тогда
//это комментарий, пропускаем символы до конца строки
Пока ТекущийСимвол <> Символы.LF И ТекущийСимвол <> Символы.CR Цикл
Позиция = Позиция +1;
Если Позиция > ДлинаТекстаДоКурсора Тогда
Прервать;
КонецЕсли;
ТекущийСимвол = Сред(ТекстДоКурсора, Позиция, 1);
КонецЦикла;
Продолжить;
КонецЕсли;
//Обработка комментария - конец
Позиция = Позиция + 1;
КонецЦикла;
//ОСОБЫМ ОБРАЗОМ ОБРАБОТАЕМ СЛУЧАЙ НАХОЖДЕНИЯ КУРСОРА В
//ДВОЙНОЙ КАВЫЧКЕ ВНУТРИ СТРОКИ ЗАПРОСА
Если НЕ ВСтроке И КавычкиЕсть И СтрДлина(ТекстПослеКурсора) > 0 Тогда
Если Сред(ТекстДоКурсора, ДлинаТекстаДоКурсора, 1) = Кавычка И Лев(ТекстПослеКурсора,1) = Кавычка Тогда
ВСтроке = Истина;
ПоизцияПоследнейКавычки = ПозицияПредыдущейКавычки;
ТекстДоКурсора = Лев(ТекстДоКурсора, ДлинаТекстаДоКурсора-1);
ТекстПослеКурсора = ЗаменаДляДвойнойКавычки + Сред(ТекстПослеКурсора, 2);
КонецЕсли;
КонецЕсли;
//ЕСЛИ НАШИЛИ ОТКРЫВАЮЩУЮ КАВЫЧКУ, ТО ИЩЕМ ЗАКРЫВАЮЩУЮ
Если ВСтроке Тогда
ПозицияОткрывающейКавычки = ПоизцияПоследнейКавычки;
ПозицияЗакрывающейКавычки = Найти(ТекстПослеКурсора, Кавычка);
КонецЕсли;
4) Теперь можно выделить код между кавычками (запрос) и код расположенный до и после запроса. Чтобы текст запроса был воспринят конструктором его необходимо преобразовать, убрав из начала каждой его строки вертикальную черту:
//БЛОК №4 - ОПРЕДЕЛЯЕМ ТЕКСТ ДО ЗАПРОСА, ТЕКСТ ЗАПРОСА И ТЕКСТ ПОСЛЕ ЗАПРОСА
//ПОСЛЕ ЧЕГО ВОЗРАЩАЕМ ДВОЙНЫЕ КАВЫЧКИ В КОД, НЕ ЯВЛЯЮЩИЙСЯ ЧАСТЬЮ ЗАПРОСА
Конструктор = Новый("КонструкторЗапроса");
ГраницыЗапросаНайдены = ПозицияОткрывающейКавычки <> 0 И ПозицияЗакрывающейКавычки <> 0;
Если НЕ ГраницыЗапросаНайдены Тогда
Сообщение = "ЗАПРОС НЕ ОБНАРУЖЕН, БУДЕТ СОЗДАН НОВЫЙ ЗАПРОС";
ПоказатьОповещениеПользователя(Сообщение, , Сообщение);
ТекстДоНачалаЗапроса = ТекстДоКурсора + Кавычка;
ТекстПослеКонцаЗапроса = Кавычка + ТекстПослеКурсора ;
Иначе
ТекстДоНачалаЗапроса = Лев(ТекстДоКурсора, ПозицияОткрывающейКавычки);
ТекстПослеКонцаЗапроса = Сред(ТекстПослеКурсора, ПозицияЗакрывающейКавычки);
ТекстЗапросаССимвовамиВертикальнойЧерты = Сред(ТекстДоКурсора, ПозицияОткрывающейКавычки + 1)
+ Лев(ТекстПослеКурсора, ПозицияЗакрывающейКавычки -1);
//для конструктора запроса вместо двойной кавычки будем подставлять одинарную
ТекстЗапросаССимвовамиВертикальнойЧерты =
СтрЗаменить(ТекстЗапросаССимвовамиВертикальнойЧерты, ЗаменаДляДвойнойКавычки, Кавычка);
КоличествоСтрокВТексте = СтрЧислоСтрок(ТекстЗапросаССимвовамиВертикальнойЧерты);
ТекстЗапроса = "";
Для К = 1 To КоличествоСтрокВТексте Цикл
СтрокаИзТекстаЗапроса = СокрЛП(СтрПолучитьСтроку(ТекстЗапросаССимвовамиВертикальнойЧерты, К));
Если Лев(СтрокаИзТекстаЗапроса, 1) = "|" Тогда
//для конструктора запроса убираем вертикальную черту в начале строки
СтрокаИзТекстаЗапроса = Сред(СтрокаИзТекстаЗапроса, 2);
КонецЕсли;
ТекстЗапроса = ТекстЗапроса + СтрокаИзТекстаЗапроса + Символы.LF;
КонецЦикла;
Конструктор.Текст = ТекстЗапроса;
КонецЕсли;
//возвращаем двойные кавычки
ТекстДоНачалаЗапроса = СтрЗаменить(ТекстДоНачалаЗапроса, ЗаменаДляДвойнойКавычки, ДвойнаяКавычка);
ТекстПослеКонцаЗапроса = СтрЗаменить(ТекстПослеКонцаЗапроса, ЗаменаДляДвойнойКавычки, ДвойнаяКавычка);
5) Передаем текст запроса в конструктор и, если конструктор отработал успешно, вычисляем отступ, который будем добавлять к строкам запроса. Отступ необходимо добавлять, чтобы код запроса вставился на форму красиво, а не безусловно лепился к левому краю текстового поля:
//БЛОК №5 - ОТКРЫВАЕМ КОНСТРУКТОР ЗАПРОСА С ПОЛУЧЕННОЙ СТРОКОЙ ЗАПРОСА И В СЛУЧАЕ УСПЕШНОГО
//РЕЗУЛЬТАТА ВЫЧИСЛЯЕМ ОТСТУП, КОТОРЫЙ БУДЕМ ДОБАВЛЯТЬ К КАЖДОЙ СТРОКЕ ЗАПРОСА
Если НЕ Конструктор.ОткрытьМодально() Тогда
Возврат;
КонецЕсли;
ТекстЗапроса = Конструктор.Текст;
Если ПустаяСтрока(ТекстЗапроса) Тогда
Возврат;
КонецЕсли;
ДлинаТекстаДоНачалаЗапроса = СтрДлина(ТекстДоНачалаЗапроса);
Позиция = ДлинаТекстаДоНачалаЗапроса-1;
Пока Позиция >= 1 Цикл
Если Сред(ТекстДоНачалаЗапроса, Позиция, 1) = Символы.LF Тогда
Прервать;
КонецЕсли;
Позиция = Позиция - 1;
КонецЦикла;
СтрокаОтступа = Сред(ТекстДоНачалаЗапроса, Позиция+1, ДлинаТекстаДоНачалаЗапроса - Позиция -1);
ДлинаСтрокиОтступа = СтрДлина(СтрокаОтступа);
СтрокаОтступаИзПробеловИТабуляций = "";
Для К = 1 To ДлинаСтрокиОтступа Цикл
Если Сред(СтрокаОтступа, К, 1) = Символы.Tab Тогда
СтрокаОтступаИзПробеловИТабуляций = СтрокаОтступаИзПробеловИТабуляций + Символы.Tab;
Иначе
СтрокаОтступаИзПробеловИТабуляций = СтрокаОтступаИзПробеловИТабуляций + " ";
КонецЕсли;
КонецЦикла;
6) Теперь у нас есть текст запроса на языке запросов. Нужно преобразовать его в строку на встроенном языке 1С. Добавляем символы вертикальной черты и отступы, преобразуем одинарные кавычки в двойные:
//БЛОК №6 - ОБРАБАТЫВАЕМ РЕЗУЛЬТАТ, ЗАМЕНЯЕМ ОДИНАРНЫЕ КАВЫЧКИ НА ДВОЙНЫЕ,
//ДОБАВЛЯЕМ ОТСТУП И ВЕРТИКАЛЬНУЮ ЧЕРТУ СТРОКАМ ЗАПРОСА НАЧИНАЯ СО ВТОРОЙ
ТекстЗапроса = СтрЗаменить(ТекстЗапроса, Кавычка, ДвойнаяКавычка);
КоличествоСтрокВТексте = СтрЧислоСтрок(ТекстЗапроса);
ТекстЗапросаССимвовамиВертикальнойЧерты = СтрПолучитьСтроку(ТекстЗапроса, 1);
Для К = 2 To КоличествоСтрокВТексте Цикл
ТекстЗапросаССимвовамиВертикальнойЧерты = ТекстЗапросаССимвовамиВертикальнойЧерты +
Символы.LF + СтрокаОтступаИзПробеловИТабуляций + "|" + СтрПолучитьСтроку(ТекстЗапроса, К);
КонецЦикла;
7) Задача фактически решена. Склеиваем код, располагавшийся до запроса, новую строку запроса и код, располагавшийся после запроса. Загружаем получившуюся строку в поле формы и восстанавливаем позицию курсора:
//ЗАГРУЖАЕМ НОВЫЙ КОД В ТЕКСТОВОЕ ПОЛЕ И УСТАНАВЛИВАЕМ КУРСОР НА ПРЕЖНЮЮ ПОЗИЦИЮ
ИтоговыйКод = ТекстДоНачалаЗапроса + ТекстЗапросаССимвовамиВертикальнойЧерты + ТекстПослеКонцаЗапроса;
ЭлементПоля.УстановитьТекст(ИтоговыйКод);
НоваяКолонка = СтрДлина(СтрокаОтступаИзПробеловИТабуляций)+2;
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НоваяКолонка, НачалоСтроки, НоваяКолонка);
ЭтаФорма.ТекущийЭлемент = ЭлементПоля;
Для применения этого метода в своих разработках вам достаточно заменить в коде имя одного элемента формы - поля текстового документа.
К публикации прилагается обработка с реализацией этого алгоритма, в которой есть обычная и управляемая форма. Обработка предназначена для работы в толстом клиенте управляемого или обычного приложения. При работе с управляемой формой есть незначительные отличия в коде. Например, восстанавливать положение курсора приходится через отложенный вызов процедуры, через обработчик ожидания.
Алгоритм был создан с целью применения в новой версии универсальной подсистемы Динамические подписки на события v.3. Не проходите мимо этой разработки, она может облегчить поддержку ваших баз:
