Для использования данной формы посмотрел, как это сделано в типовой УТ 11.
1. Добавляем реквизит Период тип Дата.
2. Добавляем на форму реквизит ПредставлениеПериода тип строка неограниченная, длина 0.
3. Добавляем кнопу выбора в свойствах реквизита формы ПредставлениеПериода.
4. Добавляем Обработчики реквизита формы ПредставлениеПериода - НачалоВыбора,Регулирование.
5. Добавляем прилагаемый код в модуль формы справочника или документа или регистра итд.
6. Используем форму и радуемся).
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ПредставлениеПериода = ПолучитьПредставлениеПериода(Объект.Период);
КонецПроцедуры
&НаКлиенте
Процедура ПредставлениеПериодаНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
Оповещение = Новый ОписаниеОповещения("ПредставлениеПериодаНачалоВыбораЗавершение", ЭтотОбъект);
ПараметрыФормыВыбораПериода = Новый Структура("Значение", Объект.Период);
ОткрытьФорму("ОбщаяФорма.ВыборПериодаИС",
ПараметрыФормыВыбораПериода,
ЭтотОбъект,
ЭтотОбъект.УникальныйИдентификатор,
,
,
Оповещение,
РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
КонецПроцедуры
&НаКлиенте
Процедура ПредставлениеПериодаНачалоВыбораЗавершение(ВыбранныйПериод, ДополнительныеПараметры) Экспорт
Если ВыбранныйПериод <> Неопределено Тогда
ВыбранныйПериод = НачалоМесяца(ВыбранныйПериод);
Если ВыбранныйПериод = Объект.Период Тогда
Возврат;
КонецЕсли;
//эту строку если нужно оставить или закоментировать
Модифицированность = Истина;
Объект.Период = ВыбранныйПериод;
ПредставлениеПериода = ПолучитьПредставлениеПериода(ВыбранныйПериод);
КонецЕсли;
КонецПроцедуры
&НаКлиенте
Процедура ПредставлениеПериодаРегулирование(Элемент, Направление, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
//эту строку если нужно оставить или закоментировать
Модифицированность = Истина;
Если Направление = 1 Тогда
Объект.Период = КонецМесяца(Объект.Период) + 1;
ИначеЕсли Направление = -1 Тогда
Объект.Период = НачалоМесяца(Объект.Период - 1);
КонецЕсли;
ПредставлениеПериода = ПолучитьПредставлениеПериода(Объект.Период);
КонецПроцедуры
&НаКлиентеНаСервереБезКонтекста
Функция ПолучитьПредставлениеПериода(Период)
Возврат Формат(Период, "ДФ='ММММ гггг'");
КонецФункции
Вступайте в нашу телеграмм-группу Инфостарт
