Содержание
- Описание разработки правил, приемы работы
- Разработка правил для простого справочника
- ПКПД. Передача Родителя иерархического справочника. Как заполнять поля, которые есть в формате, но их нет в объекте конфигурации. Алгоритмы. Обработчик события «При отправке»
- Передача табличной части документа. Передача реквизитов, которых нет в приемнике. Отложенное заполнение реквизитов. Отложенное проведение документов. Параметры конвертации.
- Отладка
В первой части материала разобрали минимальные требования к КД 3.0, сравнили КД 2.1 и КД3.0, XDTO, общую схему работы с КД 3.0, порядок создания конвертации, а также настройку обмена. Здесь, во второй части, разберем все разделы согласно содержанию.
Описание разработки правил, приемы работы
Приступим к разработке правил. Обмен будем настраивать для двух баз «УТ_Источник» и «БП_Премник». В КД 3.0 есть понятия «Отправка» и «Получение». Это направления обмена. Правила «Для отправки» разрабатываются, когда нам необходимо сконвертировать объекты 1С в «Универсальный формат», а правила «Для получения», когда необходимо сконвертировать Объекты XDTO «Универсального формата» в объекты 1С.
В любом ПОД, ПКО, ПКПД есть переключатель «Для отправки» / «Для получения» / «Для отправки и получения». Значение «Для отправки и получения» используется в основном для объектов конфигурации, в которых состав метаданных идентичен, либо необходимо обмениваться только теми реквизитами, которые совпадают в источнике и приемнике. И где мы можем прописать идентичные правила на отправку и получение.
Основное окно разработки находится по пути «Конвертации / Настройка правил конвертации», там необходимо выбрать созданную конвертацию.
Для ПОД и ПКО мы можем создать группы правил, которые необходимы для удобства разработки. Влияния на итоговый код не оказывают.
Ниже в тексте будут использованы наименования справочников, документов и т.д, такие как «ХарактеристикиНоменклатуры», «ЗаказКлиента» и др. — это сильно упрощенные объекты. Они не имеют функционала типовых конфигураций. Например, справочник «ХарактеристикиНоменклатуры» не имеет владельца и т.д.
Разработка правил для простого справочника
Для примера рассмотрим разработку правил для справочника «ХарактеристикиНоменклатуры». Сначала создадим правила для отправки в конвертации «УТ_Источник». Начинаем работу с анализа формата (пакета XDTO) в конфигураторе.
Реквизит «Наименование» и реквизит «Ключевых свойств» «НаименованиеПолное» обязательны для заполнения. Их и будем передавать. Ключевые свойства в формате — это аналог ссылки в 1С, затем создадим новое ПКО.
Выберем соответствующие «Объект конфигурации» и «Объект формата». «Область применения» уже будет установлена «Для отправки». Обязательно зададим «Идентификатор правила», причем в формате именования переменных в 1С. Следите за тем, чтобы не было точки. Если идентификатор не будет удовлетворять формату именования переменных, то в дальнейшем получим ошибки. Идентификатор принято задавать в формате «ТипОбъектаМетаданных_НаименованиеОбъектаМетаданных_Направление», например, «Справочник_ХарактеристикиНоменклатуры_Отправка».
Следующим шагом перейдем на вкладку «Правила конвертации свойств» и создадим ПКС на обязательные для заполнения поля: «Наименование» и «НаименованиеПолное». При создании ПКС необходимо сопоставить реквизиты формата и объекта конфигурации. Можно воспользоваться кнопкой «Настройка ПКС / Автосопоставление / Создать правила конвертации свойств». Но при «Автосопоставлении» важно внимательно следить за тем, какие реквизиты вы сопоставляете. Этот механизм скорее для первоначального заполнения ПКС.
Теперь необходимо создать «Правило обработки данных» ПОД для нашего справочника. ПОД, по сути – это главный объект правил, без него они просто не будут работать. ПОД`ы определяют, какие объекты 1С попадут в изначальную выборку.
Перейдем на вкладку «Правила обработки данных» и создадим ПОД для справочника «ХарактеристикиНоменклатуры». «Область применения» по умолчанию будет «Для отправки». Необходимо выбрать объект конфигурации и затем выбрать наше ПКО для характеристик, которое мы до этого создали. Также, как и в случае с ПКО необходимо обязательно задать идентификатор в формате именования переменных 1С.
Созданные ПОД`ы должны строго соответствовать составу нашего плана обмена, который выбран для обмена через текущую конвертацию. В нашем случае – это «СинхронизацияДанныхЧерезУниверсальныйФормат». Авторегистрация установлена в значение «Запретить».
Нажать «Сохранить модуль менеджера обмена». В буфер обмена будет помещен код согласно нашим правилам, который мы должны вставить в общий модуль в конфигурации «УТ_Источник», определенный в качестве менеджера обмена. В нашем случае – это «МенеджерОбменаЧерезУниверсальныйФормат».
Далее открываем конвертацию «БП_Премник» и создаем там ПКО и ПОД для справочника «ХарактеристикиНоменклатуры». Важно сразу установить свойство «Для получения», т.к. если начать настраивать правило и только потом установить «Область применения», то настроенные значения будут сброшены. Если мы настроим правило, а затем его где-то используем, то при его дальнейшем изменении будет необходимо убрать все места его использования, и только потом изменить само правило, в противном случае система не даст это сделать.
Здесь прописываем правила для сопоставления полей формата и реквизитов конфигурации, т.е. в обратную сторону по сравнению с конфигурацией «УТ_Источник». При разработке ПОД`ов уже не нужно их соответствие составу Плана обмена, в составе плана обмена вообще не должно быть объектов, соответствующих ПОД`ам «Для получения». В Плане обмена прописываем объекты только «Для отправки», что логично, т.к. План обмена нужен для определения состава узлов, по которым регистрируются изменения объектов именно для отправки.
ПКПД. Передача Родителя иерархического справочника. Как заполнять поля, которые есть в формате, но их нет в объекте конфигурации. Алгоритмы. Обработчик события «При отправке».
Рассмотрим передачу иерархического справочника «НоменклатураУТ». Начнем с Пакета XDTO.
Обязательными для заполнения являются реквизит «Ключевых свойств» «Наименование» и реквизиты «ТипНоменклатуры», «ЕдиницаИзмерения», «ТипУчетаНоменклатуры».
Для конвертации «УТ_Источник» точно также, как и раньше создаем ПКО «Для отправки», но уже для справочника «НоменклатураУТ».
Далее создаем ПКС.
Здесь есть 3 ПКС, о которых расскажу отдельно. В остальном все +/- как и при передаче справочника характеристик.
- «ТипУчетаНоменклатуры» имеет тип «ПеречислениеСсылка.ТипУчетаНоменклатуры». Для передачи ссылочных типов необходимо предварительно создать свое ПКО или ПКПД. Только после этого использовать их в других ПКО, т.к. необходимо их указать при настройке ПКС.
В данном случае создаем ПКПД. В основном окне настройки правил обмена переходим на вкладку «Правила конвертации предопределенных данных» и создаем новое ПКПД.
Для «Идентификатора правила» и «Области применения» действуют те же правила, что и для ПОД и ПКО. Теперь мы можем указать это ПКПД «Перечисление_ТипыУчетаНоменклатуры_Отправка» в ПКС для справочника «НоменклатураУТ».
2. «Родитель» имеет тип «СправочникСсылка.НоменклатураУТ». Создадим отдельное ПКО для передачи группы справочника «НоменклатураУТ».
Для данного ПКО необходимо установить «Объект формата» «Справочник.НоменклатураГруппа» — это специальный объект формата для передачи групп номенклатуры. Далее при настройке ПКС необходимо в качестве ПКС для свойства «Родитель» установить текущее ПКО, которое мы сейчас настраиваем, т.е. как бы само себя. Затем необходимо настроить ПОД для передачи справочника «НоменклатураУТ».
Здесь необходимо выбрать «Количество правил конвертации» «Несколько» и добавить еще одно ПКО для обработки группы номенклатуры. При такой схеме будут срабатывать оба ПКО, что недопустимо. Чтобы прописать алгоритм выбора ПКО, воспользуемся обработчиком «При обработке».
ИспользованиеПКО.Справочник_НоменклатураУТ_Отправка = Не ДанныеИБ.ЭтоГруппа;
ИспользованиеПКО.Справочник_НоменклатураУТ_Группа_Отправка = ДанныеИБ.ЭтоГруппа;
Код проще всего писать прямо в отладке. Необходимо написать что-то типа «а=0», а затем найти этот код в модуле менеджера и поставить точку останова. Вместо «a=0» можете писать что угодно, главное, чтобы конфигуратор не «ругался». Это нужно просто, чтобы быстрее найти.
Если нажать на «?», то можно увидеть параметры данного обработчика:
— ДанныеИБ – это непосредственно сам объект 1с СправочникОбъект, ДокументОбъект и т.д.
— ИспользованиеПКО – это структура, где ключи – это имена ПКО в данном ПОД, а значения имеют тип булево. Как раз предназначена для включения или отключения ПКО. Истина – разрешает использование ПКО, Ложь – запрещает.
— Компоненты обмена – это вся конвертация разом. Здесь доступны все ПОД, ПКО, ПКС, ПКПД и много других параметров для текущей конвертации.
В коде выше мы включаем или отключаем использование ПКО в зависимости от того являются ли группой ДанныеИБ.
- «ТипНоменклатуры». Данное поле есть в объекте формата, причем оно обязательно для заполнения. Но в объекте конфигурации его нет.
Чтобы его заполнить необходимо в ПКС, для этого поля установить галку «Используется алгоритм конвертации», а затем прописать код по заполнению в обработчике «При отправке».
ДанныеXDTO.Вставить("ТипНоменклатуры", "Товар");
ЕдиницаИзмерения = ПолучитьНастройку("ЕдиницаИзмеренияПоУмолчанию", Справочники.ЕдиницыИзмерения.НайтиПоНаименованию("шт"));
РеквезитыЕдиницыИзмерения = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(ЕдиницаИзмерения, "Код, Наименование");
ДанныеXDTO.Вставить("ЕдиницаИзмерения", РеквезитыЕдиницыИзмерения);
Рассмотрим данный код:
ДанныеXDTO – Структура. Предназначен для доступа к данным Объекта XDTO (информация из синтакс-помощника для конвертации «?»). Поле Объекта формата «Справочник.Номенклатура» имеет тип «ТипыНоменклатуры». Это можно увидеть в XDTO пакете. В свою очередь тип «ТипыНоменклатуры» имеет значения строкового типа. Значит, мы можем указать одно из них строкой.
Что мы и делаем в первой строке кода. В остальных строках кода мы получаем данные единицы измерения, т.к. это поле также является обязательным для объекта XDTO «Справочник.Номенклатура».
Здесь мы просто заполняем «КлючевыеСвойстваЕдиницаИзмерения» строковыми данными. При данном способе программного заполнения мы не используем Ссылку (УУИД), а только заполняем обязательные ключевые свойства, чтобы не возникало ошибок. Это видно при открытии получившегося в результате обмена XML файла. Здесь нет поля «Ссылка» для «ЕдиницыИзмерения».
Такой подход используется тогда, когда в системе нет данного справочника, т.е. нам не от куда взять Единицу измерения. Конечно, справочник «ЕдиницыИзмерения» есть у нас в системе, просто я описал сам подход для примера.
Существует иной подход, когда мы не заполняем поля отдельно, а в качестве «Ключевых свойств» передаем только ссылку, а дальше система сама заполнит данные «Ключевых свойств». Но для такого подхода нам необходимо предварительно настроить соответствующие ПКС и ПКО (в данном случае для единиц измерения). Такой подход используется, когда в системе есть такой объект и мы можем настроить обмен этим объектом. Например, у нас в справочнике «НоменклатураУТ» нет реквизита «Единица измерения», но в системе такой справочник есть. Подход рассмотрю ниже при отправке документа.
Рассмотрим подробнее функцию «ПолучитьНастройку»:
Начнем с расположения, которая находится в «Алгоритмах». Если перейти в основном окне настройки правил во вкладку «Алгоритмы», то там можно создавать свои алгоритмы. Это просто Процедуры и Функции, которые мы бы хотели вынести отдельно. Алгоритмы доступны из любого места текущей конвертации (в данном случае «УТ_Источник.»), т.е. это реализация принципа D.R.Y. (don't repeat yourself).
Здесь нужно заполнить имя алгоритма и его параметры (если они есть). Если необходимо, чтобы это была Функция, то необходимо установить галку «Функция». Рассмотрим код:
Если Не ЗначениеЗаполнено(ИмяНастройки) Тогда
Возврат ЗначениеПоУмолчанию;
КонецЕсли;
ИменаВсехНастроек = Метаданные.Справочники.Настройки.ПолучитьИменаПредопределенных();
ВозвращаемоеЗначение = Неопределено;
Если ИменаВсехНастроек.Найти(ИмяНастройки) <> Неопределено Тогда
ВозвращаемоеЗначение = Справочники.Настройки[ИмяНастройки].ЗначениеНастройки;
КонецЕсли;
Если ЗначениеЗаполнено(ВозвращаемоеЗначение) Тогда
Возврат ВозвращаемоеЗначение;
КонецЕсли;
Возврат ЗначениеПоУмолчанию
Есть негласный паттерн хранения различных настроек в отдельном справочнике. В данном случае в справочнике «Настройки» созданы предопределенные элементы: «ЕдиницаИзмеренияПоУмолчанию», «КонтрагентПоУмолчанию», «ОрганизацияПоУмолчанию» и «ТипНоменклатурыПоУмолчанию». И есть реквизит «ЗначениеНастройки» с типом «ЛюбаяСсылка». В 1С:Предприятие мы можем установить этим настройкам значения.
Данная функция «ПолучитьНастройки» как раз получает настройки из этого справочника по «ИмениНастройки». Также есть параметр «ЗначениеПоУмолчанию», который возвращается, если настройка не найдена по имени настройки.
Если мы вернемся к коду обработчика ПКО для «НоменклатурыУТ», то там мы получаем значение «ЕдиницаИзмеренияПоУмолчанию» из настроек, затем получаем значения реквизитов "Код, Наименование" из ссылки на Единицу измерения, а затем заполняем этими данными «КлючевыеСвойстваЕдиницаИзмерения».
Для получения данных «НоменклатурыУТ» необходимо прописать правила ПКО для элемента справочника и также отдельное ПКО для группы, плюс ПКПД для «ТипаУчетаНоменклатуры». В целом все тоже самое, как и при отправке, но с небольшими различиями.
Первое отличие – это то, что при настройке ПКО для группы номенклатуры необходимо установить галку «Правило для группы справочника».
Второе отличие – это то, что при настройке ПОД необходимо создавать два ПОД отдельно на элемент и на группу справочника.
Передача табличной части документа. Передача реквизитов, которых нет в приемнике. Отложенное заполнение реквизитов. Отложенное проведение документов. Параметры конвертации.
Рассмотрим передачу документа «ЗаказКлиента». Начнем с Пакета XDTO:
Обязательными для заполнения являются реквизиты «Ключевых свойств» «Номер», «Дата», «Организация» и реквизит «Контрагент». А также реквизиты табличной части «Товары»: «ДанныеНоменклатуры» «Количество».
Создадим ПКО для ЗаказаКлиента.
Все +/- также, как и для предыдущих объектов. Создаем ПКО «Для Отправки». Создаем ПКС`ы. Где требуется передача ссылочных типов, создаем отдельные ПКО или ПКПД. Если требуется заполнение поля в коде, то ставим галку «Используется алгоритм конвертации».
Заполнение реквизитов ТЧ Товары происходит также, как и заполнение реквизитов шапки. В более ранних версиях конвертации 3.0 такая возможность отсутствовала, и было необходимо прописывать заполнение ТЧ в коде обработчика «При отправке».
ТЧТовары = ДанныеИБ.Товары.Выгрузить();
ДанныеXDTO.Вставить("Товары", ТЧТовары);
Рассмотрим подробнее передачу реквизитов «Организация» и «Контрагент». Данных реквизитов нет в нашем документе (да, да, не удивляйтесь, вот такой у нас ЗаказКлиента,)). И мы пропишем алгоритм их заполнения в обработчике «При отправке».
Рассмотрим код обработчика:
ОрганизацияПоУмолчанию = ПолучитьНастройку("ОрганизацияПоУмолчанию", Справочники.Организации.НайтиПоНаименованию("ООО Рога2"));
КонтрагентПоУмолчанию = ПолучитьНастройку("КонтрагентПоУмолчанию", Справочники.Контрагенты.НайтиПоНаименованию("ООО_Пятерочка"));
РеквизитыКонтрагентПоУмолчанию = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(КонтрагентПоУмолчанию,
"Наименование, ПолноеНаименование, ИНН, КПП");
КлючевыеСвойстваКонтрагент = Новый Структура("Наименование, НаименованиеПолное, ИНН, КПП, ЮридическоеФизическоеЛицо");
ЗаполнитьЗначенияСвойств(КлючевыеСвойстваКонтрагент, РеквизитыКонтрагентПоУмолчанию);
КлючевыеСвойстваКонтрагент.НаименованиеПолное = РеквизитыКонтрагентПоУмолчанию.ПолноеНаименование;
КлючевыеСвойстваКонтрагент.ЮридическоеФизическоеЛицо = "ЮридическоеЛицо";
ДанныеXDTO.КлючевыеСвойства.Вставить("Организация", ОрганизацияПоУмолчанию);
ДанныеXDTO.Вставить("Контрагент", КлючевыеСвойстваКонтрагент);
Получим Организацию и Контрагента по умолчанию из справочника «Настройки». Получим «Ключевые свойства» контрагента из ссылки, а организацию заполним непосредственно ссылкой. Мы можем так заполнить организацию благодаря тому, что мы прописали в ПКС для ЗаказаКлиента ПКО для Организации. Для Контрагента такой возможности нет, т.к. ПКО для контрагента мы не создавали. Это как раз те 2 подхода, которые были описаны в прошлом разделе. И в xml документе после выгрузки можно увидеть, что для Организации передана ссылка (УУИД), а также ее ключевые свойства, а для Контрагента – только те значения, которые мы заполнили в коде, а ссылка (УУИД) – отсутствует.
Далее необходимо создать ПОД для ЗаказаКлиента, но там все будет, как описано выше.
Теперь рассмотрим ПКО и ПКС для ЗаказаКлиента при получении:
ПКПД для «ТипаЗапасов» выглядит так:
В конфигурации «БП_Приемник» нет «ТиповЗапасов» «СырьеИМатериалы» и «ВозвратнаяТара», поэтому им соответствуют несколько другие значения.
Далее рассмотрим реквизит конфигурации «Проведен». Мы создаем ПКС для него и устанавливаем галку «Используется алгоритм конвертации» и далее в обработчике «ПриКонвертацииДанныхXDTO» разместим такой код:
ПолученныеДанные.Проведен = Истина;
«ПолученныеДанные» - это объект 1С (СправочникОбъект, ДокументОбъект) до записи в ИБ. Так наш документ в итоге будет проведен, причем это не просто взведенный флаг, а именно стандартное проведение по регистрам.
Теперь рассмотрим реквизит «Контрагент». Сделаем его условное заполнение в зависимости от глобального параметра текущей конвертации «БП_Приемник» «ЗаполнятьКонтрагентаПриЗагрузке». Для этого в конфигурации «БП_Приемник» в наш План обмена «СинхронизацияДанныхЧерезУниверсальныйФормат» добавим новый реквизит «ЗаполнятьКонтрагентаПриЗагрузке».
Далее откроем текущую конвертацию «Конвертации / Конвертации / БП_Приемник». В обработчике «Перед конвертацией» вставим следующий код:
Если КомпонентыОбмена.НаправлениеОбмена = "Получение" Тогда
КомпонентыОбмена.ПараметрыКонвертации.ЗаполнятьКонтрагентаПриЗагрузке = КомпонентыОбмена.УзелКорреспондента.ЗаполнятьКонтрагентаПриЗагрузке;
КонецЕсли;
И добавим на вкладке «Параметры конвертации» новый параметр «ЗаполнятьКонтрагентаПриЗагрузке».
Затем вернемся в ПКО для ЗаказаКлиента и перейдем на вкладку обработчика «Перед записью полученных» и вставим туда следующий код:
Если КомпонентыОбмена.ПараметрыКонвертации.ЗаполнятьКонтрагентаПриЗагрузке Тогда
КонтрагентПоУмолчанию = ПолучитьНастройку("КонтрагентПоУмолчанию", Справочники.Контрагенты.НайтиПоНаименованию("ООО_Пятерочка"));
ПолученныеДанные.Контрагент = КонтрагентПоУмолчанию;
КонецЕсли;
В зависимости от значения параметра «ЗаполнятьКонтрагентаПриЗагрузке» в плане обмена заполняем или нет Контрагента в ЗаказеКлиента. Установить значение этого параметра можно в Плане обмена в 1С:Предприятие в настройках соответствующего узла.
Рассмотрим механизм отложенного заполнения данных в конвертации. Он используется для дозаполнения каких-либо данных в момент, когда конвертация уже окончена. В «Алгоритмах» создадим процедуру «ОтложеннаяОбработка_ЗаказКлиента» с одним параметром «Объект».
Код процедуры:
Для Каждого СтрокаТаблицы Из Объект.Товары Цикл
Если Не ЗначениеЗаполнено(СтрокаТаблицы.ПВЗ) Тогда
Если СтрокаТаблицы.ТипЗапасов = Перечисления.ТипыЗапасов.ПрочиеМатериалы
Или СтрокаТаблицы.ТипЗапасов = Перечисления.ТипыЗапасов.ПокупныеИзделия Тогда
СтрокаТаблицы.ПВЗ = Справочники.ПВЗ_ПунктыВыдачиЗаказов.ПГТ_Листопад;
ИначеЕсли СтрокаТаблицы.ТипЗапасов = Перечисления.ТипыЗапасов.Топливо
Или СтрокаТаблицы.ТипЗапасов = Перечисления.ТипыЗапасов.ИнвентарьИХозяйственныеПринадлежности Тогда
СтрокаТаблицы.ПВЗ = Справочники.ПВЗ_ПунктыВыдачиЗаказов.Елабуга_Восточная;
КонецЕсли
КонецЕсли
КонецЦикла
Данный код для каждой строки ТЧ Товары устанавливает ПВЗ в зависимости от значения «ТипаЗапасов». Вернемся в ПКО для ЗаказаКлиента и на вкладке обработчика «После загрузки всех данных» выберем наш Алгоритм в качестве Алгоритма для отложенного заполнения.
Отладка
Для отладки правил копируем их в общий модуль «МенеджерОбменаЧерезУниверсальныйФормат» и открываем сеанс 1С:Предприятие. Далее переходим в подсистему, связанную с обменом и находим в ней обмен, связанный с нужным планом обмена (по умолчанию «СинхронизацияДанныхЧерезУниверсальныйФормат»). Окно будет выглядеть так:
Затем в конфигураторе нужно включить отладку «Фоновых заданий», т.к. обмен проходит в «Длительных операциях». Это делается через «Отладка / Подключение… / Автоматическое подключение».
Затем необходимо поставить точку останова. Нужно найти код, добавленный в конвертации, и поставить точку. Код можно писать прямо в отладке, а потом вставлять в КД, что сильно удобнее.
Возвращаемся обратно в сеанс 1С:Предприятие и запускаем обмен по кнопке выполнить «Синхронизация данных / Синхронизировать». Далее выполнение остановится в том месте, где была установлена точка останова.
Если необходимо зарегистрировать или разрегистрировать какой-то объект к выгрузке, то переходим в «Параметры синхронизации данных / Состав определяемых данных» и откроется обработка «Регистрация изменений для обмена данными (Обработки)» (ее можно открыть и через «Все функции»).
Когда происходит загрузка (получение данных) в базе приемнике, мы не можем загрузить сообщение обмена второй раз (так работает механизм стандартного обмена). Но в данной обработке можно на 1 уменьшить «Номер принятого сообщения», нажав на «№ Отправленного, Принятого». В данном случае поменять значение с 32 на 31, тогда сообщение будет принято повторно.
После выгрузки полезно открыть файл обмена XML и проанализировать его. Если не удается отловить ошибку, но обмен идет некорректно, то включите в отладке «Остановку по ошибке». Это должно помочь, т.к. обмен идет в Длительных операциях. В моей практике было такое, что ошибка просто не выдавалась, особенно при Получении.
Автор: Александр Д., разработчик 1С.
