Ускорение перепроведения документов

Публикация № 330072

Администрирование - Производительность и оптимизация (HighLoad)

УПП оптимизация перепроведение

28
Описание незначительной доработки типовой конфигурации, которая привела к ускорению перепроведения документов на 40%.
Дорабатывалась УПП 1.3, но это должно без каких-либо изменений работать и в других конфигурациях с подобным подходом к проведению документов (КА, УТ 10)

Необходимость в такой доработке возникла после того, как такая регулярная операция, как перепроведение месяца, перестала укладываться в ночь. Начальник IT сказал, что полгода назад всё было ОК, а значит, надо откатить все изменения, сделанные предыдущим программистом (я тогда только-только устроился на эту работу) за последние полгода, благо бэкап есть.
Идея интересная, чтобы не сказать больше, но я решил пойти другим путём: запустил замер производительности, перепровёл день и посмотрел, кто вылез в топ. Одним из рекордсменов оказалась процедура ОбщегоНазначения.УдалитьЗаписанныеДвиженияДокумента, которая вызывалась перед проведением каждого документа. Процедура записывает пустые наборы записей в каждый регистр, в котором проводимый документ является регистратором, что не есть хорошо, потому что обычно в большинстве этих регистров данный документ и так не делал движений.

Список регистров для очистки процедура получала от функции ПроведениеДокументов.МассивРегистровНужноОчистить, поэтому оставалось сделать так, чтобы эта процедура возвращала только те регистры, в которых есть движения.

Для этого в конфигурацию я добавил:

  • регистр сведений ГМ_НепустыеДвижения (по старой традиции этой конфигурации, истоков которой никто не помнит, все нетиповые объекты должны содержать префикс "ГМ_") с измерениями Документ (ведущее, основной отбор) типа ДокументСсылка и НомерРегистра (основной отбор) типа Число(3,0,Неотрицательное).
  • параметр сеанса ГМ_РегистрыПоНомеру типа ФиксированныйМассив
  • параметр сеанса ГМ_НомераРегистровПоИмени типа ФиксированноеСоответствие
  • справочник ГМ_НомераРегистров с кодом типа Число длиной 3 (должно совпадать с длиной измерения НомерРегистра)

Затем подправил процедуру ПроведениеДокументов.МассивРегистровНужноОчистить:


Функция МассивРегистровНужноОчистить(ДокументОбъект) Экспорт
	
	МассивРегистров = Новый Массив();
	//Коровин 09.09.2014
	лствИмена=ПараметрыСеанса.ГМ_РегистрыПоНомеру;
	лНабор=РегистрыСведений.ГМ_НепустыеДвижения.СоздатьНаборЗаписей();
	лНабор.Отбор.Документ.Установить(ДокументОбъект.Ссылка);
	лНабор.Прочитать();
	Для каждого ТекЗапись Из лНабор Цикл
		МассивРегистров.Добавить("РегистрНакопления."+лствИмена[ТекЗапись.НомерРегистра-1]);
	КонецЦикла;
	лфлНетИнформацииОДвижениях=МассивРегистров.Количество()=0;//Мы, вероятно, в том периоде, где регистр ГМ_НепустыеДвижения пуст
	//Коровин 09.09.2014 - конец
	
	Для Каждого Движение ИЗ ДокументОбъект.Метаданные().Движения Цикл
		//Коровин 09.09.2014
		//МассивРегистров.Добавить(Движение.ПолноеИмя());
		Если лфлНетИнформацииОДвижениях ИЛИ Найти(Движение.ПолноеИмя(),"РегистрНакопления.")=0 Тогда
			МассивРегистров.Добавить(Движение.ПолноеИмя());
		КонецЕсли;
		//Коровин 09.09.2014 - конец
	КонецЦикла; 
	
	Возврат МассивРегистров;
	
КонецФункции

И добавил в привилегированный модуль процедуру, которую потом вызвал в начале процедуры ПередНачаломРаботыСистемы модуля обычного приложения:

Процедура ПодготовитьНомераРегистров() Экспорт
	лмИменаРегистров=Новый Массив;
	лствНомераПоИмени=Новый Соответствие;
	лЗапрос=Новый Запрос("ВЫБРАТЬ Код, Наименование ИЗ Справочник.ГМ_НомераРегистров УПОРЯДОЧИТЬ ПО Код");
	лВыборка=лЗапрос.Выполнить().Выбрать();
	лТекКод=0;
	Пока лВыборка.Следующий() Цикл
		лТекКод=лТекКод+1;
		Пока лВыборка.Код>лТекКод Цикл //На случай, которого не должно быть - когда коды идут не подряд
			лмИменаРегистров.Добавить();
			лТекКод=лТекКод+1;
		КонецЦикла;
		лмИменаРегистров.Добавить(лВыборка.Наименование);
		лствНомераПоИмени.Вставить(лВыборка.Наименование,лТекКод);
	КонецЦикла;
	Для каждого ТекРегистр Из Метаданные.РегистрыНакопления Цикл
		Если лствНомераПоИмени[ТекРегистр.Имя]=Неопределено Тогда //Новый регистр
			лЭлемент=Справочники.ГМ_НомераРегистров.СоздатьЭлемент();
			лЭлемент.Наименование=ТекРегистр.Имя;
			Если лЭлемент.Наименование<>ТекРегистр.Имя Тогда
				ВызватьИсключение "Наименование регистра "+ТекРегистр.Имя+" слишком длинное ("+СтрДлина(ТекРегистр.Имя)+" символов) и не влезает в справочник ГМ_НомераРегистров";
			КонецЕсли;
			лЭлемент.Записать();
			
			лмИменаРегистров.Добавить(ТекРегистр.Имя);
			лствНомераПоИмени.Вставить(ТекРегистр.Имя,лЭлемент.Код);
		КонецЕсли;
	КонецЦикла;
	ПараметрыСеанса.ГМ_РегистрыПоНомеру=Новый ФиксированныйМассив(лмИменаРегистров);
	ПараметрыСеанса.ГМ_НомераРегистровПоИмени=Новый ФиксированноеСоответствие(лствНомераПоИмени);
КонецПроцедуры

 И, наконец, добавил подписку на событие ПриЗаписи всех регистров накопления:

Процедура ПриЗаписиРегистраНакопления(Источник,Отказ,Замещение) Экспорт
	Если НЕ Отказ Тогда
		лНабор=РегистрыСведений.ГМ_НепустыеДвижения.СоздатьНаборЗаписей();
		лНабор.Отбор.Документ.Установить(Источник.Отбор.Регистратор.Значение);
		лНабор.Отбор.НомерРегистра.Установить(ПараметрыСеанса.ГМ_НомераРегистровПоИмени[Источник.Метаданные().Имя]);
		Если Источник.Количество() Тогда
			лЗапись=лНабор.Добавить();
			лЗапись.Документ=лНабор.Отбор.Документ.Значение;
			лЗапись.НомерРегистра=лНабор.Отбор.НомерРегистра.Значение;
			лНабор.Записать();
		ИначеЕсли Замещение Тогда
			//Как минимум РасчетСебестоимостиВыпуска в регистр НезавершенноеПроизводство пишет движения порциями,
			//так что без учёта флага Замещение есть риск сбросить признак, если последний дописанный набор был пустым
			лНабор.Записать();
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры


В общем, работает всё так: при запуске 1С процедура ПодготовитьНомераРегистров заполняет параметры сеанса именами и номерами регистров накопления, создавая при необходимости нужные элементы в справочнике ГМ_НомераРегистров. При каждой записи непустого набора в какой-либо регистр накопления подписка на событие ПриЗаписи добавляет для этого регистра и регистратора набора запись в регистр ГМ_НепустыеДвижения. При записи пустого набора с установленным флагом Замещение такая запись, наоборот, удаляется.

При очистке движений документа изменённая процедура ПроведениеДокументов.МассивРегистровНужноОчистить читает из регистра ГМ_НепустыеДвижения все записи по этому документу и возвращает массив регистров, для которых записи есть. Если нет ни одной записи, то работает старый алгоритм - на тот случай, если перепроводимый документ был проведён до того, как в конфигурацию были внесены эти изменения. Это также означает, что из регистра ГМ_НепустыеДвижения можно смело вычищать записи по документам из закрытых периодов, которые трогать не предполагается, так как в случае необходимости перепроведение этих документов пройдёт нормально без всяких дополнительных действий.

Upd

В комментариях мне указали на то, что переименование регистра приведёт к проблемам. Тут я вижу три способа с этим разобраться:

1. Непосредственно перед сохранением изменений конфигурации, включающих в себя переименование регистра, переименовать этот регистр в справочнике ГМ_НомераРегистров. Самый простой и быстрый способ, который, однако, требует помнить о такой необходимости, потому что если сохранить изменения в конфигурацию базы данных, воспользоваться этим способом уже не выйдет.

2. Очистить регистр ГМ_НепустыеДвижения. Способ на случай, когда не воспользовались первым. Справочник ГМ_НомераРегистров тоже можно очистить (я бы очистил), но необязательно.

3. Доработать алгоритм так, чтобы в справочнике ГМ_НомераРегистров также хранилось имя таблицы базы данных соответствующего регистра. При переименовании регистра имя таблицы не поменяется и это можно будет использовать в процедуре ПодготовитьНомераРегистров.

Я эту проблему решать не стал, потому что не помню, чтобы хоть раз менял имя регистра (разве что с ИмяРегистра на УдалитьИмяРегистра, но к этому моменту в регистре, как правило, всё равно не было записей), но эта проблема на самом деле не единственная, есть и более вероятная и неприятная: некоторые обновления релиза включают в себя какую-нибудь обработку записей регистров. При этом могут быть перезаписаны наборы записей в том периоде, для которого в регистре ГМ_НепустыеДвижения нет записей и тогда при перепроведении тех документов этого периода, которые делали движения по перезаписанному регистру, движения по всем остальным регистрам задвоятся. Неприятность этой второй проблемы в том, что вы не узнаете о ней по матюкам программы, как непременно узнаете о первой. Зато если вы про неё в курсе, решить её можно способом №2 из решений первой проблемы.

В качестве профилактической меры можно после каждого обновления релиза запускать обработку, которая бы удаляла записи из регистра ГМ_НепустыеДвижения до определённой даты. Такую обработку по-любому стоит иметь для того, чтобы удалять заведомо старые записи, ибо маленькие регистры быстрее работают.

28

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. cargobird 289 31.03.15 07:28 Сейчас в теме
Интересная идея, попробую...
2. tormozit 5615 31.03.15 07:47 Сейчас в теме
Рекомендую автору предупредить читателей о том, что в его реализации не предусмотрено переименование регистров. Последствия такого шага будут плачевными.
hulio; Diversus; +2 Ответить
3. cargobird 289 31.03.15 08:23 Сейчас в теме
(2) tormozit, на своей практике переименование регистров не встречал ни разу (у вас, видимо, опыта побольше). Копипастом по конфигурации размножаются самые причудливые названия, и чтобы принципиально потребовалось переименование - такого не было...
5. tormozit 5615 31.03.15 09:24 Сейчас в теме
(3) cargobird, конечно, у меня опыта побольше =) Думаете мало добавляют свои регистры и потом меняют им наименование, когда поймут, что промахнулись с именем? Тем более в 8.3.6 сейчас переименование стало заметно менее затратным из-за нового помощника.
4. Балабас 164 31.03.15 09:00 Сейчас в теме
где статистика на сколько увеличилась производительность в результате описанных изменений?
8. vasyak319 132 31.03.15 10:42 Сейчас в теме
(4) Балабас, (7) deadman66, в первой же фразе анонса. Понятно, что это не ровно 40.00000%, но точные цифры тут не имеют смысла - даже на одном и том же сервере, выделенном специально для тестирования и замера (а иначе как вообще было оценить прирост) время заметно плавает от перепроведения к перепроведению, а приводить его одно и то же состояние перед каждым тестом (делаем образ диска - перезагружаем - тестируем - восстанавливаем образ диска - перезагружаем - тестируем...) мне нафиг не упёрлось. А даже если бы упёрлось, это не помогло бы статье, так как это были бы цифры для моей базы и моего тестового сервера.
На рабочем сервере теперь возможно за ночь перепровести два месяца вместо одного - по мне так вполне достаточная характеристика доработки.
6. AlX0id 31.03.15 10:14 Сейчас в теме
Чота закрадываются сомнения насчет того, что подобный подход не ведет к постоянным блокировкам на регистре ГМ_НепустыеДвижения.. Каждый документ при записи каждого регистра в него лезет писать свои сочинения.. Или я чот недопонял?
9. vasyak319 132 31.03.15 10:51 Сейчас в теме
(6) AlX0id, (7) deadman66, были такие опасения и думал, что придётся накладывать управляемые блокировки (тут-то всё будет хорошо на 100%, ибо диапазоны разных документов не пересекаются), но то ли 1С сама их хорошо накладывает, то ли одно из двух (не было времени выяснять, отчего же всё хорошо), но проблем не возникло.
11. AlX0id 31.03.15 12:08 Сейчас в теме
(9)
Внимательно посмотрел структуру регистра - понял, что недопонял )
Думал, что в регистре привязка идет к типу документа, а не к конкретной ссылке. Тогда да - диапазоны не пересекаются, 1С и так наложит блокировку по измерениям, если для регистра применяется управляемый режим.
7. deadman66 31.03.15 10:24 Сейчас в теме
Статистика замеров где? И, да, с блокировками не возникает проблем?
10. Fox-trot 107 31.03.15 12:08 Сейчас в теме
так речь про файловый вариант?
15. vasyak319 132 31.03.15 14:34 Сейчас в теме
(10) Fox-trot, нет, но мне интересно, из чего вы сделали такой вывод.
17. Fox-trot 107 31.03.15 16:05 Сейчас в теме
(15) всю жись с 1с работал тока с трехзвенкой и когда-то сделал вывод, что количество информации = размер базы не влияет на скорость выполнения проги. такие дела
19. vasyak319 132 31.03.15 16:18 Сейчас в теме
(17) Fox-trot, ну, во-первых, конечно, влияет (другое дело, что вы могли этого не заметить), а во-вторых, всё равно непонятно - в статье про количество данных ни слова.
12. CrazyCD 14 31.03.15 13:46 Сейчас в теме
После проведения года попробую вкрячить на КОРП подобное.
А так ловите плюсик авансом =)))
13. Йожкин Кот 1066 31.03.15 13:55 Сейчас в теме
Еще можно сделать проведение док-та на сервере, чтобы не гонять наборы записей, результаты запросов к шапке и ТЧ туда-сюда. Тоже очень хорошо скажется на производительности.
14. vasyak319 132 31.03.15 14:33 Сейчас в теме
(13) Йожкин Кот, а я долгое время думал, ОбработкаПроведения всегда на сервере выполняется. Пока как-то утром не пришел и не увидел, что проведение (Операции - Проведение документов...) встало и ждёт, что я в окне предупреждения ОК нажму. Так я узнал две вещи: что один из тех парней, что дорабатывали эту конфигу, идиот (в ОбработкуПроведения Предупреждение воткнул!) и что перепроведение выполняется на клиенте, потому что иначе тот документ вылетел бы с ошибкой компиляции модуля.
Какое-то время попереписывался с Хотлайном на тему "Когда такое стало возможно", но получился, как это часто бывает, разговор с глухим.
25. Йожкин Кот 1066 01.04.15 12:32 Сейчас в теме
(14) Проведение, которое инициировано из формы или формы списка док-та для толстого клиента всегда выполняется на клиенте. Для тонкого клиента - всегда на сервере, в не зависимости от точки вызова.
26. tormozit 5615 01.04.15 12:40 Сейчас в теме
(25) Йожкин Кот, не совсем верно. Проведение стандартными командами вызывается
- для управляемой формы всегда на сервере
- для обычной формы всегда на клиенте
31. vasyak319 132 01.04.15 17:28 Сейчас в теме
(25) Йожкин Кот, теперь-то я в курсе, но ещё в 8.1 всё проводилось на сервере и такой мрачный прикол с Предупреждением в ОбработкеПроведения даже не компилировался. Там даже Сообщить сначала не компилировалось, это потом сделали очередь сообщений, которую сервер отдаёт клиенту вместе с возвратом управления.
16. Evg-Lylyk 2697 31.03.15 15:52 Сейчас в теме
Не понял зачем так
Я переписал функцию МассивРегистровНужноОчистить

Функция МассивРегистровНужноОчистить(ДокументОбъект) Экспорт

МассивРегистров = Новый Массив();
Запрос = Новый Запрос;

ДвиженияДокумента = ДокументОбъект.Метаданные().Движения;
Для Каждого Движение ИЗ ДвиженияДокумента Цикл

ИмяРегистра = Движение.ПолноеИмя();

Если ЗначениеЗаполнено(Запрос.Текст) Тогда
Запрос.Текст = Запрос.Текст + " ОБЪЕДИНИТЬ ВСЕ ";
КонецЕсли;
Запрос.Текст = Запрос.Текст + "ВЫБРАТЬ ПЕРВЫЕ 1""" + ИмяРегистра + """ ИЗ " + ИмяРегистра + " ГДЕ " + ИмяРегистра + ".Регистратор = &Регистратор";
КонецЦикла;

Запрос.УстановитьПараметр("Регистратор", ДокументОбъект.Ссылка);
Результат = Запрос.Выполнить();

Возврат Результат.Выгрузить().ВыгрузитьКолонку("Поле1");

КонецФункции

вроде все теперь очищает только те регистры в которых были записи...
проверял на документе ПлатежкаИсх (5 раз проводил) ускорилось очень значительно
теперь проверяю и думаю на что это может повлиять эта доработка
Mkonst; kauksi; vasyak319; AlkB; +4 Ответить
18. vasyak319 132 31.03.15 16:16 Сейчас в теме
(16) Evg-Lylyk, у меня запрос к одной маленькой таблице (вся эта заморочка с нумерацией регистров как раз для того, чтобы она была настолько маленькой, насколько возможно), а у вас к множеству очень больших. Это тоже должно ускорить перепроведение (что вы и ощутили), так как все СУБД оптимизируют на чтение, а не на запись, но тут вопрос, чего вам нужно больше - написать покороче и постабильнее (у вашего способа нет проблем моего) или выжать из возможности максимум.
Хотя я допускаю, что ответ вопрос "какой метод быстрее" не такой однозначный и зависит от обстоятельств (мозги сервера, размер базы, характер заполненности регистров и т.п.).

Думаю, будет здорово, если вы оформите свой камент в виде статьи.
20. Evg-Lylyk 2697 31.03.15 16:29 Сейчас в теме
(18) Понятно. Думаю вашей статьи достаточно.
21. ZOMI 420 31.03.15 23:44 Сейчас в теме
Ниже привожу листинг процедуры( УПП 1.3.51, которая так возбудила возмутила автора

// Процедура очистки записанных движений документа
//
// Параметры:
//	ДокументОбъект 				- документ, движения которого удаляются
//	Отказ 						- булево, признак отказа
//	ВыборочноОчищатьРегистры 	- булево, признак выборочной очистки наборов записей 
//								Если Истина - часть наборов записей не будут очищены, будут очищены только коллекции движений
//	РежимПроведенияДокумента 	- режим проведения (оперативный / неоперативный), 
//								нужен для составления списка регистров, которые не надо очищать
Процедура УдалитьЗаписанныеДвиженияДокумента(ДокументОбъект, Отказ, ВыборочноОчищатьРегистры, РежимПроведенияДокумента)
	
	// Получим перечень регистров, движения по которым нужно очистить
	МассивРегистров = ПроведениеДокументов.МассивРегистровНужноОчистить(ДокументОбъект);
	
	Если МассивРегистров.Количество() = 0 Тогда
		Возврат;
	КонецЕсли;
	
	// Если очищать регистры надо выборочно, то подготовим список таких регистров, 
	//	которые можно не очищать при перепроведении
	Если ВыборочноОчищатьРегистры Тогда
		РегистрыДляОптимизацииПерезаписиДвижений = ПолучитьРегистрыДляОптимизацииПерезаписиДвижений(РежимПроведенияДокумента);
	КонецЕсли;
	
	// Переменные логики отложенного проведения
	ДокументИспользуетсяВОтложенномПроведении = Ложь;
	ВыполняетсяДопроведение                   = Ложь;
	ПроведениеПоВсемВидамУчета                = Ложь;
	
	СтруктураПараметровПроведения = ОтложенноеПроведениеДокументов.ПолучитьПараметрыПроведенияДокумента(ДокументОбъект);
	ДокументИспользуетсяВОтложенномПроведении = СтруктураПараметровПроведения.ДокументИспользуетсяВОтложенномПроведении;
	
	Если ДокументИспользуетсяВОтложенномПроведении Тогда
		ВыполняетсяДопроведение = СтруктураПараметровПроведения.ВыполняетсяДопроведение;
		ПроведениеПоВсемВидамУчета = СтруктураПараметровПроведения.ПроведениеПоВсемВидамУчета;
		РегистрыОтложенногоПроведения = ОтложенноеПроведениеДокументов.ПолучитьРегистрыОтложенногоПроведения();
	КонецЕсли;
	
	//Обойдем список регистров, по которым существуют движения, и выполним очистку необходимых регистров
	Для Каждого ПолноеИмяРегистра ИЗ МассивРегистров Цикл
		
		// Имя регистра передается как значение, 
		// полученное с помощью функции ПолноеИмя() метаданных регистра
		ПозицияТочки = Найти(ПолноеИмяРегистра, ".");
		ТипРегистра = Лев(ПолноеИмяРегистра, ПозицияТочки - 1);
		ИмяРегистра = СокрП(Сред(ПолноеИмяРегистра, ПозицияТочки + 1));
		
		// Используется для оптимизации перезаписи движений платформой
		//	Если значение Ложь, набор записей не будет очищен
		// По умолчанию все движения надо удалять
		УдалятьДвижения = Истина;
		
		Если ВыборочноОчищатьРегистры И РегистрыДляОптимизацииПерезаписиДвижений.Найти(ИмяРегистра) <> Неопределено Тогда
			УдалятьДвижения = Ложь;
		КонецЕсли;
		
		Если ДокументИспользуетсяВОтложенномПроведении Тогда
			Если ВыполняетсяДопроведение Тогда
				//	Если выполняется допроведение, то удаляются только движения по регистрам, 
				//	которые формируются при отложенном проведении
				Если РегистрыОтложенногоПроведения.Найти(СокрЛП(ПолноеИмяРегистра)) = Неопределено Тогда
					Продолжить;
				КонецЕсли;
			Иначе
				// Документ проводится в режиме отложенного проведения
				
				// Если для документа выключен режим проведения "по всем видам учета", 
				// то всегда удаляются движения по регистрам, которые формируются при допроведении
				//	(независимо от того, входят ли они в список РегистрыДляОптимизацииПерезаписиДвижений)
				Если НЕ УдалятьДвижения
					И НЕ ПроведениеПоВсемВидамУчета 
					И РегистрыОтложенногоПроведения.Найти(СокрЛП(ПолноеИмяРегистра)) <> Неопределено Тогда
					
					УдалятьДвижения = Истина;
				КонецЕсли;
			КонецЕсли; 
		КонецЕсли; 
		
		Если УдалятьДвижения Тогда
			// Удаление движений происходит без контроля доступа - передаем пустую таблицу движений
			ПолныеПрава.ЗаписатьНаборЗаписейНаСервере(ИмяРегистра, ДокументОбъект.Ссылка,, ТипРегистра);
		Иначе
			//Установим признак модифицированности набора записей, чтобы записались все коллекции движений, по которым
			//были записи на момент проведения
			ДокументОбъект.Движения[ИмяРегистра].Очистить();
		КонецЕсли;
	КонецЦикла;	
	
КонецПроцедуры
Показать


Напрашивается вопросик - а выборочное очищение регистров - чем вам не по душе?
Извините, но то что вы нагородили кто-то (через полгодика?) уберет и заюзает механизмы типовой...


anchovy; Fox-trot; +2 Ответить
22. vasyak319 132 01.04.15 09:45 Сейчас в теме
(21) ZOMI, напрашивается встречный вопросик: Вы смотрели, что на самом деле делает эта процедура при взведённом параметре ВыборочноОчищатьРегистры и в каких вообще случаях он взведён, или вы просто увидели, что есть такой параметр и решили, что вот он - золотой ключик?
23. AlX0id 01.04.15 09:49 Сейчас в теме
(21) ZOMI,
а это выборочное очищение где-то отдельно включается или само по себе работает?
24. vasyak319 132 01.04.15 10:23 Сейчас в теме
(23) AlX0id, советую посмотреть, как и откуда вызывается процедура, вызывающая эту процедуру и, до кучи, список регистров, на который влияет упомянутый флажок, хотя последнее, в общем, необязательно.
28. AlX0id 01.04.15 15:21 Сейчас в теме
(24)
Ну вот сильно не хочется по коду лазить, если честно ) Тем более, когда не знаешь, как он должен работать. Я просто интересуюсь, может быть где-то есть описание этого использования механизма на уровне пользователя/программиста/администратора - мало ли удастся облегчить людям жизнь, не утруждая свою ))
30. vasyak319 132 01.04.15 16:49 Сейчас в теме
(28) AlX0id, там немного, потому и предложил взглянуть. Если вкратце, то этот параметр, конечно, никакими настройками не управляется. Где можно (а можно в большинстве реально используемых документов, в частности - ПТиУ и РТиУ) он уже взведён. Влияние оказывает не на все, а где-то на десяток второстепенных регистров.
В общем, что имел в виду ZOMI своей цитатой процедуры (спасибо, что не модуль целиком), а также ссылкой на загадочные "механизмы типовой", по-моему даже он сейчас не в курсе.
27. capitan 1323 01.04.15 13:54 Сейчас в теме
Программисты 1С они такие ... программисты.
А те, кто не прогуливал в институте Основы программирования, знают, что каждую задачу можно (и нужно) описать формально, потом блок-схема, потом код.
Оставив за бортом код мы увидим следующее:
1. Автор подозревает, возможно небезосновательно, что документы в УПП являются регистраторами для регистров, в которых проводки не делают. Тут камень в огород 1С ибо в каждой книге по программированию написано - не добавляйте лишних регистров/регистраторов.
И тут вот хорошо бы увидеть отчет, который пройдет по конфигурации, посчитает и выведет в виде - Документ - Количество регистров где он является регистратором - Количество регистров, где реально есть проводки.
Если автор состряпает такой отчет и выложит его сюда, да еще для любой конфигурации - звезду ему во всю грудь.
Тогда можно уже аргументированно теребить 1С и/или править документ убирая регистры, где он в регистраторах не нужен.
2. Что сделал автор (надеюсь инфостарт не читают его юзеры и начальник) - он ускорил перепроведение документов, замедлив, в зависимости от количества строк табличной части документа конечно, проведение документа. Не говоря уже о взаимных блокировках регистра сведений при проведении, до которых автору конечно дела нет - он то ночью один работает. За что конечно юзеры, говорят простое человеческое спасибо.
По хорошему нужно делать регламентное задание, заполняющее регистр сведений и всю кухню с перепроведением завязывать на принак - массовое перепроведение ли это вообще. А так - оставлять возможно стандартный механизм от 1С.
3. В итоге статья получается о том, как один, даже не выпивший фанты программист, может тормознуть десяток другой пользователей.
Designer1C; Fox-trot; 7o2uYXg; +3 Ответить
29. vasyak319 132 01.04.15 16:42 Сейчас в теме
(27) capitan, бред. Расписал бы подробнее, да вот опровергать буйные фантазии мне ещё лет 10 назад скучно стало.
32. capitan 1323 01.04.15 18:39 Сейчас в теме
(29) а ты посмотри на сколько дольше стал проводиться один документ. И поймешь чему за 10 лет научился.
Оставьте свое сообщение

См. также

Использование XML-схемы из макета внешней обработки 21

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Обмен через XML Универсальные функции

Простой способ использования XML-схем из макета внешней обработки.

28.10.2019    2578    OlesiaM    10       

Быстрое создание наполненных коллекций 58

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции

Разберем самые частые способы создания коллекции, значения которой известны заранее. И сравним скорость их выполнения.

28.10.2019    3219    SeiOkami    51       

Преобразование XML в таблицу значений или иной объект 1С методом XSL преобразования 41

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Универсальные функции Обмен через XML

Сразу открою интригу, напрямую прочитать XML, не содержащий объект 1С, не удастся. Статья раскрывает способы привести XML к формату, который возможно прочитать средствами платформы.

24.10.2019    3256    kraspila    25       

Обертка функций Excel на русском. Ускорение процесса разработки. 43

Статья Программист Нет файла v8 Windows Бесплатно (free) Загрузка и выгрузка в Excel Универсальные функции

Устали переключаться с русского на английский и обратно при работе с таблицами Excel из 1С? Сборка наиболее необходимых функций и методов работы с Excel, обернутых в функции 1С на русском языке.

24.10.2019    2348    DmitryKotov    6       

Весёлые картинки о работе Performance Monitor на Windows Server 2016 Std по мотивам расследования потери производительности на базе 1С 16

Статья Системный администратор Нет файла v8 Windows Бесплатно (free) Производительность и оптимизация (HighLoad)

Данная публикация посвящена одной особенности Performance Monitor на Windows Server 2016 Std. Как понимать графики Performance Monitor на Windows Server 2016 Std при расследовании проблем в работе 1С.

22.10.2019    2085    EugeneSemyonov    10       

Полезняшки по СКД и построителям. Просто код 45

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Универсальные функции

Полезные процедуры и функции для работы с построителями и СКД. Просто исходник.

10.10.2019    4086    Yashazz    45       

Полезные процедуры и функции для программиста 141

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Практика программирования Универсальные функции

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    9087    HostHost    23       

Мониторинг высоконагруженной системы 38

Статья Системный администратор Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad) Администрирование данных 1С

Высоконагруженной системе (более 8000 клиентских сессий) мониторинг необходим. Про опыт использования инструментов для мониторинга – самописной системы информирования, написанной на C#, и конфигурации «Центр контроля качества» в связке с системой отображения данных Grafana, на конференции Infostart Event 2018 Education рассказал Олег Репников.

13.09.2019    4163    Repich    4       

Использование Zabbix для сбора информации о серверных вызовах и управляемых блокировках с сервера 1С Предприятия, работающего на платформе GNU/Linux 73

Статья Системный администратор Программист Нет файла v8 Linux Бесплатно (free) Администрирование данных 1С Zabbix

Описанные в данном опусе механизмы ни в коей мере не противопоставляются тому, что реализует КИП от 1С или какие-либо другие инструменты (решения)! Это всего лишь еще один взгляд на "проблему", который может быть полезен в некоторых ситуациях.

10.09.2019    8130    Sloth    11       

Анализ производительности APDEX 65

Отчеты и формы Системный администратор Программист Внешний отчет (ert,erf) v8 1cv8.cf Бесплатно (free) Производительность и оптимизация (HighLoad)

Отчет для просмотра и анализа замеров производительности в конфигурациях на базе БСП.

31.08.2019    3366    93    YPermitin    7       

Отслеживание выполнения фонового задания 141

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    10649    ids79    16       

Неочевидные проблемы производительности: важность системного подхода при анализе 50

Статья Программист Нет файла v8 Россия MS SQL Бесплатно (free) Производительность и оптимизация (HighLoad)

Часто программисты и 1С-ники сталкиваются с совершенно необъяснимыми на первый взгляд проблемами. Но это потому, что их внимание направлено только на один сегмент системы, а не на всю систему полностью. О том, почему нужно стараться смотреть на ситуацию комплексно, рассказал специалист по производительности компании SOFTPOINT Александр Денисов.

19.07.2019    4730    Филин    12       

Ловля блокировок на связке "Microsoft SQL server - 1С" 38

Статья Системный администратор Программист Нет файла v8 v8::blocking MS SQL Бесплатно (free) Производительность и оптимизация (HighLoad)

Материал относится к базам данных на связке «1С - MS SQL Server». Один из способов отлова блокировок в бд 1С . Переход к управляемым блокировкам через режим "Автоматический и управляемый".

16.07.2019    4133    fhqhelp    0       

Анти-оптимизация: как мы ускорили запрос в 4 раза, сделав его неоптимальным 57

Статья Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad) Практика программирования Решение задач на 1С:Специалист Разработка

В этой статье приведен пример неочевидной "оптимизации" запроса, которая противоречит всем правилам, описанным в книгах для подготовки к сертификации "1С:Эксперт по технологическим вопросам", а также преподаваемым на курсах подготовки экспертов.

02.07.2019    6541    igordynets    119       

Ускорение чтения правил обмена в УПП 1.3 в 20 раз! 69

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Производительность и оптимизация (HighLoad)

Способ оптимизации чтения правил обмена конвертации данных. Может понадобиться при большом размере правил и высокой периодичности обмена.

27.06.2019    5105    YPermitin    16       

Хотите снизить нагрузку на процессор сервера в 2 раза? 21

Статья Системный администратор Программист Нет файла v8 Windows Бесплатно (free) Производительность и оптимизация (HighLoad)

В статье рассмотрено влияние частого запуска регламентных заданий на процессор сервера 1С.

27.06.2019    4577    Дмитрий74Чел    6       

Непридуманные истории по оптимизации. История 1 82

Статья Системный администратор Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Производительность и оптимизация (HighLoad)

Первая статья из планируемого цикла об оптимизации приложений на базе 1С. Без теории. Одна практика.

13.06.2019    8017    Repich    117       

За 5 шагов добавляем мониторинг счетчиков производительности серверов MS SQL и 1С 91

Статья Системный администратор Программист Нет файла v8 Бесплатно (free) Статистика базы данных Производительность и оптимизация (HighLoad)

Мы расскажем и покажем, как добавить данные счетчиков производительности серверов 1С и MS SQL в нашу базу мониторинга за 15 минут. Приведем список наиболее важных из них, опишем основные особенности.

28.05.2019    8402    ivanov660    5       

Не думать о секундах свысока... 56

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Производительность и оптимизация (HighLoad)

Несколько примеров оптимизации типовой конфигурации УТ11. Описанные приемы подходят для многих других конфигураций.

21.05.2019    4751    vasilev2015    21       

Альтернативная стратегия управления блокировками 45

Статья Программист Архив с данными v8 v8::blocking 1cv8.cf Россия MS SQL Бесплатно (free) Производительность и оптимизация (HighLoad)

Данная публикация освещает одну из альтернативных стратегий блокирования данных на уровне MS SQL Server, которая недоступна средствами 1С, но может быть весьма полезной. Разбирается практический пример.

20.05.2019    4183    zhichkin    15       

Сохранение запроса со всеми параметрами и временными таблицами 20

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Универсальные функции

Функция сохранения запроса со всеми параметрами и временными таблицами в формате *.q1c для открытия в консоли запросов с диска ИТС.

13.05.2019    2858    Serge R    5       

Как работают управляемые блокировки 122

Статья Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Все типовые конфигурации содержат ошибки, потому как управляемые блокировки в 1С слишком уж "управляемые", при понижении уровня изоляции про некоторые "нюансы" просто забыли. Для создания и эксплуатации качественной системы, которая способна поддерживать транзакционную целостность данных при параллельной работе, информацию в этой статье желательно знать, хотя, конечно, ничего особо нового я не открыл.

29.04.2019    14020    comol    198       

Странное потребление места на диске С 33

Статья Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Решение проблемы постоянного роста папки %AppData%/Local/Temp.

26.04.2019    10994    kuzyara    12       

Включение встроенного в платформу механизма "Копии базы данных" и использование "Дата Акселератора". Новый стандартный механизм использования баз OLAP в 1С 51

Статья Системный администратор Программист Нет файла v8 Россия Бесплатно (free) Производительность и оптимизация (HighLoad)

С версии 1С 8.3.14 в платформе появился новый функционал «Копии базы данных». В данной публикации я хочу рассказать, как включить использование данного механизма в платформе 1с и как его использовать для получения отчетов с копии базы данных, которая может быть вынесена на внешний сервер относительно текущей базы данных, а также как использовать систему «Дата акселератор», в которой база данных целиком размещена в оперативной памяти рабочего сервера кластера серверов «1С:Предприятия».

25.04.2019    8818    Elf1k    27       

5 простых шагов и 15 минут на разворачивание инструмента мониторинга проблем производительности базы 1С 202

Статья Системный администратор Программист Нет файла v8 Windows Бесплатно (free) Производительность и оптимизация (HighLoad)

В этой статье мы разберем механизм использования конфигурации "Анализ технологического журнала" на практике, и всего через 15 минут работы вы получите функциональный, удобный инструмент мониторинга проблем производительности базы 1С.

18.04.2019    19060    ivanov660    68       

Как разбить базу на файлы и не сойти с ума 108

Статья Системный администратор Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Разбиение базы данных 1C на файлы и последующее сопровождение. Нюансы, грабли и прочее.

06.04.2019    9432    YPermitin    29       

Доработка проведения типовых документов в УТ 11.4, КА 2.4, ЕРП 2.4 101

Статья Программист Нет файла v8 v8::УФ ERP2 УТ11 КА2 Россия УУ Бесплатно (free) Практика программирования Универсальные функции Разработка

Различные варианты корректировки типовых механизмов проведения документов, без корректировки основной конфигурации. Использование расширений, подписок на событие и механизма локализации типовых документов.

22.03.2019    9658    ids79    14       

Как одно изменение конфигурации PostgreSQL улучшило производительность медленных запросов в 50 раз 124

Статья Системный администратор Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Производительность и оптимизация (HighLoad)

В связи с санкциями и другими событиями сейчас все более и более актуальна тема перевода ПО компаний на отечественное и свободное программное обеспечение. Одной из самых востребанных СУБД на рынке на данный момент является PostgreSQL - надежная, высокопроизводительная и хорошо масштабируемая СУБД, которая является прямым конкуретном таким крупным компаниям с их топовыми продуктами, как Oracle, IBM и Microsoft. Однако каждый, кто переходит на PostgreSQL, сталкивается с трудностями, прежде всего с настройкой и производительностью. Не обошли проблемы с производительностью "слоника" и меня. Предлагаю вашему вниманию перевод статьи "How a single PostgreSQL config change improved slow query performance by 50x" автора Pavan Patibandla, которая мне помогла улучшить производительность PostgreSQL.

18.03.2019    10396    w.r.    23       

Простое программное решение проблем с блокировками SQL 17

Статья Системный администратор Программист Нет файла v8 v8::blocking 1cv8.cf Россия Бесплатно (free) Производительность и оптимизация (HighLoad)

Описание одного из способов программного решения проблемы блокировок при проведении документов в клиент-серверной 1С.

06.03.2019    6328    dmitrydemenew    38       

Производительность сервера 1С и фоновые задания 63

Статья Системный администратор Нет файла v8 1cv8.cf Россия Windows Бесплатно (free) Производительность и оптимизация (HighLoad)

В падении производительности сервера 1С зачастую виноваты не регламентные / фоновые задания, они выполняют полезную работу. Но задания нельзя оставлять «наедине» с базой.

05.02.2019    11380    user715208    38       

Работа со строками: от простого к сложному 26

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Простые примеры работы со строками, в конце более читаемый разбор сложных текстов.

14.01.2019    8712    Evg-Lylyk    17       

Универсальные функции ЗУП 3.1 / ЗКГУ 3.1, которые помогут в разработке 487

Статья Программист Нет файла v8 v8::СПР ЗКГУ3.0 ЗУП3.x БУ Зарплата Управление персоналом (HRM) Бесплатно (free) Универсальные функции

В статье размещен список стандартных процедур и функций с примерами, которые могут помочь при разработке (доработке) конфигураций Зарплата и управление персоналом ред. 3.1 и Зарплата и кадры государственного учреждения 3.1. Иногда бывает довольно сложно правильно получить данные или долго, поэтому лучшим вариантом будет использование стандартных процедур. Буду очень признателен, если Вы поделитесь своим опытом и предложите свои варианты стандартных процедур которые помогают в работе. Или предложите, как дополнить имеющиеся процедуры.

14.11.2018    35582    GeterX    93       

Кадровые данные сотрудников в ЗУП 3.1 в отчетах 39

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Россия Управление персоналом (HRM) Бесплатно (free) Универсальные функции

Параметры используемые для получения данных сотрудников в ЗУП 3.1. Пригодится для разработки отчетов как напоминалка.

07.11.2018    14234    fromlion    14       

Новый режим реструктуризации (обновление базы данных на сервере в режиме v2) 170

Статья Системный администратор Программист Нет файла v8 1cv8.cf Бесплатно (free) Производительность и оптимизация (HighLoad)

Данная статья скорее является заметкой и отчетом об успешном использовании нового механизма реструктуризации баз данных 1С. Актуально для больших баз данных.

31.10.2018    19447    Dach    46       

Нетривиальные подходы в решении всем известных проблем: ускорение «больших» документов в 1С и ускорение поиска по подстроке. Как добиться эффекта в разы? 62

Статья Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Часто у пользователей 1С поиск информации по большим спискам данных по подстроке занимает продолжительное время. Павел Баркетов рассматривает причины торможения запросов с поиском по подстроке и описывает возможности и подходы к их оптимизации и ускорению. Также в статье разобраны причины длительного проведения «больших» документов (более 10 000 строк) и даны рекомендации по ускорению этих операций.

30.08.2018    11441    gallam99    31       

Кейс: как мы разрабатывали систему автоматизации анализа ошибок, связанных со скоростью работы 1С 43

Статья Системный администратор Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Бурмистров Андрей рассказывает о создании инструмента по автоматизации анализа неоптимальных запросов в коде 1С. Он поднимает вопрос о предпосылках создания этого инструмента, рассказывает о возникших форс-мажорных ситуациях, с которыми столкнулась команда в процессе разработки, и о том, как они с ними справлялись.

27.08.2018    7766    Andreynikus    20       

3000 пользователей на трехъядерном Athlon – сверхтонкий веб-клиент для 1С 97

Статья Системный администратор Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Юрий Лазаренко поделится опытом ускорения 1С нестандартными методами, в том числе с помощью http-сервисов. Он расскажет, как с помощью сверхтонкого клиента для 1С и интеграции с сайтом удалось добиться ускорения 1С на порядок. Также в статье приведена статистика по отчету о нагрузочном тестировании сверхтонкого клиента для 1С:ITIL.

16.08.2018    11747    TitanLuchs    28       

Когда условие в срезе последних даже вредит 20

Статья Системный администратор Программист Нет файла v8 1cv8.cf Бесплатно (free) Производительность и оптимизация (HighLoad)

Спойлер: оптимизатор MSSQL видит внешние, по отношению к срезу, условия, и строит план с их учетом.

05.08.2018    8092    nicxxx    105       

Оптимизация без оптимизации: как мы ускорили 1С в 10 раз без трудоемкой оптимизации запросов и алгоритмов. Практический опыт 81

Статья Системный администратор Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Можно ли ускорить 1С, не оптимизируя запросы, не разбивая транзакции и не наращивая оборудование? В статье Аверьянова Алексея рассмотрены три практических кейса повышения производительности системы без трудоемкой оптимизации: отложенное резервирование «в один поток», отложенное создание и проведение реализаций.

26.07.2018    13588    avryanovalexey    100       

Альтернативные технологии нагрузочного тестирования серверной части кода прикладных решений на платформе 1С 56

Статья Программист Нет файла v8 Бесплатно (free) Производительность и оптимизация (HighLoad)

Евгений Филиппов знакомит с альтернативными технологиями нагрузочного тестирования серверной части кода прикладных решений на платформе 1С. Он рассказывает об узких местах традиционной технологии нагрузочного тестирования и методах их обхода путем переноса работы с клиентских соединений на фоновые задания и изменения способа управления сеансами. Также автор приводит примеры с реальных проектов, подтверждающие жизнеспособность предложенных технологий.

12.07.2018    8630    jf2000    10       

Архитектура ИТ-системы на базе 1С в крупной организации. Часть 2. Чудес не бывает 81

Статья Системный администратор Нет файла v8 УТ11 Россия Бесплатно (free) Производительность и оптимизация (HighLoad)

Развернуто отвечаю, как мы боремся с зависаниями системы и вообще решаем проблемы. С примерами, но без слайдов.

04.07.2018    12598    Repich    74       

Архитектура ИТ-системы на базе 1С в крупной организации 101

Статья Системный администратор Нет файла v8 УТ11 Россия Бесплатно (free) Производительность и оптимизация (HighLoad)

В данной статье я хотел бы очень крупными мазками обрисовать архитектуру ИТ системы на базе 1С в крупных (более 1 тысячи пользователей) организациях. Она не несет какой либо образовательной цели, это просто попытка показать – «а как у нас».

02.07.2018    15207    Repich    112