Полезные процедуры по работе с СКД и динамическими списками (часть 4)

17.12.18

Разработка - СКД

Несколько библиотечных процедур по работе с отборами.

Все мы уже давно привыкли к отборам в отчетах на СКД и динамических списках. 

Иногда хочется что-то подобное иметь в обработке, например, для подбора склада. 

То есть поместить на форму поле, в которое пользователь мог бы выбрать конкретный элемент, или все элементы из группы, или все элементы из нескольких групп, не помеченных на удаление. В общем, стандартный функционал отбора.

 

Самый простой вариант реализации такой идеи следующий: нужно добавить реквизит с типом ДинамическийСписок по нужной нам таблице, например, по справочнику Склады. При этом сам список на форму помещать не обязательно, достаточно просто вывести отбор этого списка. 

 

Получить все элементы, соответствующие отбору также довольно просто, например, так:

&НаКлиенте
Процедура Сформировать(Команда)
	
	МассивВыбранныхСкладов = ПолучитьСсылкиПоОтбору(СписокСклады.Отбор, "Справочник.Склады");
	
КонецПроцедуры
 Исходный код
Функция ПолучитьСсылкиПоОтбору(знач Отбор, ПолноеИмяМетаданных)
    
    Схема = Новый СхемаКомпоновкиДанных;
    ИсточникДанных = Схема.ИсточникиДанных.Добавить();
    ИсточникДанных.Имя = "ИсточникДанных";
    ИсточникДанных.ТипИсточникаДанных = "Local";
    
    НаборДанных = Схема.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
    НаборДанных.Имя = "НаборДанных1";
    НаборДанных.Запрос = "ВЫБРАТЬ * ИЗ " + ПолноеИмяМетаданных;
    НаборДанных.ИсточникДанных = "ИсточникДанных";
    НаборДанных.АвтоЗаполнениеДоступныхПолей = Истина;
    
    ИмяПоля = "Ссылка";
    ПолеНабора = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
    ПолеНабора.Поле = ИмяПоля;
    ПолеНабора.ПутьКДанным = ИмяПоля;
    
    ГруппировкаДанных = Схема.НастройкиПоУмолчанию.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));

    ПолеГруппировки = ГруппировкаДанных.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
    ПолеГруппировки.Использование = Истина;
    ПолеГруппировки.Поле = Новый ПолеКомпоновкиДанных(ИмяПоля);

    ВыбранноеПоле = ГруппировкаДанных.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
    ВыбранноеПоле.Использование = Истина;
    
    СкопироватьЭлементКомпоновкиДанных(Отбор, Схема.НастройкиПоУмолчанию.Отбор); // эта процедура была описана в предыдущей публикации
    
    ТаблицаИзСКД = Новый ТаблицаЗначений;
    
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    МакетКомпоновки = КомпоновщикМакета.Выполнить(Схема, Схема.НастройкиПоУмолчанию,,,
                Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
    
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);
    
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
    ПроцессорВывода.УстановитьОбъект(ТаблицаИзСКД);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);
    
    Возврат ТаблицаИзСКД.ВыгрузитьКолонку(0);
    
КонецФункции

 


Вместо "фиктивного" динамического списка можно использовать компоновщик настроек.

 

 

Компоновщик нужно будет инициализировать, например так:

&НаСервере
Процедура ПриСозданииНаСервере()
	
	КомпоновщикОтборСклады.Инициализировать(ИсточникДоступныхНастроек("Справочник.Склады"));
	
КонецПроцедуры

Получение элементов по отбору компоновщика аналогично получению из динамического списка

&НаКлиенте
Процедура Сформировать(Команда)
	
	МассивВыбранныхСкладов = ПолучитьСсылкиПоОтбору(КомпоновщикОтборСклады.Настройки.Отбор, "Справочник.Склады");
	
КонецПроцедуры
 Исходный код
&НаСервереБезКонтекста
Функция ИсточникДоступныхНастроек(ПолноеИмяМетаданных)
	
    Схема = Новый СхемаКомпоновкиДанных;
    ИсточникДанных = Схема.ИсточникиДанных.Добавить();
    ИсточникДанных.Имя = "ИсточникДанных";
    ИсточникДанных.ТипИсточникаДанных = "Local";
	
    НаборДанных = Схема.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
    НаборДанных.Имя = "НаборДанных1";
    НаборДанных.Запрос = "ВЫБРАТЬ * ИЗ " + ПолноеИмяМетаданных;
    НаборДанных.ИсточникДанных = "ИсточникДанных";
    НаборДанных.АвтоЗаполнениеДоступныхПолей = Истина;
	
    АдресВременногоХранилищаСхемы = ПоместитьВоВременноеХранилище(Схема, Новый УникальныйИдентификатор);
	
    Возврат Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресВременногоХранилищаСхемы);

КонецФункции

 

Описанные приемы работают для управляемых форм на платформе 8.3 в режиме совместимости с 8.2.13 и выше.

 

Всем добра, приятного кода и красивых идей!

Отбор СКД динамический список процедура функция библиотека бсп уф управляемые

См. также

SALE! 20%

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

13000 10400 руб.

02.09.2020    121574    670    389    

710

Генератор схемы компоновки данных (СКД), написание кода схемы программно

Инструментарий разработчика СКД Платформа 1С v8.3 Конфигурации 1cv8 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    4025    25    obmailok    17    

63

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    2000    2    Yashazz    0    

29

СКД на JavaScript в 1С

СКД WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    8150    20    John_d    25    

123

Использование менеджера временных таблиц в СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    4645    PROSTO-1C    13    

61

Модель СКД

Инструментарий разработчика СКД Платформа 1С v8.3 Система компоновки данных Абонемент ($m)

DSL для работы с СКД.

1 стартмани

15.11.2023    5802    15    kalyaka    5    

86

Пользовательские настройки отчетов 1С. Часть 1. Простые и расширенные настройки

СКД Инструкции пользователю Платформа 1С v8.3 Конфигурации 1cv8 1С:Бухгалтерия 3.0 Россия Бесплатно (free)

Простые приемы работы с отчетами на СКД. Что нужно знать пользователю про настройку отчетов, чтобы использовать их на полную катушку.

18.09.2023    6685    accounting_cons    5    

29

Разрыв страницы в СКД. Легко!

СКД Платформа 1С v8.3 Система компоновки данных Бесплатно (free)

Когда отчет надо разделить по страницам, это всегда проблема для разработчика. Поскольку в СКД нет стандартных вариантов, как это сделать. Нашел (на свой взгляд) самое простое и оптимальное решение.

01.09.2023    4515    KVIKS    15    

80
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. ixijixi 1775 17.12.18 20:15 Сейчас в теме
А зачем схему помещать во временное хранилище? Нельзя сразу
Возврат Новый ИсточникДоступныхНастроекКомпоновкиДанных(Схема)
? Должно сработать по идее. Или есть какие-то рекомендации?
2. json 3297 17.12.18 20:42 Сейчас в теме
(1) ну если смотреть по справке, то должно сработать. Но на практике ошибок не выдает, но список полей в отборе - пустой.
Вот тестовая обработка, можете поиграться
Прикрепленные файлы:
Пример поля с отбором.epf
4. ixijixi 1775 18.12.18 08:49 Сейчас в теме
(2) Да, реально пустой. Спасибо!
3. ediks 335 17.12.18 22:09 Сейчас в теме
(1) Помещать схему во временное хранилище - единственный (мне, по крайней мере) известный способ получить настройки СКД в обработке. Некоторое время назад столкнулся с этой проблемой и нагуглил такое решение.
5. ixijixi 1775 14.08.19 15:35 Сейчас в теме
(0) Возвращаясь к статье. А можно как-то поле отбора впихнуть в поле таблицы формы? У меня в поле формы доступные поля заполняются, а в поле таблицы - нет
Прикрепленные файлы:
Пример поля с отбором.epf
6. json 3297 14.08.19 15:43 Сейчас в теме
7. ixijixi 1775 14.08.19 15:47 Сейчас в теме
(6) Не совсем то. Мне нужно в существующую таблицу формы (не компоновщик) добавить строку с типом значения ОтборКомпоновкиДанных
8. json 3297 14.08.19 15:54 Сейчас в теме
(7) тогда сделай так:
1. создай компоновщик, как у меня в примере
2. при активизации строки - копируй отбор из текущей строки в компоновщик
3. изменение нужно завязать на этот компоновщик

как-то так.

А так у тебя похоже открывается отбор без привязки к компоновщику. А привязка к компоновщику нужна, чтобы оттуда подтянуть доступные поля
9. ixijixi 1775 14.08.19 16:17 Сейчас в теме
(8)
при активизации строки - копируй отбор из текущей строки в компоновщик

У меня сделано копирование при добавлении строки.
Попробую к активизации привязаться, без особой надежды, впрочем))
10. ixijixi 1775 14.08.19 16:40 Сейчас в теме
(8) Похоже, что то, что я задумал - невозможно.

Отбор на форме завязан на Компоновщик (Компоновщик.Настройки.Отбор), доступные поля компоновки автозаполняются при инициализации Компоновщика.
В таблице же отбор не привязан ни к какому компоновщику, это тупо поле типа ОтборКомпоновкиДанных, поэтому и доступные поля компоновки и не заполняются и не копируются в него.

Похоже, что так
11. Yashazz 4709 28.06.21 17:29 Сейчас в теме
(10) Ну почему же. Программно можно состряпать СКД, или перехватить используемую в дин.списке, допилить в коде и скормить в инициализацию компоновщику.
12. ixijixi 1775 29.06.21 08:52 Сейчас в теме
(11) Да, в итоге так и сделал)
Оставьте свое сообщение