Для примера делаю запрос к остаткам и выбираю реквизит "ФайлКартинка" справочника Номенклатура.
У реквизита тип СправочникСсылка.НоменклатураПрисоединенныеФайлы (механизм БСП)
В предприятии у элемента справочника номенклатура добавлена картинка
В СКД поле "картинка" добавляю в группировку
В модуле отчета в Процедура ПриКомпоновкеРезультата
-программно формирую отчет и обрабатываю РасшифровкуКомпоновкиДанных.
-ищу в расшифровке поле с картинкой.
-получаю двоичные данные (я воспользовался фунцией БСП) РаботаСФайлами.ДвоичныеДанныеФайла(ФайлКартинки.Значение), если у вас не БСП, то просто получите из реквизита с типом ХранилищеЗначения двоичные данные.
-помещаю картину в табличный документ
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
НастройкиСКД = КомпоновщикНастроек.ПолучитьНастройки();
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
Макет = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиСКД, ДанныеРасшифровки);
ПроцессорКомпоновкиСКД = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиСКД.Инициализировать(Макет,, ДанныеРасшифровки);
ДокументРезультат.Очистить();
ПроцессорВыводаСКД = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВыводаСКД.УстановитьДокумент(ДокументРезультат);
ПроцессорВыводаСКД.Вывести(ПроцессорКомпоновкиСКД);
КолвоСтрок = ДокументРезультат.ВысотаТаблицы;
КолвоКолонок = ДокументРезультат.ШиринаТаблицы;
Для Строка = 1 По КолвоСтрок Цикл
Для Колонка = 1 По КолвоКолонок Цикл
Область = ДокументРезультат.Область(Строка,Колонка);
Расшифровка = Область.Расшифровка;
Если ТипЗнч(Расшифровка) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда
ПоляРасшифровки = ДанныеРасшифровки.Элементы.Получить(Расшифровка).ПолучитьПоля();
ФайлКартинки = ПоляРасшифровки.Найти("Картинка");
Если ФайлКартинки <> Неопределено Тогда
КартинкаДД = РаботаСФайлами.ДвоичныеДанныеФайла(ФайлКартинки.Значение);
Картинка = Новый Картинка(КартинкаДД);
КартинкаДок = ДокументРезультат.Рисунки.Добавить(ТипРисункаТабличногоДокумента.Картинка);
КартинкаДок.Картинка = Картинка;
КартинкаДок.РазмерКартинки = РазмерКартинки.АвтоРазмер;
КартинкаДок.Расположить(Область);
КонецЕсли;
КонецЕсли;
КонецЦикла;
КонецЦикла;
КонецПроцедуры
В результате получаю в группировке картинку.
Тестировал: 1С:Комплексная автоматизация 2 (2.4.9.98)
1С:Предприятие 8.3 (8.3.15.1747)
