bdd2

Универсальное регламентное задание для запуска внешних и встроенных обработок. Как настроить легко и быстро (8.х)

Опубликовал Роман Прокопенко (ProX) в раздел Администрирование - Системное

Создаем и настраиваем регламентные задания на основании внешних и встроенных обработок просто и удобно.

Механизм, о котором пойдет речь ниже, позволяет гибко и оперативно создавать и настраивать регламентные задания без запуска конфигуратора. Это действенный инструмент, которого порой просто не хватает под рукой. 

Предлагаю рассмотреть один из способов реализации такого иснструмента собственными руками. Для тех же, у кого нет времени на болтовню автора статьи и/или же механизм нужен уже сейчас, прошу к скачиванию :)

И пока коллеги со второй категории скачивают обработку, мы ее напишем :)

Нам понадобится.

1. Создать регламентное задание с названием "ВыполнениеОбработки".

2. В качестве исполнительного метода регламентного задания указать метод ВыполнениеОбработки() из общего модуля МодульРегламентныхЗаданий (или любого другого общего модуля с такими же настройками свойств). Описать логику работы метода.

3. Написать обработку, которая будет программно создавать экземпляры регламентного задания с заданными параметрами.

Важно!

Любое регламентное задание имеет такое свойство как Параметры. Это Массив, назначение которого очевидно - хранение параметров, которые передаются на вход исполнительного метода регламентного задания. Более детально можно прочесть в синтаксис помощнике. Отметим только, что устанавливаются параметры регламентного задания только программноТакже следует помнить, что количество и состав параметров должны соответствовать параметрам метода регламентного задания.

Приступим.

Первым делом, создадим регламентное задание. Укажем исполнительный метод. Опишем его логику работы исходя из следующих условий

  • Регламентное задание должно уметь запускать как внешние, так и встроенные обработки.
  • Уметь передавать входящие параметры (первоначальные настройки) обработке на выполнение.
  • Логировать все свои действия в журнал регистрации
Первым параметром метода регламентного задания укажем ключ обработки. Он понадобится нам для идентификации обработки, которую нужно запустить на выполнение. В случае с внешней обработкой - это будет ее код из справочника "Внешние обработки", в случае со встроенной - имя из дерева метаданных. Второй параметр метода регламентного задания - произвольные настройки, которые хранятся в объекте с типом ХранилищеЗначения.
Ниже приведен листинг метода регламентного задания.

Процедура ВыполнениеОбработки(КодОбработки = Неопределено, СохраненныеНастройки = Неопределено) Экспорт

	ОбработкаРегламентногоЗадания = Неопределено;
	
	// Не указан код внешней (название встроенной) обработки 
	Если КодОбработки = Неопределено Тогда
		
		ЗаписьЖурналаРегистрации("Ошибка регламентированного выполнения обработки", УровеньЖурналаРегистрации.Предупреждение,,,
								 "Не правильно указан параметр '" + КодОбработки + "'");
		
		Возврат;		
		
	КонецЕсли;		
	
	ВнешняяОбработкаСсылка = Справочники.ВнешниеОбработки.НайтиПоКоду(КодОбработки);
	
	// Проверка, найдена ли внешняя обработка
	ВнешняяОбработкаПустая = Ложь;
	Если ВнешняяОбработкаСсылка = Неопределено Тогда
	    ВнешняяОбработкаПустая = Истина;		
	ИначеЕсли ВнешняяОбработкаСсылка.Пустая() Тогда		
		ВнешняяОбработкаПустая = Истина;	
	КонецЕсли; 
			
	// Возможно это встроенная обработка
	Если ВнешняяОбработкаПустая Тогда
	
		Для каждого ТекВстроеннаяОбработка Из Метаданные.Обработки Цикл
		
			Если СокрЛП(ТекВстроеннаяОбработка.Имя) = СокрЛП(КодОбработки) Тогда
			
				ОбработкаРегламентногоЗадания = Обработки[КодОбработки].Создать();
				
				// Нашли встроенную обработку. Выйти из цикла 
				Прервать;										
				
			КонецЕсли; 	
		
		КонецЦикла;
		
		// Не удалось найти встроенную обработку
		Если ОбработкаРегламентногоЗадания = Неопределено Тогда
		
			ЗаписьЖурналаРегистрации("Ошибка регламентированного выполнения обработки", УровеньЖурналаРегистрации.Предупреждение,,,
									 "Обработка '" + КодОбработки + "' не найдена");
		
			Возврат;	
		
		КонецЕсли; 
				
	// Это внешняя обработка			
	Иначе
		
		ДвоичныеДанные = ВнешняяОбработкаСсылка.ХранилищеВнешнейОбработки.Получить();
		
		// внешнюю обработку невозможно преобразовать в двоичные данные 
		Если ДвоичныеДанные = Неопределено Тогда
			
			ЗаписьЖурналаРегистрации("Ошибка регламентированного выполнения обработки", УровеньЖурналаРегистрации.Предупреждение,,,
									 "Внешняя обработка '"+КодОбработки+"' не имеет двоичных данных");
			
			Возврат;
			
		КонецЕсли;
		
		Попытка
			
			АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(ДвоичныеДанные);
			ИмяОбработки = ВнешниеОбработки.Подключить(АдресВоВременномХранилище, , Ложь);
			
			Если ВнешняяОбработкаСсылка.ВидОбработки = Перечисления.ВидыДополнительныхВнешнихОбработок.Обработка Тогда
				ОбработкаРегламентногоЗадания = ВнешниеОбработки.Создать(ИмяОбработки);				
			Иначе                                                                      				
				ОбработкаРегламентногоЗадания = ВнешниеОтчеты.Создать(ИмяОбработки);   				
			КонецЕсли;
			
		Исключение 			
			
			ЗаписьЖурналаРегистрации("Ошибка регламентированного выполнения обработки", УровеньЖурналаРегистрации.Предупреждение,,,
									 "Не удалось подключить внешнюю обработку '"+ВнешняяОбработкаСсылка+"'");
									 
			Возврат;
			
		КонецПопытки;
			
	КонецЕсли;
	
	Попытка
		
		Если СохраненныеНастройки = Неопределено Тогда		
			ОбработкаРегламентногоЗадания.ВыполнитьЗадание();			
		ИначеЕсли ТипЗнч(СохраненныеНастройки) <> Тип("ХранилищеЗначения") Тогда			
			ОбработкаРегламентногоЗадания.ВыполнитьЗадание();                   			
		ИначеЕсли ТипЗнч(СохраненныеНастройки) = Тип("ХранилищеЗначения") Тогда 
			ОбработкаРегламентногоЗадания.ВыполнитьЗадание(СохраненныеНастройки);			
		КонецЕсли; 
				
	Исключение
		
		ЗаписьЖурналаРегистрации("Ошибка регламентированного выполнения обработки", УровеньЖурналаРегистрации.Предупреждение,,,
								 "Обработка '" + ОбработкаРегламентногоЗадания + "' должна иметь в модуле экспортную процедуру 'ВыполнитьЗадание()'");
		
	КонецПопытки;
	
КонецПроцедуры

Теперь опишем обработку, которая будет создавать экземпляры выше описанного регламентного задания.

Как все работает изнутри, лучше всего расскажет программный код исполнительной процедуры (обработчик нажатия на кнопку "Запустить регламентное задание").

Процедура КнопкаВыполнитьНажатие(Кнопка)
	// Проверим все ли реквизиты на форме заполнены корректно
	Если НЕ ОбязательныеРеквизитыЗаполнены() Тогда
		
		Возврат;
		
	КонецЕсли;
	
    ОбъектЗадания = РегламентныеЗадания.СоздатьРегламентноеЗадание("ВыполнениеОбработки");
	ОбъектЗадания.Наименование 	= Наименование;
	ОбъектЗадания.Ключ 		= Ключ;
	ОбъектЗадания.Использование	= Использование;
	
	ОбъектЗадания.ИмяПользователя = ИмяПользователя;
	
	ОбъектЗадания.КоличествоПовторовПриАварийномЗавершении 	= КоличествоПовторовПриАварийномЗавершении;
	ОбъектЗадания.ИнтервалПовтораПриАварийномЗавершении 	= ИнтервалПовтораПриАварийномЗавершении;
	
	ЗначениеСохраненнойНастройки = ПолучитьЗначениеСохраненнойНастройки();
	
	Параметры = Новый Массив();
	Параметры.Добавить(Ключ);
	
	Если ЗначениеСохраненнойНастройки <> Неопределено Тогда
	
		Параметры.Добавить(ЗначениеСохраненнойНастройки);	
	
	КонецЕсли; 
	
	ОбъектЗадания.Параметры = Параметры;
			
	Попытка
		
		ОбъектЗадания.Записать();
						
	Исключение
		
		ВызватьИсключение "Произошла ошибка при запуске регламентного задания.
		|Подробное описание ошибки: " + ОписаниеОшибки();
		
	КонецПопытки;
	
КонецПроцедуры

После всего проделанного, любая обработка может быть запущена регламентным заданием. Для этого ей достаточно в модуле объекта содержать экспортную процедуру ВыполнитьЗадание().

Оставляйте свои вопросы и предложения по улучшению функциональности механизма в комментариях. 

Дополнительную информацию по теме читайте в статьях http://infostart.ru/public/183110/ и http://infostart.ru/public/191266/ . Авторам спасибо за идеи, мысли и изложенный материал.

Скачать файлы

Наименование Файл Версия Размер
Настройка регламентного выполнения внешних и встроенных обработок
.epf 12,97Kb
09.06.15
51
.epf 12,97Kb 51 Скачать

См. также

PowerTools от 1 000
Добавить вознаграждение
Комментарии
1. Роман Прокопенко (ProX) 27 16.06.15 11:24 Сейчас в теме
Если вам помогла обработка, оставьте комментарий :)
2. Иван Дмитриченко (dmitrichenko.ivan) 4 17.06.15 17:43 Сейчас в теме
В БСП же реализован запуск внешних обработок по расписанию?
3. Роман Прокопенко (ProX) 27 18.06.15 14:22 Сейчас в теме
Реализовано. На управляемых формах и без возможности подключения встроенных обработок.
Для переноса механизма регламентированного запуска внешних обработок из БСП в любую другую конфигурацию придется попотеть, и доработать гораздо больше объектов нежели того требует механизм, описанный в статье. Выбор за Вами :)
4. Mr. Alf Garcia (mip128) 29.06.15 15:22 Сейчас в теме
А ты можешь написать типы значений реквизитов обработки?
5. Роман Прокопенко (ProX) 27 30.06.15 11:19 Сейчас в теме
Наименование: Поле ввода (Строка),
Ключ: Поле ввода (Строка),
Имя пользователя: Поле ввода (Строка) (Список пользователей заполняется программно в модуле формы)
Сохраненная настройка: Поле выбора (Строка) (Список настроек заполняется программно в модуле формы)
Внешняя обработка: Поле ввода (СправочникСсылка.ВнешниеОбработки)
Обработка из конфигуратора: Поле выбора (Строка). Список обработок заполняется программно по метаданным.
Использование: Булево
Расписание регламентного задания: гиперссылка открывающая форму диалога расписания регламентного задания
6. Mr. Alf Garcia (mip128) 06.07.15 17:53 Сейчас в теме
Ну без скачивания обработки все равно сложно самостоятельно создать)
7. Mr. Alf Garcia (mip128) 05.02.16 10:06 Сейчас в теме
У тебя еще в
ВнешниеОбработки.Создать(ИмяОбработки)
надо бы указывать второй параметр БезопасныйРежим, это довольно важно