Новичок новичку: самый простой способ сделать расшифровку в СКД (обычные\управляемые формы)
Здравствуйте.
Допустим, Вы сделали красивый и, ужас какой, нужный отчет, но до полного идеала не хватает маленького шажочка - нужно по щелчку ячейки отчета вывести дополнительные данные.
Это называется расшифровкой. Стандартно, расшифровка строится только для ссылочных данных: если в ячейке указан какой-то документ, то щелкнув по этой ячейке документ и откроется.
Если Вы начнете искать в интернете информацию по расшифровке. То получите огромное количество информации, как изменить команды расшифровки, как добавить свое действие... Все это будет сопровождаться сотнями строк кода.
Однако, в 99% случаев задача перед программистом стоит такая: по щелчку мыши вывести дополнительную информацию. И все! 99% изученной информации Вам не потребуется.
Вы, конечно же, во всем разберетесь, но если тратить время не хочется, то я покажу как всего несколькими строчками кода изменить поведение Вашего отчета - получить расшифровку, любого поля, изменить расшифровку, которая идет по умолчанию.
Прежде всего следует понять, что расшифровка делается не в данных, а в элементе на форме. То есть, мы будем менять не данные отчета, а то, куда эти данные выводятся.
В 99% случаях, данные выводятся в табличный документ.
Форму с этим элементом может создать за Вас система 1С автоматически, но в этом случае, в рамках данной статьи, повлиять на работу данного элемента не получится. Поэтому форму отчета Вам придется создать самим.
При создании пользовательской формы отчета, система автоматически создает на ней элемент вывода данных. Как правило, это табличный документ с именем Результат:
обычные формы
У данного элемента есть событие Обработка расшифровки. Создайте событие, выбрав его:

Мы увидим следующий текст:
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)
// Вставить содержимое обработчика.
КонецПроцедуры
Комментарий нам не нужен, можете как оставить его так и удалить.
Прежде всего, нужно указать системе, что стандартное поведение расшифровки нас не устраивает, для этого вставим строку:
СтандартнаяОбработка = Ложь;
Если Вы теперь запустите свой отчет, то никакой расшифровки проводиться не будет. Даже стандартной. То есть мы отключили стандартное поведение, а из стандартных команд расшифровки осталась только "Открытие", но так как и ее поведение мы еще не программировали, то и оно не работает.
Затем, следует запомнить выражение: ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0]
Именно здесь система хранить информацию о ячейке, по которой пользователь щелкнул мышью. Присвоив переменной данное выражение, мы получим переменную, состоящую из нескольких полей. Нас будут интересовать поля: Поле и Значение.
Данные = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0];
Допустим, наш отчет имеет следующий вид:

Щелкнув по ячейке "1000", наша переменная Данные "получит информацию". Данные.Поле будет содержать "СуммаДокумента", а Данные.Значение будет содержать "1000". А вот если щелкнуть, по сотруднику Юмин КГ, то Данные.Поле станет "Сотрудник", а Данные.Значение, будет содержать ссылку на элемент справочника Сотрудники - Юмина КГ.
Но почему, в первом случае был просто текст, а во-втором - ссылка на сотрудника? Просто, в схеме компоновки данных отчета, я так указал именно эти типы полей:

Кстати, тип значения полей можно и не указывать, главное понимать, какие типы данных возвращает запрос к базе.
Перейдем к практике.
Стандартно, данный отчет по щелчку на сотруднике должен открывать справочник сотрудника. Изменим поведение, чтобы открывался не сотрудник, а физическое лицо, которое привязано к этому сотруднику.
Не забываем отменить стандартное поведение расшифровки:
СтандартнаяОбработка = Ложь;
Далее мы должны посмотреть, а не щелкнул ли пользователь по полю сотрудника, и если это так, то открыть физическое лицо:
Если ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Поле = "Сотрудник" Тогда
Ссылка = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Значение;
ОткрытьЗначение(Ссылка.ФизЛицо);
КонецЕсли;
Вот и все!
Теперь, давайте попробуем не ссылочный тип данных: выведем в текстовой документ сумму документа, если пользователь щелкает по сумме:
Если ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Поле = "СуммаДокумента" Тогда
СуммаДокумента = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Значение;
Текст = Строка(СуммаДокумента);
ТекстовойДокумент = Новый ТекстовыйДокумент;
ТекстовойДокумент.ДобавитьСтроку(Текст);
ТекстовойДокумент.Показать();
КонецЕсли;
В итоге, вся процедура расшифровки получилась такой:
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)
СтандартнаяОбработка = Ложь;
Если ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Поле = "Сотрудник" Тогда
Ссылка = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Значение;
ОткрытьЗначение(Ссылка.ФизЛицо);
КонецЕсли;
Если ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Поле = "СуммаДокумента" Тогда
СуммаДокумента = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Значение;
Текст = Строка(СуммаДокумента);
ТекстовойДокумент = Новый ТекстовыйДокумент;
ТекстовойДокумент.ДобавитьСтроку(Текст);
ТекстовойДокумент.Показать();
КонецЕсли;
КонецПроцедуры
Для управляемых форм почти все тоже самое, отличие в том что, данные расшифровки не в памяти, а в хранилище, и их надо получить, кроме того, работа с расшифровкой в управляемых формах должна проводиться на сервере:
&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)
СтандартнаяОбработка = Ложь;
СтруктураДанных = ПолучитьРасшифровку(Расшифровка, ДанныеРасшифровки);
Если СтруктураДанных.Поле = "Склад" Тогда
ОткрытьЗначение(СтруктураДанных.Значение);
КонецЕсли;
КонецПроцедуры
&НаСервере
Функция ПолучитьРасшифровку(Расшифровка, ДанныеРасшифровки)
//получим из хранилища данные
ДанныеРасшифровкиОбъект = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);
//вернулись к строке вида: ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0]
Данные = ДанныеРасшифровкиОбъект.Элементы[Расшифровка].ПолучитьПоля()[0];
//переменную Данные в управляемых формах на клиент передавать нельзя, а потому, перобразуем ее в структуру
СтруктураДанных = Новый Структура;
СтруктураДанных.Вставить("Поле", Данные.Поле);
СтруктураДанных.Вставить("Значение", Данные.Значение);
//возвращаем
Возврат СтруктураДанных;
КонецФункции
P.S. При усложнении схемы, а точнее ее настроек, значения полей расшифровки могут "теряться". Например, при введении группировок... Тогда следует получать расшифровку не прямым указанием: взять первое поле элемента расшифровки... Но это тема отдельной статьи. Главное новичку понять откуда что берется и только затем ставить перед собой более сложные задачи!
На сегодня это все! Жду вопросов, критики и пожеланий....
Вступайте в нашу телеграмм-группу Инфостарт
Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
См. также
Инструментарий разработчика Роли и права Запросы СКД Разработчик Руководитель проекта 1С:Предприятие 8 Платные (руб)
Инструменты для разработчиков 1С 8.3 и 8.5: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.
16500 руб.
02.09.2020 286914 1612 423
СКД Разработчик 1С:Предприятие 8 Бесплатно (free)
Как решить проблему с отборами по полям СКД, когда с одинаковым отбором Отчет показывает одно, а Консоль запросов другое.
16.06.2026 6484 sapervodichka 45
Инструментарий разработчика СКД Разработчик 1С 8.3 Бесплатно (free)
В этой статье представлен ПовелительОтчетов — общий модуль-обёртка над объектной моделью СКД, который сокращает код в 3-4 раза и делает его читаемым.
29.01.2026 9567 459 shapa_pro 31
СКД Разработчик 1С:Предприятие 8 Бесплатно (free)
Статья написана по результатам проведенного внутреннего обучающего вебинара для разработчиков ГК «СофтБаланс». Если осилить 25 000 знаков - задача для вас непосильная, где-то на бескрайних просторах интернета видео есть (или будет). Но здесь информация точнее. Разберем, чем запрос для СКД принципиально отличается от обычного запроса и как модифицируется в зависимости от настроек. Изучим «базовый рецепт» написания запроса для СКД, сформируем чек-лист. Полезно будет всем – от стажеров до тех. лидов. Всем, кто не снимает галку «автозаполнение» и пишет запросы для отчетов в консоли запросов – читать (вдумчиво) обязательно.
29.10.2025 27325 ovetgana 112
СКД Разработчик 1С:Предприятие 8 Бесплатно (free)
Описан способ заполнения списка доступных значений для полей наборов данных и параметров в схеме компоновки данных для любых конфигураций (с использованием БСП или без).
01.07.2025 15953 krasnoshchekovpavel 7
СКД Разработчик Стажер 1С:Предприятие 8 Россия Бесплатно (free)
Несколько способов управления формами выбора параметров и отборов СКД.
10.04.2025 15360 Neti 0
СКД Разработчик 1С:Предприятие 8 Бесплатно (free)
Хорошая отчетная форма - сродни искусству. Есть какое-то невероятное эстетическое удовольствие в том, чтобы разобраться в логике учета и анализируемых показателях, спроектировать архитектуру хранения данных так, чтобы оптимально собрать эти показатели вместе с аналитическими разрезами в запросе, а затем настроить отображение так, чтобы, глядя на результат, сразу было понятно, что это за отчет и какие задачи он призван решать. Система компоновки данных - это моя первая, главная и, наверное, единственная "рабочая" любовь. Ее я использую везде, где только можно и где нельзя тоже. Хочу поделиться с вами некоторыми практическими приемами в работе с отчетами на СКД, которые, надеюсь, будут полезны.
27.02.2025 19951 ovetgana 50
СКД Разработчик 1С:Предприятие 8 Бесплатно (free)
СКД – инструмент, на базе которого в современных конфигурациях реализованы практически все отчеты. СКД используется в динамических списках, печатных формах и универсальных механизмах. Если построить простейший отчет может каждый разработчик, то с нюансами знакомы далеко не все. Расскажем о неочевидных на первый взгляд приемах, способных значительно повысить качество отчетов.
24.12.2024 17839 Akcium 17
P.S. а в расшифровку, которая детализация, СКД умеет без единой строчки кода
Например, у вас в отчёте вывелась общая задолженность организации перед сотрудниками в 100500 рублей, а вы хотите понять какому сотруднику вы сколько должны. Вы щелкаете 2 раза по циферке 100500 и у вас отображается окошко, в котором вы выбираете "Сотрудник". Открывается окно расшифровки отчёта и вы видите кучу строк, где есть сотрудник и суммы по каждому сотруднику.
Вот это называется расшифровка, и реализуется она с помощью СКД вообще без единой строчки кода.
И вы своим СтандартнаяОбработка = Ложь убиваете эту стандартную расшифровку, и вынуждены теперь для каждого поля описывать что должно произойти при попытке расшифровки поля.
А дальше вообще непонятно что происходит
Зачем писать какой-то код, чтобы по нажатию сотрудника открывалось физлицо? Это можно сделать опять же без кода с помощью средств СКД.
Открытие текстового документа с суммой документа - зачем? Просто показать что можно открывать какую-то форму при расшифровке?
А не поделитесь ссылочкой/двумя, где можно почитать, как на СКД сделать расшифровку грамотно?
На тестовом задании все ошибки устранил, кроме этой: по расшифровке выходили все подряд регистраторы, а нужно было только тот, который относился к конкретной записи по товару и складу.
(3)
Но, если я такой же код формирую в модуле объекта через процедуру "ПриКомпоновкеРезультата", и нажимаю стандартную кнопку "Сформировать", то обработчик срабатывает, но если использовать Вашу строчку кода:
Данные = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля[0];
то СКД данные формирует, появляется моя таблица в стандартном поле, а не в табличном документе, который выводится из формы и появляется сообщение: "Значение не является значением объектного типа (Элементы)".
Если, возможно, подскажите, я что то не правильно делаю? Разве нельзя из модуля формы запускать код на процесс компоновки данных, почему у меня не отслеживается событие ОбработкаРасшифровки?
И, конечно, почему выдаётся эта ошибка? Это может как раз из-за того что у меня данные получены из модуля объекта?
Вопрос не совсем понял... Вот мой код при компоновке:
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
//////////////////////////////////////////////////////////// //////////////////////////////////////////
//Получаем введенные даты пользователем
Начало = КомпоновщикНастроек.Настройки.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ДатаНачала"));
Если НЕ Начало = Неопределено Тогда
Начало.Использование = Истина;
Начало.Значение = НачалоДня(ДатаНачала);
КонецЕсли;
Окончание = КомпоновщикНастроек.Настройки.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ДатаОкончания"));
Если НЕ Окончание = Неопределено Тогда
Окончание.Использование = Истина;
Окончание.Значение = КонецДня(ДатаОкончания);
КонецЕсли;
Состояние("Выбираю данные из базы...");
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| РеализацияТоваровУслуг.Ссылка
|ИЗ
| Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
|ГДЕ
| РеализацияТоваровУслуг.Дата МЕЖДУ &Начало И &Окончание";
Запрос.УстановитьПараметр("Начало", Начало.Значение);
Запрос.УстановитьПараметр("Окончание", Окончание.Значение);
ТЗ = Запрос.Выполнить().Выгрузить();
//////////////////////////////////////////////////////////// ////////////////////////////////////////
//Вывод отчета
//Связь между таблицей значений и именами в СКД
ВнешниеНаборыДанных = Новый Структура;
ВнешниеНаборыДанных.Вставить("ТаблицаДанных", ТЗ);
//Макет компоновки
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(ЭтотОбъект.СхемаКомпоновкиДанных, ЭтотОбъект.КомпоновщикНастроек.ПолучитьНастройки(), ДанныеРасшифровки);
//Компоновка данных
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки);
//Вывод результата
ДокументРезультат.Очистить();
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);
//////////////////////////////////////////////////////////// ////
//Группируем на уровне
ДокументРезультат.ПоказатьУровеньГруппировокСтрок(1);
КонецПроцедуры ПоказатьВозможно, он Вам поможет. Если нет, то объясните яснее
Если формировать отчет из модуля формы..., например при открытии формы это делается так:
Процедура ПриОткрытии()
НачПериода = ТекущаяДата() - 60*60*24*7;
КонПериода = ТекущаяДата();
ДатаНач = КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ДатаНач");
ДатаНач.Значение = НачалоДня(НачПериода);
ДатаНач.Использование = Истина;
ДатаКон = КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ДатаКон");
ДатаКон.Значение = КонецДня(КонПериода);
ДатаКон.Использование = Истина;
ДокументРезультат = ЭлементыФормы.Результат;
ДокументРезультат.Очистить();
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
СкомпоноватьРезультат(ДокументРезультат,ДанныеРасшифровки);
КонецПроцедуры ПоказатьЕсли вывод происходит в табличный документ, а не в элемент на форме, то это разное и код будет иным.
Еще могу посоветовать попробовать разобраться на простом примере, и только потом переходить к решению Вашего вопроса.
&НаКлиенте
Процедура ПриОткрытии(Отказ)
СкомпоноватьРезультат();
КонецПроцедуры
"e1cib/tempstorage/acf9764e-0703-4b17-833e-dc9f178df227?seanceId=8f42302f-8c32-4e8e-accf-344807b86f83"
Расшифровка имеет значение 2, а тип "ИдентификаторРасшифровкиКомпоновкиДанных",
и уже выражение "ДанныеРасшифровки.Элементы[Расшифровка]" выдаёт в отладчике:
"{(1)}: Значение не является значением объектного типа (Элементы)"
Что здесь не так может быть?
&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)
СтандартнаяОбработка = Ложь;
СтруктураДанных = ПолучитьРасшифровку(Расшифровка, ДанныеРасшифровки);
Если СтруктураДанных.Поле = "Склад" Тогда
ОткрытьЗначение(СтруктураДанных.Значение);
КонецЕсли;
КонецПроцедуры
&НаСервере
Функция ПолучитьРасшифровку(Расшифровка, ДанныеРасшифровки)
//получим из хранилища данные
ДанныеРасшифровкиОбъект = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);
//вернулись к строке вида: ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0]
Данные = ДанныеРасшифровкиОбъект.Элементы[Расшифровка].ПолучитьПоля()[0];
//переменную Данные в управляемых формах на клиент передавать нельзя, а потому, перобразуем ее в структуру
СтруктураДанных = Новый Структура;
СтруктураДанных.Вставить("Поле", Данные.Поле);
СтруктураДанных.Вставить("Значение", Данные.Значение);
//возвращаем
Возврат СтруктураДанных;
КонецФункции ПоказатьЕщё раз отдельное спасибо за подробное пояснение, это очень помогает разобраться и главное это двигает желание разобраться. Я так понимаю, у Вас толстый клиент, у меня тонкий. Заменил функцию «ОткрытьЗначание», на «ПоказатьЗначение» и всё получилось. Понял, что ДанныеРасшифровки берутся на сервере, как и Вы показали в специальной функции. Но, как всегда есть «НО»))).
Поясню ещё раз вопрос, с Вашего позволения.
Вы оперировали предопределённым обработчиком события «ПриКомпоновкеРезультата».
Эта процедура является процедурой модуля объекта и у Вас она присутствует, поэтому могу предположить, что она нужна. У меня же был вопрос, а можно обойтись без неё? Я так и не понял. И зачем нужна эта расшифровка тогда?
В чём её смысл?
Если я убираю эту процедуру (РезультатОбработкаРасшифровки) из модуля формы, которые Вы привели для УФорм, но заполняю процедуру (ПриКомпоновкеРезультата) в модуле объекта, и нажимаю кнопку «Сформировать», то ровным счётом ничего не меняется, ничего.
Что в первом, что и во втором случае я нажимая на выбранную ячейку сформированного отчёта получаю один и тот же результат.
К примеру, у меня выводится одно поле, которое я задал в СКД, Покупатель. Нажимаю на него два раза, проваливаюсь в карточку. Если я убираю код в модуле формы, то тоже проваливаюсь в карточку. Зачем тогда писать код в модуле формы, не пойму?
А вопрос был такой. Если я хочу на форме сделать свою кнопочку, не используя стандартную («Сформировать»), которая по умолчанию выдаётся, и захочу вывести отчёт в ТабДок отдельную таблицу, то:
1) Нужно ли писать процедуру компоновки и вывода данных в предопределённой процедуре (ПриКомпоновкеРезультата), если я пишу такой же код в модуле Формы
2) Можно ли при этом в этой таблице получить расшифровку, потому как я не смог расшифровать данные, при выводе отчёта в отдельном ТабДоке, даже написав процедуру (РезультатОбработкаРасшифровки).
Т.е. я нажимаю на ячейку, а результата нет. Не возникает событие ОбработкаРасшифровки, оно не активно в этом случае?
Два раза прочел Ваш текст, все равно не понял в чем проблема...
Процедуры: ПриКомпоновкеРезультата и РезультатОбработкаРасшифровки вообще никак не связаны друг с другом...Ну может, связаны через реквизит ДанныеРасшифровки, одна в него записывает данные, вторая читает... И как это делает одна и вторая совершенно не важно, стандартно или нет... для расшифровки Вам следует смотреть только процедуру расшифровки...
Если вы выводите результат не на форму, а в табличный документ, то у каждой ячейки табличного документа есть текст, значение и расшифровка...Как Вы будете заполнять эти свойства, не важно, можно в цикле перебором всех ячеек, можно через макет...
Отказавшись от стандартного формирования отчета, Вы, по сути, превратили отчет в обработку! И тогда у Вас появляется куча путей решения сформировать Табличный документ...
0) просто нарисовать таблицу ячейку за ячейкой или через макет, как это делается в печатных формах
1) юзать, команду СкомпоноватьРезультат(); Чтобы результат при этом не был стандартным придется менять процедуру компоновки
2) вызвать не посредственно процедуру компоновки при нажатии на кнопку. Так как эта процедура в модуле объекта, то для ее доступности из модуля формы нужно будет сделать экспортной
3) не париться с процедурой компоновки, а перенести ее код в модуль формы
Главное! НЕ ЗАБЫВАЙТЕ УСТАНОВИТЬ ДЛЯ ТАБЛИЦЫ ТОЛЬКО ПРОСМОТР
&НаКлиенте
Процедура Команда1(Команда)
ТабДок = СформироватьТабДок();
ТабДок.Показать();
КонецПроцедуры
&НаСервере
Функция СформироватьТабДок()
ТабДок = Новый ТабличныйДокумент;
ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
ДР = Новый ДанныеРасшифровкиКомпоновкиДанных;
//Макет компоновки
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(ОтчетОбъект.СхемаКомпоновкиДанных, ОтчетОбъект.КомпоновщикНастроек.ПолучитьНастройки(),ДР,,Тип("ГенераторМакетаКомпоновкиДанных"));
//Компоновка данных
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДР);
//Вывод результата
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.ОтображатьПроцентВывода = Истина;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновки, Истина);
ТабДок.ТолькоПросмотр = Истина;
//Здесь код, который сделает расшифровку. Он чужой, копировать не буду, смотрите по ссылке
Возврат ТабДок;
КонецФункции
ПоказатьНе получается, я понимаю, что я что то не доделываю, но где и как?
Хочу выложить свою обработку, в ней использовал Вашу функцию, ДанныеРасшифровки не работают, более того при
выполнении макета выдаёт ошибку 3. Может просмотрите бегло, всю структуру, и Вам сразу станет понятно, потому как обрывки кода уже не могут разъяснить ситуацию.
Процедура РезультатОбработкаРасшифровки вообще не проявляет ни каких откликов.
А вот если в модуле объекта заполнить ПриКомпоновкеРезультата, тогда и обработка расшифровки участвует при нажатии на поле выведенной таблицы. Могу этот вариант так же выложить, для сравнения.
Спасибо.
У Вас на форме 2 кнопки: Сформировать, ПечатьДок... Зачем вторая, если есть первая? Вторая - чтобы вывести тоже самое, что на форме, но только в отдельный в табличный документ или вывести в табличный документ вообще что-то другое? Если тоже самое, то зачем проводить вычисления в ПечатьДокНаСервере(), если что-то иное, то не проще было сделать еще одну схему компоновки и по нажатию на ПечатьДок брать не основную, а дополнительную?
Я проверить работу отчета не могу, так как нет Вашей базы...У Вас отчет то работает по кнопке сформировать? Вы делаете схему отчета с набором данных объект. По кнопке сформировать, подразумевается, что 1с получит данные при компоновке. А компоновки у Вас нет! Она располагается в модуле объекта, а модуль отчета у Вас чист!
Или Вам кнопка Сформировать вообще не нужна, и Вы хотите сделать, как в примере ?
&НаСервере
Функция ВыполнитьПечатьДокВТаблицу(Ссылка)
ТабДок = Новый ТабличныйДокумент;
ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
ДР = Новый ДанныеРасшифровкиКомпоновкиДанных;
//настройки
Настройки = ОтчетОбъект.КомпоновщикНастроек.ПолучитьНастройки();
ПараметрСсылка = Настройки.ПараметрыДанных.Элементы.Найти("Ссылка");
ПараметрСсылка.Значение = Ссылка;
ПараметрСсылка.Использование = Истина;
//Макет компоновки
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(ОтчетОбъект.СхемаКомпоновкиДанных, Настройки,ДР,,Тип("ГенераторМакетаКомпоновкиДанных"));
//Компоновка данных
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДР);
//Вывод результата
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.ОтображатьПроцентВывода = Истина;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);
ТабДок.ТолькоПросмотр = Истина;
//Здесь код, который сделает расшифровку. Он чужой, копировать не буду, смотрите по ссылке
Возврат ТабДок;
КонецФункции
&НаСервере
Процедура ВыполнитьПечатьДокНаФорму(Ссылка)
Результат.Очистить();
ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
Схема = ОтчетОбъект.СхемаКомпоновкиДанных;
ДР = Новый ДанныеРасшифровкиКомпоновкиДанных;
//настройки
Настройки = Отчет.КомпоновщикНастроек.ПолучитьНастройки();
ПараметрСсылка = Настройки.ПараметрыДанных.Элементы.Найти("Ссылка");
ПараметрСсылка.Значение = Ссылка;
ПараметрСсылка.Использование = Истина;
//Макет компоновки
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(Схема, Настройки, ДР);
//Компоновка данных
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДР);
//Вывод результата
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.ОтображатьПроцентВывода = Истина;
ПроцессорВывода.УстановитьДокумент(Результат);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);
//Здесь код, который сделает расшифровку. Он чужой, копировать не буду, смотрите по ссылке
КонецПроцедуры
&НаКлиенте
Процедура ПечатьДокНаФорму(Команда)
Элементы.Результат.ОтображениеСостояния.Видимость = Ложь;
Элементы.Результат.ОтображениеСостояния.ДополнительныйРежимОтображения = ДополнительныйРежимОтображения.НеИспользовать;
ВыполнитьПечатьДокНаФорму(Документ);
КонецПроцедуры
&НаКлиенте
Процедура ПечатьДокВТаблицу(Команда)
ТабДок = ВыполнитьПечатьДокВТаблицу(Документ);
ТабДок.Показать();
КонецПроцедуры ПоказатьЭлементы.Результат.ОтображениеСостояния.Видимость = Ложь;
Элементы.Результат.ОтображениеСостояния.ДополнительныйРежимОтображения = ДополнительныйРежимОтображения.НеИспользовать;Вот 4 варианта:
Что я хотел. Есть база. Я делаю внешний отчёт. Получаю данные, к примеру, с какого нибудь документа. Хочу сделать формирование отчёта по своей кнопке, пусть это будет ПечатьДок.
Я хотел узнать, можно ли так делать? Будет ли это работать? Можно ли при этом получить расшифровки?. Потому как при реализации столкнулся с определёнными трудностями, о которых писал - не получаю расшифровки, нет ни какой реакции на мои действия с сформированным табдоком.
Попробуйте прочитать статьи других авторов, возможно их стиль будет Вам более понятен. Начните с Там про расшифровку тоже неплохо написано
Я думал что ярлык "Таблица" как раз показывает Табличный Документ "Результат", который создан автоматически при добавлении Формы отчёта во внешний отчёт. Потому как я задаю строчкой кода ПроцессорВывода.УстановитьДокумент(Результат) , в функции СформироватьОтчёт(ПараметрДанных). А Результат это поле ТабДока в Форме (элемент Формы).
А ярлык "СхемаСтр224" показывает Табличный Документ, который автоматом, без моего кода должен формироваться системой, на основе Схемы, которую я создал.
Вот ещё, что я подметил для себя.
Если я создаю отчёт, описываю схему, через запрос например, формирую через кнопку "Сформировать", то получаю отчёт в том же окне, где и кнопка "Сформировать" и настройки и выбрать вариант.
В этом случае у меня есть и отфильтровать, упорядочить и расшифровать, которое правда не активно и требует, как раз описание расшифровки???
Если же я добавляю форму в отчёт, в ней кнопку и к ней подвязываю процедуру(ы), там где есть как раз Результат - элемент формы, то получаю дополнительный ярлык "Таблица", со всеми теми же данными, но там нет расшифровать, упорядочить и т.д.
Т.е. этот отдельный ТабДок, по Вашей стрелке справа, как раз формируется с формы???
Стандартно результат должен выводиться на форму отчета!!! Указывайте в процессор вывода не табличный документ, а элемент на форме! Желательно элемент на форме перед этим очищать...
Выводить отчет через процессор - это тоже применимо только в крайних случаях, когда без этого не обойтись никак, в том числе и при нажатии дополнительных кнопок...Для этого придумали процедуру СкомпоноватьРезультат();
Схема получается из макета этого же отчёта, настройки отдельной процедурой добавляются и отдельной процедурой формируется отчёт, в котором после инициализации есть вот такие строки:
Результат.Очистить();
ДокументРезультат = Результат;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);Всё как Вы описали - очищение и вывод в элемент формы.
Открываю отчёт, он сразу появляется, без нажатия кнопки "Сформировать", а иных кнопок и нет.
Но, возможности расшифровок, упорядочивания, группировок нет. Т.е. как как будто отдельный ТабДок.
Теперь я нажимаю сформировать и всё это появляется, правой клавишей мышки, пожалуйста, все ресурсы СКД доступны к расшифровке.
Вот мне это не понятно??? Так и должно быть? Или что то не так?
У формы есть событие при открытии...Если в это событие написать код формирования отчета, то при открытии отчет сформируется без нажатия кнопки
Но так как формы еще нет, то все параметры отчета нужно заполнить программно, а не тыкая мышкой в кнопки и настройки...
После того как отчет открылся, Вы можете уже менять настройки и формировать отчет уже с новыми настройками.
Что не понятно?
Спасибо.
Сейчас я хочу его использовать для попытки выяснить о объекте ДанныеРасшифровки. В статье автора расшифровок не было. Потом я пытаюсь добавить и у меня получается очень интересная ситуация. Я думаю Вам, как новичку, тоже будет это интересно, проверить.
Привожу первоначальный код:
НаКлиенте
Процедура Команда1(Команда)
Команда1НаСервере().Показать();
КонецПроцедуры
&НаСервере
Функция Команда1НаСервере()
СтандартнаяОбработка = Ложь;
ТЗВывод = Новый ТаблицаЗначений;
ТЗВывод.Колонки.Добавить("Автомобиль");
ТЗВывод.Колонки.Добавить("Количество");
ТЗВывод.Колонки.Добавить("Сумма");
НоваяСтрока = ТЗВывод.Добавить();
НоваяСтрока.Автомобиль = "ВАЗ";
НоваяСтрока.Количество = 10;
НоваяСтрока.Сумма = 500;
НоваяСтрока = ТЗВывод.Добавить();
НоваяСтрока.Автомобиль = "Мерс";
НоваяСтрока.Количество = 3;
НоваяСтрока.Сумма = 1500;
НоваяСтрока = ТЗВывод.Добавить();
НоваяСтрока.Автомобиль = "Шкода";
НоваяСтрока.Количество = 5;
НоваяСтрока.Сумма = 900;
НашМакет = РеквизитФормыВЗначение("Отчет");
СКД = НашМакет.ПолучитьМакет("СКД");
Настройки = СКД.НастройкиПоУмолчанию;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД, Настройки);
ВнешнийНаборДанных = Новый Структура("ПримерТаблицыЗначений", ТЗВывод);
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешнийНаборДанных);
//Результат = Новый ТабличныйДокумент; //можно и без этой строчки
Результат.Очистить();
ПроцесорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцесорВывода.УстановитьДокумент(Результат);
ПроцесорВывода.Вывести(ПроцессорКомпоновкиДанных);
Результат.ОтображатьСетку = Ложь;
Результат.ОтображатьЗаголовки = Ложь;
Возврат Результат;
КонецФункции ПоказатьПриведу код, что бы можно было подключить и проверить. Ни каких данных первоначальных не надо, просто подключай и всё.
Кстати я этот код склеял на просторах инета, к сожалению, у кого не помню, код не мой, но автору ОГРОМНОЕ СПАСИБО!!!
Помог мне разобраться.
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;перед строкой:
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;то при нажатии на Кнопка1 таблица в отдельном окне формируется, а при нажатии на "Сформировать", выдаётся сообщение:
Неправильный путь к файлу 'ДанныеРасшифровкиКомпоновкиДанных'
Это так, просто наблюдение.
Если я пытаюсь вставить ДанныеРасшифровки в метод Выполнить и Инициализировать то при нажатии Кнопка1 выдаётся ошибка:
Несоответствие типов (параметр номер '3')
Привожу участок кода:
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД, Настройки, ДанныеРасшифровки);
ВнешнийНаборДанных = Новый Структура("ПримерТаблицыЗначений", ТЗВывод);
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешнийНаборДанных, ДанныеРасшифровки);
Потому что строка
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;формирует не объект, который должен передаться в эти два метода, а просто имеет тип Строка. ПОЧЕМУ??? Ни как не могу этого понять.
Порылся в инете, приводят код, который получает данные из временного хранилища:
Данные = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);Вставил его в функция и действительно получился в переменной Данные нужный объект,
НО только после того, когда нажал кнопку "Сформировать". Только после этого.
Если сразу нажать кнопку Команда1, выдаётся сообщение что несоответствие параметра1.
И в этом случае ДанныеРасшифровка имеет значение "", соттветственно из хранилища брать нечего.
В изначальном коде по Команда1 нет расшифровки, потому что она не определяется, не вычисляется, не выводится, про нее просто забыли...
Чтобы ее добавить нужно ввести переменную и писать в нее расшифровку.
Так как переменная ДанныеРасшифровки УЖЕ занята и используется для ДРУГОГО, то ее использовать для расшифровки нельзя!!!! Придумайте ЛЮБОЕ другое не занятое, не системное имя!
В итоге надо добавить в кнопку строку до макета компоновки:
ДанныеРасшиф = Новый ДанныеРасшифровкиКомпоновкиДанных;
И изменить строку на:
МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД, Настройки, ДанныеРасшиф);
Кстати, при этом варианте, таблица формируется, только после формирования отчёта, без него как я уже говорил выдаёт несоответствие типов 3, но всё равно расшифровки нет, так и должно быть?
Т.е. вопрос открытый и совсем не понятный...
Данные = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);
Эта строка будет работать если ДанныеРасшифровки вычислялись!!!!!!
Как Вы можете ДанныеРасшифровки получать, если до этого в коде Команды1 нет ни слова о ДанныеРасшифровки?!
А так как в модуле ПриКомпоновкеРезультата идет вычисление ДанныеРасшифровки , то естественно после запуска стандартной команды формирования, эти данные на сервере есть и ошибки не будет!
И последнее:
Возврат Результат; - это зачем? Вы результат получили, на форме он отобразился в поле результат...Зачем Вы его возвращаете дополнительно в виде таблицы, да потом еще используете метод показать()?
Вы дополнительно открываете окно с тем же результатом, только в виде таблицы! Причем расшифровка работать не будет, так как Вы не прочитали мой совет, о том что для расшифровки таблиц, следует их делать только для чтения....
Оно и понятно, откуда этой расшифровки взяться. Только не понятно, как её достать без заполнения предопределённой процедуры.
Это если соблюсти Вашу логику, то надо добавить Реквизит, типа ТаблицаЗначений. Это будет аналог Вашего запроса для получения документа, и передать в качестве ссылки в параметр компоновки и затем уже вызвать метод СкомпоноватьРезультат. А он является аналогом предопределённой процедуры ПриКомпоновкеРезультата для модуля формы?
Потому как после этого появляется форма типа отчёт, а не таблица, поэтому и формируется только после этого объект ДанныеРасшифровки, который уже можно вытащить из хранилища?
Неужели иначе ни как?
Для расшифровки по кнопке, без ухода из модуля формы в модуль объекта не нужно никаких реквизитов...Реквизиты нужны для передачи данных из одних модулей в другие, Вы в пределах одного модуля можете просто создать переменную и использовать ее: см (52)
Нажимаю Кнопка1 и вижу таблицу. А если нажимаю сформировать, то пишет мне ошибку: Не найден внешний набор данных: "ПримерТаблицыЗначений".
Ну вот как это сделать, как изменить этот вариант, к примеру (высылаю пример, там я добавил Ваши замечания по поводу только чтения, так ведь нужно?
В Вашей схеме НЕТ ПАРАМЕТРОВ! Зачем Вы их пытаетесь установить строками:
ПараметрыКомпоновки = Новый ПараметрКомпоновкиДанных("ВнешнийНаборДанных");
ПараметрСсылка = Настройки.ПараметрыДанных.НайтиЗначениеПараметра(ПараметрыКомпоновки);
ПараметрСсылка.Значение = ВнешнийНаборДанных;
ПараметрСсылка.Использование = Истина;
Ваш отчет не работает по кнопке сформировать, тогда почему Вы пытаетесь программно на нее нажать, выполнив СкомпоноватьРезультат(); - результат будет тотже - ошибка!
Вы вообще не понимаете зачем нужна каждая строчка кода в процедуре открытия?
я хочу добиться выполнения кода с расшифровкой без заполнения в модуле объекта процедуры ПриКомпоновкеРезультата.
Но ничего не получается. Даже без расшифровки.
Спасибо автору. Вы подсказали главную идею, что нельзя делать код
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
А нужно присваивать это другой переменной, например ДанныеРасшифровки111.
И все везде, почему то пишут одинаково, а так не работает.
С методом СкомпоноватьРезультат не получилось. Использовал его, но к сожалению формируется отчёт, но
как бы в фоновом режиме, и требует нажать "Сформировать". Пошёл по другому пути.
Спасибо публикации , в ней я нашёл как правильно сделать
расшифровку, но часть кода, который приводится в конце у меня никого эффекта не дал, - что есть этот код, что его нет, я не понял как добиться:
1) Как добавить стандартные функции (расшифровку, оформление, фильтрацию) в контекстное меню расшифровки?
2) Как добавить нестандартные функции?
Код вроде есть, а что поменялось я так и не понял.
В итоге привожу код, который позволяет получить расшифровки на тонком клиенте (УФормы).
Да, нужно добавить два реквизита на форму, для хранения схемы и расшифровки.
Используется режим отказа от модальности, для этого в коде присутствует метод Оповещение.
перем Настройки;
перем СхемаКомпоновкиДанных;
&НаСервере
Процедура СформироватьОтчет() Экспорт
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
ДанныеРасшифровки111 = Новый ДанныеРасшифровкиКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки111);
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки111);
Результат.Очистить();
ДокументРезультат = Результат;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
АдресХранилищаСКД = ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных, УникальныйИдентификатор);
АдресРасшифровки = ПоместитьВоВременноеХранилище(ДанныеРасшифровки111, УникальныйИдентификатор);
КонецПроцедуры
&НаСервере
Процедура УстановитьНастройки()
ПараметрДанныхНачалоПериода = Этотобъект.Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы[0];
ПараметрДанныхНачалоПериода.Значение = НачалоМесяца(ТекущаяДата());
ПараметрДанныхНачалоПериода.Использование = Истина;
ПараметрДанныхКонецПериода = Этотобъект.Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы[1];
ПараметрДанныхКонецПериода.Значение = КонецМесяца(ТекущаяДата());
ПараметрДанныхКонецПериода.Использование = Истина;
Настройки = Этотобъект.Отчет.КомпоновщикНастроек.Настройки;
КонецПроцедуры
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
СтандартнаяОбработка = ложь;
ПолучитьОтчёт = РеквизитФормыВЗначение("Отчет");
СхемаКомпоновкиДанных = ПолучитьОтчёт.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
УстановитьНастройки();
СформироватьОтчет();
КонецПроцедуры
&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
СтандартнаяОбработка = ложь;
ИсточникДоступныхНастроек = Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресХранилищаСКД);
ОбработкаРасшифровки = Новый ОбработкаРасшифровкиКомпоновкиДанных(АдресРасшифровки, ИсточникДоступныхНастроек);
ДоступныеДействия = Новый Массив();
ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);
Оповещение = Новый ОписаниеОповещения("РезультатОбработкиРасшифровки_Продолжение", ЭтаФорма, Расшифровка);
ОбработкаРасшифровки.ПоказатьВыборДействия(Оповещение, Расшифровка, ДоступныеДействия, , Истина);
КонецПроцедуры
&НаКлиенте
Процедура РезультатОбработкиРасшифровки_Продолжение(ВыполненноеДействие, ПараметрВыполненногоДействия, ДополнительныеПараметры) Экспорт
Если ПараметрВыполненногоДействия <> Неопределено Тогда
Если ВыполненноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение Тогда
ПоказатьЗначение( , ПараметрВыполненногоДействия);
КонецЕсли;
КонецЕсли;
КонецПроцедуры
ПоказатьВсегда мучаюсь вот с такой задачей: в конфигурации имеются самописные отдельные отчеты на скд. Требуется в обработке каждый отчет вывести в отдельный ТабличныйДокумент (здесь проблем нет). Проблема в выводе Расшифровки ресурсов по регистратору. Хотелось бы получить наглядный пример подобной задачи.
Там вывод в таблицу. И частичная расшифровка тоже есть. Однако по нажатию, выдается индекс, а не объект.
Так вот, после получения таблицы, не нужно ее сразу выводить, а нужно обработать каждую ячейку. То есть в двойном вложенном цикле (столбцы, строки) обойти ячейки, глянуть заполнена ли расшифровка, и если да, то заменить индекс, на непосредственно ссылку на объект...
Чужой труд забирать не буду, дам ссылку на пример: Смотрите самый последний код...
&НаСервере
Функция ВыполнитьПечатьДокВТаблицу(Ссылка)
ТабДок = Новый ТабличныйДокумент;
ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
ДР = Новый ДанныеРасшифровкиКомпоновкиДанных;
//настройки
Настройки = ОтчетОбъект.КомпоновщикНастроек.ПолучитьНастройки();
//Макет компоновки
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(ОтчетОбъект.СхемаКомпоновкиДанных, Настройки,ДР,,Тип("ГенераторМакетаКомпоновкиДанных"));
//Компоновка данных
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДР);
//Вывод результата
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.ОтображатьПроцентВывода = Истина;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);
ТабДок.ТолькоПросмотр = Истина;
//восстанавливаем расшифровку
Для Стр = 1 По ТабДок.ШиринаТаблицы - 1 Цикл
Для Кол = 1 По ТабДок.ВысотаТаблицы - 1 Цикл
Область = ТабДок.Область(Стр, Кол);
Если ТипЗнч(Область.Расшифровка) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда
Область.Расшифровка = ДР.Элементы[Область.Расшифровка].ПолучитьПоля()[0].Значение;
КонецЕсли;
КонецЦикла;
КонецЦикла;
Возврат ТабДок;
КонецФункции
&НаКлиенте
Процедура ПечатьДокВТаблицу(Команда)
ТабДок = ВыполнитьПечатьДокВТаблицу(Документ);
ТабДок.Показать();
КонецПроцедуры ПоказатьПрикладываю выгрузку вашей обучалки чуть измененную с описанием того что хотелось бы.
Выкладываю работающий пример, и вот такой там код:
&НаКлиенте
Процедура Сформировать(Команда)
СформироватьОтчет();
КонецПроцедуры
&НаСервере
Процедура СформироватьОтчет();
Отчет = Отчеты.Материалы.Создать();
ТабДок.Очистить();
Настройки = Отчет.КомпоновщикНастроек.ПолучитьНастройки();
Начало = Настройки.ПараметрыДанных.Элементы.Найти("НачалоПериода");
Начало.Значение = Объект.НачалоПериода;
Начало.Использование = Истина;
Конец = Настройки.ПараметрыДанных.Элементы.Найти("КонецПериода");
Конец.Значение = Объект.КонецПериода;
Конец.Использование = Истина;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(Отчет.СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДанныеРасшифровки);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновки, Истина);
ТабДок.ТолькоПросмотр = Истина;
Для Стр = 1 По ТабДок.ВысотаТаблицы Цикл
Для Кол = 1 По ТабДок.ШиринаТаблицы Цикл
Область = ТабДок.Область(Стр, Кол);
Если ТипЗнч(Область.Расшифровка) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда
Область.Расшифровка = ДанныеРасшифровки.Элементы[Область.Расшифровка].ПолучитьПоля()[0].Значение;
КонецЕсли;
КонецЦикла;
КонецЦикла;
КонецПроцедуры
&НаКлиенте
Процедура ПриОткрытии(Отказ)
Объект.НачалоПериода = НачалоГода(ТекущаяДата());
Объект.КонецПериода = КонецГода(ТекущаяДата());
КонецПроцедуры
ПоказатьДля Стр = 1 По ТабДок.ШиринаТаблицы - 1 Цикл
Для Кол = 1 По ТабДок.ВысотаТаблицы - 1 Цикл
Область = ТабДок.Область(Стр, Кол);
Если ТипЗнч(Область.Расшифровка) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда
Область.Расшифровка = ДР.Элементы[Область.Расшифровка].ПолучитьПоля()[0].Значение;
КонецЕсли;
КонецЦикла;
КонецЦикла;Этот код не рабочий...Перепутал строки и колонки. Рабочий вариант в другом сообщении
Я новичок, всего не знаю, но думаю, что это все можно создать вручную. Но именно все! То есть, в отчете по щелчку в отчете на ресурсе выскакивает запрос по какому полю сделать расшифровку. Такое нужно будет сделать и в обработке, но руками, автоматически такое не появится. А после, нужно будет очистить поле ТабДок и сформировать в него новый отчет, и будет он совсем другим, чем изначальный... Этот отчет тоже нужно будет "рисовать"...Не знаю готовы ли Вы пойти на это...
Если бы знать, что конкретно требуется, код можно было бы и сократить, например, сделать отдельный отчет с параметрами регистратор и ресурс и выводить его по щелчку на ресурсе в ТабДок, но превратить форму обработки в форму отчета один в один, это слишком утомительно....
Что-то подобное делал автор в статье
Вот Вам пример
Значение ресурсов или Null, или значение в таблице. Зависит от версии платформы. На работе возвращает нормально, дома возвращает Null.
в этом случае, значение можно брать не из расшифровки, а непосредственно из ячейки табличного документа.
ТестЗначениеИзЯчейки.epf
По сути, при расшифровке по регистратору меняется только схема и добавляются отборы, как на скриншоте:
&НаКлиенте
Процедура Сформировать(Команда)
СформироватьОтчет();
КонецПроцедуры
&НаСервере
Процедура СформироватьОтчет();
Отчет = Отчеты.Материалы.Создать();
ТабДок.Очистить();
Настройки = Отчет.КомпоновщикНастроек.ПолучитьНастройки();
Начало = Настройки.ПараметрыДанных.Элементы.Найти("НачалоПериода");
Начало.Значение = Объект.НачалоПериода;
Начало.Использование = Истина;
Конец = Настройки.ПараметрыДанных.Элементы.Найти("КонецПериода");
Конец.Значение = Объект.КонецПериода;
Конец.Использование = Истина;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(Отчет.СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДанныеРасшифровки);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновки, Истина);
ТабДок.ТолькоПросмотр = Истина;
ВременноеХранилищеРасшифровки = ПоместитьВоВременноеХранилище(ДанныеРасшифровки,ЭтаФорма);
КонецПроцедуры
&НаКлиенте
Процедура ПриОткрытии(Отказ)
Объект.НачалоПериода = НачалоГода(ТекущаяДата());
Объект.КонецПериода = КонецГода(ТекущаяДата());
КонецПроцедуры
&НаКлиенте
Процедура ТабДокОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)
СтандартнаяОбработка = Ложь;
СтруктураДанных = ПолучитьРасшифровку(Расшифровка);
Если СтруктураДанных.Поле = "Склад" Тогда
ОткрытьЗначение(СтруктураДанных.Значение);
КонецЕсли;
Если СтруктураДанных.Поле = "Материал" Тогда
ОткрытьЗначение(СтруктураДанных.Значение);
КонецЕсли;
Если СтруктураДанных.Поле = "КоличествоНачальныйОстаток" Тогда
ВывестиРасшифровку();
КонецЕсли;
Если СтруктураДанных.Поле = "КоличествоПриход" Тогда
ВывестиРасшифровку();
КонецЕсли;
Если СтруктураДанных.Поле = "КоличествоРасход" Тогда
ВывестиРасшифровку();
КонецЕсли;
Если СтруктураДанных.Поле = "КоличествоКонечныйОстаток" Тогда
ВывестиРасшифровку();
КонецЕсли;
КонецПроцедуры
&НаСервере
Функция ПолучитьРасшифровку(Расшифровка)
//получим из хранилища данные
ДанныеРасшифровкиОбъект = ПолучитьИзВременногоХранилища(ВременноеХранилищеРасшифровки);
//вернулись к строке вида: ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0]
Данные = ДанныеРасшифровкиОбъект.Элементы[Расшифровка].ПолучитьПоля()[0];
//переменную Данные в управляемых формах на клиент передавать нельзя, а потому, перобразуем ее в структуру
СтруктураДанных = Новый Структура;
СтруктураДанных.Вставить("Поле", Данные.Поле);
СтруктураДанных.Вставить("Значение", Данные.Значение);
//возвращаем
Возврат СтруктураДанных;
КонецФункции
&НаСервере
Функция ВывестиРасшифровку()
Отчет = Отчеты.Материалы.Создать();
ТабДок.Очистить();
Настройки = Отчет.КомпоновщикНастроек.ПолучитьНастройки();
Начало = Настройки.ПараметрыДанных.Элементы.Найти("НачалоПериода");
Начало.Значение = Объект.НачалоПериода;
Начало.Использование = Истина;
Конец = Настройки.ПараметрыДанных.Элементы.Найти("КонецПериода");
Конец.Значение = Объект.КонецПериода;
Конец.Использование = Истина;
//рисуем новую структуру
Настройки.Структура.Очистить();
Гру = Настройки.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
Гру.Использование = Истина;
ПолеГру = Гру.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
ПолеГру.Поле = Новый ПолеКомпоновкиДанных("Регистратор");
АвтоПоле = Гру.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
АвтоПоле.Использование = Истина;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(Отчет.СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,ДанныеРасшифровки);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновки, Истина);
ТабДок.ТолькоПросмотр = Истина;
ВременноеХранилищеРасшифровки = ПоместитьВоВременноеХранилище(ДанныеРасшифровки,ЭтаФорма);
КонецФункции
ПоказатьТеперь осталось сделать так, тоб уже у вновь сформированного отчета заработала расшифровка. Постарайтесь решить это самостоятельно
&НаКлиенте
Процедура ОтчетТабличныйДокументОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
//ИнтеграцияПодсистемБСПКлиент.ПриОбработкеРасшифровки(ЭтотОбъект, Элемент, Расшифровка, СтандартнаяОбработка);
//ОтчетыКлиентПереопределяемый.ОбработкаРасшифровки(ЭтотОбъект, Элемент, Расшифровка, СтандартнаяОбработка);
//Если СтандартнаяОбработка Тогда
// ВариантыОтчетовСлужебныйКлиент.ОбработкаРасшифровки(ЭтотОбъект, Элемент, Расшифровка, СтандартнаяОбработка);
//КонецЕсли;
СтандартнаяОбработка = Ложь;
мСсылка = НайтиСсылку(Расшифровка);
КонецПроцедуры
&НаСервере
Функция НайтиСсылку(Расшифровка)
СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(НастройкиОтчета.АдресСхемы);
ДанныеРасшифровки = ПолучитьИзВременногоХранилища(ОтчетДанныеРасшифровки);
мСсылка = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0].Значение;
Возврат мСсылка;
КонецФункции ПоказатьА далее при создании параметров на форме визуально типа радиокнопок при выборе которых можно или открывать ссылку или работать со ссылкой, не открывая ссылочный объект из ячейки , полученный отчетом.
Когда создаю форму отчета, то при этом слетает макет оформления, по кнопке "настройки" ошибка и СтандартныйПериод выглядит по-другому.
Кто с таким сталкивался?
Может помочь скопировать типовую ФормаОтчета из общих форм
Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 1829344
Создание 20.03.23 11:00
Обновление 17.05.23 11:32
Просмотры 66229
Загрузки 0
Рейтинг
68
Комментарии 96
Код открыт Да
Рубрики СКД
Кому Разработчик
Тип файла Нет файла
Платформа 1С:Предприятие 8
Конфигурация Универсальные
Операционная система Не имеет значения
Страна Не имеет значения
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Бесплатно (free)