БСП 2.3.2: Просто про выполнение внешней обработки в фоне (c индикацией)

Опубликовал Роман Озеряный (rozer) в раздел Программирование - Инструментарий

Простое пояснение о том, как сделать внешнюю обработку с фоновым выполнением и индикацией процесса для любой конфигурации на основе БСП 2.3.2.

Не секрет, что после запуска "тяжелой" обработки хочется продолжать работать в программе, а также "видеть" время от времени сам процесс выполнения. Для простого пояснения, как это реализовано, и предназначена эта статья. Если ваша конфигурация не на БСП 2.3.2, можно сразу перейти, например, на эту статью //infostart.ru/public/157706/ 

Важно! Обработка должна использоваться только через штатный механизм БСП "Дополнительные отчеты и обработки".

Код модуля обработки

Примечание: обработку можно запустить как из формы (см. представление команды "Открыть форму и выполнить в фоне с индикацией") так и сразу на сервере (см представление команды "Выполняем на сервере"). Запуск непосредственно на сервере можно сделать по расписанию.

// Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
	ПараметрыРегистрации.Версия = "2.1";
	ПараметрыРегистрации.БезопасныйРежим = Истина;
	
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Выполняем на сервере'");
	НоваяКоманда.Идентификатор = "ВыполнениеНаСервереОбработку";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	НоваяКоманда.ПоказыватьОповещение = Истина;
	
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Открыть форму и выполнить в фоне с индикацией'");
	НоваяКоманда.Идентификатор = "ОткрытьФормуОбработку";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	НоваяКоманда.ПоказыватьОповещение = Ложь;
	
	Возврат ПараметрыРегистрации;
КонецФункции

// Интерфейс для выполнения команд обработки.
Процедура ВыполнитьКоманду(ИмяКоманды,ПараметрыВыполнения) Экспорт
	ДатаЗавершенияВМиллисекундах = ТекущаяУниверсальнаяДатаВМиллисекундах() + 1000*10;
	
	Попытка
		СтандартныеПодсистемыКлиентСервер.ВывестиОповещение(
		ПараметрыВыполнения.РезультатВыполнения,
		НСтр("ru = 'Выполнена длит. операция!'"),,
		БиблиотекаКартинок.Успешно32);
	Исключение
		СтандартныеПодсистемыКлиентСервер.ВывестиИнформациюОбОшибке(
		ПараметрыВыполнения.РезультатВыполнения,
		СтрШаблон(НСтр("ru = 'Ошибка выполнения команды ""%1""'"), ИмяКоманды),
		ИнформацияОбОшибке());
		Возврат;
	КонецПопытки;
	
	 //Имитация длительной операции - вместо этого вставте свой код который будет выполняться на сервере в фоне
	Пока ТекущаяУниверсальнаяДатаВМиллисекундах() < ДатаЗавершенияВМиллисекундах Цикл
	КонецЦикла;
КонецПроцедуры

Код модуля формы обработки

Важно добавить в форму эти параметры:

  • ДополнительнаяОбработкаСсылка (тип "СправочникСсылка.ДополнительныеОтчетыИОбработки").
  • ИдентификаторКоманды (тип "Строка")

.. и эти реквизиты:

  • ОбъектСсылка (тип "СправочникСсылка.ДополнительныеОтчетыИОбработки")
  • ИдентификаторКоманды (тип "Строка")
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	ОбъектСсылка = Параметры.ДополнительнаяОбработкаСсылка;
	ИдентификаторКоманды = Параметры.ИдентификаторКоманды;
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)
	Если ИсточникВыбора.ИмяФормы = ДополнительныеОтчетыИОбработкиКлиент.ИмяФормыДлительнойОперации() Тогда
		ЗагрузитьРезультат(ВыбранноеЗначение);
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура Фигачить(Команда)
	ПараметрыКоманды = Новый Структура("ДополнительнаяОбработкаСсылка, СопровождающийТекст");
	ПараметрыКоманды.ДополнительнаяОбработкаСсылка = ОбъектСсылка;
	ПараметрыКоманды.СопровождающийТекст = НСтр("ru = 'Выполняем из формы в фоне...'");
	Состояние(ПараметрыКоманды.СопровождающийТекст);
	ДополнительныеОтчетыИОбработкиКлиент.ВыполнитьКомандуВФоне(ИдентификаторКоманды, ПараметрыКоманды, ЭтаФорма);	
КонецПроцедуры

&НаКлиенте
Процедура ЗагрузитьРезультат(РезультатВыполнения)
	Если Открыта() Тогда
	   Закрыть();
	КонецЕсли;
	ДополнительныеОтчетыИОбработкиКлиент.ПоказатьРезультатВыполненияКоманды(ВладелецФормы, РезультатВыполнения);
КонецПроцедуры

&НаСервере
Функция ВыполнитьКомандуНапрямую(ИдентификаторКоманды, ПараметрыКоманды)
	Возврат ДополнительныеОтчетыИОбработки.ВыполнитьКомандуИзФормыВнешнегоОбъекта(ИдентификаторКоманды, ПараметрыКоманды, ЭтаФорма);
КонецФункции

Примечание: для формы нужно назначить обработчики событий для процедур "ПриСозданииНаСервере" и "ОбработкаВыбора".

Вот, собственно, и все...

З.Ы. Для тех, кому недостаточно "простого" описания и кто хочет подробно разобраться в предмете - см. описание с ИТС

Скачать файлы

Наименование Файл Версия Размер
ОбработкаТестДлитОпераций.epf
.epf 7,86Kb
18.05.16
53
.epf 7,86Kb 53 Скачать

См. также

Комментарии
1. Антонио Антонио (Fragster) 668 19.05.16 11:50 Сейчас в теме
Добавьте в пример вывод прогресс-бара
2. Роман Озеряный (rozer) 183 19.05.16 17:22 Сейчас в теме
(1) Fragster, можно конечно как тут http://infostart.ru/public/458778/ но пришлось бы снимать с поддержки для добавления своей общей формы. Другого способа более легкого не знаю )
3. Антонио Антонио (Fragster) 668 19.05.16 17:38 Сейчас в теме
(2) rozer, Зачем? есть же "ДлительныеОперации.СообщитьПрогресс" и ".ПрочитатьПрогресс", а отображать прогресс можно в своей форме с обработчиком ожидания? Или в данном случае это неприменимо?
4. Роман Озеряный (rozer) 183 19.05.16 19:22 Сейчас в теме
(3) хм, посмотрю на досуге...
5. Роман Озеряный (rozer) 183 20.05.16 10:37 Сейчас в теме
если запустить эту обработку в последней версии БП 3.0 то вместо "крутящегося колесика" - этот
веселый котэ )))
Настоящий подарок бухгалтерам )
Atori-kun; TeMochkiN; invertex; +3 Ответить 2
6. Роман Озеряный (rozer) 183 21.05.16 16:03 Сейчас в теме
(3) Fragster, у меня не получилось с индикатором в этом случае.
Дело в том что нет возможности получить "ИдентификаторЗадания" для использования
ДлительныеОперации.ПрочитатьПрогресс(ФоновоеЗаданиеИдентификатор)
.

Вот если используется "ДлительныеОперации.ЗапуститьВыполнениеВФоне" тогда да это получиться:

РезультатФоновогоЗадания = ДлительныеОперации.ЗапуститьВыполнениеВФоне(
				УникальныйИдентификатор,
				"МойМодуль.МояФоноваяПроцедура",
				ПараметрыЗадания,
				ПараметрыЗадания.НаименованиеЗадания);
			
ФоновоеЗаданиеИдентификатор  = РезультатФоновогоЗадания.ИдентификаторЗадания;
...Показать Скрыть


Но это не для внешних обработок - остается только как в http://infostart.ru/public/159607/ самому запускать фоновое оповещать через "СообщениеПользователю" и "ловить" в форме в "обработчике ожидания".
7. Александр Дорожкин (aldor188) 25.05.16 08:48 Сейчас в теме
А что за процедура Фигачить()? Она не используется по коду.
8. Роман Озеряный (rozer) 183 25.05.16 10:30 Сейчас в теме
(7) это обработчик команды формы обработки
9. Vit IVA (1vasia1) 15 27.05.16 15:35 Сейчас в теме
(5) rozer, И правда котэ в картинки "ДлительнаяОперация48" добавили :)
10. Ирина Удачливая (config) 86 27.05.16 15:41 Сейчас в теме
(5) rozer, бухгалтерия ЛИЧНО звонила и благодарила за "такого замечательного котика"
11. Александр Юдин (aaudin90) 02.06.16 10:58 Сейчас в теме
(8) rozer, есть опыт работы с длительными операциями для внешних отчетов? Делаем через набор данных "объект" и стандартная обработка в процедуре ПриКомпоновкеРезультата = ложь, поэтому стандартное скдшное фоновое задание не работает.
12. Роман Озеряный (rozer) 183 02.06.16 12:40 Сейчас в теме
(11) aaudin90,
внешних отчетов



а зачем - отчет сервер смотрит ? ))
13. Александр Юдин (aaudin90) 02.06.16 12:52 Сейчас в теме
Отчет делается около 60 секунд, хотелось бы его каким то образом перевести в фон.
14. Роман Озеряный (rozer) 183 02.06.16 13:48 Сейчас в теме
(13) aaudin90, примерно так: сделайте на сервере программный вывод из ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент в табл документ, заполните в РезультатВыполнения табл.документ и на клиенте "ловите" этот РезультатВыполнения и демонстрируете его пользователю...
15. Александр Юдин (aaudin90) 03.06.16 05:35 Сейчас в теме
(14) rozer, спасибо за совет, но все таки отказались от идеи использования набора данных объект)
16. Геннадий (user595572_katigugu) 02.08.16 20:04 Сейчас в теме
Здравствуйте! Что-то не могу допереть, как передать параметры в серверную экспортную процедуру ВыполнитьКоманду. Т.е., если длительная операция содержит выполнение запроса к базе, значения параметров вводятся через форму, как их подтянуть в процедуру? День протупил. :) Буду очень признателен за помощь. Заранее спасибо.
17. Роман Озеряный (rozer) 183 03.08.16 10:29 Сейчас в теме
(16) user595572_katigugu, поместить в "ПараметрыКоманды " в Фигачить()
например:
ПараметрыКоманды .Вставить("струкНастроек", РеквизитФормыВЗначение("Объект").ПолучитьСтруктуруНастроекСервер());


и получать в ВыполнитьКоманду(ИмяКоманды,ПараметрыВыполнения)
например:
ПараметрыНастроекВФорме=ПараметрыВыполненияКоманды.струкНастроек;

Дмитрий74Чел; +1 Ответить 1
18. Геннадий (user595572_katigugu) 09.08.16 13:49 Сейчас в теме
19. Yackov . (Yackov) 95 15.11.16 09:57 Сейчас в теме
На новом релизе бухгалтерии обработка перестала работать
20. Роман Озеряный (rozer) 183 13.02.17 08:24 Сейчас в теме
(19) ну видимо БСП поменяли как обычно...
21. Дмитрий Г (Дмитрий74Чел) 14 02.03.17 16:40 Сейчас в теме
Вопрос: а как отлаживать фоновое? Отладчик не хочет заходить в созданный объект-обработку. Останавливается на Объект.Выполнить(ИмяКоманды,ПараметрыВыполнения)
22. Никита Заранко (nikita0832) 8 02.03.17 17:07 Сейчас в теме
Рассказываю рабочий способ: запускаем фоновое задание
Результат = ВыполнитьЗапускВФонеНаСервере();	
ИдентификаторЗадания = Результат.ИдентификаторЗадания;


И
Функция ВыполнитьЗапускВФонеНаСервере()
	НаименованиеЗадания = "Любое название";
	ПараметрыЗапуска = Новый Структура;
	ПараметрыЗапуска.Вставить("Режим", Объект.Режим);
	//тут еще параметры	
        Результат = ДлительныеОперации.ЗапуститьВыполнениеВФоне(
															Новый УникальныйИдентификатор, 
															"Модуль.Процедура", 
															ПараметрыЗапуска, 
															НаименованиеЗадания);
	Лог="";
	Возврат Результат;
															
КонецФункции
...Показать Скрыть

Дальше для прогресс бара нам понадобится из запущенного сеанса выводить сообщения нужного нам формата, например "Прогресс=32". в основной обработке получаем эти сообщения и интерпретируем(парсим) через ПолучитьСообщенияПользователю() так:
ПодключитьОбработчикОжидания("ВыводСообщений",1,Ложь);

И
&НаКлиенте
Процедура ВыводСообщений()
	Рез=ВыводСообщенийНаСервере();
	Если Рез=Ложь Тогда
		ОтключитьОбработчикОжидания("ВыводСообщений");
		ПоказатьПредупреждение(,"Процесс завершен");
	КонецЕсли;
	Состояние("Наш процесс",Прогресс);
КонецПроцедуры

&НаСервере
Функция ВыводСообщенийНаСервере()
	ДлинаЛога = 50000;
	Задание=ФоновыеЗадания.НайтиПоУникальномуИдентификатору(ИдентификаторЗадания);
	Если Задание=Неопределено Тогда
		Возврат Ложь;
	КонецЕсли;
	Сообщения=Задание.ПолучитьСообщенияПользователю(Истина);
		Для Каждого Сообщение ИЗ Сообщения Цикл
			Если Лев(Сообщение.Текст,8)="Прогресс" Тогда
				Прогресс=Число(Сообщение.Текст,2);
								
			Иначе
				
				Лог=Строка(ТекущаяДата())+": "+Сообщение.Текст+Символы.ПС+Лев(Лог,ДлинаЛога);
			КонецЕсли;
			
			
		КонецЦикла;
	Если Задание.Состояние=СостояниеФоновогоЗадания.Активно Тогда
		
		Возврат Истина;
	Иначе
		
		Возврат Ложь;
	КонецЕсли;
КонецФункции
...Показать Скрыть

На форме у меня Переменные ИдентификаторЗадания, Прогресс и Лог(многострочное текстовое поле для вывода прочих служебных сообщений).
23. Никита Заранко (nikita0832) 8 02.03.17 17:27 Сейчас в теме
(21)Отладку к сожалению можно делать только поставив галку на форме для отладки и по ней запускать процедуру непосредственно, не через фоновое задание. Если кто знает другой способ- мне и самому будет интересно узнать.
Оставьте свое сообщение