gifts2017

Добавление команд печати в свои документы в Бухгалтерии 3.0

Опубликовал nick-max nick-max (nick-max) в раздел Программирование - Практика программирования

Данная публикация может быть вам полезна, если вы хотите сделать своим нетиповым документам в Бухгалтерии 3.0 универсализированную печать (не затрагивая типовые объекты). Эта статья подойдет для любой конфигурации на основе БСП, так как использует возможности ее подсистемы "Печать"

В Бухгалтерии 2.0 была очень удобная типовая процедура

УниверсальныеМеханизмы.НапечататьДокумент(ТабДокумент, КоличествоЭкземпляров, НаПринтер,
					  Заголовок, НепосредственнаяПечать, Ссылка, ИмяМакета) 

Она помогала вывести ваш печатный документ в универсальное окно печати, где вы выбирали количество копий, вариант сохранения и тому подобное

Сейчас, переходя с 2.0 на 3.0, я стал искать аналог этой процедуры и не нашел. Но это к лучшему, потому что я нашел еще более универсальный механизм. Он опирается на механизмы подсистемы "Печать" БСП (БСП - это основа всех современных конфигураций фирмы 1С). Нужно добавить несколько функций в два модуля: Модуль менеджера и Модуль формы. Пусть у нас есть нетиповой документ Приказ, и у него есть два макета и две формы. 

Для каждого из двух макетов у нас подготовлены функции СформироватьАкт(Ссылка) и СформироватьПриказ(Ссылка), возвращающие табличные документы, которые нам нужно будет красиво выводить на печать. Хочется, не прилагая больших усилий, добиться следующего результата: чтобы в каждой из двух форм этого документа в командной панели была кнопка-подменю Печать, в которой был бы список из наших печатных форм.

     

Откроем форму ФормаДокумента, и создадим обработчик ПриСозданииНаСервере. Скопируем в модуль формы следующий код:

&НаСервере 
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
		
	УправлениеПечатью.ПриСозданииНаСервере(ЭтаФорма)	
	
КонецПроцедуры 

&НаКлиенте 
Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)
	
	УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтаФорма, Объект)
	
КонецПроцедуры  

 

Теперь откроем Модуль менеджера и скопируем туда следующий код:

Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт 

	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "Акт";
	КомандаПечати.Представление = "Дополнительный акт";
	КомандаПечати.Обработчик    = "УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати";
	КомандаПечати.СписокФорм    = "ФормаСписка,ФормаДокумента";
	
	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "Приказ";
	КомандаПечати.Представление = "Приказ";
	КомандаПечати.Обработчик    = "УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати";
	КомандаПечати.СписокФорм    = "ФормаСписка,ФормаДокумента";
	
КонецПроцедуры 

Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт 	
	
	ПараметрыВывода.ДоступнаПечатьПоКомплектно = Истина;
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "Акт") Тогда
 		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "Акт", "Акт", 
			СформироватьНесколькоАктов(МассивОбъектов),"Документ.Приказ.Акт");
	КонецЕсли;
	
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "Приказ") Тогда
 		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "Приказ", "Приказ", 
			СформироватьНесколькоПриказов(МассивОбъектов),"Документ.Приказ.Приказ");
	КонецЕсли;
	
КонецПроцедуры 

Функция   СформироватьНесколькоАктов(МассивОбъектов)
	
	ТабДокумент = Новый ТабличныйДокумент;
	Для каждого Ссылка из МассивОбъектов Цикл
		ТабДокументОбъекта = СформироватьАкт(Ссылка); 
		Если ТабДокумент.ВысотаТаблицы > 0 И ТабДокументОбъекта.ВысотаТаблицы > 0 Тогда 
			ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц()
		КонецЕсли;
		ТабДокумент.Вывести(ТабДокументОбъекта)
	КонецЦикла;

	Возврат ТабДокумент

КонецФункции 

Функция   СформироватьНесколькоПриказов(МассивОбъектов)
	
	ТабДокумент = Новый ТабличныйДокумент;
	Для каждого Ссылка из МассивОбъектов Цикл
		ТабДокументОбъекта = СформироватьПриказ(Ссылка); 
		Если ТабДокумент.ВысотаТаблицы > 0 И ТабДокументОбъекта.ВысотаТаблицы > 0 Тогда 
			ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц()
		КонецЕсли;
		ТабДокумент.Вывести(ТабДокументОбъекта)
	КонецЦикла;

	Возврат ТабДокумент

КонецФункции 

Функция  СформироватьАкт(Ссылка)

	ТабДокумент = Новый ТабличныйДокумент; 
	// подготовка ТабДокумента
	Возврат ТабДокумент 

КонецФункции 

Функция   СформироватьПриказ(Ссылка)
	
    ТабДокумент = Новый ТабличныйДокумент;
    // подготовка ТабДокумента 
    Возврат ТабДокумент 

КонецФункции 

Все готово, в форме документа у нас теперь программно будут добавляться кнопки печати. Чтобы они появились и в форме списка, проделайте с ней тоже самое (создайте обработчик ПриСозданииНаСервере и скопируйте код в Модуль формы ФормаСписка, в Модуле менеджера уже ничего менять не надо). Единственное отличие в третьем параметре функции ВыполнитьПодключаемуюКомандуПечати: вместо Объект нужно написать Элементы.Список. Также у этого списка обязательно должна быть колонка Ссылка, пусть даже невидимая. 

Результат всего этого выглядит так:

 

Форма документа

 

Форма списка

 

Универсальное окно печати в Бухгалтерии 3.0

 

P.S. Если при открытии информационной базы появится такое окно, то просто выполните то, что там написано, это нормально

подробнее о подсистеме "Печать" на ИТС:  https://its.1c.ru/db/bspdoc#content:219:hdoc

См. также

Подписаться Добавить вознаграждение
Комментарии
1. Игорь Иванов (paybaseme) 02.12.13 13:09
Самое интересное в предлагаемой Вами методике, осталось за кадром: если в форме списка выделить НЕСКОЛЬКО элементов (в вашем случае, приказов), то как же тогда будут напечатаны все Ваши документы, ежели Вы пишите:

Ссылка = МассивОбъектов[0];


Для одного объекта и будет напечатано.

Полагаю, Вам нужно заглянуть в БСП.
2. nick-max nick-max (nick-max) 02.12.13 16:26
(1) paybaseme,

Понятно, что где-то реализованы целые блоки и фреймворки для управления печатью. Эта статья только для Бухгалтерии 3.0, она полностью опирается на функционал этой конфигурации.

Да, из кода понятно, что если выделить шифтом несколько строк с документами, то можно напечатать их пакетно. Но для меня это ненужная функция. Однако, спасибо, что обратили на это внимание, может кому-то будет полезно)
3. Игорь Иванов (paybaseme) 02.12.13 17:47
(2) nick-max,

Понятно, что где-то реализованы целые блоки и фреймворки для управления печатью. Эта статья только для Бухгалтерии 3.0, она полностью опирается на функционал этой конфигурации.


Я ключевую неточность у Вас подчеркнул. В БП 3.0 портирована подсистема "Печать". Механизм печати, в части касающейся Вашей статьи, одинаков для конфигураций, где данная подсистема уже внедрена. Т.е. "фреймворк" печати (в вашей терминологии), уже встроен в БП 3.0. И говорить, что Ваша статья "опирается на функционал этой конфигурации." видимо, не совсем, точно. Ваша статья опирается на использование типовой подсистемы "Печать" из БСП.

Все выше сказанное, не в критику, а в уточнение :)
borzyj; kostyaomsk; Bukaska; Makushimo; +4 Ответить 2
4. nick-max nick-max (nick-max) 03.12.13 11:00
(3) paybaseme,

Спасибо за уточнение
Значит эта статья кросс-конфигурационная)
5. Светлана Мамонтова (Saifa) 08.12.13 19:03
Статья мне пригодилась, спасибо!
6. Никита Грызлов (nixel) 08.12.13 19:32
В БП 3.0 помимо подсистемы "Печать" встроена подсистема "Дополнительные отчеты и обработки", которая позволяет вообще без внесения изменений в конфигурацию добавлять произвольные команды печати и обработок в документы. Единственное требование от конфигурации - наличие документа/справочника в определенной подписке. Если этого нет, то контроллировать изменение одной/двух подписок намного проще, чем модулей объекта и менеджера. Сама же печать располагается во внешней обработке, которая имеет в своем модуле информацию для подключения к какому-либо документу, и все это дело настраивается в пользовательском режиме.
Как уже писалось выше, почитайте документацию по новой БСП, там правда много интересного :)
kostyaomsk; +1 Ответить
7. Aleksandr Filonov (AleksSF) 10.12.13 09:44
А через команды документа и конструкторы не пробовали. Там все автоматом размещается и на форму документа и на форму списка. В БП 3.0 как и во всех управляемых приложениях ко многим вещам другой подход. И лучше как следует изучить новую конфигурацию, а затем переносить свои изменения. Иначе получиться изобретение велосипеда.
8. nick-max nick-max (nick-max) 10.12.13 10:19
(7) AleksSF,

Пробовал, конечно, с этого и начал. Но такая печать просто формирует и открывает табличный документ, а мне требовалось, чтобы он открывался в форме с кнопкой "Печать", количеством экземпляров, возможностью сохранить
9. Aleksandr Filonov (AleksSF) 10.12.13 15:55
(8) nick-max,
В принципе Ваш способ имеет право жить, если в конфигурацию добавляешь свои Документы. Но для стандартных документов все же лучше использовать Дополнительные внешние печатные формы. Они добавляются с таким-же функционалом. Но при обновлениях ничего не будет пропадать и для последователей более прозрачно. Поэтому +.
10. Елена Пименова (Bukaska) 10.12.13 17:25
(1) paybaseme, Я думаю множественная печать и Без БСП реализуется, если глянуть в типовую..
Для этого даже с самодельными печатными формами вместо ссылки на объект, делаем
Запрос.УстановитьПараметр("МассивОбъектов", МассивОбъектов)
А в самом запросе:
...
ГДЕ
НужноеПоле.Ссылка В(&МассивОбъектов)


И переменную результата запроса Шапка прокрутить в цикле и усе.. и все будет ОК))))
Это как раз если внешнюю печатную форму встраивать через доп.Отчеты и обработки))))
11. Игорь Иванов (paybaseme) 10.12.13 20:45
(10) Bukaska,
Я думаю множественная печать и Без БСП реализуется, если глянуть в типовую..


Все таки, по внимательнее перечитайте (3). Если Вы гляните в типовую БП 3.0, то все о чем Вы написали, НЕ ИМЕЕТ СМЫСЛА без внедренной подсистемы "Печать". Поэтому, Ваши думы о том, что множественная печать реализуется БЕЗ БСП, могут существовать в контексте Ваших исключительных рассуждений и дум :) А если глубже копнуть, то выяснится, что ваш алгоритм - это типовая методика, которую можно было увидеть в БСП версии 1.0.7.5 от 05.08.2010, в то время как БП 3.0 зарелизилась с версии 3.0.9.4 от 28.04.2012. Т.е., тот алгоритм, который Вы описали, опирается на обвяз, который уже был представлен в демо БСП практически за 2 года, до первого релиза БП 3.0

Это как раз если внешнюю печатную форму встраивать через доп.Отчеты и обработки


А это, в свою очередь, еще одна подсистема БСП под названием "Дополнительные отчеты и обработки", которая также портирована в БП 3.0

Итоги моего поста какие? :)
12. Елена Пименова (Bukaska) 10.12.13 21:45
(11) paybaseme, Я сказала именно про множественную печать, что не нужно так глубоко копать для привязки ВПФ к документу)))
Вопрос в том, как по вашей методике согласно публикации сделать так, чтобы работала множественная печать.А то нулевой индекс строки правильно ребята подметили, - это печать одного документа, как будто из бух 2.0 печатаем)
13. Игорь Иванов (paybaseme) 10.12.13 22:53
(12) Bukaska,
не нужно так глубоко копать для привязки ВПФ к документу


Как раз таки нужно, ибо если не копать, тогда сложится мнение как у вас и у вашего коллеги: что оно якобы как-то само там живет, в типовой, своей жизнью.

Надо за правило взять, если что-то по печати, доп.отчетам и обработкам, ролям и прочему не понятно - то первое что надо делать, это не пытаться раскуривать самому, а скачать демо БСП, той редакции, которая сейчас в типовой, и посмотреть примеры.

Пожалуйста! Всегда Ваш, Кэп.

:)
14. Елена Пименова (Bukaska) 10.12.13 23:19
(13) paybaseme, БСП недоступна ни по учетке учебной версии, ни по комплекту разраба вроде как.. Это только франям..)))
Если бы оно везде на ресурсах валялось.. другой бы разговор)))
Лучше подскажите как в типовой найти версию БСП, и где посмотреть справку о функционале БСП.
15. Игорь Иванов (paybaseme) 11.12.13 09:35
(14) Bukaska,
Прикрепленные файлы:
16. Елена Пименова (Bukaska) 11.12.13 09:57
(15) paybaseme, Спасибо! А как в типовой бух 3.0 выйти на эту справку?
17. Игорь Иванов (paybaseme) 11.12.13 10:17
(16) Bukaska,
А как в типовой бух 3.0 выйти на эту справку?

1. Версия подсистем - РС
2. Справка по подсистемам БСП - никак. Только на ИТС.
18. Елена Пименова (Bukaska) 11.12.13 10:19
(17) paybaseme, ну вот.. опять двадцать пять((( жаль.. Ладно.. может меня когда-нить и допустят до ИТС)))
19. Игорь Иванов (paybaseme) 11.12.13 11:25
(18) Bukaska,

может меня когда-нить и допустят до ИТС


Если у Вас ваше скромное чувство собственного "я" позволит себя допустить до ИТС, то для этого нужно сделать всего лишь четыре шага:

1. Зарегать новый e-mail
2. Открыть http://its.1c.ru/test-drive/
3. Получить доступ к ИТС по е-mail из п.1 на 7 дней
4. Через 7 дней, выполнить в п.1

Пожалуйста! Всегда Ваш, Кэп.
SunShinne; +1 Ответить
20. Елена Пименова (Bukaska) 19.12.13 14:35
(2) nick-max, Вот теперь спасибо! Правда вперед ИТС под рукой был)))) есть другой вопрос, по части внешних печатных форм для самодельных документов. Эти все дела по вашей публикации я сделала, потом отлаживаю сейчас родной макет самодельного документа.. но вот Внешнюю печатную форму не зарегить, выскакивает ошибка: Тип не определен.ДокументСсылка.ИмяДокумента.. В Общую команду составного типа добавила свой док, но все равно видать что-то где-то не хватает... Благо что хоть родной макет отлаживается))))
21. Татьяна Крестьянкина (oleg212) 03.01.14 11:16
22. Дмитрий Денисов (SoulCast) 04.01.14 00:15
Спасибо, сделал по этой схеме несколько печатных форм в новых документах. Как раз в процессе переход на БП 3.0 )) А есть идеи как передать в процедуру печати дополнительные параметры?
23. Ирина Махно (mie24) 09.01.14 09:26
(20) Bukaska, Чтобы к новому документу иметь возможность подключить ВПФ необходимо этот документ указать в списке Типов параметров Общей команды "ДополнительныеОтчетыИОбработкиПечатныеФормы", а лучше подстраховаться и указать новый(ые) документ(ы) и в других Общих командах "ДополнительныеОтчетыИОбработкиОтчеты", "ДополнительныеОтчетыИОбработкиЗаполнениеОбъекта", "ДополнительныеОтчетыИОбработкиСозданиеСвязанныхОбъектов".
Далее необходимо в Модуле формы (Документа и Списка) нового документа необходимо создать процедуру ПриСозданииНаСервере:
&
НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
		// СтандартныеПодсистемы.Печать
	УправлениеПечатью.ПриСозданииНаСервере(ЭтаФорма);
	// Конец СтандартныеПодсистемы.Печать
	
	// ДополнительныеОтчетыИОбработки
	ДополнительныеОтчетыИОбработки.ПриСозданииНаСервере(ЭтаФорма);
	// Конец ДополнительныеОтчетыИОбработки
	
	Если Параметры.Ключ.Пустая() Тогда
		ПодготовитьФормуНаСервере();
	КонецЕсли;

КонецПроцедуры
...Показать Скрыть

Кажется этого должно быть достаточно.

Только нужно еще проверить на форме на панели (Вид - ГруппаКнопок и Источник - Форма) появилась ли кнопка Печать с выпадающим меню "ДополнительныеПечатныеФормы"
Sherdrada; +1 Ответить
24. nick-max nick-max (nick-max) 09.01.14 12:38
(22) SoulCast,

а для чего это может быть нужно? то есть, какой например может быть доп. параметр, и почему его нельзя получить уже внутри процедуры типа СформироватьАкт?
25. Дмитрий Денисов (SoulCast) 09.01.14 19:21
(24) nick-max, например получить текущую строку табличной части. У меня были печатные формы, которые получали данные по выбранной строке.
26. Дмитрий Лумбов (Dima69) 07.03.14 10:05
27. Дмитрий Лумбов (Dima69) 07.03.14 10:09
Да чуть не забыл, а не подскажите какие стандартные процедуры
ставят значок Дб-Кр (при ручной корректировки операции) в списке документов
28. nick-max nick-max (nick-max) 07.03.14 10:30
(27) Dima69,

для выведения на форму кнопки ДтКт нужно добавить свой документ в общую команду ПоказатьДвиженияДокумента.
Но с точки зрения доработки типовой конфигурации с минимальными изменениями в типовых объектах лучше всего скопировать эту общую команду, назвать ПоказатьДвиженияМоегоДокумента и указывать в ней только свои документы. Тогда при обновлении кнопка ДтКт точно не слетит
29. Дмитрий Лумбов (Dima69) 19.03.14 20:49
Спасибо за ответ, но я имел в виду не кнопку ДтКт,
а значок ДтКт левее документа, операция которого отредактированна вручную, рядом
с зеленой галкой проведенного документа
30. Сергей Курышов (sudmorsh) 02.08.14 19:51
Спасибо за статью очень пригодилась
31. Константин Юрин (kostyaomsk) 20.08.14 08:03
Интересная статья про печать в БП 3.0 с использованием стандартных механизмов. Но, может быть, даже для новых нетиповых документов использовать внешние печатные формы если нужно оперативно (не выгоняя пользователей) исправить ошибку при печати?
Печатную форму сделать проще чем копаться в механизмах печати новых релизов? Постоянно ведь корректировать конфигурацию будет затруднительно? Особенно если новых документов много.
32. Александр Астафьев (Astafan) 11.11.14 08:15
Спасибо за статью, очень пригодилась.
Но есть один вопрос: Создал в типовой конфигурации новый документ. Чтобы использовать механизм подключаемых печатных форм нужно редактировать команду "ДополнительныеОтчетыИОбработкиПечатныеФормы". НО при обновлении изменения слетят. Как правильно поступить в данном случае?
33. Екатерина * * (ekaterinaeon) 28.11.14 08:53
Нашла эту статью как раз в тот момент, когда больше всего была нужна) и помогло! спасибо!
34. alex Pidodny (helox) 04.12.14 15:23
В процедуре Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт 

	КомандаПечати = КомандыПечати.Добавить();
	КомандаПечати.Идентификатор = "Акт";
	КомандаПечати.Представление = "Дополнительный акт";
	КомандаПечати.Обработчик    = "УправлениеПечатьюБПКлиент.ВыполнитьКомандуПечати";
	КомандаПечати.СписокФорм    = "ФормаСписка,ФормаДокумента"; 
...Показать Скрыть

в списке форм должны быть наименования форм используемых при печати, добавил форму "ФормаДокументаУФ" - и долго гадал почему не появилась кнопочка печати!!
35. Роман Антонов (ronhard) 29.01.15 17:52
Также у этого списка обязательно должна быть колонка Ссылка, пусть даже невидимая
В конфигураторе на форме у колонки "Ссылка" должна стоять галочка "Использовать всегда", иначе невидимая колонка работать не будет, а только если она видимая.
bird21; PoZiTiFFF; cleaner_it; +3 Ответить
36. AK UI (ui69) 11.02.15 13:50
Спасибо, помогла данная статья. Создавал новый документ в БП 3.0 с двумя печатными формами.
37. Василь Галимов (Baser) 12.02.16 09:07
А можете ссылку дать, как это более правильно делать? Я уже который день пытаюсь понять, как свою печать через БСП пустить, а не по старинке, через команды; везде методики для использования во внешних печатных формах

Ну, вот почему так... как вопрос задал, так сразу и нашел... спасибо всем :)
http://its.1c.ru/db/bspdoc#content:219:1:issogl2_%D1%80%D0%B0%D0%B7%D1%80%D0%B0%D0%B1%D0%BE%D1%82%D0%­BA%D0%B0_%D0%BF%D1%80%D0%BE%D1%86%D0%B5%D0%B4%D1%83%D1%80%D1­%8B_%D0%BF%D0%B5%D1%87%D0%B0%D1%82%D1%8C
38. jandi kokandi (user590836_zhan_chick) 08.07.16 14:24
Теперь у меня программно добавились 2 лишние кнопки печати, которые мне не нужны. Помимо тех что созданы на форме вручную. Вопрос: как мне их убрать?
39. Max Зиннуров (zmx) 25.07.16 00:29
В форме списка документа в процедуре ВыполнитьПодключаемуюКомандуПечати нужно поставить условие выполнения печати только, если документ проведен. Почему здесь не виден реквизит проведения документа?

Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)

Объект=Элементы.Список.ТекущаяСтрока;
Если Объект.Проведен = Ложь Тогда
Сообщить("Документ не проведен !!! Печать не возможна");
Возврат;
КонецЕсли;

УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтаФорма, Элементы.Список);
КонецПроцедуры

Спасибо заранее!
40. nick-max nick-max (nick-max) 25.09.16 03:24
(39) zmx,

думаю, тут лучше использовать Элементы.Список.ТекущиеДанные.Ссылка.Проведен, при условии, что в список выведена колонка Ссылка. Но я бы такие проверки перенес внутрь функций типа СформироватьПриказ
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа