Задвоились предопределенные элементы справочников? Выход есть!

02.11.16

База данных - Чистка данных

Дублирование предопределенных элементов справочников может произойти как по причине того, что при обмене данными в режиме загрузки уникальность предопределенного элемента в пределах области информационной базы не проверяется, так и при объединении/обновлении конфигураций. При попытке переименовать, или, например, пометить на удаление 1С показывает сообщение «Предопределенный элемент не уникален». В этой статье мы напишем обработку, которая позволит избавиться от дублей предопределенных элементов справочника.

Скачать файлы

Наименование Файл Версия Размер
Обработка избавление от дублей предопределенных элементов справочника
.epf 11,47Kb
158
.epf 11,47Kb 158 Скачать

Задвоились предопределенные элементы справочников? Выход есть!

Дублирование предопределенных элементов справочников может произойти как по причине того, что при обмене данными в режиме загрузки уникальность предопределенного элемента в пределах области информационной базы не проверяется, так и при объединении/обновлении конфигураций.

При попытке переименовать, или, например, пометить на удаление 1С показывает сообщение «Предопределенный элемент не уникален».

В этой статье мы напишем обработку, которая позволит избавиться от дублей предопределенных элементов справочника.

Алгоритм следующий:

  • Первым делом мы найдем задвоенные (затроенные и т.д.) предопределенные элементы всех справочников.
  • Затем определим на какие элементы больше всего ссылаются другие объекты базы.
  • С учетом количества ссылок, определим как «правильные» те, на которые меньше всего других ссылок.
  • Оставим эти элементы предопределенными, а дубликаты сделаем непредопределенными (наименование сделаем как у предопределенных, для возможности дальнейшей замены всех ссылок на «правильный» соответствующий предопределенный элемент справочника).
  • Дальше можно заменить все ссылки объектов к этим дубликатам ссылками на те элементы, которые мы решили оставить предопределенными и при необходимости удалить дубликаты. Мы просто предложим пометить дубликаты на удаление.

Создадим новую обработку, и добавим табличную часть «ЗадублированныеСправочники»:

tablichnaya_chast_obrabotki.PNG

Реквизиты табличной части «ИмяСправочника», «СинонимСправочника» и «ИмяПредопределенныхДанных» - переменная строка неограниченной длины;

«КоличествоДублей» и «КоличествоСсылок» - неотрицательное число;

«ОставитьПредопределенным» - булево;

«ЭлементСправочника» тип «Справочник».

Создадим основную форму и разместим на ней табличную часть и кнопки «1. Заполнить», «2. Подсказать правильные», «3. Оставить предопределенными только отмеченные»:

forma_obrabotki.PNG

В теле процедуры обработчика нажатия кнопки «1. Заполнить» будем вызывать процедуру ЗадублированныеСправочникиЗаполнить()

Процедура ЗадублированныеСправочникиЗаполнить()
	
	//Очистим табличную часть, так как после выполнения конечного этапа
	//проконтролируем, что дубликаты исчезли
	ЗадублированныеСправочники.Очистить();
	
	//Построим текст запроса, для определения дубликатов
	//предопределенных элементов справочника #ИмяСправочника
	ТекстЗапроса = "ВЫБРАТЬ
	               |	#ИмяСправочника.Ссылка КАК Ссылка,
	               |	#ИмяСправочника.ИмяПредопределенныхДанных КАК ИмяПредопределенныхДанных
	               |ПОМЕСТИТЬ ВремТЗ
	               |ИЗ
	               |	Справочник.#ИмяСправочника КАК #ИмяСправочника
	               |ГДЕ
	               |	#ИмяСправочника.Предопределенный
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	ВремТЗ.ИмяПредопределенныхДанных,
	               |	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ВремТЗ.Ссылка) КАК КоличествоДублей
	               |ПОМЕСТИТЬ Дубли
	               |ИЗ
	               |	ВремТЗ КАК ВремТЗ
	               |
	               |СГРУППИРОВАТЬ ПО
	               |	ВремТЗ.ИмяПредопределенныхДанных
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	Дубли.ИмяПредопределенныхДанных КАК ИмяПредопределенныхДанных,
	               |	Дубли.КоличествоДублей КАК КоличествоДублей,
				   |	""#ИмяСправочника"" КАК ИмяСправочника,
				   |	""#СинонимСправочника"" КАК СинонимСправочника,
				   |	ЛОЖЬ КАК ОставитьПредопределенным,
	               |	ВремТЗ.Ссылка КАК ЭлементСправочника
	               |ИЗ
	               |	Дубли КАК Дубли
	               |		ЛЕВОЕ СОЕДИНЕНИЕ ВремТЗ КАК ВремТЗ
	               |		ПО Дубли.ИмяПредопределенныхДанных = ВремТЗ.ИмяПредопределенныхДанных
	               |ГДЕ
	               |	Дубли.КоличествоДублей > 1";
	
	Запрос = Новый Запрос;
	
	//Предупреждая замечания читателей и вопреки всем рекомендациям, будем выполнять запрос в цикле
	//для каждого справочника -
	//это читабельней и не приводит к существенной нагрузке на информационную базу,
	//нежели одним запросом охватывать все справочники 
	//(что, при определенных ограничениях на количество объединений может и вовсе не представлятся возможным)
	Для Каждого Стр Из Метаданные.Справочники Цикл
		
		ИмяСправочника = Стр.Имя;
		СинонимСправочника = Стр.Синоним;
		
		ПоказатьОповещениеПользователя("Поиск по справочнику " + СинонимСправочника);
		
		Запрос.Текст = ТекстЗапроса;
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "#ИмяСправочника", ИмяСправочника);
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "#СинонимСправочника", СинонимСправочника);
		
		Результат = Запрос.Выполнить();
		
		//В этом цикле добавляем строки в табличную часть
		Если Не Результат.Пустой() Тогда
			
			Выборка = Результат.Выбрать();
			
			Пока Выборка.Следующий() Цикл
				НовСтр = ЗадублированныеСправочники.Добавить();
				ЗаполнитьЗначенияСвойств(НовСтр, Выборка);
			КонецЦикла;
			
		КонецЕсли;
		
	КонецЦикла;
	
	//Отстортируем табличную часть и скроем колонку, в которой отображается
	//количество ссылок на предопределенный элемент справочника
	//(по количеству ссылок на объект, пользователю будет легче определить "правильный" объект)
	ЗадублированныеСправочники.Сортировать("ИмяСправочника, ИмяПредопределенныхДанных");
	ЭлементыФормы.ЗадублированныеСправочники.Колонки.КоличествоСсылок.Видимость = Ложь;
	
КонецПроцедуры

В процессе работы данной процедуры мы будем следить за тем, какие справочники проверяются на дубли в специальном окне:

knopka 1 sostoyanie.PNG

Это окно реализовано функцией глобального контекста ПоказатьОповещениеПользователя()

При окончании процедуры мы получим заполненную дубликатами табличную часть, в колонке «Правильные» указывается предопределенный элемент справочника, который необходимо оставить:

zapolnenaya_dublikatami.PNG

Теперь пользователь может либо сам определить «правильные» предопределенные, либо воспользоваться подсказкой по кнопке «2. Подсказать правильные».

В теле процедуры обработчика нажатия этой кнопки будем вызывать процедуру ПодсказатьПравильные() – как уже было сказано, подсказка заключается в определении количества ссылающихся объектов информационной базы на предопределенный элемент справочника – чем больше ссылок на элемент, тем он «правильнее» (меньше ссылок придется заменять в дальнейшем):

Процедура ПодсказатьПравильные()
	
	//Находим ссылки на дубликаты
	ТаблицаСсылок = НайтиПоСсылкам(ЗадублированныеСправочники.ВыгрузитьКолонку("ЭлементСправочника"));
	ТаблицаСсылок.Колонки.Добавить("Количество", Новый ОписаниеТипов("Число"));
	ТаблицаСсылок.ЗаполнитьЗначения(1,"Количество");
	
	//считаем количество ссылок на каждый дубликат
	ТаблицаСсылок.Свернуть("Ссылка", "Количество");
	
	//Заполняем колонку "Количество ссылок"
	Для Каждого СтрТаблицаСсылок Из ТаблицаСсылок Цикл
		
		НайденныеСтроки = ЗадублированныеСправочники.НайтиСтроки(Новый Структура("ЭлементСправочника, КоличествоСсылок", СтрТаблицаСсылок.Ссылка, 0));
		Если НайденныеСтроки.Количество() > 0 Тогда
			НайденныеСтроки[0].КоличествоСсылок = СтрТаблицаСсылок.Количество;
		КонецЕсли;
		
	КонецЦикла;
	
	//Пусть максимальное количество каждого предопределенного элемента
	//будет наверху в группе каждого типа справочника
	ЗадублированныеСправочники.Сортировать("ИмяСправочника, ИмяПредопределенныхДанных, КоличествоСсылок Убыв");
	//Покажем эту колонку пользователю
	ЭлементыФормы.ЗадублированныеСправочники.Колонки.КоличествоСсылок.Видимость = Истина;
	
КонецПроцедуры

Данная операция будет довольно длительной – производится поиск всех ссылающихся объектов, по окончании мы получим рекомендации:

rekomendacii.PNG

Теперь пользователь может определить «правильный» элемент, руководствуясь данными о количестве ссылающихся объектов базы на конкретный элемент предопределенного справочника:

pravilnii.PNG

В теле процедуры обработчика нажатия кнопки «3. Оставить предопределенными только отмеченные» будем вызывать процедуру ОставитьТолькоОдинПредопределенный(). Кстати, спросим – помечать ли на удаление «неправильные».

vopros.PNG

Процедура ОставитьТолькоОдинПредопределенный()
	
	ПометкаУдаления = Ложь;
	
	ВыполненоУспешно = Ложь;
	
	//спросим – помечать ли на удаление «неправильные»
	Режим = РежимДиалогаВопрос.ДаНет;
	Ответ = Вопрос("Пометить на удаление дубли элементов?", Режим, 0);
	
	Если Ответ = КодВозвратаДиалога.Да Тогда
		
	    ПометкаУдаления = Истина;
		
	КонецЕсли; 
	
	ОставитьПредопределеннымКонтроль = ЗадублированныеСправочники.Выгрузить();
	ОставитьПредопределеннымКонтроль.Свернуть("ИмяСправочника, ИмяПредопределенныхДанных", "ОставитьПредопределенным");
	
	Для Каждого Стр Из ЗадублированныеСправочники Цикл
		
		ОтборНеУказанОставитьПредопределенным = Новый Структура("ИмяСправочника, ИмяПредопределенныхДанных, ОставитьПредопределенным", Стр.ИмяСправочника, Стр.ИмяПредопределенныхДанных, Ложь);
		
		Если НЕ Стр.ОставитьПредопределенным И ОставитьПредопределеннымКонтроль.НайтиСтроки(ОтборНеУказанОставитьПредопределенным).Количество() = 0 Тогда
			
			ЭлементОбъект = Стр.ЭлементСправочника.ПолучитьОбъект();
			Если ЭлементОбъект <> Неопределено Тогда
				
				Если Не ЗначениеЗаполнено(ЭлементОбъект.Наименование) Тогда
					ЭлементОбъект.Наименование = ЭлементОбъект.ИмяПредопределенныхДанных;
				КонецЕсли;
				
				ЭлементОбъект.ИмяПредопределенныхДанных = "";//Именно в этом месте мы избавляемся от предопределенности
				ЭлементОбъект.ПометкаУдаления = ПометкаУдаления;
				ЭлементОбъект.Записать();
				ВыполненоУспешно = Истина;
				
				Сообщить("Элемент" + ЭлементОбъект.Наименование + " справочника " + Стр.СинонимСправочника + " сделан непредопределенным.");
				
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЦикла;
	
	//Проконтролируем результат, а также, возможно пользователь "работал" только с определенными справочниками
	Если ВыполненоУспешно Тогда
		ЗадублированныеСправочникиЗаполнить();
	КонецЕсли;
	
КонецПроцедуры

Ну, и по традиции - во вложении исходная обработка.

См. также

Удаление данных с отбором и построением дерева ссылок в базах 1С 8.1-8.3 УТ 10.3./11, БП 2/3, ЗУП 2.5/3, КА 1.1/2, УНФ 1.6/3.0

Чистка данных Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 1С:Управление торговлей 10 1С:Управление торговлей 11 Платные (руб)

Данные обработки помогут Вам легко и, главное быстро, выполнить удаление любых данных в Ваших базах 1С на платформах 8.1-8.3. Обработки помогут легко просмотреть связи ссылок в виде дерева, выбрать что удалять, а что нет, используя любые отборы. Это позволит уменьшить объем лишней и не нужной информации в справочниках и документах, планах видов характеристик и др. объектах и облегчит работу с данными пользователям и Вам. Понятное расположение команд и настроек, в сочетании с описанием и справкой, еще упростят процесс. (Обновление от 04.10.2023, версия 4.2)

9600 руб.

22.02.2013    135747    248    144    

418

SALE! 10%

Выборочное удаление организаций из баз (управляемые формы), с удалением всех ссылающихся на эти организации данных

Чистка данных Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Позволяет удалить организации из любых программ на управляемых формах (БП 3.0, УТ 11, КА 2, ERP 2, ЗУП 3.0, УНФ, Розница 2.0 и пр.). Главное требование - программа должна содержать справочник "Организации". Реализован самый быстрый алгоритм непосредственного удаления объектов. Работает даже на базах большого размера. Для ускорения работы алгоритма не запускается проверка контроля ссылочной целостности. Проверку учета можно запустить отдельно с помощью дополнительной обработки. Необходимо перед удалением самостоятельно проверить базу на наличие перекрестных ссылок разных организаций в одном документе. Эту дополнительную обработку проверки перекрестных ссылок по запросу предоставляем бесплатно нашим покупателям.

3980 3582 руб.

16.03.2015    113518    181    75    

217

Универсальное выборочное удаление данных из базы 1С (любые конфигурации на упр.формах: БП 3.0, УТ 11, КА 2, ERP, УНФ, ЗУП 3, Розница и т.д.)

Чистка данных Платформа 1С v8.3 Управляемые формы 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Зарплата и кадры государственного учреждения 3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Платные (руб)

Обработка позволяет удобно выборочно удалить данные из базы 1С. Это могут быть как неиспользуемые элементы справочников, так и неактуальные организации. При этом есть возможность провести анализ пересечений документов с другими организациями и таким образом уберечься от того, что при удалении обороты по другой организации изменятся.

3350 руб.

28.11.2019    24236    45    16    

58

Замена Номенклатуры+Характеристики

Чистка данных Логистика, склад и ТМЦ Платформа 1С v8.3 План видов характеристик 1С:Комплексная автоматизация 1.х 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)

Настраиваемая обработка, позволяющая заменить пару: Номенклатура+Характеристика в документах, их движениях и независимых регистрах сведений. Без перепроведения. Поможет, если вы по каким-то причинам решили отказаться от характеристик

3600 руб.

04.08.2015    41063    88    70    

49

Очистка дублей в синхронизированных базах (УТ, БП, РТ, УНФ)

Чистка данных Управляемые формы Конфигурации 1cv8 Россия Платные (руб)

Решение по удалению дублей позволяет определить связанные элементы в двух синхронизированных базах в качестве оригиналов и избежать необходимости ручного сравнения объектов в базах перед синхронизацией.

3960 руб.

27.06.2018    18782    10    3    

15

Удаление битых ссылок 1С в базе без монопольного режима

Чистка данных Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Если в вашей информационной базе крутится очень много данных, или база должна быть доступна 24/7 (как в моем случае), или же вы боитесь запускать тестирование и исправление, НО существует потребность удалить битые ссылки, тогда эта обработка сможет Вам помочь. Обработка выявляет битые ссылки как в самих объектах метаданных, так и в их табличных частях(!), а так же может их удалить.

2400 руб.

23.08.2021    9223    15    3    

20

Очистка регистров сведений от записей по помеченным на удаление элементам

Чистка данных Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

в современных конфигурациях стало очень много регистров сведений, хранящих вспомогательную и периодическую информацию и администраторы информационных систем стали сталкиваться с проблемой удаления помеченных на удаление объектов, так как ссылки на них хранятся в многочисленных регистрах сведений. Помочь почистить базу от ненужных записей предназначенная данная внешняя обработка на управляемой форме, которая ищет записи во всех регистрах сведений по помеченным на удаление объектах и очищает по ним записи их после использования данной обработки дальше можно смело пользоваться типовой обработкой удаление помеченных на удаление и проблем с удалением не возникнет! Удачи всем!

1200 руб.

21.01.2022    7095    5    6    

9

Очистка кэша 1С. Исполнитель

Чистка данных Инструментарий разработчика Платформа 1С v8.3 Абонемент ($m)

Очередная вариативная очистка кэша 1С с помощью Исполнителя 3.0.2.2.

1 стартмани

25.10.2023    4494    4    SerVer1C    25    

22
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. vakula28 14 09.11.16 09:10 Сейчас в теме
Как, минимум, есть уже вот это. Достаточно удобный инструмент и на УФ.
http://infostart.ru/public/305892/
2. Luchik 673 09.11.16 09:44 Сейчас в теме
(1) Но в указанной Вами публикации можно только скачать обработку. А пользуясь этой статьей читатель может написать обработку под свои задачи.
B-Anna; GhostIrviWolf; Romario_; Swetlana; +4 Ответить
3. chmv 09.11.16 11:52 Сейчас в теме
да и писать ничего не надо. делаешь заменой реквизитов один элемент непредопределенным, помечаешь на удаление, перебрасываешь ссылки
У нас делал делал продвинутый пользователь
9. Monex 01.03.22 07:02 Сейчас в теме
(3) Как-то сомнительно - групповой обработкой даже в режиме разработчика нельзя изменить признак предопределенности
4. Michael0507 22.08.18 09:10 Сейчас в теме
Тем не менее держать под руками такую обработку очень удобно. Полный автомат. Спасибо.
5. WellMaster 104 14.11.18 13:58 Сейчас в теме
Есть нюанс, отметил на рисунке.
Прикрепленные файлы:
6. Luchik 673 14.11.18 14:12 Сейчас в теме
7. Улыбайка 7 16.01.19 16:22 Сейчас в теме
Скачала обработку, не открывается в упр форах, обидно, не обратила внимания что в описании ничего не сказано в каких форах работает обработка
8. Поручик 4670 27.05.19 13:44 Сейчас в теме
Вот и пригодилось. Будем делать обработку на УФ. Эта мне больше понравилась.
10. Dimkis 12.04.22 08:24 Сейчас в теме
Спасибо, очень помогли. Собрал для УФ. Нужно было исправлять 90 РИБов.
Оставьте свое сообщение