С появлением новых статей в разделе практики программирования, появились шаблонные решения некоторых задач, которые ранее решались в обычном приложении за несколько строчек кода.
При использовании БСП жизнь улучшается.
Версия БСП на которой тестировалось: 2.4.2.124.
Диалог выбора файла
Если читать документацию то можно сократить свой простор для творчества и пользоваться достаточно гибкими и универсальными инструментами, такими как БСП.
Тогда не придется писать процедуры и функции выбора для одного или для нескольких файлов.
&НаКлиенте
Процедура ВыбратьИПрочитатьФайл(Команда)
Обработчик = Новый ОписаниеОповещения("ВыбратьИПрочитатьФайлПослеВыбораФайла", ЭтотОбъект);
ПараметрыДиалога = Новый Структура("Режим, Фильтр, ИндексФильтра, Заголовок");
ПараметрыДиалога.Режим = РежимДиалогаВыбораФайла.Открытие;
ПараметрыДиалога.Фильтр = НСтр("ru = 'Файлы TXT (*.txt)|*.txt|Все файлы (*.*)|*'");
ПараметрыДиалога.ИндексФильтра = 0;
ПараметрыДиалога.Заголовок = НСтр("ru = 'Выберите файл который будем отправлять на сервер'");
СтандартныеПодсистемыКлиент.ПоказатьПомещениеФайла(Обработчик, УникальныйИдентификатор, "", ПараметрыДиалога);
КонецПроцедуры
В этой процедуре все просто - показывается диалог выбора описанного файла и файл помещается во временное хранилище.
Загрузка файлов с клиента на сервер
Остается получить файл на сервере по адресу хранилища и обработать его.
&НаКлиенте
Процедура ВыбратьИПрочитатьФайлПослеВыбораФайла(ПомещенныеФайлы, ПустойПараметр) Экспорт
Если ПомещенныеФайлы = Неопределено Или ПомещенныеФайлы.Количество() = 0 Тогда
Возврат;
КонецЕсли;
Для Каждого ПомещенныйФайл Из ПомещенныеФайлы Цикл
ПрочитатьФайлаНаСервере(ПомещенныйФайл.Хранение);
КонецЦикла;
КонецПроцедуры
&НаСервере
Процедура ПрочитатьФайлаНаСервере(АдресФайла)
ПолноеИмяФайла = ПолучитьИмяВременногоФайла("txt");
ДвоичныеДанные = ПолучитьИзВременногоХранилища(АдресФайла);
ДвоичныеДанные.Записать(ПолноеИмяФайла);
ТекстДокумент = Новый ТекстовыйДокумент;
ТекстДокумент.Прочитать(ПолноеИмяФайла);
Текст = ТекстДокумент.ПолучитьТекст();
УдалитьФайлы(ПолноеИмяФайла);
ШаблонТекста = НСтр("ru = '%1%2%3'");
ТекстФайла = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ШаблонТекста, ТекстФайла, Символы.ПС, Текст);
КонецПроцедуры