Описание проблемы
При разработке обмена с использованием технологии "Конвертация данных 3.1 формат XDTO (Enterprise Data)" может возникнуть потребность на стороне "базы-приемника", в случае нахождения для загружаемого объекта соответствия, не обновлять найденный объект загружаемыми данными. То есть в кратце задача звучит как "При обмене необходимо загружать только новые объекты (для которых не найдено соответствие)".
Решение
Базовый принцип
Поставляемые настройки конвертации, позволяющие реализовать описанный нами формат обмена, отсутствуют. Поэтому будем использовать произвольный алгоритм в обработчиках событий правил конвертации объектов (Далее "ПКО").
Доступные обработчики событий для ПКО на получение данных:
- При конвертации данных XDTO. Выполняется в ходе получения данных, при конвертации объекта XDTO в объект информационной базы.
- Перед записью полученных данных. Выполняется в ходе получения данных, перед записью полученного объекта информационной базы.
- После загрузки всех данных. Выполняется для каждого объекта, загруженного по правилу конвертации, на этапе после получения всех данных.
Обработчик "При конвертации данных XDTO" не подходит, так как на этапе его выполнения происходит только преобразования данных из формата обмена в загружаемый объект (На основе которого далее и происходит сопоставление).
Обработчик "После загрузки всех данных" не подходит, так как на этапе его выполнения загрузка уже выполнена.
Нам необходим обработчик "Перед записью полученных данных". В нем есть два интересующих нас параметра:
- ПолученныеДанные - Объект, полученный после выполнения обработчика "При конвертации данных XDTO".
- ДанныеИБ - Найденный объект из базы данных, сопоставленный "полученным данным".
Для реализации нашей задачи все что нам требуется это написать в этом обработчике следующий алгоритм:
Процедура ПКО_ИмяПКО_ПередЗаписьюПолученныхДанных(ПолученныеДанные, ДанныеИБ, КонвертацияСвойств, КомпонентыОбмена)
// Если нашлось соответствие (Объект не новый), то обнуляем ПолученныеДанные.
Если ДанныеИБ <> Неопределено Тогда
// Если ПолученныеДанные = Неопределено, то согласно документации КД 3.1
// создание/обновление объекта ложиться на наши плечи.
// А мы делать ничего не будем. Таким образом мы отменили загрузку.
ПолученныеДанные = Неопределено;
КонецЕсли;
КонецПроцедуры
Теперь, что бы применить наше правило ко всем объектам, то же самое нужно прописать в остальных ПКО. В базе "Управление торговлей 11.5" в типовых правилах конвертации на базе формата "Enterprise Data 1.19" было насчитано 208 ПКО на получение. Думаю понятно, что вариант пройтись по всем ПКО и прописать в обработчике наш алгоритм - нам не подходит. Нам нужен глобальный обработчик для всех ПКО.
Создание глобальных обработчиков событий ПКО
Для начала определим в модуле МенеджерОбменаЧерезУниверсальныйФормат (Далее "менеджер обмена") экспортную функцию со списком глобальных обработчиков.
Функция обмен_ГлобальныеОбработчикиПередЗаписьюПолученныхДанных() Экспорт
ГлобальныеОбработчики = Новый Массив;
ГлобальныеОбработчики.Добавить("обмен_ПередЗаписьюПолученныхДанных_ЗаписьТолькоНовых");
Возврат ГлобальныеОбработчики;
КонецФункции
В нашем примере будет следующая архитектура:
В основной конфигурации есть типовой менеджер обмена, который мы будем расширять через расширение. Поэтому все дальнейшие примеры кода будут в расширении (префикс "обмен_").
Далее находим место вызова обработчика "Перед записью полученных данных". Оно находиться в общем модуле ОбменДаннымиXDTOСервер в процедуре ПередЗаписьюПолученныхДанных. И расширяем алгоритм, вызывая глобальные обработчики перед вызовом локального (определенного для текущего ПКО) обработчика.
&ИзменениеИКонтроль("ПередЗаписьюПолученныхДанных")
Процедура обмен_ПередЗаписьюПолученныхДанных(ПолученныеДанные, ДанныеИБ, КомпонентыОбмена, ИмяОбработчика, КонвертацияСвойств)
...
#Вставка
Попытка
// Функции может не быть если это типовой мендежер обмена, а мы работаем только со своим
ГлобальныеОбработчики = МенеджерОбмена.обмен_ГлобальныеОбработчикиПередЗаписьюПолученныхДанных();
Исключение
ГлобальныеОбработчики = Новый Массив;
КонецПопытки;
Для каждого ИмяГлобальногоОбработчика Из ГлобальныеОбработчики Цикл
ВремяНачала = ОбменДаннымиОценкаПроизводительности.НачатьЗамер();
МенеджерОбмена.ВыполнитьПроцедуруМодуляМенеджера(ИмяГлобальногоОбработчика, СтруктураПараметров);
ОбменДаннымиОценкаПроизводительности.ЗавершитьЗамер(
ВремяНачала, ИмяГлобальногоОбработчика, ДанныеИБ, КомпонентыОбмена,
ОбменДаннымиОценкаПроизводительности.ТипСобытияПравило());
КонецЦикла;
#КонецВставки
ВремяНачала = ОбменДаннымиОценкаПроизводительности.НачатьЗамер();
МенеджерОбмена.ВыполнитьПроцедуруМодуляМенеджера(ИмяОбработчика, СтруктураПараметров);
ОбменДаннымиОценкаПроизводительности.ЗавершитьЗамер(
ВремяНачала, ИмяОбработчика, ДанныеИБ, КомпонентыОбмена,
ОбменДаннымиОценкаПроизводительности.ТипСобытияПравило());
...
КонецПроцедуры
Возвращаемся в менеджер обмена и не забываем расширить метод ВыполнитьПроцедуруМодуляМенеджера
&Вместо("ВыполнитьПроцедуруМодуляМенеджера")
Процедура обмен_ВыполнитьПроцедуруМодуляМенеджера(ИмяПроцедуры, Параметры)
ПродолжитьВызов(ИмяПроцедуры, Параметры);
Если ИмяПроцедуры = "обмен_ПередЗаписьюПолученныхДанных_ЗаписьТолькоНовых" Тогда
обмен_ПередЗаписьюПолученныхДанных_ЗаписьТолькоНовых(
Параметры.ПолученныеДанные, Параметры.ДанныеИБ, Параметры.КонвертацияСвойств, Параметры.КомпонентыОбмена);
КонецЕсли;
КонецПроцедуры
И определим собственно сам метод глобального обработчика
Процедура обмен_ПередЗаписьюПолученныхДанных_ЗаписьТолькоНовых(ПолученныеДанные, ДанныеИБ, КонвертацияСвойств, КомпонентыОбмена)
Если ДанныеИБ <> Неопределено Тогда
ПолученныеДанные = Неопределено;
КонецЕсли;
КонецПроцедуры
Итоговый код расширения:
Итоги
Мы решили поставленную задачу, и в ходе её решения научились создавать глобальные обработчики "Перед записью полученных данных" для ПКО. Но по тому же принципу можно создать общие (глобальные) обработчики для любых других событий как ПКО так и ПОД (Правила обработки данных).
Нужно понимать что применив данный метод к модулю менеджера обмена, его уже нельзя будет загрузить в КД 3.1, и выгрузить в том же виде. КД 3.1 не знает о нашей доработке и при выгрузке модуля менеджера обмена просто затрет созданные нами процедуры связанные с глобальными обработчиками событий. Т.е. это решение подходит для случаев когда мы программно (не прибегая к использованию КД 3.1) дорабатываем типовые правила.
Используемые при написании статьи версии конфигураций и платформы:
- Конвертация данных, редакция 3.1 (3.1.5.35)
- Управление торговлей, редакция 11 (11.5.21.106)
- СтандартныеПодсистемы (БСП) 3.1.10.467
- 1С:Предприятие 8.3 (8.3.25.1546)
Вступайте в нашу телеграмм-группу Инфостарт
