Полное копирование одной формы в другую

03.10.19

Разработка - Универсальные функции

+38 –
> > > >
  • 2019-10-03_11-13-03.png
  • 2019-10-03_11-14-04.png
  • 2019-10-03_11-40-21.png
  • 2019-10-03_11-41-47.png
  • 2019-10-03_11-43-05.png
Однажды я столкнулся с необходимостью открыть форму ЛЮБОГО документа с определенными изменениями, не зависящими от структуры объекта (например, заблокировать все кнопки). В интернете решения я не нашел. Обычно на форумах на запросы подобного рода отвечают чем-то вроде "покажи первоначальную задачу, а не спрашивай как реализовать то, что ты придумал". Тем не менее, мне стало интересно, как это можно сделать.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование По подписке [?] Купить один файл
Заполнение из внешней формы:
.epf 10,32Kb ver:1.0.0
8
8 Скачать (1 SM) Купить за 1 850 руб.
Копирование форм:
.epf 23,67Kb ver:1.0.0
16
16 Скачать (1 SM) Купить за 1 850 руб.

Возможные варианты использования:

  • У вас есть документ, вам надо что-то в нем поменять, но срабатывает событие "при изменении" и едут суммы. Во внешней форме можно это сделать без обработчиков событий.
  • Вам нужно заполнить реквизит формы (не объекта). Групповое изменение реквизитов работает с объектами, а не с данными формы.
  • Нужно изменить заблокированные реквизиты формы (серенькие).

Изначально идея была такова (упрощенно):

ФормаИсточник = ПолучитьФорму("Документ.ЗаказКлиента.ФормаОбъекта");
ФормаПриемник = ПолучитьФорму("ВнешняяОбработка.с_ЗаполнениеИзВнешнейФормы.Форма");

Для Каждого ЭлементИсточник Из ФормаИсточник.Элементы Цикл
	
	ЭлементПриемник = ФормаПриемник.Элементы.Добавить(ЭлементИсточник.Имя, 
		ЭлементИсточник.ТипЭлемента, ФормаПриемник.Элементы[ЭлементИсточник.Родитель.Имя]);
	
	ЗаполнитьЗначенияСвойств(ЭлементПриемник, ЭлементИсточник);

КонецЦикла;

Но такой подход оказался нежизнеспособным. Для того чтобы скопировать элементы одной формы на другую, нужно иметь к ним обеим одновременный доступ. А из-за того, что метод ПолучитьФорму() доступен только на клиенте, управлять копированием можно только с клиента. Но на клиенте недоступно свойство ПутьКДанным элементов формы, не доступен метод ПолучитьРеквизиты(). Они доступны только в серверном контексте. А к нему есть доступ только у самой формы.

Поместить форму во временное хранилище и передать через клиента адрес тоже не получится, потому что она не сериализуется. Единственный выход - сериализовать форму самостоятельно.

 
Кстати, интересное наблюдение  

Из-за того что серверный контекст формы доступен только из нее самой, копируемую форму придется редактировать. В нее нужно будет добавить функцию, возвращающую структуру с описанием формы:

&НаСервере
Функция с_ПолучитьОписаниеФормы() Экспорт
	
	Возврат с_КопированиеФорм.с_ПолучитьОписаниеФормы(ЭтаФорма, РеквизитФормыВЗначение("Объект"));
	
КонецФункции

Объект мы передаем для того чтобы можно было отличить добавленные на форму колонки табличных частей от тех которые были в объекте изначально.

В форме-приемнике нужно будет прописать процедуру заполнения по переданному описанию:

&НаСервере
Процедура с_ЗаполнитьФормуПоОписанию(АдресВоВременномХранилище) Экспорт
	
	с_КопированиеФорм.с_ЗаполнитьФормуПоОписанию(ЭтаФорма, АдресВоВременномХранилище);
	
КонецПроцедуры

В обработке для копирования остается только выполнить код:

ФормаИсточник = ПолучитьФорму("Документ.ЗаказКлиента.ФормаОбъекта");
ФормаПриемник = ПолучитьФорму("ВнешняяОбработка.с_ЗаполнениеИзВнешнейФормы.Форма");

АдресВоВременномХранилище = ФормаИсточник.с_ПолучитьОписаниеФормы();
ФормаПриемник.с_ЗаполнитьФормуПоОписанию(АдресВоВременномХранилище);

Вообще говоря, этого достаточно. Но если мы копируем уже открытую форму документа, хотелось бы чтобы в нее переносились данные которые уже есть на форме. Для этого делаем так:

КопироватьДанныеФормы(ФормаИсточник.Объект, ФормаПриемник.Obj);

Obj - это объект, который будет хранить копию объекта источника в форме приемника. Использовать объект приемника не получится, т.к. он будет с другим типом (вероятно, ВнешняяОбработкаОбъект).

Примечание: Если вы хотите побыстрее воспользоваться обработкой - идите в конец статьи. Там под спойлером я спрятал код, который копируется в общий модуль, и выложил пару примеров, демонстрирующих решение. Далее я поясняю как всё работает и почему так сделано.

Структура передается через временное хранилище чтобы уменьшить количество передаваемых между клиентом и сервером данных. К тому же, системные перечисления, которые используются в качестве свойств элементов, не сериализуются, и с ними пришлось бы возиться отдельно.

С добавлением элементов в структуру тоже есть некоторые нюансы, которые следует учесть:

Во-первых, элементы формы не помещаются во временное хранилище, поэтому их тоже придется сериализовать самостоятельно.

Во-вторых, если мы возьмем просто список элементов, то отсортированы они будут по алфавиту, и может так получиться, что подчиненный элемент будет добавляться раньше родителя, что вызовет ошибку.

В-третьих, в зависимости от типов и видов элементов меняется набор имеющихся свойств. 

Для добавления свойства в структуру используется отдельная процедура. Свойств у элементов очень много, и если копировать их через "ОписаниеЭлемента.Вставить()" то имя свойства придется указывать дважды. Процедура просто сокращает объем текста.

Процедура с_ДобавитьЗначениеСвойства(ОписаниеЭлемента, Элемент, ИмяСвойства)
	
	Значение = Элемент[ИмяСвойства];
	ОписаниеЭлемента.Вставить(ИмяСвойства, Значение);
	
КонецПроцедуры

И вызывается она как то так:

с_ДобавитьЗначениеСвойства(ОписаниеЭлемента, Элемент, "Видимость");

В зависимости от типа элемента меняется его набор свойств.

Функция с_ПолучитьОписаниеЭлемента(Элемент)
	
	ОписаниеЭлемента = Новый Структура;
	
	//Чтобы отличать корневые элементы от остальных, для корневых в качестве родителя передаем "Неопределено"
	Если ТипЗнч(Элемент.Родитель) = Тип("УправляемаяФорма") Тогда
		ОписаниеЭлемента.Вставить("Родитель", Неопределено);
	Иначе
		ОписаниеЭлемента.Вставить("Родитель", Элемент.Родитель.Имя);
	КонецЕсли;
	
	//Основные свойства элемента
	ОписаниеЭлемента.Вставить("Имя", Элемент.Имя);
	ОписаниеЭлемента.Вставить("ТипЭлемента", ТипЗнч(Элемент));
	
	//Остальные свойства в зависимости от типа элемента
	Если ТипЗнч(Элемент) = Тип("ГруппаФормы") Тогда
		с_ДобавитьОписаниеГруппыФормы(ОписаниеЭлемента, Элемент);
		
	ИначеЕсли ТипЗнч(Элемент) = Тип("ТаблицаФормы") Тогда
		с_ДобавитьОписаниеТаблицыФормы(ОписаниеЭлемента, Элемент);
		
	ИначеЕсли ТипЗнч(Элемент) = Тип("ПолеФормы") Тогда
		с_ДобавитьОписаниеПоляФормы(ОписаниеЭлемента, Элемент);
		
	ИначеЕсли ТипЗнч(Элемент) = Тип("КнопкаФормы") Тогда
		с_ДобавитьОписаниеКнопкиФормы(ОписаниеЭлемента, Элемент);
		
	КонецЕсли;
	
	Для Каждого КлючИЗначение Из ОписаниеЭлемента Цикл
		
		//Заменяем в пути к данным "Объект" на "Obj" чтобы не было конфликтов между объектами форм источника и приемника
		Если (КлючИЗначение.Ключ = "ПутьКДанным"
			Или КлючИЗначение.Ключ = "ПутьКДаннымПодвала"
			Или КлючИЗначение.Ключ = "ПутьКДаннымЗаголовка")
			И Лев(КлючИЗначение.Значение, 6) = "Объект" Тогда
			ОписаниеЭлемента[КлючИЗначение.Ключ] = "Obj" + Прав(КлючИЗначение.Значение, СтрДлина(КлючИЗначение.Значение) - 6);
		КонецЕсли;
		
	КонецЦикла;
	
	Возврат ОписаниеЭлемента;
	
КонецФункции

Для получения коллекций (подчиненных элементов или командной панели) создана отдельная процедура, добавляющая элементы в цикле.

Функция с_ПолучитьОписаниеЭлементов(КоллекцияЭлементовФормы)
	
	ОписаниеКоллекции = Новый Массив;

	Для Каждого Элемент Из КоллекцияЭлементовФормы Цикл
		
		ОписаниеЭлемента = с_ПолучитьОписаниеЭлемента(Элемент);
		ОписаниеКоллекции.Добавить(ОписаниеЭлемента);
		
	КонецЦикла;
	
	Возврат ОписаниеКоллекции;
	
КонецФункции

Заполнение описания в зависимости от типов элементов можно посмотреть в коде в конце статьи. Интеллектуальной нагрузки оно не содержит, только долгую кропотливую работу.

Аналогичные действия производятся и в обратном порядке.

Заполнение свойств выделено в отдельную процедуру с той же целью - уменьшить количество текста.

&НаСервере
Процедура с_ЗаполнитьЗначениеСвойства(Элемент, ОписаниеЭлемента, ИмяСвойства);
	
	Если Элемент[ИмяСвойства] <> ОписаниеЭлемента[ИмяСвойства] Тогда
		Элемент[ИмяСвойства] = ОписаниеЭлемента[ИмяСвойства];
	КонецЕсли;
	
КонецПроцедуры

И вызывается она так:

с_ЗаполнитьЗначениеСвойства(Элемент, ОписаниеЭлемента, "Видимость");

Что касается архитектуры загрузки, то она немного изменена. Обусловлено это тем, что когда мы заполняли описание из формы, то работали и с отдельными элементами/группами и с коллекциями (подчиненными элементами). В структуре же содержатся только массивы описаний, поэтому отталкиваться следует не от процедуры заполнения свойств по одному элементу, а от обработки массива.

Процедура с_СоздатьЭлементы(Форма, ОписаниеКоллекции)
	
	Для Каждого ОписаниеЭлемента Из ОписаниеКоллекции Цикл
		
		//"Неопределено" в качестве родителя записано у корневых элементов
		Если ОписаниеЭлемента.Родитель = Неопределено Тогда
			Родитель = Форма;
		Иначе
			Родитель = Форма.Элементы[ОписаниеЭлемента.Родитель];
		КонецЕсли;
		
		//Создаем элемент на форме
		Элемент = Форма.Элементы.Добавить(ОписаниеЭлемента.Имя, ОписаниеЭлемента.ТипЭлемента, Родитель);
		
		//Заполняем элемент в соответствии с описанием
		с_ЗаполнитьСвойстваЭлементаФормы(Форма, Элемент, ОписаниеЭлемента);
		
	КонецЦикла;

КонецПроцедуры

И уже в процедуре заполнения делается ветвление в зависимости от типа элемента:

Процедура с_ЗаполнитьСвойстваЭлементаФормы(Форма, Элемент, ОписаниеЭлемента)
	
	Если ОписаниеЭлемента.ТипЭлемента = Тип("ГруппаФормы") Тогда
		с_ЗаполнитьСвойстваГруппыФормы(Форма, Элемент, ОписаниеЭлемента);
		
	ИначеЕсли ОписаниеЭлемента.ТипЭлемента = Тип("ТаблицаФормы") Тогда
		с_ЗаполнитьСвойстваТаблицыФормы(Форма, Элемент, ОписаниеЭлемента);
		
	ИначеЕсли ОписаниеЭлемента.ТипЭлемента = Тип("ПолеФормы") Тогда
		с_ЗаполнитьСвойстваПоляФормы(Элемент, ОписаниеЭлемента);
		
	ИначеЕсли ОписаниеЭлемента.ТипЭлемента = Тип("КнопкаФормы") Тогда
		с_ЗаполнитьСвойстваКнопкиФормы(Элемент, ОписаниеЭлемента);
		
	КонецЕсли;
	
КонецПроцедуры

Как и при заполнении описания, заполнение свойств элементов в зависимости от типа интереса не представляет и можно найти в полной версии кода (тремя абзацами ниже).

Для демонстрации кода я сделал две простые обработки. Их краткое описание:

Заполнение из внешней формы. Подключаемая к подсистеме дополнительных отчетов и обработок БСП обработка заполнения. В документах, указанных в списке назначений появляется кнопка "Заполнение->Заполнение из внешней формы (С)". При нажатии на кнопку открывается копия формы со всеми данными, но отключенными событиями. При нажатии на кнопку "Перенести в документ" введенные данные копируются в первоначальную форму. ВАЖНО!!! Для работы обработки в форме документа должна быть процедура с_ПолучитьОписаниеФормы(), которую можно найти в модуле объекта обработки.

Копирование форм. Демонстрирует работу описанного в статье подхода. Имеет форму источник и форму приемник. Весь код находится в них, изменять конфигурацию не нужно.

 
 Общий модуль с_КопированиеФорм

 

Конфигурация значения не имеет.

Обе обработки тестировались на платформе 8.3.15.1565

Внешняя обработка заполнения тестировалась на БСП версии 3.0.3.77

Обработка копирования форм от БСП не зависит.

Управляемая форма внешняя обработка элементы копирование добавление

+38 –

См. также

Загрузка табличного документа в таблицу значений. Пять строк кода, которые изменили мир

Универсальные функции Программист Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Благодаря этим пяти строчкам можно больше не заморачиваться с загрузкой из внешних файлов. Пользуюсь везде, всегда и постоянно.

21.05.2024    22013    dimanich70    81    

147
Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Программист Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    4241    3    John_d    11    

57
GUID в 1С 8.3

Универсальные функции Программист Стажер Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    20846    atdonya    25    

58
Переоткрытие внешних обработок

Универсальные функции Программист Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    5714    ke.92@mail.ru    17    

65
Генерация штрихкода и QR, разбор настроек и примеры

БСП (Библиотека стандартных подсистем) Сканер штрих-кода Универсальные функции Этикетки, ценники Программист Бизнес-аналитик Конфигурации 1cv8 Бесплатно (free)

Разберем на примерах использование компоненты из БСП для генерации штрихкода и матричных кодов.

15.09.2023    19895    YA_418728146    9    

119
Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Программист Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    15471    YA_418728146    7    

169
Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    3768    59    progmaster    8    

4
Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    18757    173    sapervodichka    112    

136
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. VmvLer 03.10.19 13:30 Сейчас в теме
КопироватьДанныеФормы(ВладелецФормы.Объект, ИсточникФормы);
+ – Ответить
2. nekit_rdx 221 03.10.19 14:17 Сейчас в теме
(1)
КопироватьДанныеФормы

Во-первых, источник в этом методе идет в первом параметре. Во-вторых, что вы пытаетесь им сделать? В статье я использую КопироватьДанныеФормы(), но сделано это для переноса данных формы, а не элементов.
+ – Ответить
3. VmvLer 03.10.19 14:41 Сейчас в теме
(2) я не читал статью, думал вы вопрос задал - поэтому копирнул вызов из своего кода.
сейчас пробежал по тексту и слегка в замешательстве от количества костылей.

мне хватало метода КопироватьДанныеФормы() для подобных задач
и что-там в параметрах я использую зависит от моей задачи.

минимизировать безразмерные костыли может помогут идеи
тут https://forum.infostart.ru/forum9/topic102786/
+ – Ответить
4. nekit_rdx 221 03.10.19 15:00 Сейчас в теме
(3) Странно отвечать не читая статью, но да ладно, время ресурс ограниченный, можно понять.

По ссылке довольно интересное решение, спасибо. Правда там задача немного другая, сохранить и передать параметры не зная их список. У меня же задача сохранить и передать все элементы формы. Предполагаю что с параметрами как раз таки проблем не возникнет просто преобразовать их через ДанныеФормыВЗначение(), что в общем то может сработать.

Использовать же СериализаторXDTO для записи формы в XML врядли сработает по той же причине, по которой она не помещается во-временное хранилище - платформа не позволяет сериализовать форму и считает что она должна быть доступна только на клиенте.
Sintson; +1 – Ответить
5. VmvLer 03.10.19 15:14 Сейчас в теме
Полагаю, что идея по ссылке применима ко всей форме, поэтому я и закинул ее вам, вдруг вы решите отпимизировать свой продукт и вместо массы странного кода получиться метод на один лист.

И вот потом я обязательно внимательно его прочитаю и заберу себе - моя цель чужие идеи в публичном доступе, а не мучения с их реализацией.

старайтесь!
+ –1 Ответить
6. nekit_rdx 221 03.10.19 16:13 Сейчас в теме
(5) Сериализация работает для параметров, но не работает для управляемой формы, я проверил.

Текст ошибки


Есть еще идеи как избавиться от костылей? Кстати, а что вы называете костылями?
+ – Ответить
7. SlavaKron 03.10.19 18:38 Сейчас в теме
Форма документа доступна на сервере вне своего модуля, для подключенной обработки с видом ЗаполнениеФормы (примерно так), если имеем дело с БСП.
nekit_rdx; +1 – Ответить
8. Yashazz 4796 04.10.19 12:10 Сейчас в теме
Можно предположить, что форму все-таки можно получить из метаданных на сервере и там же обработать

Нельзя. И никогда не было и не будет можно, пока разработкой платформы рулит С.Нуралиев. По его словам, все эти штуки в метаданных - настолько для внутреннего служебного, что нам не светит.
+ – Ответить
11. nekit_rdx 221 04.10.19 13:41 Сейчас в теме
(8) Забавно что в других языках ограничения создаются в целях безопасности, исключения утечек памяти и подобного, а в 1С из-за несоответствия с концепцией.
+ – Ответить
9. Yashazz 4796 04.10.19 12:14 Сейчас в теме
1. Переменные, объявленные в модуле формы, копируются?
2. Что происходит с данными во временных хранилищах, загнанных туда по GUID исходной формы?
3. Учитываются ли обработчики ожидания исходной формы?
+ – Ответить
10. nekit_rdx 221 04.10.19 13:36 Сейчас в теме
(9)

1. Копировать переменные, объявленные в модуле формы равносильно копированию кода этого модуля. По крайней мере я не знаю другого способа получить к ним доступ. Теоретически да, можно выгрузить модуль в файл и распарсить его. Технически - не проще ли использовать реквизиты формы?

2. Данные формы во временное хранилище передаются через структуру. При помещении в структуру происходит копирование значения. Причем это обычное поведение, исключение я видел разве что с объектами XDTO, да со строками таблиц. В этом случае может быть несколько переменных, управляющих одним объектом. В структуре во временном хранилище же по факту доступа к данным исходной формы нет, она даже может безболезненно перестать существовать. Хотя может быть вы спрашивали что-то другое?

3. Ни обработчики событий, ни обработчики ожидания в новую форму не переносятся.
+ – Ответить
12. Yashazz 4796 04.10.19 14:13 Сейчас в теме
(10)
1. Насчёт того, что проще использовать - вопрос к писателям типовых конфигураций) Там есть любители во множестве юзать переменные формы.
2. Я про другое: ПоместитьВоВременноеХранилище(НекиеДанные,ЭтотОбъект.УникальныйИдентификатор) - среди таких бывает важное и даже ключевое.
3. ОК
+ – Ответить
14. nekit_rdx 221 04.10.19 15:32 Сейчас в теме
(12)
1. Что верно то верно) Я пожалуй позже добавлю получение переменных, хотя само по себе оно может потянуть на статью, и я не уверен что у меня выйдет. Время покажет)
2. Если верить справке - НекиеДанные исчезнут после закрытия формы. Если хочется сохранить их подольше то лучше использовать 
ПоместитьВоВременноеХранилище(НекиеДанные, Новый УникальныйИдентификатор)

тогда НекиеДанные будут храниться до завершения сеанса.
Кстати спасибо, не знал об этих особенностях. Похоже от ошибок меня спасло только то что данные из временного хранилища я использую сразу.
+ – Ответить
17. Yashazz 4796 04.10.19 16:38 Сейчас в теме
(14) Верно, но опять же, многое привязывают к гуиду формы именно чтоб не висело почём зря, на это логику вешают - скопируете вы форму, а времянок-то и нету, хз как код начнёт себя вести.
+ – Ответить
13. zarankony 311 04.10.19 15:05 Сейчас в теме
Вы же в курсе что Вы можете получить форму, сделать на ней любые изменения без обработчиков изменения, а уже потом открывать? 
Форма = ПолучитьФорму(ИмяФормы,Параметры);
Форма.Объект.Сумма = 0;
Форма.Элементы.Кнопка.Доступность = Ложь;
Форма.Открыть();

Если я правильно понял суть проблемы, то это решение проще и изящнее будет.
+ – Ответить
15. nekit_rdx 221 04.10.19 15:48 Сейчас в теме
(13) Я похоже ввел в заблуждение постановкой задачи.

Изначальная проблема с которой я столкнулся и которую не смог решить другими способами, это невозможность установить в события элементов свое действие. Да, у элемента есть метод "УстановитьДействие()", но само действие должно существовать в форме. Если действий много, то все они должны быть прописаны в форме, а это приводит к копированию потрянок текста в каждую из форм. 
Форма = ПолучитьФорму(ИмяФормы, Параметры);
Элемент = Форма.Элементы.Номер;
Элемент.УстановитьДействие("ПриИзменении", "МоеДействие"); //Не работает если в модуле формы нет моего действия
Элемент.УстановитьДействие("ПриИзменении", "ОбщийМодуль.МоеДействие"); //нельзя устанавливать действия из общих модулей
Форма.Открыть();

Сама же статья немножко не об этом. Она о том как взять пустую форму без элементов и заполнить ее элементами другой формы.
+ – Ответить
16. Yashazz 4796 04.10.19 16:37 Сейчас в теме
(15) Ну насчёт действий можно же проще. Взять да при создании формы, либо получив её и ещё не открывая, порезать все действия. Например 
НужнаяФорма.Элементы.НужноеПоле.УстановитьДействие("ПриИзменении","")
и "адью" всем событийщикам, никто не рыпнется.
+ – Ответить
18. nekit_rdx 221 05.10.19 09:56 Сейчас в теме
(16) Удалить действие это частный случай, в нем конечно проще сделать так как предлагаете вы. А установить МоеДействие не прописав процедуру в форму уже не получится.
+ – Ответить
19. Cyberhawk 135 30.10.19 13:46 Сейчас в теме
(18) Но ведь можно прописать в целевую форму один универсальный обработчтик (по аналогии с "Подключаемый_..." из БСП) и дело в шляпе? Будет одна точка входа, из нее уже вызывать свои общие модули.
+ – Ответить
20. nekit_rdx 221 31.10.19 10:14 Сейчас в теме
(19) Точно, именно так и сделано в обработке Заполнение из внешней формы. И именно поэтому весь код в конце (под спойлером) записан одним длинным текстом. Этот текст можно скопировать в общий модуль и вызывать из нужной формы. Неудобство только в том что этот вызов нужно прописывать в каждую форму.

Кстати, использовать "Подключаемый_..." это интересная идея, которой я загорелся после комментария @SlavaKron (7). Правда я пока не разобрался как ее использовать. Может быть можно генерировать адрес временного хранилища, передавать его в подключаемую команду, которая описание формы поместит по этому адресу. В таком случае можно будет даже не менять форму, что очень обрадует тех кто не хочет снимать конфу с поддержки. Если у меня получится я дополню статью)
+ – Ответить
21. SlavaKron 31.10.19 12:02 Сейчас в теме
(20) Я такое делал. Вот обработка, которая внедряется в открытую форму на сервере. Она, правда, сыровата - всё руки не дойдут доделать.
Прикрепленные файлы:
ИсследованиеФормы.epf
purgin; nekit_rdx; +2 – Ответить
22. nekit_rdx 221 31.10.19 16:14 Сейчас в теме
(21) Вау
+ – Ответить
23. Cyberhawk 135 31.10.19 17:31 Сейчас в теме
(20)
Неудобство только в том что этот вызов нужно прописывать в каждую форму
Ну так и точка входа для получения структуры данных формы тоже надо прописать в каждую.
+ – Ответить
25. RocKeR_13 1369 28.06.21 17:34 Сейчас в теме
(15)
Если действий много, то все они должны быть прописаны в форме, а это приводит к копированию потрянок текста в каждую из форм.

Если конфа на БСП, то обычно использую обработчик 

&НаКлиенте
Процедура Подключаемый_ВыполнитьПереопределяемуюКоманду(Команда)
	
	СобытияФормКлиент.ВыполнитьПереопределяемуюКоманду(ЭтаФорма, Команда);
	
КонецПроцедуры


Дальше уже по имени команды разбираемся, что делать

UPD. Ниже не прочел, что метод уже предложили)
+ – Ответить
24. buzzzard 51 03.12.20 10:06 Сейчас в теме
Никита, большое человеческое тебе спасибо за исходники!
+ – Ответить
26. Mobile888 19.03.23 14:16 Сейчас в теме
Здравствуйте. Есть возможность скопировать состав набора (список комплектующих в динамическом наборе (набора с характеристиками))? УТ 11.5
+ – Ответить
Оставьте свое сообщение