Запрос возвращает таблицу с остатками по дня приходов.
ВЫБРАТЬ
ТоварыНаСкладах.Склад,
ТоварыНаСкладах.Номенклатура,
ТоварыНаСкладах.ХарактеристикаНоменклатуры,
ТоварыНаСкладах.КоличествоОстаток
ПОМЕСТИТЬ ВТ_Остатки
ИЗ
РегистрНакопления.ТоварыНаСкладах.Остатки КАК ТоварыНаСкладах
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ТоварыНаСкладах.Склад,
ТоварыНаСкладах.Номенклатура,
ТоварыНаСкладах.ХарактеристикаНоменклатуры,
НАЧАЛОПЕРИОДА(ТоварыНаСкладах.Период, ДЕНЬ) КАК ПериодДень,
СУММА(ТоварыНаСкладах.Количество) КАК Количество
ПОМЕСТИТЬ ВТ_Приходы
ИЗ
РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
ПО ТоварыНаСкладах.Склад = ВТ_Остатки.Склад
И ТоварыНаСкладах.Номенклатура = ВТ_Остатки.Номенклатура
И ТоварыНаСкладах.ХарактеристикаНоменклатуры = ВТ_Остатки.ХарактеристикаНоменклатуры
ГДЕ
ТоварыНаСкладах.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
СГРУППИРОВАТЬ ПО
ТоварыНаСкладах.Склад,
ТоварыНаСкладах.Номенклатура,
ТоварыНаСкладах.ХарактеристикаНоменклатуры,
НАЧАЛОПЕРИОДА(ТоварыНаСкладах.Период, ДЕНЬ)
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Т1.Склад,
Т1.Номенклатура,
Т1.ХарактеристикаНоменклатуры,
Т1.ПериодДень,
МАКСИМУМ(Т1.Количество) КАК Количество,
ЕстьNULL(СУММА(Т2.Количество),0) КАК КоличествоСледующих
ПОМЕСТИТЬ ВТ_НакопленныеПриходы
ИЗ ВТ_Приходы КАК Т1
ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Приходы КАК Т2
ПО Т1.Склад = Т2.Склад
И Т1.Номенклатура = Т2.Номенклатура
И Т1.ХарактеристикаНоменклатуры = Т2.ХарактеристикаНоменклатуры
И Т1.ПериодДень < Т2.ПериодДень
СГРУППИРОВАТЬ ПО
Т1.Склад,
Т1.Номенклатура,
Т1.ХарактеристикаНоменклатуры,
Т1.ПериодДень
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВТ_НакопленныеПриходы.Склад,
ВТ_НакопленныеПриходы.Номенклатура,
ВТ_НакопленныеПриходы.ХарактеристикаНоменклатуры,
ВТ_НакопленныеПриходы.ПериодДень,
ВТ_НакопленныеПриходы.Количество,
ВТ_НакопленныеПриходы.КоличествоСледующих,
ВЫБОР КОГДА ВТ_Остатки.КоличествоОстаток-ВТ_НакопленныеПриходы.КоличествоСледующих<ВТ_НакопленныеПриходы.Количество ТОГДА
ВТ_Остатки.КоличествоОстаток-ВТ_НакопленныеПриходы.КоличествоСледующих
ИНАЧЕ
ВТ_НакопленныеПриходы.Количество
КОНЕЦ КАК ОстатокПрихода
ИЗ ВТ_НакопленныеПриходы КАК ВТ_НакопленныеПриходы
СОЕДИНЕНИЕ ВТ_Остатки
ПО ВТ_НакопленныеПриходы.Склад = ВТ_Остатки.Склад
И ВТ_НакопленныеПриходы.Номенклатура = ВТ_Остатки.Номенклатура
И ВТ_НакопленныеПриходы.ХарактеристикаНоменклатуры = ВТ_Остатки.ХарактеристикаНоменклатуры
И ВТ_НакопленныеПриходы.КоличествоСледующих < ВТ_Остатки.КоличествоОстаток
УПОРЯДОЧИТЬ ПО
ВТ_НакопленныеПриходы.Склад,
ВТ_НакопленныеПриходы.Номенклатура,
ВТ_НакопленныеПриходы.ХарактеристикаНоменклатуры,
ВТ_НакопленныеПриходы.ПериодДень
Показать