Для решения типичной задачи загрузки ТЧ из файла обычно используют внешнюю/дополнительную обработку с видом "ЗаполнениеОбъекта". Решил рассмотреть альтернативный вариант - подсистему БСП "ЗагрузкаДанныхИзФайла".
Пользовательская документация сей подсистемы довольно подробно описана, а вот программный интерфейс - скуден. Пришлось немного поковыряться. Привожу практический пример.
Имеется документ "НастройкиНачисленийБонусов" с ТЧ "Контрагенты" и реквизитами "Контрагент", "Договор", "ЛимитСкидки", "ПланПродаж":
| Имя реквизита | Тип значения |
| Контрагент | СправочникСсылка.Контрагенты |
| Договор | СправочникСсылка.ДоговорыКонтрагентов |
| ЛимитСкидки | Число(4,2) |
| ПланПродаж | Число(15,2) |
Требуется добавить возможность загрузки из файла в ТЧ.
1. Для начала создадим макет для этого документа. По умолчанию имя должно быть "ЗагрузкаИзФайла", но можно и переопределить. В макет по желанию можно добавлять примечания, чтобы пользователь мог увидеть описание колонки при загрузке. Для каждой ячейки колонки заголовка задаём имя:
2. Добавляем команду и обработчики на форму документа:
&НаКлиенте
Процедура ЗагрузитьИзФайла(Команда)
ПараметрыЗагрузки = ЗагрузкаДанныхИзФайлаКлиент.ПараметрыЗагрузкиДанных();
ПараметрыЗагрузки.ПолноеИмяТабличнойЧасти = "Документ.НастройкиНачисленийБонусов.Контрагенты";
ПараметрыЗагрузки.Заголовок = НСтр("ru = 'Загрузка из файла';
|en = 'Import from file'");
Оповещение = Новый ОписаниеОповещения("ЗагрузитьИзФайлаЗавершение", ЭтотОбъект);
ЗагрузкаДанныхИзФайлаКлиент.ПоказатьФормуЗагрузки(ПараметрыЗагрузки, Оповещение);
КонецПроцедуры
&НаКлиенте
Процедура ЗагрузитьИзФайлаЗавершение(АдресЗагруженныхДанных, ДополнительныеПараметры) Экспорт
Если АдресЗагруженныхДанных = Неопределено Тогда
Возврат;
КонецЕсли;
ЗагрузитьИзФайлаНаСервере(АдресЗагруженныхДанных);
КонецПроцедуры
&НаСервере
Процедура ЗагрузитьИзФайлаНаСервере(АдресЗагруженныхДанных)
ЗагруженныеДанные = ПолучитьИзВременногоХранилища(АдресЗагруженныхДанных);
Для каждого СтрокаТаблицы Из ЗагруженныеДанные Цикл
Если Не ЗначениеЗаполнено(СтрокаТаблицы.Контрагент) Тогда
Продолжить;
КонецЕсли;
ЗаполнитьЗначенияСвойств(Объект.Контрагенты.Добавить(), СтрокаТаблицы);
КонецЦикла;
КонецПроцедуры
3. Идём в модуль менеджера этого документа, переопределяем параметры загрузки, где я типизирую колонки (имена совпадают со значениями имен колонок) и указываю обязательные поля, ну, и остаётся главная процедура - сопоставление объектов, где нужно из считанного файла найти/сопоставить объекты системы, поместив результат во временное хранилище с адресом "АдресТаблицыСопоставления".
Пару слов о параметре СписокНеоднозначностей: я намеренно его не рассматриваю, т.к. алгоритм сопоставления заметно усложняется. Вообще он нужен для того, чтобы в пользовательском интерфейсе рассмотреть случаи (кнопка "Устранить неоднозначность"), когда для ссылочного типа наш поиск нашёл несколько значений. Для этого нужно заполнить этот параметр, а затем ещё и переопределить метод ЗаполнитьСписокНеоднозначностей(), где уже определить дополнительный поиск значений таких полей.
#Область ЗагрузкаИзФайлаВТЧ
// Переопределяет параметры загрузки данных из файла.
//
// Параметры:
// Параметры - Структура:
// * ИмяМакетаСШаблоном - Строка - наименование макета. Например, "ЗагрузкаИзФайла".
// * ИмяТабличнойЧасти - Строка - Полное имя табличной части. Например, "Документ._ДемоСчетНаОплатуПокупателю.ТабличнаяЧасть.Товары"
// * ОбязательныеКолонки - Массив из Строка - наименования обязательных для заполнения колонок.
// * ТипДанныхКолонки - Соответствие из КлючИЗначение:
// * Ключ - Строка - имя колонки;
// * Значение - ОписаниеТипов - тип колонки загружаемых данных.
// * ДополнительныеПараметры - Структура
//
Процедура УстановитьПараметрыЗагрузкиИзФайлаВТЧ(Параметры) Экспорт
ТипДанныхКолонки = Параметры.ТипДанныхКолонки;
ТипДанныхКолонки.Вставить("ИНН", Новый ОписаниеТипов("Строка",, Новый КвалификаторыСтроки(12)));
ТипДанныхКолонки.Вставить("КПП", Новый ОписаниеТипов("Строка",, Новый КвалификаторыСтроки(9)));
ТипДанныхКолонки.Вставить("НаименованиеДоговора", Новый ОписаниеТипов("Строка",, Новый КвалификаторыСтроки(150)));
ТипДанныхКолонки.Вставить("НомерДоговора", Новый ОписаниеТипов("Строка",, Новый КвалификаторыСтроки(128)));
ТипДанныхКолонки.Вставить("ЛимитСкидки", Новый ОписаниеТипов("Число",, Новый КвалификаторыЧисла(4, 2)));
ТипДанныхКолонки.Вставить("ПланПродаж", Новый ОписаниеТипов("Число",, Новый КвалификаторыЧисла(15, 2)));
МассивОбзятельныхКолонок = Новый Массив;
МассивОбзятельныхКолонок.Добавить("ИНН");
МассивОбзятельныхКолонок.Добавить("НаименованиеДоговора");
Параметры.ОбязательныеКолонки = МассивОбзятельныхКолонок;
КонецПроцедуры
// Производит сопоставление данных, загружаемых в табличную часть ПолноеИмяТабличнойЧасти,
// с данными в ИБ, и заполняет параметры АдресТаблицыСопоставления и СписокНеоднозначностей.
//
// Параметры:
// АдресЗагружаемыхДанных- Строка - адрес временного хранилища с таблицей значений, в которой
// находятся загруженные данные из файла.
// АдресТаблицыСопоставления - Строка - адрес временного хранилища с пустой таблицей значений,
// являющейся копией табличной части документа,
// которую необходимо заполнить из таблицы АдресЗагружаемыхДанных.
// СписокНеоднозначностей - ТаблицаЗначений - состоит из:
// * Идентификатор - Число - идентификатор
// * Колонка - Строка - имя колонки
// ПолноеИмяТабличнойЧасти - Строка - полное имя табличной части
// ДополнительныеПараметры - Структура - дополнительные параметры, переданные из формы-источнике.
//
Процедура СопоставитьЗагружаемыеДанные(АдресЗагружаемыхДанных, АдресТаблицыСопоставления, СписокНеоднозначностей, ПолноеИмяТабличнойЧасти, ДополнительныеПараметры) Экспорт
Контрагенты = ПолучитьИзВременногоХранилища(АдресТаблицыСопоставления); // ТаблицаЗначений
ЗагружаемыеДанные = ПолучитьИзВременногоХранилища(АдресЗагружаемыхДанных); // ТаблицаЗначений
МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
Запрос.Текст =
"ВЫБРАТЬ
| ДанныеДляСопоставления.Идентификатор КАК ИдентификаторСтроки,
| ДанныеДляСопоставления.ИНН КАК ИНН,
| ДанныеДляСопоставления.КПП КАК КПП,
| ДанныеДляСопоставления.НаименованиеДоговора КАК НаименованиеДоговора,
| ДанныеДляСопоставления.НомерДоговора КАК НомерДоговора,
| ДанныеДляСопоставления.ЛимитСкидки КАК ЛимитСкидки,
| ДанныеДляСопоставления.ПланПродаж КАК ПланПродаж
|ПОМЕСТИТЬ ДанныеДляСопоставления
|ИЗ
| &ДанныеДляСопоставления КАК ДанныеДляСопоставления
|
|ИНДЕКСИРОВАТЬ ПО
| ИдентификаторСтроки,
| ИНН,
| КПП,
| НаименованиеДоговора
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| МАКСИМУМ(Контрагенты.Ссылка) КАК Ссылка,
| ДанныеДляСопоставления.ИдентификаторСтроки КАК ИдентификаторСтроки
|ПОМЕСТИТЬ СопоставленныеКонтрагенты
|ИЗ
| ДанныеДляСопоставления КАК ДанныеДляСопоставления
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Контрагенты КАК Контрагенты
| ПО (Контрагенты.ИНН = ДанныеДляСопоставления.ИНН)
| И (ВЫБОР
| КОГДА ДанныеДляСопоставления.КПП <> """"
| ТОГДА Контрагенты.КПП = ДанныеДляСопоставления.КПП
| ИНАЧЕ ИСТИНА
| КОНЕЦ)
|
|СГРУППИРОВАТЬ ПО
| ДанныеДляСопоставления.ИдентификаторСтроки
|
|ИНДЕКСИРОВАТЬ ПО
| ИдентификаторСтроки
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| МАКСИМУМ(Договоры.Ссылка) КАК Ссылка,
| ДанныеДляСопоставления.ИдентификаторСтроки КАК ИдентификаторСтроки
|ПОМЕСТИТЬ СопоставленныеДоговоры
|ИЗ
| ДанныеДляСопоставления КАК ДанныеДляСопоставления
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ СопоставленныеКонтрагенты КАК СопоставленныеКонтрагенты
| ПО ДанныеДляСопоставления.ИдентификаторСтроки = СопоставленныеКонтрагенты.ИдентификаторСтроки
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ДоговорыКонтрагентов КАК Договоры
| ПО (Договоры.Контрагент = СопоставленныеКонтрагенты.Ссылка)
| И ДанныеДляСопоставления.НаименованиеДоговора = Договоры.Наименование
| И (ВЫБОР
| КОГДА ДанныеДляСопоставления.НомерДоговора <> """"
| ТОГДА ДанныеДляСопоставления.НомерДоговора = Договоры.Номер
| ИНАЧЕ ИСТИНА
| КОНЕЦ)
|
|СГРУППИРОВАТЬ ПО
| ДанныеДляСопоставления.ИдентификаторСтроки
|
|ИНДЕКСИРОВАТЬ ПО
| ИдентификаторСтроки
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| СопоставленныеКонтрагенты.Ссылка КАК Контрагент,
| СопоставленныеДоговоры.Ссылка КАК Договор,
| ДанныеДляСопоставления.ЛимитСкидки КАК ЛимитСкидки,
| ДанныеДляСопоставления.ПланПродаж КАК ПланПродаж
|ИЗ
| ДанныеДляСопоставления КАК ДанныеДляСопоставления
| ЛЕВОЕ СОЕДИНЕНИЕ СопоставленныеКонтрагенты КАК СопоставленныеКонтрагенты
| ПО ДанныеДляСопоставления.ИдентификаторСтроки = СопоставленныеКонтрагенты.ИдентификаторСтроки
| ЛЕВОЕ СОЕДИНЕНИЕ СопоставленныеДоговоры КАК СопоставленныеДоговоры
| ПО ДанныеДляСопоставления.ИдентификаторСтроки = СопоставленныеДоговоры.ИдентификаторСтроки";
Запрос.УстановитьПараметр("ДанныеДляСопоставления", ЗагружаемыеДанные);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
ЗаполнитьЗначенияСвойств(Контрагенты.Добавить(), Выборка);
КонецЦикла;
ПоместитьВоВременноеХранилище(Контрагенты, АдресТаблицыСопоставления);
КонецПроцедуры
#КонецОбласти
Вуаля:
Вступайте в нашу телеграмм-группу Инфостарт
