Использование свойств объектов при доработке типовых конфигураций

Публикация № 57375

Программирование - Практика программирования

139
Часто при реализации небольших проектов по доработке типовых конфигураций второстепенным, но не менее важным выступает требование минимизации трудоемкости подготовки обновления на следующие релизы.

Статья является продолжением цикла статей:
Внешние печатные формы в восьмерке http://infostart.ru/blogs/157
Использование встроенного почтового клиента - http://infostart.ru/blogs/161/
Документ с печатью и подписью - http://infostart.ru/blogs/162/
Внешние печатные формы в восьмерке II - http://infostart.ru/blogs/324/
Заполнение табличных частей документов в восьмерке (внешние обработки) http://infostart.ru/blogs/345/
Использование свойств объектов при доработке типовых конфигураций http://infostart.ru/blogs/692/
Рассмотрим возможные доработки в порядке увеличения трудоемкости:
- использование существующих механизмов типовой конфигурации;
- использование внешних обработок и отчетов;
- создание новых объектов метаданных;
- изменение текстов модулей;
- изменение метаданных существующих объектов;
- изменение форм;
- изменение макетов;
- и т.д.

Для реализации требований минимизации трудоемкости подготовки необходимо ограничить или отказаться от наиболее трудоемких доработок в пользу менее трудоемких. В статье рассматривается использование свойств объектов вместо того чтобы изменять метаданные и формы объектов.
Задача #1.
В типовой конфигурации УТ ведется учет торговой деятельности нескольких юридических лиц холдинга. Юридические лица используют различные системы налогообложения – общую систему и УСН. Необходимо реализовать автоматическую установку флага УчитыватьНДС в документах в зависимости от выбранной фирмы.

Вариант #1. С использованием свойств объектов
Для решения задачи необходимо внести следующие изменения в модулях конфигурации:
В общем модуле «ЗаполнениеДокументов» в процедуре ЗаполнитьШапкуДокумента() добавить код:
УчитыватьНДС = Истина;
Если ОбщегоНазначения.ЕстьРеквизитДокумента("Организация", МетаданныеДокумента) Тогда

	СвойствоУчитыватьНДС = ПланыВидовХарактеристик.СвойстваОбъектов.НайтиПоНаименованию("УчитыватьНДС");
	Если не СвойствоУчитыватьНДС.Пустая() Тогда
		Отбор = Новый Структура;
		Отбор.Вставить("Объект", ДокументОбъект.Организация);
		Отбор.Вставить("Свойство", СвойствоУчитыватьНДС);
		УчитыватьНДС = РегистрыСведений.ЗначенияСвойствОбъектов.Получить(Отбор).Значение;
		УчитыватьНДС = ?(УчитыватьНДС = Неопределено, Истина, УчитыватьНДС);
	КонецЕсли;
КонецЕсли;


Изменить код:
ДокументОбъект.УчитыватьНДС     = Истина;

На код:
ДокументОбъект.УчитыватьНДС     = УчитыватьНДС; 


В общем модуле «ЗаполнениеДокументов» в процедуре ПриИзмененииЗначенияОрганизации() добавить код:
Если ОбщегоНазначения.ЕстьРеквизитДокумента("УчитыватьНДС", МетаданныеДокумента) Тогда
	СвойствоУчитыватьНДС = ПланыВидовХарактеристик.СвойстваОбъектов.НайтиПоНаименованию("УчитыватьНДС");
	Если не СвойствоУчитыватьНДС.Пустая() Тогда
		Отбор = Новый Структура;
		Отбор.Вставить("Объект", ДокументОбъект.Организация);
		Отбор.Вставить("Свойство", СвойствоУчитыватьНДС);
		УчитыватьНДС = РегистрыСведений.ЗначенияСвойствОбъектов.Получить(Отбор).Значение;
		Если (не УчитыватьНДС = Неопределено) и (не ДокументОбъект.УчитыватьНДС = УчитыватьНДС) Тогда
			ДокументОбъект.УчитыватьНДС = УчитыватьНДС;

			мКолонкиТовары	= ДокументОбъект.ПолучитьФорму().ЭлементыФормы.Товары.Колонки;
			мКолонкиУслуги	= ДокументОбъект.ПолучитьФорму().ЭлементыФормы.Услуги.Колонки;
			// Колонки налога показываем только тогда, когда его учитываем.
			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиТовары.СтавкаНДС, УчитыватьНДС);
			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиТовары.СуммаНДС, УчитыватьНДС);

			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиУслуги.СтавкаНДС, УчитыватьНДС);
			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиУслуги.СуммаНДС, УчитыватьНДС);
		КонецЕсли;
	КонецЕсли;
КонецЕсли;


После того, как в рабочую базу внесены изменения в плане видов характеристик «Свойства объектов» в группе «Справочник "Организации"» создадим новое свойство.
Наименование = «УчитыватьНДС»; Тип значения = Булево.
У элементов справочника «Организации» установим значение созданного свойства:
 
Вариант #2. С использованием категорий объектов
Для решения задачи необходимо внести следующие изменения в модулях конфигурации:
В общем модуле «ЗаполнениеДокументов» в процедуре ЗаполнитьШапкуДокумента() добавить код:
УчитыватьНДС = Истина;
Если  ОбщегоНазначения.ЕстьРеквизитДокумента("Организация", МетаданныеДокумента) Тогда
	КатегорияУчитыватьНДС = Справочники.КатегорииОбъектов.НайтиПоНаименованию("УчитыватьНДС");
	Если  не КатегорияУчитыватьНДС.Пустая() Тогда
		Запрос = Новый Запрос();
		Запрос.Текст = "
		|ВЫБРАТЬ РАЗЛИЧНЫЕ ПЕРВЫЕ 1
		|	РегистрСведений.КатегорииОбъектов.Категория КАК Категория
		|ИЗ
		|	РегистрСведений.КатегорииОбъектов
		|
		|ГДЕ
		|	РегистрСведений.КатегорииОбъектов.Категория = &Категория и
		|	РегистрСведений.КатегорииОбъектов.Объект = &Объект
		|";
		Запрос.УстановитьПараметр("Объект", ДокументОбъект.Организация);
		Запрос.УстановитьПараметр("Категория", КатегорияУчитыватьНДС);
		УчитыватьНДС = НЕ Запрос.Выполнить().Пустой();
	КонецЕсли;
КонецЕсли;

Изменить код:
ДокументОбъект.УчитыватьНДС     = Истина;
На код:
ДокументОбъект.УчитыватьНДС     = УчитыватьНДС; 
В общем модуле «ЗаполнениеДокументов» в процедуре ПриИзмененииЗначенияОрганизации() добавить код:
Если ОбщегоНазначения.ЕстьРеквизитДокумента("УчитыватьНДС", МетаданныеДокумента) Тогда
	КатегорияУчитыватьНДС = Справочники.КатегорииОбъектов.НайтиПоНаименованию("УчитыватьНДС");
	Если не КатегорияУчитыватьНДС.Пустая() Тогда
		Запрос = Новый Запрос();
		Запрос.Текст =  "
		|ВЫБРАТЬ РАЗЛИЧНЫЕ ПЕРВЫЕ 1 
		|	РегистрСведений.КатегорииОбъектов.Категория КАК Категория 
		|ИЗ 
		|	РегистрСведений.КатегорииОбъектов 
		|
		|ГДЕ 
		|	РегистрСведений.КатегорииОбъектов.Категория = &Категория и 
		|	РегистрСведений.КатегорииОбъектов.Объект = &Объект 
		|"; 
		Запрос.УстановитьПараметр("Объект", ДокументОбъект.Организация); 
		Запрос.УстановитьПараметр("Категория", КатегорияУчитыватьНДС); 
		УчитыватьНДС = НЕ Запрос.Выполнить().Пустой();  
		Если не ДокументОбъект.УчитыватьНДС = УчитыватьНДС Тогда 
			ДокументОбъект.УчитыватьНДС = УчитыватьНДС;  
			мКолонкиТовары = ДокументОбъект.ПолучитьФорму().ЭлементыФормы.Товары.Колонки; мКолонкиУслуги = ДокументОбъект.ПолучитьФорму().ЭлементыФормы.Услуги.Колонки; // Колонки налога показываем только Тогда, когда его учитываем.
			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиТовары.СтавкаНДС, УчитыватьНДС);
			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиТовары.СуммаНДС, УчитыватьНДС);
			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиУслуги.СтавкаНДС, УчитыватьНДС);
 			ОбработкаТабличныхЧастей.УстановитьВидимостьКолонкиТабЧасти(мКолонкиУслуги.СуммаНДС, УчитыватьНДС);
		КонецЕсли;
	КонецЕсли;
КонецЕсли;

Установим принадлежность организаций к категории:
4
Задача #2
Несколько организаций холдинга отгружают товар с разных складов. Склады принадлежат разным организациям холдинга. Организацию-владельца склада необходимо указывать в качестве грузоотправителя в документах ТОРГ-12 и счет-фактура. Для этого необходимо заполнять реквизит «Грузоотправитель» документа «РеализацияТоваровУслуг» при выборе склада.

Для решения задачи необходимо внести следующие изменения в модулях конфигурации:
В модуле формы документа «РеализацияТоваровУслуг», в процедуре СкладПриИзменении() добавить код:
СвойствоГрузоотправитель = ПланыВидовХарактеристик.СвойстваОбъектов.НайтиПоНаименованию("Грузоотправитель");
Если не СвойствоГрузоотправитель.Пустая() Тогда
	Отбор = Новый Структура;
	Отбор.Вставить("Объект", Склад);
	Отбор.Вставить("Свойство", СвойствоГрузоотправитель);
	ЗначениеСвойства = РегистрыСведений.ЗначенияСвойствОбъектов.Получить(Отбор).Значение;
	Если не ЗначениеСвойства = Неопределено Тогда
		Если не Грузоотправитель = ЗначениеСвойства Тогда
			Грузоотправитель = ЗначениеСвойства;
		КонецЕсли;
	КонецЕсли;
КонецЕсли;

В прцедуре ПриОткрытии() внутри условия Если ЭтоНовый() Тогда добавить код:
СкладПриИзменении(Неопределено); 

Аналогично первой задаче добавляем свойство «Грузоотправитель» справочнику «Склады».
139

См. также

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. brr 05.11.08 09:58 Сейчас в теме
Плюс, однозначно. Я примерно также использую свойства контрагентов и номенклатуры в клюшках.
2. fabrikant 06.11.08 05:11 Сейчас в теме
Имхо, такие вещи у нормального спеца отрабатываются спинным мозгом. Без подключения головы. Зачем данная статья? Непонятно.
3. luns 3 06.11.08 07:36 Сейчас в теме
(2) Не у всех к сожалению. Вещь действительно очевидная, но! Как изложено. Отличный методический материал для начинающих.
Продолжай Poppy
А то иногда лень очевидное расказывать начинающему, а так, носом в статью ткнул и красота.
Так что +
Михаська; DenisF8; +2 Ответить
4. coder1cv8 3441 06.11.08 09:50 Сейчас в теме
Хорошая статья для новичков.
5. PeRom 51 06.11.08 16:02 Сейчас в теме
+3 Тут и придраться некчему. Однозначно полезно. Ждём продолжения.
6. PeRom 51 06.11.08 16:09 Сейчас в теме
Были похожие вопросы на форуме, да и самому скоро придётся с разными организациями и складами разбираться, поможет, чтоб поменьше в типовой копаться.
Есть ещё задача: у одного заказчика по разным договорам разные адреса доставки. Могу выслать своё решение.
7. CheBurator 06.11.08 19:31 Сейчас в теме
> Плюс, однозначно. Я примерно также использую свойства контрагентов и номенклатуры в клюшках.
а то!
только многие почему-то не удосуживаются проверять/отрабатывать ветку когда своство отсутсвует как класс...
8. PointAnd 44 21.11.08 18:21 Сейчас в теме
А что здесь нового? Если конфа не снята с поддержки, то только таким способом и выкручиваются. Но здесь есть одно "НО" - если в базе работает около 30-40 пользователей, то с этим методом надо быть осторожнее, т.к. чем больше свойст вводишь в базу, тем больше возникает транзакций, а так же возникают ситуации с порчей СсылокНаОбъекты (ссылка одного объекта присваивается другому) в следствии чего идет недостоверная информация.
Все это взято не спотолка, а при работе с типовой УПП в течении года.
9. poppy 3348 24.11.08 01:07 Сейчас в теме
(8)
> А что здесь нового?

По сравнению с чем?

> Если конфа не снята с поддержки, то только таким способом и выкручиваются.

Я бы сказала по-другому. Таким способом выкручиваются для того, чтобы не снимать с поддержки.

> т.к. чем больше свойст вводишь в базу, тем больше возникает транзакций

О каких транзакциях идет речь?

> а так же возникают ситуации с порчей СсылокНаОбъекты

Причина порчи? Мною приведены примеры чтения свойств. Как чтение может испортить ссылки?

> Все это взято не спотолка, а при работе с типовой УПП в течении года.

Может поделишься своим опытом? А то складывается впечатление, что все это взято с потолка...
10. luns 3 24.11.08 07:24 Сейчас в теме
(8) У нас более 40 свойств использовано (УПП) проблем особых нет. Не удобно только в некоторых отчетах, что "служебные" своиства мешают, но это можно решить, например: http://infostart.ru/profile/10590/projects/1993/
Ценность этой статьи, не в том что она описывает что то новое, а в том что это сделано подробно и понятно. Насчет транзакций вообще непонятно.. что имется ввиду? Какие таблицы? А про порчу ссылок вообще ересь, свойства они только называются страшно )))))) на деле обычный регистр сведений да ПВХ..
11. v_id 94 24.12.08 11:11 Сейчас в теме
Спасибо!

1. Почему в первом примере не стали использовать Категории, и собственно...
2. Если не сложно дополните статью способами отбора по Категориям.
12. poppy 3348 05.01.09 17:52 Сейчас в теме
13. Hans 11.04.09 09:37 Сейчас в теме
Что то я не понял... Как не снимать с поддержки если общий модуль изменен?
14. poppy 3348 13.04.09 00:05 Сейчас в теме
(13) Ты, Hans, о чем? В статье описан способ не изменять общий модуль.

По твоему вопросу смотри мои комментарии здесь http://infostart.ru/blogs/892/
15. Hans 29.04.09 11:21 Сейчас в теме
а я что то попутал... Плохо прочитал... Подумал что в статье писывается решение без изменения конфы ваще... а тут только без изменения метаданных и форм.
16. NickKom 25.08.09 20:53 Сейчас в теме
Да, предлагаемая методика может быть полезна во многих случаях. Но как быть в ситуации, когда нужно использовать свойства документа?
Например, после проведения документа необходимо установить некий признак в одно из нескольких фиксированных значений. Установленный признак - свойство именно текущего документа. Но это второстепенный признак, в регистрах не прописан, и из-за него перепроводить документ не стоит. Напрашивается использование свойства документа. Но типовая конфигурация УТ этого не позволяет. Как быть?
17. poppy 3348 26.08.09 20:03 Сейчас в теме
(16) В типовой УТ10.3 свойства у документов есть.
18. NickKom 26.08.09 20:45 Сейчас в теме
(17) Действительно, есть. Поторопился, не разобрался.
Спасибо.
19. artbear 1143 12.02.10 15:07 Сейчас в теме
(17) В своей публикации http://www.infostart.ru/public/65526/
сослался на некоторые Ваши работы, т.к. сам использую практически те же самые технологии :)
23. poppy 3348 18.02.10 11:59 Сейчас в теме
(19) Спасибо, artbear! Для меня важно твое мнение.
20. bulpi 155 17.02.10 17:05 Сейчас в теме
И фсе это только для того, чтобы не добавить один реквизит в метаданные ??? А потом долбаться с выводом в отчеты информации по условию, накладываемому на свойство... Да ну вас, окститесь.
Михаська; Tciban; krosaf4eg; +3 Ответить
22. poppy 3348 18.02.10 11:55 Сейчас в теме
(20) Не надо все возводить в абсолют. Многие отчеты типовых конфигураций поддерживают механизм свойств.
Как говорится - кто на что учился. Проще добавить реквизит? Добавляй. Это твое решение, как архитектора ИС.

(21) Спасибо, что обратил внимание...
21. anig99 2685 17.02.10 20:39 Сейчас в теме
есть свои плюсы и минусы у способа... у статьи тоже... в результате пока "0"
24. anig99 2685 18.02.10 14:42 Сейчас в теме
хотя за подробность описания поставлю +
25. rasswet 82 28.02.10 18:05 Сейчас в теме
нужно это обдумать..может и пригодится.. :)
26. Alexey55 16.09.11 12:38 Сейчас в теме
27. infosoft-v 13.10.11 10:16 Сейчас в теме
Здравствуйте.
Полезная статья для тех кто осваивает возможности 1С. Это знание - кирпичик в копилку профессионала.
Я попробовал применить эту идею в 1С Бухгалтерия для регистрации менеджера который сделал продажу в документе реализации. Окончательно задачу реализовал по другому, но возможность работать со свойствами заняло своё место в копилке.
28. alenakrr 28.10.11 15:42 Сейчас в теме
если создать непериодический регистр сведений "ТекущиеКонстанты" и добавить в него все используемые свойства, то не придется писать в модуле "НайтиПоНаименованию" и обеспечит однозначность использования))
ogorana21; heavymetal; +2 Ответить
30. dyak84 04.04.13 12:25 Сейчас в теме
Спасибо очень полезно и познавательно.Про такую возможность работать со свойствами даже не догадивался. Так держать
31. sns-bizon 07.04.13 09:12 Сейчас в теме
Оставьте свое сообщение