Маркировка обуви и других нетабачных и немолочных категорий товаров. Без паники

Причины две:
1) на этикетке с ДатаМатрикс-кодом должны быть указаны код товара GTIN и серийный номер - который присваивает Честный Знак. Для тех случаев, когда при продаже ДатаМатрикс-код не считывается сканером, тогда необходимо внести код товара GTIN и серийный номер вручную. То есть код товара GTIN  и серийный номер должны быть отражены на этикетке.

2) второй момент, если у вас изменилась цена на обувь, то вам придется распечатать заново этикетку с ценой. А ЦРПТ в своих рекомендациях запрещает повторно печатать ДатаМатрикс-код. Методисты 1С в свою очередь в своих механизмах заблокировали повторную печать ДатаМатрикс-код (по крайней мере, анонсировали так, а как по факту и в каких конфигурациях - проверяйте, пож-та, сами). Запрет наложили, чтобы не было проблем: что дважды распечатали и наклеили один ДатаМатрикс-код на разные коробки.

Нужно понимать, что если ваш штрихкод определяется в приложениях из п.12 как Data Matrix, значит он не содержит символов-разделителей GS, и не начинается с символов FNC1 (так называемый префикс).
С другой стороны, если бы он содержал и символы-разделители GS и начинался с префикса FNC1, то он должен определяться как GS1 Data Matrix.
GS1 Data Matrix - это тоже ДатаМатрикс-код, но только другого типа.
QR-код - тоже двумерный код, как ДатаМатрикс, только другого типа.
Все это тоже условно называется штрихкодами - только штрихов нет и только двумерные, а не одномерные, как мы привыкли для EAN-13.

Серии в УТ - предназначены для учета рекламаций по серийным номерам товаров, для учета товаров по срокам годности,  для учета остатков товаров в рулонах, бухтах, отрезках и т.д., для учета себестоимости товаров с разными сериями.

Серия в Честном знаке - это часть кода маркировки - для учета уникальности каждой пары обуви (каждой коробки).

Нужно ли их как-то связывать?  Вопрос открытый.

Для размышления:

- для учета КМ меховых изделий используются серии - серия идентифицирует экземпляр товара, имеющий уникальный серийный номер, в данном случае им будет номер КиЗ (контрольный идентификационный знак, тоже самое что и код маркировки). Дополнительно в серии указывается наличие RFID метки.

- для учета алкогольной продукции серии используются в ряде сценариев, но в других сценариях могут не использоваться. Для идентификации отдельной единицы алкогольной продукции (кода маркировки) серии не применяются – для этого в подсистеме взаимодействия с ЕГАИС есть собственный механизм поштучного учета маркируемой продукции.

- продукция, подконтрольная ветеринарному надзору учитывается в разрезе партий – записей складского журнала в терминах ВетИС. В ряде сценариев для этих целей используются серии - идентифицирующие партию, плюс дополнительно в серию указываются дополнительные сведения в виде отдельных полей.

Функция РазложитьКодМаркировкиНаГруппы(Знач КМ)
	
	МассивГрупп = Новый Массив;
	
	УдалитьСимволРазделителяГрупп(КМ);
	
	Если Лев(КМ, 2) = "01" Тогда
		
		GTIN = Сред(КМ, 3, 14);
		МассивГрупп.Добавить(GTIN); //первый элемент массива
		
		КМ = Прав(КМ, СтрДлина(КМ)-16);
		
		УдалитьСимволРазделителяГрупп(КМ);
		
		Если Лев(КМ, 2) = "21" Тогда
			
			СерийныйНомер = Сред(КМ, 3, 13);
			МассивГрупп.Добавить(СерийныйНомер); //второй элемент массива
			
			КМ = Прав(КМ, СтрДлина(КМ) - 15);
			
			УдалитьСимволРазделителяГрупп(КМ);
			
			Если Лев(КМ, 2) = "91" Тогда
				
				КлючПроверки = Сред(КМ, 3, 4);
				МассивГрупп.Добавить(КлючПроверки); //третий элемент массива
				
				КМ = Прав(КМ, СтрДлина(КМ) - 6);
				
				УдалитьСимволРазделителяГрупп(КМ);
				
				Если Лев(КМ, 2) = "92" Тогда
					
					КодПроверки = Сред(КМ, 3, 88);
					МассивГрупп.Добавить(КодПроверки); //четвертый элемент массива
					
					КМ = Прав(КМ, СтрДлина(КМ) - 90); 	
					
					УдалитьСимволРазделителяГрупп(КМ);
					
					Если СтрДлина(КМ)>0 Тогда
						Сообщить("Имеются нераспознанные символы " + КМ);
					КонецЕсли;
					
				КонецЕсли; 				
				
			КонецЕсли;   			
			
		КонецЕсли;   		
		
	КонецЕсли;  	
	
	Возврат МассивГрупп;
	
КонецФункции

Процедура УдалитьСимволРазделителяГрупп(КМ)
	
	Если Лев(КМ, 1) = Символ(232) ИЛИ Лев(КМ, 1) = Символ(29) Тогда
		КМ = Прав(КМ, СтрДлина(КМ) - 1);
	КонецЕсли;	
	
КонецПроцедуры

Процедура ВыгрузитьXMLНажатие(Элемент)
	
	Если НЕ ЗначениеЗаполнено(Организация) ИЛИ ПустаяСтрока(Организация.ИНН) Тогда
		Сообщить("Укажите организацию или проверьте ИНН по ней");
		Возврат;		
	КонецЕсли;
	
	Если ПустаяСтрока(ПутьКФайлуВводВОборот) Тогда
		Сообщить("Выберите файл-xml для выгрузки сведений");
		Возврат;
	КонецЕсли;
	
	Файл = Новый Файл(ПутьКФайлуВводВОборот);

	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.ОткрытьФайл(Файл.ПолноеИмя);
	ЗаписьXML.ЗаписатьОбъявлениеXML();
	
	ЗаписьXML.ЗаписатьНачалоЭлемента("vvod_ostatky");	
	ЗаписьXML.ЗаписатьАтрибут("version","2");
	ЗаписьXML.ЗаписатьАтрибут("action_id","5.4");
	
		ЗаписьXML.ЗаписатьНачалоЭлемента("trade_participant_inn");
		ЗаписьXML.ЗаписатьТекст(Организация.ИНН);
		ЗаписьXML.ЗаписатьКонецЭлемента();
		
		ЗаписьXML.ЗаписатьНачалоЭлемента("products_list");
			
		Для Каждого Стр Из КодыМаркировок Цикл
			
			Если НЕ Стр.Вкл Тогда
				Продолжить;
			КонецЕсли;
			
			КИ = "01" + Стр.КодТовараGTIN + "21" + Стр.СерийныйНомер;
			ЭкранироватьКИ(КИ);
			
			ЗаписьXML.ЗаписатьНачалоЭлемента("product");
				ЗаписьXML.ЗаписатьНачалоЭлемента("ki");
				ЗаписьXML.ЗаписатьТекст(КИ);
				ЗаписьXML.ЗаписатьКонецЭлемента();
			ЗаписьXML.ЗаписатьКонецЭлемента();
			
		КонецЦикла;
				
		ЗаписьXML.ЗаписатьКонецЭлемента();
	
	ЗаписьXML.ЗаписатьКонецЭлемента(); 		
	ЗаписьXML.Закрыть();
	
КонецПроцедуры

//Пример шаблона из раздела Помощь сайта Честный Знак
//<vvod_ostatky version="2" action_id="5.4">
//<trade_participant_inn>1111111111</trade_participant_inn>
//<products_list>
//<product>
//<ki>
//<![CDATA[ 00000000000000000000000000000 ]]>
//</ki>
//<country>111</country>
//<declaration_date>12.04.2019</declaration_date>
//<declaration_number>123456</declaration_number>
//<certificate_type>CONFORMITY_CERTIFICATE</certificate_type>
//<certificate_number>123456</certificate_number>
//<certificate_date>12.04.2019</certificate_date>
//</product>
//</products_list>
//</vvod_ostatky>

Файл = Новый Файл(ПутьКФайлуВводВОборот);

Текст = Новый ЗаписьТекста(Файл.ПолноеИмя, КодировкаТекста.UTF8);

//ЗаписьXML = Новый ЗаписьXML;
//ЗаписьXML.ОткрытьФайл(Файл.ПолноеИмя);
//ЗаписьXML.ЗаписатьОбъявлениеXML();

Текст.ЗаписатьСтроку("<vvod_ostatky version=""2"" action_id=""5.4"">");
Текст.ЗаписатьСтроку("<trade_participant_inn>" + Организация.ИНН + "</trade_participant_inn>");
Текст.ЗаписатьСтроку("<products_list>");

Для Каждого Стр Из КодыМаркировок Цикл
	
	Если НЕ Стр.Обработан Тогда
		Продолжить;
	КонецЕсли;
	
	Текст.ЗаписатьСтроку("<product>");
	
	КИ = "01" + Стр.КодТовараGTIN + "21" + Стр.СерийныйНомер;
	ЭкранироватьКИ(КИ);
	
	Текст.ЗаписатьСтроку("<ki>" + КИ + "</ki>");
	
	Текст.ЗаписатьСтроку("</product>");
	
КонецЦикла;

Текст.ЗаписатьСтроку("</products_list>");
Текст.ЗаписатьСтроку("</vvod_ostatky>");		
Текст.Закрыть();

Процедура ЭкранироватьКИ(КИ)
	
	КИ = "<![CDATA[" + КИ + "]]>";
	
КонецПроцедуры