gifts2017

Организация выбора из произвольной формы

Опубликовал boltoff (boltoff) в раздел Программирование - Практика программирования

1С:Предприятие 8 поддерживает готовую функциональность для организации выбора из форм списков объектных данных (справочников, документов и т.д.). В большинстве случаев выбираются именно такие значения. Однако, в некоторых случаях, необходимо организовать выбор и других значений. Механизм форм 1С:Предприятия 8 включает универсальный механизм выбора, позволяющий организовать выбор практически любых значений.

Для этого используется возможность открытия формы в режиме выбора и возможность обработки события выбора.

В качестве примера приведем реализацию выбора записи регистра сведений. Стандартные расширения форм не поддерживают механику выбора, однако ее несложно реализовать.

Вначале создадим новую форму списка регистра сведений и назовем ее "ФормаВыбора". В форме реализуем событие Выбор табличного поля отображающего список.

// Форма списка регистра сведений
Процедура РегистрСведенийСписокВыбор(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)
    ОповеститьОВыборе(ВыбраннаяСтрока);
    СтандартнаяОбработка = Ложь;
КонецПроцедуры

В этом событии мы отменяем стандартное действие, предусмотренное расширением табличного поля, и вместо него вызываем метод ОповеститьОВыборе(), передавая ему в качестве параметра текущую строку. Значением текущей строки будет являться значение типа РегистрСведенийКлючЗаписи.<имя>.

Теперь реализуем функциональность выбора в той форме, в которой это требуется. Например, в форме обработки, имеющей поля ввода "Валюта" и "Период".
// Форма, из которой выполняется выбор
Процедура КнопкаВыполнитьНажатие(Кнопка)

// Создадим ключ, идентифицирующий строку в списке регистра
ДанныеКлюча = Новый Структура("Период, Валюта", Период, Валюта);
Ключ = РегистрыСведений.КурсыВалют.СоздатьКлючЗаписи(ДанныеКлюча);

// Создадим форму регистра и откроем ее
Фрм = РегистрыСведений.КурсыВалют.ПолучитьФормуСписка("ФормаВыбора");
Фрм.РежимВыбора = Истина;
Фрм.ВладелецФормы = ЭтаФорма;
Фрм.ПараметрТекущаяСтрока = Ключ;
Фрм.Открыть();

КонецПроцедуры

Процедура ОбработкаВыбора(ЗначениеВыбора, Источник)

// Обработаем значение выбора
Валюта = ЗначениеВыбора.Валюта;
Период = ЗначениеВыбора.Период;

КонецПроцедуры

Вначале мы сформируем ключ записи регистра сведений, который будет использоваться для установки в списке текущей строки в соответствии с текущими значениями полей ввода. Сама установка будет выполняться через стандартный параметр формы ПараметрТекущаяСтрока.

Заметим, что если для установки текущей строки расширение формы не предоставляет стандартного параметра, то можно создать свой реквизит у формы выбора, заполнить его аналогично заполнению стандартного параметра в этом примере, и при открытии формы обеспечить позиционирование в списке в соответствии со значением данного реквизита.

Далее мы создаем форму, устанавливаем ей режим выбора, владельца формы, и выполняем открытие формы.

Теперь нам нужно только реализовать обработчик выбора в форме и выполнить в нем необходимее действия с выбранным значением.

Заметим, что в качестве владельца формы может устанавливаться не только сама форма, в которой осуществляется выбор, но и ТабличноеПоле, ПолеВвода и ПолеВыбора. Соответственно и обработчик выбора нужно будет реализовывать у этих элементов управления.

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Александр Полтава (Патриот) 12.08.14 12:55
Большое человеческое спасибо!
Написал отчет на СКД для самописной конфы на УФ, но никак не мог выбрать подразделение из справочника Подразделения в реквизитах отбора.

В итоге пришёл к тому, что косячит форма выбора справочника Подразделения, где в обработчике события "выбор" нашёл такой код
	ЭтаФорма.Закрыть(Элемент.ТекущиеДанные.Подразделение);

Никак не мог разобраться, т.к. уже два года не писал на УФ, но благодаря этой статье, код выше заменил на

	//Патриот 12.08.2014\
	//заменил строку, т.к. не работал предопределённый платформой механизм выбора (нельзя было выбрать подразделение в 
	//произвольный реквизит произвольной формы, не писав при этом программный код создания формы и получения выбранного значения)
	//ЭтаФорма.Закрыть(Элемент.ТекущиеДанные.Подразделение);
	ОповеститьОВыборе(Элемент.ТекущиеДанные.Подразделение);
	//Патриот 12.08.2014/
...Показать Скрыть


и всё заработало (код написанный до меня тоже продолжил функционировать)
2. Александр Полтава (Патриот) 12.08.14 12:58
Кстати, очень удачное название статьи, благодаря этому она оказалась в первых результатах поиска)
3. Василий Орлов (Bublik2011) 09.12.14 15:44
(2) Патриот, +1

Я нашел эту статью при поиске, прочитал, проблему не решило. Мне вспомнилось - "вот, только скачивают, сами ничего не пишут"

Учитывая оба этиъ обстоятельства, пишу код :)

ФормаОтбора = ПолучитьФорму("ФормаОтбора");	
ТаблицаОтбора = Новый ТаблицаЗначений;	
ОбщегоНазначения.ЗаполнитьОтборПоТаблицеЗначений(ФормаОтбора.Отбор, ТаблицаОтбора);


Чуть позже нашел статью "Формирование отчета с использованием СКД и внешних наборов данных". Подробно написано, удалось решить задачу - соединить остатки 2 разных баз "Управление Торговлей" и бухгалтерской.

Ой, извините, год публикации устарел, за это время вышла книга Гилева, в которой все так хорошо написано.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа