[Замер] Соответствие в структуру

Сколько себя помню, всегда, когда мне нужно было конвертировать соответствие в структуру, я использовал цикл, в котором наполнял структуру.

Результат = Новый Структура;
Для Каждого текЭлемент Из ЯСоответствие Цикл 
        Результат.Вставить(текЭлемент.Ключ, текЭлемент.Значение);             
КонецЦикла;

Уверен, что это самый популярный вариант. Конечно, нужно быть уверенным, что в ключах нет запрещенных символов, которые не сможет переварить структура. Вообще примеров конвертации может быть очень много. Но...

Когда-то давно мне пришел в голову другой способ, который использует JSON преобразование, и только на этой неделе пришла мысль в голову, все замерить.

В замере буду использовать еще два странных варианта и вариант через ЗначениеВСтрокуВнутр (этот способ мне подсказали в Телеграм канале e1c_community). Также буду использовать вариант через JSON и XML (этот способ отсутствовал в первоначальной версии статьи, он громоздкий и содержит много замен строк).

Озвученные варианты:

Запрос = Новый Запрос;
Для Каждого текЭлемент Из ЯСоответствие Цикл 
        Запрос.УстановитьПараметр(текЭлемент.Ключ, текЭлемент.Значение); 
КонецЦикла;
Результат = Запрос.Параметры;

НастройкиКомпоновкиДанных = Новый НастройкиКомпоновкиДанных;
Для Каждого текЭлемент Из ЯСоответствие Цикл 
        НастройкиКомпоновкиДанных.ДополнительныеСвойства.Вставить(текЭлемент.Ключ, текЭлемент.Значение);             
КонецЦикла;
Результат = НастройкиКомпоновкиДанных.ДополнительныеСвойства;

НастройкиКомпоновкиДанных = Новый НастройкиКомпоновкиДанных;
Результат = НастройкиКомпоновкиДанных.ДополнительныеСвойства;
Для Каждого текЭлемент Из ЯСоответствие Цикл 
	Результат.Вставить(текЭлемент.Ключ, текЭлемент.Значение); 	
КонецЦикла;

Строка = ЗначениеВСтрокуВнутр(ЯСоответствие);
СтрокаМод = СтрЗаменить(Строка, "3d48feae-a9c6-4c5a-a099-9eb6477630c6", "4238019d-7e49-4fc9-91db-b6b951d5cf8e");
Результат = ЗначениеИзСтрокиВнутр(СтрокаМод);

ЗаписьJSON     = Новый ЗаписьJSON;
ЗаписьJSON.УстановитьСтроку();          
ЗаписатьJSON(ЗаписьJSON, ЯСоответствие);            
ЧтениеJSON     = Новый ЧтениеJSON;
ЧтениеJSON.УстановитьСтроку(ЗаписьJSON.Закрыть());
Результат = ПрочитатьJSON(ЧтениеJSON);

ЗаписьXML = Новый ЗаписьXML();
ЗаписьXML.УстановитьСтроку();
СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ЯСоответствие);
РезультатMAP = ЗаписьXML.Закрыть(); 
		
РезультатMAP = СтрЗаменить(РезультатMAP,"<Map","<Structure");		
РезультатMAP = СтрЗаменить(РезультатMAP,"</Map>","</Structure>");
РезультатMAP = СтрЗаменить(РезультатMAP,"<pair>","");
РезультатMAP = СтрЗаменить(РезультатMAP,"</pair>","</Property>");
РезультатMAP = СтрЗаменить(РезультатMAP,"<Key xsi:type=""xs:string"">","<Property name="""); 
РезультатMAP = СтрЗаменить(РезультатMAP,"</Key>",""">");
	
ЧтениеXML = Новый ЧтениеXML;
ЧтениеXML.УстановитьСтроку(РезультатMAP);
Результат = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
ЧтениеXML.Закрыть();

Какие замеры я решил проделать?

1 Сформировать небольшое соответствие из 10 элементов. В цикле в несколько повторений провести преобразование. Замерять только работу в цикле. Повторений будет 1, 1000 и 10000.

2 Сформировать среднее соответствие из 1000 элементов. В цикле в несколько повторений провести преобразование. Замерять только работу в цикле. Повторений будет 1 и 1000.

3 Сформировать большое соответствие из 10000 элементов. В цикле в несколько повторений провести преобразование. Замерять только работу в цикле. Повторений будет 1 и 100.

• Во всех замерах, буду включать debug, а затем выключать.
• Соответствие формирую разово и наполняю его в зависимости от указанного количества элементов.

Функция СформироватьСоответствиеСМокДанными(КоличествоЭлементов = 1)
        Результат = Новый Соответствие;
        ШаблонКлюча = "Эл%1";
        Для счетчик = 1 По КоличествоЭлементов Цикл
                Результат.Вставить(СтрШаблон(ШаблонКлюча,Формат(счетчик,"ЧН=0; ЧГ=")),?(счетчик % 2 > 0,Формат(счетчик,"ЧН=0; ЧГ="),счетчик));
        КонецЦикла; 
        Возврат Результат;
КонецФункции

Замер 1-1 (Соответствие 10 элементов, 1 повторение)

[Debug включен]

1. Запрос :0мс.
2. НастройкиКомпоновкиДанных :0мс.
3. Структура :0мс.
4. ЗначениеВСтроку :0мс.
5. XML :0мс.
6. JSON :0мс.

[Debug выключен]

1. Запрос :0мс.
2. НастройкиКомпоновкиДанных :0мс.
3. Структура :0мс.
4. ЗначениеВСтроку :0мс.
5. НастройкиКомпоновкиДанныхВ2 :0мс.
6. JSON :0мс.
7. XML :1мс.

На глаз победителя выявить не удалось, и я запустил с замером и получил самые тяжелые операции:

1. СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
2. СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ЯСоответствие);
3. НастройкиКомпоновкиДанных = Новый НастройкиКомпоновкиДанных;        

При следующих замерах будет уже более показательно.

Замер 1-2 (Соответствие 10 элементов, 1000 повторений)

[Debug включен]

1. JSON :43мс.
2. ЗначениеВСтроку :46мс.
3. Структура :70мс.
4. Запрос :115мс.
5. НастройкиКомпоновкиДанных :123мс.
6. XML :332мс.

[Debug выключен]

1. Структура :19мс.
2. JSON :22мс.
3. Запрос :24мс.
4. ЗначениеВСтроку :42мс.
5. НастройкиКомпоновкиДанных :53мс.
6. НастройкиКомпоновкиДанныхВ2 :53мс.
7. XML :315мс.

Обратите внимание метод через JSON вырвался вперед при включенном debug. Почти в два раза быстрее того метода, который я использую повсеместно... Что будет дальше?

Замер 1-3 (Соответствие 10 элементов, 10000 повторений)

[Debug включен]

1. JSON :318мс.
2. ЗначениеВСтроку :538мс.
3. Структура :622мс.
4. Запрос :733мс.
5. НастройкиКомпоновкиДанных :1093мс.
6. XML :3366мс.

[Debug выключен]

1. Структура :188мс.
2. JSON :228мс.
3. Запрос :313мс.
4. ЗначениеВСтроку :474мс.
5. НастройкиКомпоновкиДанныхВ2 :523мс.
6. НастройкиКомпоновкиДанных :732мс.
7. XML :3602мс.

Метод через JSON просто разорвал конкурентов cо включенным debug, но и вариант ЗначениеВСтроку выглядит интересно. С выключенным debug метод используемый мной повсеместно показал лучший результат.

Теперь увеличим количество элементов в соответствии и замерим.

Замер 2-1 (Соответствие 1000 элементов, 1 повторение)

[Debug включен]

1. JSON :2мс.
2. ЗначениеВСтроку :3мс.
3. Запрос :6мс.
4. НастройкиКомпоновкиДанных :6мс.
5. Структура :7мс.
6. XML :23мс.

[Debug выключен]

1. JSON :1мс.
2. Структура :2мс.
3. НастройкиКомпоновкиДанных :2мс.
4. ЗначениеВСтроку :2мс.
5. НастройкиКомпоновкиДанныхВ2 :2мс.
6. Запрос :3мс.
7. XML :20мс.

Уже на старте JSON и ЗначениеВСтроку идут в отрыв при включенном debug.

Топ операции:

1. Результат = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
2. СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ЯСоответствие);       
3. НастройкиКомпоновкиДанных.ДополнительныеСвойства.Вставить(текЭлемент.Ключ, текЭлемент.Значение);      
4. Каждого текЭлемент Из ЯСоответствие Цикл

Замер 2-2 (Соответствие 1000 элементов, 1000 повторений)

[Debug включен]

1. JSON :1433мс.
2. ЗначениеВСтроку :2457мс.
3. Структура :5915мс.
4. Запрос :6384мс.
5. НастройкиКомпоновкиДанных :6392мс.
6. XML :28048мс.

[Debug выключен]

1. JSON :1206мс.
2. Структура :1629мс.
3. Запрос :2071мс.
4. НастройкиКомпоновкиДанных :2094мс.
5. ЗначениеВСтроку :2264мс.
6. НастройкиКомпоновкиДанныхВ2 :2367мс.
7. XML :23069мс.

Картина, по-моему, уже ясна.

Еще увеличим количество элементов в соответствии и замерим.

Замер 3-1 (Соответствие 10000 элементов, 1 повторение)

[Debug включен]

1. JSON :15мс.
2. ЗначениеВСтроку :25мс.
3. Структура :63мс.
4. НастройкиКомпоновкиДанных :65мс.
5. Запрос :66мс.
6. XML :232мс.

[Debug выключен]

1. JSON :13мс.
2. Структура :18мс.
3. НастройкиКомпоновкиДанных :20мс.
4. Запрос :21мс.
5. НастройкиКомпоновкиДанныхВ2 :22мс.
6. ЗначениеВСтроку :23мс.
7. XML :228мс.

Топ операций:

1. Результат = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
2. СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ЯСоответствие);
3. Запрос.УстановитьПараметр(текЭлемент.Ключ, текЭлемент.Значение);
4. НастройкиКомпоновкиДанных.ДополнительныеСвойства.Вставить(текЭлемент.Ключ, текЭлемент.Значение);
5. Каждого текЭлемент Из ЯСоответствие Цикл

Замер 3-2 (Соответствие 10000 элементов, 100 повторений)

[Debug включен]

1. JSON :1883мс.
2. ЗначениеВСтроку :2931мс.
3. Структура :6594мс.
4. Запрос :7242мс.
5. НастройкиКомпоновкиДанных :7354мс.
6. XML :26675мс.

[Debug выключен]

1. JSON :1542мс.
2. Структура :2223мс.
3. Запрос :2250мс.
4. НастройкиКомпоновкиДанныхВ2 :2538мс.
5. НастройкиКомпоновкиДанных :2649мс.
6. ЗначениеВСтроку :2810мс.
7. XML :23086мс.

Выводы:

Судя по замерам, метод с JSON хорош как при большом числе элементов в соответствии, так и при преобразовании в цикле. Нужно учесть недостатки, что ключ должен быть строкой, в которой только разрешенные символы. Соответственно если вы уверены, что ограничения нет, то почему бы и да?

На что еще хочется обратить внимание?

Циклы работают довольно-таки долго, но СериализаторXDTO.ЗаписатьXML и СериализаторXDTO.ПрочитатьXML работает крайне медленно, я бы сказал, отвратительно.

Обратите внимание, что при включенном и выключенном debug картина меняется и в местах где используется цикл с небольшим количеством элементов в соответствии выигрывает метод через структуру в цикле.

Так же есть важный нюанс отмеченный в комментариях, чем больше символов в значениях у соответствия, тем медленнее начинает работать способ с JSON (дополнительные замеры в комментариях).

На этом статью заканчиваю. Надеюсь, она была вам полезна.

П.С. Данная статья появилась благодаря читателям моего канала, она набрала оговоренное количество эмоций.