Управление версиями внешних обработок: вариант реализации

Опубликовал Анатолий Златов (zan_od) в раздел Программирование - Инструментарий

Как известно, в 1С:Предприятие имеется встроенная система управления версиями - "Хранилище конфигурации". К сожалению, в ней нельзя хранить версии внешних файлов 1С (отчетов, обработок, печатных форм и т.д.). Предлагаю свой вариант учета версий внешних обработок, который, на мой взгляд, обладает простотой, гибкостью и универсальностью.

Для чего это нужно

Учет версий внешних обработок будет полезен для разработчиков, которые разрабатывают универсальные модули в виде внешних обработок, например: модули обмена, панели продаж, отчеты и т.д. 

Как это работает

Для хранения версий внешних обработок я использую TortoiseHg (скачать можно здесь - http://tortoisehg.bitbucket.org/). Обработки хранятся в программе как бинарные файлы.

Хранение версий внешних обработок


Для сравнения двух версий обработок был написан скрипт на AutoIT:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <Array.au3>

Func SelectWindow($configList)
   GUICreate("Выберите окно конфигуратора", 700, 200, -1, -1, -1) ;BitOR($DS_MODALFRAME, $WS_SYSMENU))

   Local $idListview = GUICtrlCreateListView("", 0, 0, 700, 200, $LVS_LIST)
   ;GUISetBkColor(0xf0f0f0, $idListview)

   Local $ListItems[0]
   For $i = 0 To UBound($configList) - 1
	  _ArrayAdd($ListItems, GUICtrlCreateListViewItem($configList[$i][0], $idListview))
	  ;$ListItems[$i] = GUICtrlCreateListViewItem($configList[$i], $idListview)
   Next

   Local $result = -1
   Local $rowsCount = UBound($ListItems)

   GUISetState(@SW_SHOW)

   Local $idMsg = 0
   ; Loop until the user exits.
   While 1
	  $idMsg = GUIGetMsg()
      Switch $idMsg
         Case $GUI_EVENT_NONE
         Case $GUI_EVENT_CLOSE
            ExitLoop
		 Case Else
			For $i = 0 To $rowsCount - 1
			   If $idMsg = $ListItems[$i] Then
				  ;MsgBox($MB_SYSTEMMODAL, "listview", "clicked="+$i, 2)
				  $result = $configList[$i][1]
				  ExitLoop 2
			   EndIf
			Next
	  EndSwitch
   WEnd

   GUISetState(@SW_HIDE)
   GUIDelete()

   Return $result
EndFunc

Func Main()

   $test = 0
   If $test = 1 Then
	  $FileName1 = "D:\bases.1c\v82\test\ExtFiles\Обработка0.epf"
	  $FileName2 = "D:\bases.1c\v82\test\ExtFiles\Обработка.epf"
   Else
	  if $CmdLine[0] < 2 Then
		 MsgBox($MB_SYSTEMMODAL, "Ошибка", "Использование скрипта: 1c_diff <первый файл> <второй файл>")
		 Exit
	  EndIf

	  $FileName1 = $CmdLine[1]
	  $FileName2 = $CmdLine[2]
   EndIf

   Local $configList[0][0]

   Local $aList = WinList("[REGEXPTITLE: *Конфигуратор*; CLASS:V8TopLevelFrame]")
   ;_ArrayDisplay($aList)
   For $i = 1 To $aList[0][0]
	  If $aList[$i][0] <> "" And BitAND(WinGetState($aList[$i][1]), 2) Then
		 ReDim $configList[UBound($configList) + 1][2]
		 $configList[UBound($configList) - 1][0] = $aList[$i][0]
		 $configList[UBound($configList) - 1][1] = $aList[$i][1]
	  EndIf
   Next

   ;_ArrayDisplay($configList)

   If UBound($configList) = 0 Then
	  MsgBox($MB_SYSTEMMODAL, "Ошибка!", "Не найден открытый конфигуратор!")
	  Exit
   EndIf

   Local $selectedWindow = -1
   If UBound($configList) = 1 Then
	  $selectedWindow = $configList[0][1]
   Else
	  $selectedWindow = SelectWindow($configList)
   EndIf

   If $selectedWindow = -1 Then
	  Exit
   EndIf

   ;MsgBox($MB_SYSTEMMODAL, "Ошибка", $selectedWindow)

   WinActivate($selectedWindow)
   Send("{ALT}")
   Sleep(1000)
   Send("{DOWN}")
   Send("{DOWN}")
   Send("{DOWN}")
   Send("{DOWN}")
   Send("{DOWN}")
   Send("{DOWN}")
   Send("{DOWN}")
   Send("{ENTER}")

   $dialog = WinGetHandle("Сравнить файлы")

   ;ControlSend($dialog, "", "[CLASS:V8FormElement; X:66; Y:6]", "{HOME}+{END}{DEL}")
   ;ControlSend($dialog, "", "[CLASS:V8FormElement; X:66; Y:6]", $FileName1)
   ;ControlSend($dialog, "", "[CLASS:V8FormElement; X:66; Y:30]", "{HOME}+{END}{DEL}")
   ;ControlSend($dialog, "", "[CLASS:V8FormElement; X:66; Y:30]", $FileName2)

   $old = ClipGet()

   ClipPut($FileName1)
   ControlSend($dialog, "", "[CLASS:V8FormElement; X:66; Y:6]", "{HOME}+{END}{DEL}^v{TAB}")

   ClipPut($FileName2)
   ControlSend($dialog, "", "[CLASS:V8FormElement; X:66; Y:30]", "{HOME}+{END}{DEL}^v{TAB}")

   ClipPut($old)

   Send("^{ENTER}")
EndFunc

Main()

Скрипт ищет открытые окна конфигуратора, предлагает выбрать (если их несколько), запускает стандатный диалог "Сравнить файлы" и подставляет пути к файлам, указанные в командной строке файла. Т.е. это аналог утилиты kdiff, только для файлов 1С. С помощью этого скрипта сравнение двух версий выполняется в несколько кликов:

1. Находим нужную версию файла и вызываем команду сравнения:

Команда сравнения двух версий

Скрипт открывает диалог сравнения в конфигураторе:

Диалог сравнения файлов

и запускает стандартную процедуру сравнения:

Результат сравнения

 

Как настроить

Настройка очень проста.

1. Нужно переписать файл "1c_diff.exe" (есть в архиве) в папку с установленной программой TortoiseHg (обычно это C:\Program Files\TortoiseHg\). В этой же папке обычно лежит kdiff3.

2. В папке локального хранилища зайти в служебную папку .hg и добавить текстовый файл "hgrc" (без расширения!) следующего содержания:

# Generated by TortoiseHg setting dialog


[extensions]
extdiff =

[extdiff]
cmd.vdiff = 1c_diff.exe

[tortoisehg]
vdiff = 1c_diff

Настройка закончена. После этого вместо стандартного сравнения kdiff будет использоваться скрипт 1c_diff.

В чем преимущества

Используются штатные средства, простая настройка, сохраняются все возможности работы с системой контроля версий, простое использование.

Замечания и предложения

Работа скрипта была проверена на 1С 8.2 и 8.3, серьезных неполадок замечено не было. Иногда в окно сравнения файлов "попадали" старые пути, т.е. высвечивался результат предыдущего сравнения. После закрытия и повторного запуска сравнения проблема пропадала. Думаю, проблема в кешировании файлов TortoiseHg, но дальше не разбирался.

Скрипт универсален, его можно применить и в других системах контроля версий. Если кто-то из читателей сможет применить его в другой программе - просьба отписаться в комментариях.

Скачать файлы

Наименование Файл Версия Размер
1c_diff.zip
.zip 467,84Kb
02.06.16
1
.zip 1 467,84Kb 1 Скачать

См. также

Комментарии
1. Игорь Пашутин (Alien_job) 111 02.06.16 07:03 Сейчас в теме
Для сравнения http://infostart.ru/public/334621/
Для версионирования используем именно то решение. Сам тоже использую Tortoise (только TortoiseGit) - мне им удобнее сравнивать тексты модулей, ну и поддерживаю зеркало своей рабочей папки в облаке.
2. Анатолий Златов (zan_od) 48 02.06.16 10:37 Сейчас в теме
(1) Alien_job, спасибо, ознакомился. Стараюсь следить за новинками на infostart, но эту статью я пропустил. В свое время пробовал пользоваться v8viewer (версия 1.0.2.6) - не впечатлил, функционал не дотягивал до штатного в 1С. Попробовал использовать штатное сравнение. Для коллективной разработки вряд ли подойдет, но для наведения порядка в версиях - самое то, имхо.
3. Сергей (ret-Phoenix) 137 03.06.16 14:02 Сейчас в теме
"Для хранения версий внешних обработок я использую TortoiseHg" - Правильней было бы "Для хранения версий внешних обработок я использую Mercurial"

TortoiseHg - не система контроля версий, а лишь оболочка над Mercurial.

Все продукты Tortoise представляют собой оболочки над какой-либо системой версий, в ряде случаев установка Tortoise без самой системы контроля версий ничего не делает, например при работе с Git.
4. Анатолий Златов (zan_od) 48 03.06.16 14:54 Сейчас в теме
(3) ret-Phoenix,
TortoiseHg - не система контроля версий, а лишь оболочка над Mercurial
- конечно Вы правы.
Но фразой "Для хранения версий внешних обработок я использую TortoiseHg" я хотел сказать, что речь идет о конкретной программе, используемой мной. Именно для этой программы приведена инструкция по настройке. Скорей всего, для других "оболочек" Mercurial (а тем более Git) настройка будет отличаться.