18.04.2015. Новая редакция с возможностью загрузки изображений из файла.
В данной статье приведен функционал, с помощью которого в обработке
"Импорт из EXCEL и др.источников (xls,xlsx,ods,sxc,dbf,mxl,csv,sql) в 1С": //infostart.ru/public/120961/
производится считывание данных из файлов табличного типа *xls, *.xlsx.
Методы загрузки из внешнего источника:
- Метод "MS ADO" (Чтение файлов xls, xlsx средствами Microsoft ADO): //infostart.ru/public/163640/
- Метод "MS EXCEL" (Чтение файлов xls, xlsx с картинками средствами Microsoft Office): //infostart.ru/public/163641/
- Метод "LO CALC" (Чтение файлов xls, xlsx, ods, sxc с картинками средствами LibreOffice): //infostart.ru/public/163642/
- Метод "NativeXLSX" (Чтение файлов xlsx с картинками средствами 1С. ПостроительDOM): //infostart.ru/public/300092/
- Метод "NativeXLSX". Предыдущий вариант (Чтение файлов xlsx средствами 1С. ЧтениеXML)://infostart.ru/public/225624/
- Метод "Excel1C" (Загрузка на платформе 8.3.6 с картинками. Чтение файлов xls, xlsx, ods): //infostart.ru/public/341855/
- Список листов файла: //infostart.ru/public/163724/
Публикаций на тему загрузки из EXCEL - множество, но
"
— Вам билетёр нужен?
— Был нужен, да уже взяли.
— Может и я на что сгожусь?
— Может и сгодишься, если скалиться не будешь ...
"
"НЕУЛОВИМЫЕ МСТИТЕЛИ" (1966).
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ФайлEXCEL= "D:\Товар1Лист.xlsx";
ИмяЛиста = Новый Структура ("ИмяЛиста, НомерЛиста","СФКартинок2", 16);
СтрокаЗаголовка = 1;
НачСтрока = 0;
КонСтрока = 0;
КолвоСтрокExcel = 0;
ТаблицаФайла = ЗагрузитьМетодом_LOCALC(ФайлEXCEL, ИмяЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel);
КонецПроцедуры
// Метод "LibreOffice com.sun.star.ServiceManager" для файлов с расширениями: XLSX, XLS, ODS, SXC.
//
// Параметры:
// ФайлEXCEL - Полное имя файла (путь к файлу с именем файла и расширением)
// ИмяЛиста - Имя выбранного листа файла EXCEL.
// СтрокаЗаголовка (по умолчанию = 1) - Номер строки EXCEL, в которой расположены заголовки колонок.
// Не используется.
// В обработке 1-я строка анализируется для сопоставления колонок EXCEL с реквизитами 1С (справочники, докуметны, регистры).
// НачСтрока (по-умолчанию = 0) - Номер начальной строки, начиная с которой считываются данные из EXCEL.
// КонСтрока (по-умолчанию = 0) - Номер конечной строки, которой заканчиваются считываемые данные из EXCEL.
// Если НачСтрока=0 и КонСтрока=0, то считывается вся таблица, находящаяся на листе EXCEL.
// КолвоСтрокEXCEL - Количество строк на листе "ИмяЛиста" EXCEL. Возвращается в вызываемую процедуру.
//
// Возвращаемые значения:
// ТаблицаРезультат - Результат считывания с листа "ИмяЛиста" EXCEL.
//
&НаСервере
Функция ЗагрузитьМетодом_LOCALC(Знач ФайлEXCEL, Знач ИмяНомерЛиста, Знач СтрокаЗаголовка = 1, НачСтрока = 0, КонСтрока = 0, КолвоСтрокEXCEL)
Перем ИмяФайлаEXCEL, ФайлИмяЛиста, ФайлНомерЛиста;
Перем ServiceManager, Desktop, Book, Sheets, Sheet, Cursor;
Перем Properties1, Properties2, Arguments;
Перем oLocale, oFormatsALL, oFormatsDATA, oFormatsTIME, oFormatsUSER;
Перем ВсегоЛистов, КонечнаяКолонка, НачальнаяСтрока, КонечнаяСтрока;
Перем нСтрокаТФ, нСтрока, нКолонкаТФ, нКолонка;
Перем ДиапазонДанных, МассивДанных, СтрокДиапазона, ДиапазонЗаголовка, МассивЗаголовка, МассивЗначений, ЗначениеЯчейки, ЗначениеString, УсловиеДругиеФорматы;
Перем МассивКодовФорматаДата, МассивКодовФорматаВремя, МассивКодовФорматаЮзер, МассивКодовПроверяемыхДата, МассивКодовПроверяемыхВремя, КодФормата, ВозможноДата;
Перем ТаблицаРезультат, МассивСкрытыхКолонок, НоваяСтрокаТФ, ИмяКолонки;
// При использовании данного метода рекомендуется использовать файлы, созданные в LibreOffice.
// При использовании LibreOffice рекомендуется придерживаться следующего правила:
// Использовать высокие версии LibreOffice, заканчивающиеся на 3 и выше (4.3.3 - 4.3.6).
ИмяФайлаEXCEL = ПолучитьИмяФайлаБезРасширения(ФайлEXCEL);
// Нумерация LibreOffice начинается с 0.
ФайлИмяЛиста = ИмяНомерЛиста.ИмяЛиста;
ФайлНомерЛиста = ИмяНомерЛиста.НомерЛиста;
// Инициализация COMОбъектов.
ServiceManager = ПолучитьLOServiceManager();
Desktop = ПолучитьLODesktop(ServiceManager);
Book = ПолучитьLOBook(ServiceManager, Desktop, ФайлEXCEL);
Sheet = ПолучитьLOSheet(Book, ФайлEXCEL, ФайлИмяЛиста, ФайлНомерЛиста);
Если Sheet = Неопределено Тогда
MessageLO = "Не удалось получить лист книги.";
Сообщить(НСтр("ru = '"+MessageLO+"'"), СтатусСообщения.Внимание);
// Завершение работы.
// Закрытие Объектов.
Попытка
Book.Close(Истина);
Desktop.Terminate();
Desktop = Неопределено;
ServiceManager = Неопределено;
Исключение
КонецПопытки;
Возврат Новый ТаблицаЗначений;
КонецЕсли;
// Определим используемые форматы.
// ===============================================================
// Constant Value Description
// ===============================================================
// 0 ALL All number formats.
// 1 DEFINED User-defined number formats.
// 2 DATE Date formats.
// 4 TIME Time formats.
// 8 CURRENCY Currency formats.
// 16 NUMBER Decimal number formats.
// 32 SCIENTIFIC Scientific number formats.
// 64 FRACTION Number formats for fractions.
// 128 PERCENT Percentage number formats.
// 256 TEXT Text number formats.
// 6 DATETIME Number formats that contain date and time.
// 1024 LOGICAL Boolean number formats.
// 2048 UNDEFINED Used if no number format exists.
// ===============================================================
// Все форматы.
oLocale = ServiceManager.Bridge_GetStruct("com.sun.star.lang.Locale");
oFormatsALL = Book.getNumberFormats();
// Массивы могут по отдельным кодам форматов пересекаться, в частности:
// Например, Коды 50 и 51 могут присутствовать в форматах даты и времени.
// Это может потребовать корректировки "типизации" числовых значений,
// имеющих нестандартные форматы, в результате форматирования ячейки.
// LibreOffice большее количество форматов, в частности по дате.
// Форматы даты.
// Возможный состав: "30;32;33;34;35;36;37;50;51;80;81;82;83;84;85;106;107;108;109;110;111;112;113;114;115;116;117;118;119;120;121;122;123;10030;10032;10033;10034;10036;10037;10050;10051;10080;10081;10082;10083;10084;5036";
oFormatsDATA = oFormatsALL.queryKeys(2, oLocale, FALSE);
МассивКодовФорматаДата = Новый Массив;
Для Каждого КодФормата ИЗ oFormatsDATA Цикл
МассивКодовФорматаДата.Добавить(КодФормата);
КонецЦикла;
// Форматы времени.
// Возможный состав: "40;41;42;43;44;45;46"; // 50,51,106,107,108 - Дата.
oFormatsTIME = oFormatsALL.queryKeys(4, oLocale, FALSE);
МассивКодовФорматаВремя = Новый Массив;
Для Каждого КодФормата ИЗ oFormatsTIME Цикл
МассивКодовФорматаВремя.Добавить(КодФормата);
КонецЦикла;
// Форматы нестандартные, определенны пользователем.
// Значимое пересечение по значением с массивом даты.
// "Типизацию" значений необходимо запрограммировать.
oFormatsUSER = oFormatsALL.queryKeys(1, oLocale, FALSE);
МассивКодовФорматаЮзер = Новый Массив;
Для Каждого КодФормата ИЗ oFormatsUSER Цикл
МассивКодовФорматаЮзер.Добавить(КодФормата);
КонецЦикла;
// Массив кодов дат проверяемых.
// По факту могут находиться в пользовательских форматах,
// а в действительности являются кодами формата даты.
МассивКодовПроверяемыхДата = Новый Массив;
МассивКодовПроверяемыхДата.Добавить(120);
МассивКодовПроверяемыхДата.Добавить(122);
МассивКодовПроверяемыхДата.Добавить(123);
МассивКодовПроверяемыхДата.Добавить(124);
МассивКодовПроверяемыхДата.Добавить(10033);
МассивКодовПроверяемыхДата.Добавить(10036);
Для Каждого КодФормата ИЗ МассивКодовПроверяемыхДата Цикл
Если МассивКодовФорматаДата.Найти(КодФормата) = Неопределено Тогда
МассивКодовФорматаДата.Добавить(КодФормата);
КонецЕсли;
КонецЦикла;
// Массив кодов времени проверяемых.
// По факту могут находиться в пользовательских форматах,
// а в действительности являются кодами формата времени.
МассивКодовПроверяемыхВремя = Новый Массив;
МассивКодовПроверяемыхВремя.Добавить(121);
МассивКодовПроверяемыхВремя.Добавить(125);
МассивКодовПроверяемыхВремя.Добавить(126);
МассивКодовПроверяемыхВремя.Добавить(127);
МассивКодовПроверяемыхВремя.Добавить(128);
МассивКодовПроверяемыхВремя.Добавить(10113);
Для Каждого КодФормата ИЗ МассивКодовПроверяемыхВремя Цикл
Если МассивКодовФорматаВремя.Найти(КодФормата) = Неопределено Тогда
МассивКодовФорматаВремя.Добавить(КодФормата);
КонецЕсли;
КонецЦикла;
// Инициализация дочернего объекта Листа типа Курсор для определения диапазона данных файла.
Cursor = Sheet.CreateCursor();
Cursor.gotoEndOfUsedArea(Истина);
// Определение начальной и конечной ячеек диапазона данных файла.
КолвоСтрокEXCEL = Cursor.Rows.Count;
КонечнаяКолонка = Cursor.Columns.Count - 1;
// Проверка заполненности листа.
Если КолвоСтрокEXCEL <= 1 И КонечнаяКолонка <= 0 Тогда
КолвоСтрокEXCEL = 0;
Сообщить(НСтр("ru = '" + ФайлИмяЛиста + ": Лист, содержащий 1 строку считаем пустым.'"), СтатусСообщения.Внимание);
// Завершение работы.
// Закрытие Объектов.
Book.Close(Истина);
Desktop.Terminate();
Desktop = Неопределено;
ServiceManager = Неопределено;
Возврат Новый ТаблицаЗначений;
КонецЕсли;
НачальнаяСтрока = ?(НачСтрока = 0 , 1 , НачСтрока);
КонечнаяСтрока = ?(КонСтрока = 0 , Cursor.Rows.Count - 1 , КонСтрока);
НачальнаяСтрока = ?(НачальнаяСтрока > КолвоСтрокEXCEL, КолвоСтрокEXCEL-1, НачальнаяСтрока);
КонечнаяСтрока = ?(КонечнаяСтрока > КолвоСтрокEXCEL, КолвоСтрокEXCEL-1, КонечнаяСтрока);
КонечнаяСтрока = ?(КонечнаяСтрока < НачальнаяСтрока, НачальнаяСтрока, КонечнаяСтрока);
// Диапазон: Считываемые данные.
ДиапазонДанных = Sheet.getCellRangeByPosition(0, НачальнаяСтрока, КонечнаяКолонка, КонечнаяСтрока);
СтрокДиапазона = ДиапазонДанных.Rows.Count;
// Создание результирующей таблицы, в которую будут записываться считанные из файла данные.
ТаблицаРезультат = Новый ТаблицаЗначений;
// Создание колонок результирующей таблицы.
ТаблицаРезультат.Колонки.Добавить("НомерСтроки", Новый ОписаниеТипов("Число"), "№", 10);
ТаблицаРезультат.Колонки.Добавить("РядЗаполнен", Новый ОписаниеТипов("Булево"), "Заполнено", 1);
//ТаблицаРезультат.Колонки.Добавить("УровеньГруппировки", Новый ОписаниеТипов("Число"), "Гр", 2); // Группировка строк в файле.
МассивСкрытыхКолонок = Новый Массив;
Для нКолонкаТФ = 0 ПО КонечнаяКолонка Цикл
нКолонка = СтрЗаменить(нКолонкаТФ+1, Символы.НПП, "");
ИмяКолонки = "N" + нКолонка;
ТаблицаРезультат.Колонки.Добавить(ИмяКолонки);
Если НЕ ДиапазонДанных.Columns.getbyindex(нКолонкаТФ).isVisible Тогда // Скрытые колонки файла пропустить.
МассивСкрытыхКолонок.Добавить(ИмяКолонки);
КонецЕсли;
КонецЦикла;
// 1-я строка. Заголовки.
ДиапазонЗаголовка = Sheet.getCellRangeByPosition(0, 0, КонечнаяКолонка, 0);
МассивЗаголовка = ДиапазонЗаголовка.getDataArray().Выгрузить();
НоваяСтрокаТФ = ТаблицаРезультат.Добавить();
НоваяСтрокаТФ.НомерСтроки = 1;
Для Каждого МассивЗначений ИЗ МассивЗаголовка Цикл
//
Для нКолонкаТФ = 0 ПО КонечнаяКолонка Цикл
нКолонка = СтрЗаменить(нКолонкаТФ+1, Символы.НПП, "");
ИмяКолонки = "N" + нКолонка;
ЗначениеЯчейки = МассивЗначений[нКолонкаТФ];
НоваяСтрокаТФ[ИмяКолонки] = СокрЛП(ЗначениеЯчейки);
// Значение ширины колонки используется при формировании таблицы на форме обработки.
// Значение ширины колонки анализируется при удалении незаполненных колонок.
// Значение флажка заполнения строки анализируется при удалении незаполненных строк.
ШиринаКолонки = ТаблицаРезультат.Колонки[ИмяКолонки].Ширина;
ДлинаСтроки = СтрДлина(СокрЛП(НоваяСтрокаТФ[ИмяКолонки]));
НоваяСтрокаТФ.РядЗаполнен = ?(ДлинаСтроки > 0, Истина, НоваяСтрокаТФ.РядЗаполнен);
ТаблицаРезультат.Колонки[ИмяКолонки].Ширина = ?(ШиринаКолонки < ДлинаСтроки, ДлинаСтроки, ШиринаКолонки);
КонецЦикла;
//
КонецЦикла;
// Формирование результирующей таблицы.
МассивДанных = ДиапазонДанных.getDataArray().Выгрузить();
нСтрокаТФ = НачальнаяСтрока;
Для Каждого МассивЗначений ИЗ МассивДанных Цикл
нСтрокаТФ = нСтрокаТФ + 1;
НоваяСтрокаТФ = ТаблицаРезультат.Добавить();
НоваяСтрокаТФ.НомерСтроки = нСтрокаТФ;
Для нКолонкаТФ = 0 ПО КонечнаяКолонка Цикл
нКолонка = СтрЗаменить(нКолонкаТФ+1, Символы.НПП, "");
ИмяКолонки = "N" + нКолонка;
// Считать данные в соответствии с их типами.
Cell = Sheet.getCellByPosition(нКолонкаТФ, нСтрокаТФ-1); // Cell.AbsoluteName.
//
// Type:
// 0 - пустая;
// 1 - число;
// 2 - строка;
// 3 - формула.
TypeCell = Cell.getType();
ЗначениеЯчейки = МассивЗначений[нКолонкаТФ];
ЗначениеString = Cell.GetString();
Если TypeCell = 0 И НЕ ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
ЗначениеЯчейки = ПрочитатьКартинку_LOCALC(ServiceManager, Sheet, нКолонкаТФ, нСтрокаТФ, ИмяФайлаEXCEL, ФайлНомерЛиста, "УИД");
КонецЕсли;
Если ЗначениеЗаполнено(ЗначениеЯчейки) ИЛИ TypeCell = 3 Тогда
// "ТИПИЗАЦИЯ" ЗНАЧЕНИЙ.
Если TypeCell = 1 Тогда // ЧИСЛО, ДАТА, ВРЕМЯ.
ФорматЯчейки = Cell.NumberFormat;
УсловиеДругиеФорматы =
( Найти(ЗначениеString, "%") > 0 // Процент.
ИЛИ Найти(ЗначениеString, "р.") > 0 // Российский рубль.
ИЛИ Найти(ЗначениеString, "S72;") > 0 // Украинская гривна.
ИЛИ Найти(ЗначениеString, "Br") > 0 // Белорусский рубль.
ИЛИ Найти(ЗначениеString, "$") > 0 // Доллар.
ИЛИ Найти(ЗначениеString, "€") > 0 // Евро.
ИЛИ Найти(ЗначениеString, "E+") > 0 // Экспонента.
ИЛИ Найти(ЗначениеString, "E-") > 0 ); // Экспонента.
Если
(НЕ МассивКодовФорматаДата.Найти(ФорматЯчейки) = Неопределено
ИЛИ НЕ МассивКодовФорматаВремя.Найти(ФорматЯчейки) = Неопределено)
И НЕ УсловиеДругиеФорматы
Тогда
Если ЗначениеЯчейки >= 1 Тогда
// ДАТА.
// Дата('18991230') - начало периода отсчета.
// ЗначениеЯчейки - преобразуемое число.
// 60*60*24 - число секунд в сутках
х_Дата = Дата('18991230') + ЗначениеЯчейки * 24*60*60;
х_Дата = ?(х_Дата < Дата("19000101"), х_Дата + 2*24*60*60, х_Дата);
НоваяСтрокаТФ[ИмяКолонки] = х_Дата;
Иначе
// ВРЕМЯ.
// Дата("19001010") - начало периода отсчета для времени.
х_Дата = Дата("19000101") + ЗначениеЯчейки * 24*60*60;
НоваяСтрокаТФ[ИмяКолонки] = х_Дата;
КонецЕсли;
Иначе
// ЧИСЛО.
НоваяСтрокаТФ[ИмяКолонки] = ЗначениеЯчейки;
КонецЕсли;
ИначеЕсли TypeCell = 3 Тогда // ФОРМУЛА.
Если Cell.GetFormula() = "=TRUE()" ИЛИ Cell.GetFormula() = "=FALSE()" Тогда
Попытка
// БУЛЕВО.
НоваяСтрокаТФ[ИмяКолонки] = Булево(ЗначениеЯчейки);
Исключение
// "КАК ЕСТЬ".
НоваяСтрокаТФ[ИмяКолонки] = ЗначениеЯчейки;
КонецПопытки;
Иначе
// ЗНАЧЕНИЕ ФОРМУЛЫ.
ВозможноДата = Неопределено;
// Ограниченная обработка строкового значения для перобразования в основные варианты даты типа "12.12.12", "12.12.2012" (+ "00:00:00").
Если (ТолькоЦифрыИТочкиВСтроке(ЗначениеString, Истина, Ложь) И СтрЧислоВхождений(ЗначениеString, ".") = 2)
ИЛИ (ТолькоЦифрыИТочкиИДвоеточиеВСтроке(ЗначениеString, Истина, Ложь) И СтрЧислоВхождений(ЗначениеString, ".") = 2 И СтрЧислоВхождений(ЗначениеString, ":") = 2 ) Тогда
ВозможноДата = ПреобразоватьПростоеЗначениеИзСтрокиИлиЧислаВДату(ЗначениеString);
КонецЕсли;
Если ТипЗнч(ВозможноДата) = Тип("Дата") Тогда
НоваяСтрокаТФ[ИмяКолонки] = ВозможноДата;
Иначе
НоваяСтрокаТФ[ИмяКолонки] = ЗначениеЯчейки;
КонецЕсли;
КонецЕсли;
Иначе
// СТРОКА.
НоваяСтрокаТФ[ИмяКолонки] = СокрЛП(ЗначениеЯчейки);
КонецЕсли;
// Значение ширины колонки используется при формировании таблицы на форме обработки.
// Значение ширины колонки анализируется при удалении незаполненных колонок.
// Значение флажка заполнения строки анализируется при удалении незаполненных строк.
ШиринаКолонки = ТаблицаРезультат.Колонки[ИмяКолонки].Ширина;
ДлинаСтроки = СтрДлина(СокрЛП(НоваяСтрокаТФ[ИмяКолонки]));
НоваяСтрокаТФ.РядЗаполнен = ?(ДлинаСтроки > 0, Истина, НоваяСтрокаТФ.РядЗаполнен);
ТаблицаРезультат.Колонки[ИмяКолонки].Ширина = ?(ШиринаКолонки < ДлинаСтроки, ДлинаСтроки, ШиринаКолонки);
КонецЕсли;
//
КонецЦикла;
//
КонецЦикла;
// Завершение работы.
// Закрытие Объектов.
Book.Close(Истина);
Desktop.Terminate();
Desktop = Неопределено;
ServiceManager = Неопределено;
// Удалить пустые колонки и строки.
УдалитьПустыеКолонкиИСтрокиИзТаблицыФайла(ТаблицаРезультат);
// Удалить скрытые колонки.
Для Каждого КолонкаТФ ИЗ МассивСкрытыхКолонок Цикл
ТаблицаРезультат.Колонки.Удалить(КолонкаТФ);
КонецЦикла;
Возврат ТаблицаРезультат;
КонецФункции
// Функция осуществляет экспорт изображения во внешние графические файлы и возвращает имена этих файлов.
//
// Параметры:
// ServiceManager - Объект типа "com.sun.star.ServiceManager".
// Sheet - Обект типа "Лист книги EXCEL".
// НомерКолонки - Номер колонки листа.
// НомерСтроки - Номер строки листа.
// ИмяФайлаEXCEL - Короткое имя файла без расширения, из которого производится импорт.
// НомерЛиста - Номер листа книги EXCEL.
// ПравилоИмяФайлаКартинки - правило формирования имени выходного графического файла.
// - "УИД" (по умолчанию).
// - Иначе на основании имени исходного файла EXCEL, Номера листа, Номера строки, Номера колонки.
//
// Возвращаемые значения:
// Результат - Полное имя графического файла.
//
&НаСервере
Функция ПрочитатьКартинку_LOCALC(Знач ServiceManager, Знач Sheet, Знач НомерКолонки, Знач НомерСтроки, Знач ИмяФайлаEXCEL, Знач НомерЛиста, Знач ПравилоИмяФайлаКартинки = "УИД")
Перем Cell, GraphicObject, GraphicExportFilter, Properties1, Properties2, Arguments, ит;
Перем Результат, ПолноеИмяФК, ФайлКартинки;
Если Sheet.Drawpage.getCount() = 0 Тогда
Возврат Неопределено;
КонецЕсли;
Cell = Sheet.getCellByPosition(НомерКолонки, НомерСтроки-1);
Результат = "";
Для ит = 0 ПО Sheet.Drawpage.getCount()-1 Цикл
Попытка
GraphicObject = Sheet.Drawpage.getByIndex(ит);
Если Cell.Position.X <= GraphicObject.Position.X И (Cell.Position.X + Cell.Size.Width) >= GraphicObject.Position.X
И Cell.Position.Y <= GraphicObject.Position.Y И (Cell.Position.Y + Cell.Size.Height) >= GraphicObject.Position.Y Тогда
// Graph.Name, Graph.LinkDisplayName, GraphicObject.Text.Name.
Если ПравилоИмяФайлаКартинки = "УИД" Тогда
ПолноеИмяФК = КаталогВременныхФайлов() + Новый УникальныйИдентификатор() + ".jpg";
Иначе
ПолноеИмяФК = КаталогВременныхФайлов() + ИмяФайлаEXCEL + "Л"+НомерЛиста+"С"+НомерСтроки+"К"+(НомерКолонки+1) + ".jpg";
КонецЕсли;
GraphicExportFilter = ServiceManager.CreateInstance("com.sun.star.drawing.GraphicExportFilter");
GraphicExportFilter.setSourceDocument(GraphicObject);
// Объявление свойств и аргументов.
Properties1 = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");
Properties1.Name = "URL";
Properties1.Value = "file:///"+СтрЗаменить(ПолноеИмяФК, "\", "/");
// GraphicObject.GraphicURL
Properties2 = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");
Properties2.Name = "MediaType";
Properties2.Value = "image/jpeg";
// GraphicObject.Graphic
Arguments = Новый COMSafeArray("VT_VARIANT", 2);
Arguments.SetValue(0, Properties1);
Arguments.SetValue(1, Properties2);
GraphicExportFilter.Filter(Arguments);
GraphicExportFilter = Неопределено;
ФайлКартинки = Новый Файл(ПолноеИмяФК);
Если ФайлКартинки.Существует() Тогда
Результат = Результат + ПолноеИмяФК + Символы.ПС;
Иначе
Сообщить("Не удалось экспортировать картинку из строки " + НомерСтроки + " колонки " + (НомерКолонки+1) + " в " + ПолноеИмяФК);
КонецЕсли;
КонецЕсли;
Исключение
Сообщить(ОписаниеОшибки());
Сообщить("Не удалось экспортировать картинку из строки " + НомерСтроки + " колонки " + (НомерКолонки+1) + " в " + ПолноеИмяФК);
КонецПопытки;
КонецЦикла;
УдалитьПоследнийСимволВСтроке(Результат, 1);
Возврат Результат;
КонецФункции
&НаСервере
Процедура УдалитьПустыеКолонкиИСтрокиИзТаблицыФайла(ТаблицаРезультат)
Перем МассивПустыхКолонок, МассивПустыхСтрок;
Перем КолонкаТФ, СтрокаТФ, СтрокаБезЗначений;
// Найдем пустые колонки.
МассивПустыхКолонок = Новый Массив;
Для Каждого КолонкаТФ ИЗ ТаблицаРезультат.Колонки Цикл
Если КолонкаТФ.Ширина = 0 Тогда
МассивПустыхКолонок.Добавить(КолонкаТФ.Имя);
КонецЕсли;
КонецЦикла;
// Удалим пустые колонки.
Для Каждого КолонкаТФ ИЗ МассивПустыхКолонок Цикл
ТаблицаРезультат.Колонки.Удалить(КолонкаТФ);
КонецЦикла;
// Найдем пустые строки.
МассивПустыхСтрок = Новый Массив;
Для Каждого СтрокаТФ ИЗ ТаблицаРезультат Цикл
Если НЕ СтрокаТФ.РядЗаполнен Тогда
МассивПустыхСтрок.Добавить(СтрокаТФ);
КонецЕсли;
КонецЦикла;
// Удалим пустые строки.
Для Каждого СтрокаМС ИЗ МассивПустыхСтрок Цикл
ТаблицаРезультат.Удалить(СтрокаМС);
КонецЦикла;
ТаблицаРезультат.Колонки.Удалить("РядЗаполнен");
КонецПроцедуры
// Для файлов типа .ODS,*.SXC используем ServiceManager LibreOffice.
&НаСервере
Функция ПолучитьLOServiceManager()
Перем ServiceManager;
Попытка
// Инициализация основного СОМОбъекта типа com.sun.star.ServiceManager (LibreOffice/OpenOffice).
ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");
Исключение
ServiceManager = Неопределено;
КонецПопытки;
Возврат ServiceManager;
КонецФункции
&НаСервере
Функция ПолучитьLODesktop(ServiceManager)
Перем Desktop;
Попытка
// Инициализация дочернего объекта Desktop.
Desktop = ServiceManager.CreateInstance("com.sun.star.frame.Desktop");
Исключение
Desktop = Неопределено;
КонецПопытки;
Возврат Desktop;
КонецФункции
&НаСервере
Функция ПолучитьLOBook(ServiceManager, Desktop, Знач ФайлEXCEL)
Перем Properties1, Properties2, Arguments, Book;
Попытка
// Объявление свойств и аргументов.
Properties1 = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");
Properties1.Name = "AsFile"; // Свойство "КАК ФАЙЛ", альтернатива "AsTemplate" - "КАК ШАБЛОН".
Properties1.Value = Истина;
Properties2 = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");
Properties2.Name = "Hidden"; // Запускать скрытно. Реализовано в LibreOffice 3.6.
Properties2.Value = Истина;
Arguments = Новый COMSafeArray("VT_VARIANT", 2);
Arguments.SetValue(0, Properties1);
Arguments.SetValue(1, Properties2);
// Дочерний объект Desktop-а: Книга EXCEL.
Book = Desktop.LoadComponentFromURL(ConvertToURL(ФайлEXCEL), "_blank", 0, Arguments);
Исключение
Book = Неопределено;
КонецПопытки;
Возврат Book;
КонецФункции
&НаСервере
Функция ПолучитьLOSheet(Book, Знач ФайлEXCEL, Знач ФайлИмяЛиста, Знач ФайлНомерЛиста)
Перем Sheets, Sheet, Cursor;
// Дочерний объект Book-а: Листы EXCEL.
Sheets = Book.getSheets();
ВсегоЛистов = Sheets.getCount();
// Инициализация дочернего объекта Книги типа Лист EXCEL.
Если Лев(ФайлИмяЛиста, 1) = "'" И Прав(ФайлИмяЛиста, 1) = "'" Тогда
ФайлИмяЛиста = УдалитьКавычки(ФайлИмяЛиста, "'");
КонецЕсли;
Если Прав(ФайлИмяЛиста, 1) = "$" Тогда
УдалитьПоследнийСимволВСтроке(ФайлИмяЛиста, 1);
КонецЕсли;
Попытка
Sheet = Sheets.getByName(ФайлИмяЛиста);
Исключение
Sheet = Неопределено;
Сообщить("Некорректное имя листа: " + ФайлИмяЛиста + ".");
//Попытка
// Sheet = Sheets.getByIndex(ФайлНомерЛиста); // Нумерация LibreOffice начинается с 0.
//Исключение
// Sheet = Неопределено;
// Сообщить("Некорректное имя листа: <" + ФайлИмяЛиста + "> или его номер: <" + ФайлНомерЛиста + ">.");
//КонецПопытки;
КонецПопытки;
Возврат Sheet;
КонецФункции
// Выделяет из полного имени файла имя файла без расширения.
//
// Параметры
// ПолноеИмяФайла – Строка, содержащая имя файла, неважно с именем каталога или без.
//
// Возвращаемое значение:
// ИмяФайлаБезРасширения – короткое имя файла.
//
&НаСервере
Функция ПолучитьИмяФайлаБезРасширения(ПолноеИмяФайла)
Перем ФайлТМП, РасширениеФайла, ИмяФайлаБезРасширения;
ФайлТМП = РазложитьСтрокуВМассивПодстрок(ПолноеИмяФайла, "\");
ФайлТМП = ФайлТМП[ФайлТМП.Количество()-1];
РасширениеФайла = "." + ПолучитьРасширениеИмениФайла(ФайлТМП);
ИмяФайлаБезРасширения = СтрЗаменить(ФайлТМП, РасширениеФайла, "");
Возврат ИмяФайлаБезРасширения;
КонецФункции
// Выделяет из имени файла его расширение (набор символов после последней точки).
//
// Параметры
// ИмяФайла – Строка, содержащая имя файла, неважно с именем каталога или без.
//
// Возвращаемое значение:
// Строка – расширение файла.
//
&НаСервере
Функция ПолучитьРасширениеИмениФайла(Знач ИмяФайла)
Перем Расширение;
Расширение = ПолучитьСтрокуОтделеннойСимволом(ИмяФайла, ".");
Возврат Расширение;
КонецФункции
// Конвертировать имя файла для метода "LibreOffice CALC".
//
&НаСервере
функция ConvertToURL(ФайлEXCEL)
ФайлEXCEL = СтрЗаменить(ФайлEXCEL," ","%20");
ФайлEXCEL = СтрЗаменить(ФайлEXCEL,"\","/");
Возврат "file:/" + "/localhost/" + ФайлEXCEL;
Конецфункции
// Функция "расщепляет" строку на подстроки, используя заданный
// разделитель. Разделитель может иметь любую длину.
// Если в качестве разделителя задан пробел, рядом стоящие пробелы
// считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
// игнорируются.
// Например,
// РазложитьСтрокуВМассивПодстрок(",один,,,два", ",") возвратит массив значений из пяти элементов,
// три из которых - пустые строки, а
// РазложитьСтрокуВМассивПодстрок(" один два", " ") возвратит массив значений из двух элементов
//
// Параметры:
// Стр - строка, которую необходимо разложить на подстроки.
// Параметр передается по значению.
// Разделитель - строка-разделитель, по умолчанию - запятая.
//
// Возвращаемое значение:
// массив значений, элементы которого - подстроки
//
&НаСервере
Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт
МассивСтрок = Новый Массив();
Если Разделитель = " " Тогда
Стр = СокрЛП(Стр);
Пока 1 = 1 Цикл
Поз = Найти(Стр, Разделитель);
Если Поз = 0 Тогда
МассивСтрок.Добавить(СокрЛП(Стр));
Возврат МассивСтрок;
КонецЕсли;
МассивСтрок.Добавить(СокрЛП(Лев(Стр, Поз - 1)));
Стр = СокрЛ(Сред(Стр, Поз));
КонецЦикла;
Иначе
ДлинаРазделителя = СтрДлина(Разделитель);
Пока 1 = 1 Цикл
Поз = Найти(Стр, Разделитель);
Если Поз = 0 Тогда
Если (СокрЛП(Стр) <> "") Тогда
МассивСтрок.Добавить(СокрЛП(Стр));
КонецЕсли;
Возврат МассивСтрок;
КонецЕсли;
МассивСтрок.Добавить(СокрЛП(Лев(Стр,Поз - 1)));
Стр = Сред(Стр, Поз + ДлинаРазделителя);
КонецЦикла;
КонецЕсли;
КонецФункции
// Функция возвращает часть строки после последнего встреченного символа в строке
&НаСервере
Функция ПолучитьСтрокуОтделеннойСимволом(Знач ИсходнаяСтрока, Знач СимволПоиска)
ПозицияСимвола = СтрДлина(ИсходнаяСтрока);
Пока ПозицияСимвола >= 1 Цикл
Если Сред(ИсходнаяСтрока, ПозицияСимвола, 1) = СимволПоиска Тогда
Возврат Сред(ИсходнаяСтрока, ПозицияСимвола + 1);
КонецЕсли;
ПозицияСимвола = ПозицияСимвола - 1;
КонецЦикла;
Возврат "";
КонецФункции
// Удаляет кавычки с начала и конца строки, если они есть.
//
// Параметры:
// Строка - входная строка;
//
// Возвращаемое значение:
// Строка - строка без двойных кавычек.
//
&НаСервере
Функция УдалитьКавычки(Знач Строка, Кавычка = """")
Пока Лев(Строка, 1) = Кавычка Цикл
Строка = Сред(Строка, 2);
КонецЦикла;
Пока Прав(Строка, 1) = Кавычка Цикл
Строка = Лев(Строка, СтрДлина(Строка) - 1);
КонецЦикла;
Возврат Строка;
КонецФункции
// Удаляет из строки указанное количество символов справа.
//
// Параметры:
// Текст - Строка - строка, в которой необходимо удалить последние символы;
// ЧислоСимволов - Число - количество удаляемых символов.
//
&НаСервере
Процедура УдалитьПоследнийСимволВСтроке(Текст, ЧислоСимволов)
Текст = Лев(Текст, СтрДлина(Текст) - ЧислоСимволов);
КонецПроцедуры
// Проверяет, содержит ли строка только цифры и точки.
//
// Параметры:
// СтрокаПроверки - Строка - Строка для проверки
// УчитыватьЛидирующиеНули - Булево - Флаг учета лидирующих нулей, если Истина, то ведущие нули пропускаются
// УчитыватьПробелы - Булево - Флаг учета пробелов, если Истина, то пробелы при проверке игнорируются
//
// Возвращаемое значение:
// Булево - Истина - строка содержит только цифры или пустая, Ложь - строка содержит иные символы.
//
&НаСервере
Функция ТолькоЦифрыИТочкиВСтроке(Знач СтрокаПроверки, Знач УчитыватьЛидирующиеНули = Истина, Знач УчитыватьПробелы = Истина)
СтрокаПроверки = ТолькоЦифрыВСтрокеОбщий(СтрокаПроверки, УчитыватьЛидирующиеНули, УчитыватьПробелы);
// Если содержит только цифры и точки, то в результате замен должна быть получена пустая строка
// Проверять при помощи ПустаяСтрока нельзя, так как в исходной строке могут быть пробельные символы
Возврат СтрДлина(
СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить(
СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить(
СтрокаПроверки, "0", ""), "1", ""), "2", ""), "3", ""), "4", ""), "5", ""), "6", ""), "7", ""), "8", ""), "9", ""), ".", "")
) = 0;
КонецФункции
// Проверяет, содержит ли строка только цифры, точки и двоеточие.
//
// Параметры:
// СтрокаПроверки - Строка - Строка для проверки
// УчитыватьЛидирующиеНули - Булево - Флаг учета лидирующих нулей, если Истина, то ведущие нули пропускаются
// УчитыватьПробелы - Булево - Флаг учета пробелов, если Истина, то пробелы при проверке игнорируются
//
// Возвращаемое значение:
// Булево - Истина - строка содержит только цифры или пустая, Ложь - строка содержит иные символы.
//
&НаСервере
Функция ТолькоЦифрыИТочкиИДвоеточиеВСтроке(Знач СтрокаПроверки, Знач УчитыватьЛидирующиеНули = Истина, Знач УчитыватьПробелы = Истина)
СтрокаПроверки = ТолькоЦифрыВСтрокеОбщий(СтрокаПроверки, УчитыватьЛидирующиеНули, УчитыватьПробелы);
// Если содержит только цифры и точки, то в результате замен должна быть получена пустая строка
// Проверять при помощи ПустаяСтрока нельзя, так как в исходной строке могут быть пробельные символы
Возврат СтрДлина(
СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить(
СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить( СтрЗаменить(
СтрокаПроверки, "0", ""), "1", ""), "2", ""), "3", ""), "4", ""), "5", ""), "6", ""), "7", ""), "8", ""), "9", ""), ".", ""), ":", "")
) = 0;
КонецФункции
// Преобразование строки символов в зависимости от параметров.
//
// Параметры:
// СтрокаПроверки - Строка - Строка для проверки
// УчитыватьЛидирующиеНули - Булево - Флаг учета лидирующих нулей, если Истина, то ведущие нули пропускаются
// УчитыватьПробелы - Булево - Флаг учета пробелов, если Истина, то пробелы при проверке игнорируются
//
// Возвращаемое значение:
// Булево - Истина - строка содержит только цифры или пустая, Ложь - строка содержит иные символы.
//
&НаСервере
Функция ТолькоЦифрыВСтрокеОбщий(Знач СтрокаПроверки, Знач УчитыватьЛидирующиеНули = Истина, Знач УчитыватьПробелы = Истина)
Если ТипЗнч(СтрокаПроверки) <> Тип("Строка") Тогда
Возврат Ложь;
КонецЕсли;
Если НЕ УчитыватьПробелы Тогда
СтрокаПроверки = СтрЗаменить(СтрокаПроверки, " ", "");
СтрокаПроверки = СтрЗаменить(СтрокаПроверки, Символы.НПП, "");
КонецЕсли;
Если ПустаяСтрока(СтрокаПроверки) Тогда
Возврат Истина;
КонецЕсли;
Если НЕ УчитыватьЛидирующиеНули Тогда
Позиция = 1;
// Взятие символа за границей строки возвращает пустую строку
Пока Сред(СтрокаПроверки, Позиция, 1) = "0" Цикл
Позиция = Позиция + 1;
КонецЦикла;
СтрокаПроверки = Сред(СтрокаПроверки, Позиция);
КонецЕсли;
Возврат СтрокаПроверки;
КонецФункции
// Преобразование строки: "01.01.13" или "01.01.2013" или "01.01.2013 01:00:00" к значению типа "дата".
&НаСервере
Функция ПреобразоватьПростоеЗначениеИзСтрокиИлиЧислаВДату(ЧислоСтрока, Век="19", РазделительВЧДата=".", РазделительВЧВремя=":")
Перем МассивДата, ЧастьДата, ЧастьВремя, ЗначениеДата, МассивВремя, ЗначениеВремя;
Перем ScrptCtrl, OutDate;
Попытка
ScrptCtrl = Новый COMОбъект("MSScriptControl.ScriptControl");
ScrptCtrl.Language="vbscript";
OutDate = ScrptCtrl.Eval("CDate(""" + ЧислоСтрока + """)");
Возврат OutDate;
Исключение
Попытка
ScrptCtrl = Новый COMОбъект("MSScriptControl_ScriptControl");
ScrptCtrl.Language="vbscript";
OutDate = ScrptCtrl.Eval("CDate(""" + ЧислоСтрока + """)");
Возврат OutDate;
Исключение
//Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПопытки;
Если ТипЗнч(ЧислоСтрока) = Тип("Число") Тогда
OutDate = Дата('18991230')+(ЧислоСтрока)*24*60*60;
OutDate = ?(OutDate < Дата("19000101"), OutDate + 2*24*60*60, OutDate);
Возврат OutDate;
КонецЕсли;
// Ограниченная обработка строкового значения для перобразования в основные варианты даты типа "12.12.12", "12.12.2012" (+ "00:00:00").
Если (ТолькоЦифрыИТочкиВСтроке(ЧислоСтрока, Истина, Ложь) И СтрЧислоВхождений(ЧислоСтрока, ".") = 2)
ИЛИ (ТолькоЦифрыИТочкиИДвоеточиеВСтроке(ЧислоСтрока, Истина, Ложь) И СтрЧислоВхождений(ЧислоСтрока, ".") = 2 И СтрЧислоВхождений(ЧислоСтрока, ":") = 2 ) Тогда
МассивДата = РазложитьСтрокуВМассивПодстрок(ЧислоСтрока, " ");
ЧастьДата = МассивДата[0];
Если МассивДата.Количество() = 2 Тогда
ЧастьВремя = МассивДата[1];
Иначе
ЧастьВремя = Неопределено;
КонецЕсли;
// Часть "Дата".
МассивДата = РазложитьСтрокуВМассивПодстрок(ЧастьДата, РазделительВЧДата);
Если МассивДата.Количество() < 3 Тогда
Возврат ЧислоСтрока;
КонецЕсли;
ЗначениеДата = МассивДата[2] + МассивДата[1] + МассивДата[0];
Если СтрДлина(ЗначениеДата) = 6 Тогда
ЗначениеДата = Век + ЗначениеДата;
КонецЕсли;
// Часть "Время".
ЗначениеВремя = Неопределено;
Если НЕ ЧастьВремя = Неопределено Тогда
МассивВремя = РазложитьСтрокуВМассивПодстрок(ЧастьВремя, РазделительВЧВремя);
Если МассивВремя.Количество() > 0 Тогда
Если СтрДлина(МассивВремя[0]) = 1 Тогда
МассивВремя[0] = "0" + МассивВремя[0];
КонецЕсли;
Если МассивВремя.Количество() = 3 Тогда
ЗначениеВремя = МассивВремя[0] + МассивВремя[1] + МассивВремя[2];
ИначеЕсли МассивВремя.Количество() = 2 Тогда
ЗначениеВремя = МассивВремя[0] + МассивВремя[1] + "00";
ИначеЕсли МассивВремя.Количество() = 1 Тогда
ЗначениеВремя = МассивВремя[0] + "0000";
КонецЕсли;
КонецЕсли;
КонецЕсли;
Попытка
Возврат Дата(ЗначениеДата+ЗначениеВремя);
Исключение
Возврат ЧислоСтрока;
КонецПопытки;
КонецЕсли;
Возврат ЧислоСтрока;
КонецФункции
Преимущества:
1. Метод «LibreOffice CALC» поддерживает наибольшее количество форматов.
2. Бесплатен.
Особенности и Ограничения:
1.Для функционирования метода «LibreOffuce CALC» необходим установленный LibreOffice.
2. 1-я строка файла EXCEL - строка, содержащая заголовки колонок.
С уважением к сообществу МА!
