Открываем свою лавку на платформе VK Market

Если вы не слышали ранее об Открытом Пакете Интеграций (что вполне вероятно), то небольшая вводная часть ниже, под катом. Для тех, кто уже знаком с ОПИ, данный раздел можно пропустить.

Я думаю, ВКонтакте в представлении не нуждается - это одна из самых популярных социальных сетей в России и странах СНГ. Однако не все знают, что помимо возможности создавать развлекательный контент, в ВК также предусмотрен серьезный функционал для организации продаж и продвижения своих товаров и услуг, который буквально позволяет превратить группу в интерактивную витрину собственного онлайн магазина.

Вот, для примера, просто первый попавшийся магазин с прикольными керамическими изделиями:

Таких магазинов на просторах ВК целая куча. Все подобные товары и витрины объединены в общую систему маркета: любой пользователь может нажать на кнопку в главном меню сайта и на странице торговой площадки будут подобраны интересные для него товары

Это, на самом деле, интересная и глубокая система.

Во-первых, интернет маркетинг - направление не новое, но при работе с маркетом продвижение через группы позволяет не только делится новостями магазина с заинтересованными подписчиками, но и конкретно выводить товары пользователю в том месте, где он захочет на них посмотреть - на специальной странице, куда заходят как раз лишь для того, чтобы что-нибудь прикупить.

Во-вторых, как бы сомнительно и пугающе это не звучало, ВК имеет кучу информации о каждом своем пользователе, что позволяет ему собирать более точные персональные подборки товаров. А это, в свою очередь - серьезное увеличение шансов для вашего товара быть замеченным потенциальным покупателем. 

Ну и еще можно отметить наличие смежных сервисов: VK Pay для приема оплаты, Ads для продвижения своего магазина через рекламу или банально система сообщений, которая позволяет общаться с клиентами. 

Ну и что?

Это все, конечно, не стоило бы того, чтобы здесь сегодня собраться, однако как и у практически любого другого механизма ВКонтакте, у маркета есть свой API. Мысль о возможности выгружать товары из справочника Номенклатуры и регистра Свободных остатков в группу ВК не давала мне покоя. Поэтому я добавил методы этого API в библиотеку работы с ВК Открытого Пакета Интеграций.

Вот что я успел реализовать к текущему обновлению:

• Методы работы с товарами
  • Получить список категорий товаров
  • Получить список товаров группы
  • Получить товары по ID
  • Добавить товар
  • Изменить товар
  • Удалить товар
  • Сгруппировать товары
• Методы работы с подборками товаров
  • Получить список подборок
  • Получить подборки по ID
  • Добавить подборку
  • Удалить товар из подборки
  • Удалить подборку
• Работа со свойствами товаров
  • Получить список свойств
  • Создать универсальное свойство товара
  • Изменить универсальное свойство товара
  • Удалить универсальное свойство товара
  • Создать вариант значения свойства
  • Изменить вариант значения свойства
  • Удалить вариант значения свойства
     

Ну а сейчас мы создадим свою небольшую лавку и посмотрим, как это все работает изнутри.

Автоматизируем продажу пирожков

Тематика нашей лавки - пекарня. При помощи нейросети и небольшой ловкости рук я создал пафосный мега бренд своего будущего заведения

Называется он BARX RIXY, так как эту, на удивление приятную уху, билиберду Midjourney написал на нижней ленте, когда я попросил его сделать эмблему. Но пока это просто группа. Для превращения ее в магазин нам необходимо включить данный функционал в настройках



Выбираем Расширенные товары. Также можно нажать Показать настройки и, собственно, настроить под себя еще некоторые моменты

Теперь можно добавлять на витрину нашу продукцию. Так как это не дебют библиотеки для работы с ВК, я не буду здесь подробно разбирать начало работы с API - инструкцию по получению необходимых данных вы можете найти в документации. Скажу лишь, что буквально недавно ВКонтакте обновили процедуру создания приложения для получения токена - она стала сложнее. Однако, если вы всерьез намерены заниматься продажами через маркет, то никаких смертельных препятствий в этом процессе вы не встретите.

Если далее в листингах кода вы видите ПараметрыВК - то это как раз  та структура с токеном, ID приложения и прочими данными, необходимыми для работы с любыми методами библиотеки ВК.

 

Подборки товаров

Прежде чем добавлять товар, удобнее будет определится с группами, в которые мы их будем объединять. Раз уж у нас пекарня, то я создам 3 подборки: пироги, булочки и хлеб. 

Выполним следующий код:
 

	ПараметрыВК          = ПолучитьПараметрыВК();
	СоответствиеПодборок = Новый Соответствие;
	СоответствиеСоздания = Новый Соответствие;
	
	СоответствиеСоздания.Вставить("Пироги" , "C:/pie.png");
	СоответствиеСоздания.Вставить("Булочки", "C:/small_pie.png");
	СоответствиеСоздания.Вставить("Хлеб"   , "C:/bread.png");
	
	Для Каждого Подборка Из СоответствиеСоздания Цикл
		
		Результат = OPI_VK.СоздатьПодборкуТоваров(Подборка.Ключ, Подборка.Значение, , , ПараметрыВК);
		СоответствиеПодборок.Вставить(Подборка.Ключ, Результат["response"]["market_album_id"]);
		
	КонецЦикла;

Он не сложный, но некоторые моменты требуют объяснения:

• При создании подборок я использую пути к файлам png картинок, однако функция создания (как и все остальные функции, принимающие в качестве параметров файлы) может принимать и двоичные данные точно так же. Просто мне, в данном случае, было удобнее использовать файлы на диске.
• При вызове СоздатьПодборкуТоваров я пропускаю два параметра - это булево Главная и булево Скрытая. Оба по умолчанию - Ложь и оба нам пока не нужны.

В итоге у нас появилось три группы. Они пока не видны пользователям, так как нет ни одного товара, но мы можем посмотреть их в меню управления магазином.

В финале нашей функции мы заполняем соответствие подборок. Там теперь находятся имя подборки и ID, возвращенное от ВК. Последнее мы будем использовать для добавления туда товаров.

Создаем товары

Теперь нам нужно добавить непосредственно продукцию пекарни, для чего необходимо её описать. Так как всевозможных полей свойств товаров очень много, внутри библиотеки они описываются как соответствие, состав полей (макет) которого можно найти в функции ПолучитьОписаниеТовара()

    Товар = Новый Соответствие();
    Товар.Вставить("Имя"                , "Новый товар");     // Имя товара
    Товар.Вставить("Описание"           , "Описание товара"); // Описание товара
    Товар.Вставить("Категория"          , "20173");           // См ПолучитьСписокКатегорийТоваров()
    Товар.Вставить("Цена"               , 1);                 // Цена.
    Товар.Вставить("СтараяЦена"         , Неопределено);      // Для отражения изменения цены 
    Товар.Вставить("ОсновноеФото"       , Неопределено);      // ДД или путь к осн. фото
    Товар.Вставить("URL"                , Неопределено);      // Ссылка на страницу магазина
    Товар.Вставить("ДополнительныеФото" , Новый Массив);      // Массив путей или ДД для доп. фото
    Товар.Вставить("ЗначенияСвойств"    , Новый Массив);      // Значения свойств (варианты). Максимум 2
    Товар.Вставить("ГлавныйВГруппе"     , Ложь);              // Сделать главным в своей группе  
    Товар.Вставить("Ширина"             , Неопределено);      // В миллиметрах
    Товар.Вставить("Высота"             , Неопределено);      // В миллиметрах
    Товар.Вставить("Глубина"            , Неопределено);      // В миллиметрах
    Товар.Вставить("Вес"                , Неопределено);      // В граммах
    Товар.Вставить("SKU"                , Неопределено);      // Артикул
    Товар.Вставить("ДоступныйОстаток"   , 1);

Добавим в каталог продукции нашей пекарни пирожки с капустой

    ПараметрыВК = ПолучитьПараметрыВК();
	
    ИДПодборки = СоответствиеПодборок["Булочки"];
    МассивФото = Новый Массив;
    МассивФото.Добавить("C:/Пекарня/Пирожок с капустой (доп 1).jpg");
    МассивФото.Добавить("C:/Пекарня/Пирожок с капустой (доп 2).jpg");
	
    Товар = Новый Соответствие();
    Товар.Вставить("Имя"                , "Пирожок с капустой");
    Товар.Вставить("Описание"           , "Очень вкусный пирожок с капустой никого не оставит равнодушными. Настоящий вкус детства");
    Товар.Вставить("Категория"          , "20063");           
    Товар.Вставить("Цена"               , 60);                
    Товар.Вставить("СтараяЦена"         , 70);     
    Товар.Вставить("ОсновноеФото"       , "C:/Пекарня/Пирожки с капустой.jpg");     
    Товар.Вставить("URL"                , "https://vk.com/barxrixy");     
    Товар.Вставить("ДополнительныеФото" , МассивФото);     
    Товар.Вставить("ЗначенияСвойств"    , Неопределено);     
    Товар.Вставить("ГлавныйВГруппе"     , Истина);             
    Товар.Вставить("Ширина"             , 30);     
    Товар.Вставить("Высота"             , 20);     
    Товар.Вставить("Глубина"            , 10);     
    Товар.Вставить("Вес"                , 120);     
    Товар.Вставить("SKU"                , "123123");     
    Товар.Вставить("ДоступныйОстаток"   , 100);

    Результат = OPI_VK.ДобавитьТовар(Товар, ИДПодборки, ПараметрыВК); 
    ИДТовара  = Результат["response"]["market_item_id"];

Рассмотрим теперь эту функцию

• Вместо путей к файлу, как и в предыдущем примере, можно использовать двоичные данные
• В поле категория указывается номер раздела товаров ВК, который можно получить при помощи функции ПолучитьСписокКатегорийТоваров(). Также полный список текстом есть в документации на странице описания этой самой функции получения списка категорий.
• В конце мы получаем ID товара. В последствии его можно использовать для изменения данных (Функция ИзменитьТовар) или удаления товара (Функция УдалитьТовар) 
• Мы добавляем товар в подборку, передавая ее ID прямо в функцию создания - это сделано для упрощения работы с библиотекой. Однако, вы также всегда можете добавить товар в подборку отдельно специальной функцией ДобавитьТоварВПодборку

Теперь наши пирожки отображаются на главной странице группы

Вот так выглядит их страница. Не все данные, которые мы отправили, здесь видны - некоторые из них предназначены больше для служебного пользования: определения доступности по наличию остатка или расчета доставки по весу и габаритам.

Добавился он и в нашу подборку булочек

Объединение товаров

Последнее, что я хотел бы сегодня показать - группировка по свойствам. Часто бывает так, что несколько предметов - это вариации одного и того же товара, но с какой-то особенностью. Например, разного цвета или разного объема. Для таких случаев существуют свойства. Сейчас мы создадим дав товара - два пирога с ягодами, но ягоды в них будут разные.

    ИДПодборки              = СоотвтествиеПодборок["Пироги"];
    ПараметрыВК             = ПолучитьПараметрыВК();	
    СоответствиеВариантов   = Новый Соответствие;
	
    Результат = OPI_VK.СоздатьСвойствоТовара("Ягоды", ПараметрыВК);                       //Создаем свойство
    Свойство  = Результат["response"]["property_id"];
	
    МассивВариантов = Новый Массив;
    МассивВариантов.Добавить("Брусника");
    МассивВариантов.Добавить("Малина");
	
    Для Каждого Вариант Из МассивВариантов Цикл
        
        Результат = OPI_VK.ДобавитьВариантСвойстваТовара(Вариант, Свойство, ПараметрыВК); //Добавляем варианты свойств
        СоответствиеВариантов.Вставить(Вариант, Результат["response"]["variant_id"]);
		
    КонецЦикла;
	
    Товар = Новый Соответствие();
    Товар.Вставить("Имя"                , "Пироог с ягодами (брусника)");
    Товар.Вставить("Описание"           , "Вкусный ягодный прирог");
    Товар.Вставить("Категория"          , "20063");           
    Товар.Вставить("Цена"               , 400);                
    Товар.Вставить("СтараяЦена"         , 410);     
    Товар.Вставить("ОсновноеФото"       , "C:/Пекарня/Пирог с ягодами.jpg");     
    Товар.Вставить("URL"                , "https://vk.com/barxrixy");     
    Товар.Вставить("ДополнительныеФото" , Неопределено);     
    Товар.Вставить("ЗначенияСвойств"    , СоответствиеВариантов["Брусника"]);     
    Товар.Вставить("ГлавныйВГруппе"     , Ложь);                 
    Товар.Вставить("SKU"                , "123124");     
    Товар.Вставить("ДоступныйОстаток"   , 100);

    Результат      = OPI_VK.ДобавитьТовар(Товар, ИДПодборки, ПараметрыВК);              //Добавляем пирог с брусникой
    ИДБрусничного  = Результат["response"]["market_item_id"];
	
    Товар.Вставить("Имя"            , "Пироог с ягодами (малина)");                     //Меняем бруснику на малину
    Товар.Вставить("ЗначенияСвойств", СоответствиеВариантов["Малина"]);
    Товар.Вставить("SKU"            , "123125"); 
    Товар.Вставить("ОсновноеФото"   , "C:/Пекарня/Пирог с ягодами 2.jpg");
	
    Результат    = OPI_VK.ДобавитьТовар(Товар, ИДПодборки, ПараметрыВК);                //Добавляем пирог с малиной
    ИДМалинового = Результат["response"]["market_item_id"];
	
    МассивТоваров = Новый Массив;
    МассивТоваров.Добавить(ИДБрусничного);
    МассивТоваров.Добавить(ИДМалинового);
	
    Результат = OPI_VK.СгруппироватьТовары(МассивТоваров, , ПараметрыВК);
    ИДГруппы  = Результат["response"]["item_group_id"];

В список товаров у нас добавился только 1 пирог

Но если мы зайдем на его страничку, то увидим там выпадающий список с выбором типа ягод

В заключение

Вот такой вот небольшой онлайн магазин на базе сообщества ВК у нас получился. Его несомненным преимуществом является интегрированность в общую экосистему социальной сети: создавая витрину с товарами мы все так же оставляем за собой возможность делать посты в группе - рекламные или просто развлекательные для поднятия интереса аудитории, создавать обсуждения, добавлять разделы, публиковать истории, собирать комментарии и многое многое другое. Когда-то у меня, например, была статья, где в рамках проекта онлайн библиотеки на 1С раз в период формировались рекламные посты. Это достаточно эффективный способ продвижения своих товаров и хорошая бюджетная альтернатива сайту, которая, по итогу, может оказаться даже более успешной. Особенно если автоматизировать все из 1С ;)

P.S. информация о заказах может приходить в диалоги сообщества или в раздел заказов. Возможно когда-нибудь я расскажу, как и их можно обрабатывать из 1С. 

Спасибо за внимание!

Репозиторий ОПИ: github.com/Bayselonarrend/OpenIntegrations

Последний релиз: github.com/Bayselonarrend/OpenIntegrations/releases/latest

Другие статьи про Открытый пакет интеграций на Инфостарт:

• Открытый пакет интеграций для популярных API: Telegram, VK, Viber, Twitter

• Работа с Notion API | Обновление Открытого пакета интеграций

• Библиотека работы с Яндекс Диском (Open-source) 

• Открываем свою лавку на платформе VK Market

• Библиотека для работы с Google Calendar API (open-source) 

• Telegram в режиме форума: делаем чаты комфортными

• Открытый пакет интеграций для OneScript

• Библиотека для работы с Google Drive API (open-source)

• OInt CLI - приложение Открытого пакета интеграций для командной строки

 

 Мой GitHub:     https://gitub.com/Bayselonarrend 
 Лицензия MIT:   https://mit-license.org