Если моя публикация Вам полезна, не забудьте поставить плюсик :-)
Рекомендую также дополнительно ознакомиться с этими публикациями на этом сайте:
//infostart.ru/public/102366/
//infostart.ru/public/126813/
Ну а теперь мои наработки и заметки, которые я создал в процессе подготовки.
Постараюсь по минимуму повторяться с упомянутыми выше двумя последними публикациями.
Итак, приступим:
*************************************************************************************************
В случае удаленной сдачи у вас должно быть в конце экзамена на рабочем столе два объекта:
1. Итоговая выгрузка информационной базы (файл dt)
2. Пояснительная записка
Ничего другого быть не должно, никаких промежуточных копий и т.д.
Пояснительную записку пишете обязательно!
В случае нечетко сформулированного задания обязательно напишите там, что выбрали именно такой-то вариант решения.
Также в коде в ключевых местах лучше оставлять краткие комментарии, без фанатизма, но там где могут возникнуть вопросы у экзаменатора, лучше напишите.
Но об этом Вам и так будет сказано в инструкции, которую дадут прочесть перед началом экзамена.
Просто лучше знать заранее)
*************************************************************************************************
Использование знака амперсанда в запросах.
Иногда быстрее набрать с дополнительной клавиатуры, чем переключать туда-сюда раскладку, экономится время
& = Alt+38
*************************************************************************************************
Использование МоментВремени() в запросах
В запросах к регистрам накопления, бухгалтерии в качестве параметра виртуальной таблицы (периода) необходимо использовать не дату документа, а параметр Момент который определяется в коде следующим образом:
Момент = ?(РежимПроведения = РежимПроведенияДокумента.Оперативный, Неопределено, МоментВремени());
*************************************************************************************************
При формировании движений документа по регистру в самом начале процедуры обработки проведения необходимо очищать движения текущего документа по регистру.
Код такой:
Движения.НазваниеРегистра.Записывать = Истина;
Движения.НазваниеРегистра.Очистить();
Возможно, что в процессе проведения нужно будет анализировать записи по этому регистру.
Так вот, чтобы при анализе текущие записи (старые, до изменения документа) точно не попали в выборку, к приведенным двум строчкам можно добавить еще одну:
Движения.НазваниеРегистра.Записать();
Или же при анализе записей явно указывать границу, не включающую момент времени текущего документа.
Но я везде просто указывал сразу конструкцию из этих трех строчек:
Движения.НазваниеРегистра.Записывать = Истина;
Движения.НазваниеРегистра.Очистить();
Движения.НазваниеРегистра.Записать();
*************************************************************************************************
Есть два способа блокировки данных, выбор между ними зависит от методики проведения - старой или новой:
1) Обычная управляемая блокировка, старая методика проведения документа (объект БлокировкаДанных)
Устанавливается в случае, если сначала идет проверка остатков, а затем списание.
В том случае, когда нам для формирования движения необходимо иметь какую-то информацию из регистра.
Пример:
Рассмотрим операцию реализации товара.
В документе - количество, в регистре - количество и сумма (себестоимость)
Так вот, количество товара мы знаем из документа - сколько списываем, а себестоимость - нет.
Мы можем ее узнать только из регистра, но для того, чтобы никто не изменил регистр между моментом получения остатков и моментом записи движений, нам необходимо еще до чтения остатков заблокировать регистр.
Так вот, в этом случае и используется объект БлокировкаДанных. И при его создании правильнее указать по каким измерениям мы блокируем регистр (например в нашем случае - только по указанной в документе номенклатуре) - чтобы не было излишних блокировок и другой пользователь смог продавать другую номенклатуру.
То есть последовательность такая:
1. Устанавливаем блокировку с помощью объекта БлокировкаДанных
2. Читаем остатки
3. Проверяем возможность списания
4. Формируем движения, к примеру списываем товар
5. После проведения документа блокировка автоматически снимается (блокировка действует в рамках транзакции проведения и снимается автоматически системой). То есть как-то специально разблокировать объект не надо.
2) Новая методика проведения документов (использование свойства БлокироватьДляИзменения = Истина)
Используется в случае, если нам для формирования движений не нужна информация из регистров, а проверить не ушли ли мы в минус при списании мы сможем, если после записи посмотрим остатки по регистру и увидим что есть отрицательные. В этом случае, мы поймем, что списали лишнее и отменим операцию списания.
Пример:
Рассмотрим операцию реализации товара.
В документе - количество, в регистре - только количество
Так вот, количество товара мы знаем из документа.
Мы формируем движения с указанным в документе количеством и записываем их. Далее читаем регистр, смотрим остатки, анализируем - есть ли отрицательные. Если есть выводим ошибку и ставим Отказ = Истина.
То есть последовательность такая:
1. Для движения по регистру устанавливаем свойство БлокироватьДляИзменения = Истина
2. Формируем движения - списываем товар
3. Записываем движения
4. Читаем регистр, смотрим, чтобы не было отрицательных остатков. Если есть - то списали лишнее, если нет - то все нормально.
Так вот, в этом случае нет необходимости указывать по каким измерениям нам надо блокировать регистр.
Мы просто устанавливаем свойство БлокироватьДляИзменения = Истина до записи наших движений, формируем движения и записываем.
Система сама заблокирует регистр в момент записи по тем измерениям, которые надо, проанализировав то, что мы записали.
После проведения блокировка снимется.
Этот вариант (второй) проще, называется "новая методика проведения документов" и 1С рекомендует использовать именно его в случае возможности и снимает баллы, если используется первый вариант, но в некоторых случаях его просто невозможно применить и используется первый вариант с объектом БлокировкаДанных (см. приведенный выше пример).
Также замечу, что независимо от выбранного способа, движения перед работой с ними необходимо очистить (см. предыдыщий совет)
*************************************************************************************************
Блокировка данных (способ блокировки №1 из приведенного выше описания)
Управляемая блокировка требуется там, где читаются данные и на основании этих данных делаются движения
Сам код управляемой блокировки быстрее всего получить, если ввести "БлокировкаДанных", вызвать Синтакс-помощник и оттуда просто скопировав код примера. Далее его просто изменить под название своего регистра и измерений.
Выглядит примерно следующим образом:
Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.ТоварыНаСкладах");
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
ЭлементБлокировки.ИсточникДанных = ТЧ;
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
Блокировка.Заблокировать();
*************************************************************************************************
Табличную часть документов лучше называть просто "ТЧ"
Табличная часть в 99% документов - одна. Такое унифицированное название табличных частей очень поможет сэкономить время, так как:
1) Очень короткое - быстро писать
2) Одинаковое для всех документов, не придется вспоминать при написании кода как она называется
*************************************************************************************************
Результат запроса проверять на пустоту перед выборкой или выгрузкой в ТЗ.
Вообще во всех задачах использовал выборку.
Выборка более оптимальна для системы с точки зрения производительности, так как "заточена" только для чтения данных (в отличие от ТЗ).
Но в любом случае до метода Выбрать() лучше проверить на пустоту результат запроса, это еще уменьшит нагрузку на систему.
Результат = Запрос.Выполнить();
Если Не Результат.Пустой() Тогда
Выборка = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
...
КонецЕсли;
А в случае, если нам нужно получить только одно значение из запроса
(например только метод списания в соответствии с учетной политикой, установленной на этот год):
Результат = Запрос.Выполнить();
Если Не Результат.Пустой() Тогда
Выборка = Результат.Выбрать();
Выборка.Следующий();
МетодСписанияСебестоимости = Выборка.МетодСписанияСебестоимости;
КонецЕсли;
*************************************************************************************************
Документ "Операция" для задачи по БУ
Обязательно нужно создавать документ Операция для задач по БУ.
Отключаем у него проведение вообще (в свойствах "Проведение = Запретить"), указываем, что делает движения по регистру бухгалтерии, движения вытаскиваем на форму.
*************************************************************************************************
Оперативное проведение документов:
Должно быть включено:
В оперативном и бух. учете у документов должно быть включено (кроме документа "Операция", см. ниже).
Должно быть выключено:
в расчетных задачах не имеет смысла для документа начисления зарплаты.
Для документа "Операция" проведение вообще должно быть отключено (в свойствах документа "Проведение = Запретить"),
так как он пишет просто пишет данные напрямую в регистр при записи.
*************************************************************************************************
Условие в запросе вида "Или указанная номенклатура или любая, если не указана"
В запросах встречается такая задача: например нужно выбрать документы с указанной номенклатурой или все документы, если номенклатура не указана.
Решается следующим условием в самом запросе:
Номенклатура = &Номенклатура ИЛИ &Номенклатура = Значение(Справочник.Номенклатура.ПустаяСсылка)
Но более оптимально и правильнее это условие будет преобразовать (спасибо yukon):
Если ЗначениеЗаполнено(Номенклатура) Тогда
Запрос.Текст = Запрос.Текст + " ГДЕ Номенклатура = &Номенклатура";
Запрос.УстановитьПараметр("Номенклатура", Номенклатура);
КонецЕсли;
С появлением объектной модели запроса в 8.3.5 условие можно будет добавлять безопаснее:
Если ЗначениеЗаполнено(Номенклатура) Тогда
Запрос1.Отбор.Добавить("Номенклатура = &Номенклатура");
Запрос.УстановитьПараметр("Номенклатура", Номенклатура);
КонецЕсли;
*************************************************************************************************
Присоединение таблиц в запросах:
Количество итоговых записей не зависит от того, будет ли выведено поле присоединяемой таблицы, зависит только от настроенных связей.
То есть поле присоединенной таблицы можно и не выводить.
Если требуется присоединить таблицу без всяких условий, то на закладке с условиями просто писать условие "ИСТИНА".
В этом случае таблица присоединится точно.
*************************************************************************************************
Использование плана видов характеристик (ПВХ):
1. Использование в качестве механизма описания характеристик объектов.
1.1. Создаем ПВХ. Это будут ВидыХарактеристик (например, цвет, размер, макс. скорость и т.д.). В настройках выбираем все возможные типы значений характеристик и если нужно создаем объект из пункта 1.2 и указываем его также в настройках.
1.2. Для дополнительных значений ПВХ создаем подчиненный ему справочник ДопЗначенияХарактеристик (или просто ЗначенияХарактеристик).
В нем будут хранится характеристики, если их нет в существующих справочниках. Мы можем его не создавать, если все нужные нам характеристики есть в существующих справочниках, либо эти значения можно представить элементарными типами данных. В настройках ПВХ указываем, что этот справочник будет использоваться для доп. значений характерестик.
1.3. Создаем регистр сведений, который собственно и связывает три объекта:
- Объект, к которому мы подключаем механизм характеристик
- ВидХарактеристики (тип ПВХ)
- ЗначениеХарактеристики (тип - характеристика, это новый тип, который появился в системе после создания ПВХ
и описывающий все возможные типы данных, которые может принимать значение характеристики).
В регистре сведений указываем, что ВидХарактеристики является владельцем для ЗначенияХарактеристики (свяхь параметра выбора), а также связь по типу для ЗначенияХарактеристики опять же от ВидаХарактеристики.
Еще такая особенность, что для каждого создаваемого вида характеристики можно указывать тип значения характеристики, если не нужны все возможные типы для описания значения этой характеристики.
2. Использование ПВХ для создания механизма субконто регистра бухгалтерии.
2.1. Создаем ПВХ ВидыСубконто.
2.2. Создаем подчиненный справочник ЗначенияСубконто (как с характеристиками, в нем будут значения субконто, если нет таких в других справочниках).
2.3. Связь производится с помощью плана счетов.
*************************************************************************************************
Ресурсы регистра бухгалтерии:
Сумма - балансовый,
Количество - небалансовый и связан с признаком учета Количественный
*************************************************************************************************
Виртуальные таблицы регистра бухгалтерии:
Обороты: обороты какого-то одного счета
ОборотыДтКт: обороты между какими-то двумя счетами, то есть все одинаковые проводки за период.
*************************************************************************************************
Валютный учет на регистрах бухгалтерии - как реализовать:
Создаем признак учета "валютный" в плане счетов.
В регистре бухгалтерии создаем дополнительно:
- измерение Валюта (запрет незаполненных значений, небалансовый, признак учета - валютный)
- ресурс ВалютнаяСумма (небалансовый, признак учета - валютный, в нем будет хранится сумма в валюте, то есть 100$ например)
Все.
Таким образом структура регистра:
Измерения:
- Валюта
Ресурсы
- Количество
- Сумма (сумма в рублях)
- ВалютнаяСумма (сумма в валюте)
Таким образом валютный учет - это лишь доработка обычного учета на РБ, он не изменяет сути к примеру ресурса Сумма
(там как и обычно сумма в рублях, независимо от того, валютный ли счет или нет).
И если признак учета Валютный для счета выключен, то это обычная структура РБ (ресурсы - только количество и сумма).
*************************************************************************************************
Условия при установке параметров виртуальной таблицы для получения среза последних накладываем на измерения, а не на ресурсы.
Иначе получим не срез последних, а последнюю запись с указанным значением ресурса - она может быть не последней по набору измерений
*************************************************************************************************
Смысл ресурса и реквизита в регистре расчета
В регистрах расчета создание ресурса дает возможность получать его при расчете базы по этому регистру.
И даже пропорционально заданному периоду будет пересчитываться значение ресурса (если базовый период не совпадает с периодичностью регистра).
А значение реквизита доступно только в реальной таблице регистра расчета, в виртуальных таблицах его нет.
*************************************************************************************************
Галочка "Базовое" в свойствах измерения регистра расчета
Означает, что по этому измерению в дальнейшем будет получаться база и служит для дополнительной индексации значений по этому полю.
*************************************************************************************************
Разбивка периода действия отпуска по месяцам при записи наборов записей регистра,
в случае если отпуск задается в документе одной строкой сразу на несколько месяцев одной строкой:
ДатаНачалаТекМесяца = НачалоМесяца(ТекСтрокаОсновныеНачисления.ПериодДействияНачало);
ДатаОкончанияТекМесяца = КонецМесяца(ТекСтрокаОсновныеНачисления.ПериодДействияНачало);
ТекМесяц = Дата;
Пока ДатаНачалаТекМесяца <= НачалоМесяца(ТекСтрокаОсновныеНачисления.ПериодДействияКонец) Цикл
Движение = Движения.ОсновныеНачисления.Добавить();
Движение.Сторно = Ложь;
Движение.ВидРасчета = ТекСтрокаОсновныеНачисления.ВидРасчета;
Движение.ПериодДействияНачало = Макс(ДатаНачалаТекМесяца, ТекСтрокаОсновныеНачисления.ПериодДействияНачало);
Движение.ПериодДействияКонец = КонецДня(Мин(ДатаОкончанияТекМесяца, ТекСтрокаОсновныеНачисления.ПериодДействияКонец));
Движение.ПериодРегистрации = Дата;
Движение.Сотрудник = ТекСтрокаОсновныеНачисления.Сотрудник;
Движение.Подразделение = ТекСтрокаОсновныеНачисления.Подразделение;
Движение.Сумма = 0;
Движение.КоличествоДней = 0;
Движение.График = ТекСтрокаОсновныеНачисления.График;
Движение.Параметр = ТекСтрокаОсновныеНачисления.Параметр;
Движение.БазовыйПериодНачало = НачалоМесяца(ДобавитьМесяц(Дата, -3));
Движение.БазовыйПериодКонец = КонецДня(КонецМесяца(ДобавитьМесяц(Дата, -1)));
ДатаНачалаТекМесяца = НачалоМесяца(ДобавитьМесяц(ДатаНачалаТекМесяца, 1));
ДатаОкончанияТекМесяца = КонецМесяца(ДатаНачалаТекМесяца);
КонецЦикла;
КонецЕсли;
*************************************************************************************************
Построение Диаграммы Ганта:
Размещаем на форме элемент типа "ДиаграммаГанта", называем ДГ, далее создаем команду "Сформировать" и в модуле формы пишем следующее:
&НаКлиенте
Процедура Сформировать(Команда)
СформироватьНаСервере();
КонецПроцедуры
&НаСервере
Процедура СформироватьНаСервере()
ДГ.Очистить();
ДГ.Обновление = Ложь;
Запрос = Новый Запрос(
"ВЫБРАТЬ
|ОсновныеНачисленияФактическийПериодДействия.Сотрудник,
|ОсновныеНачисленияФактическийПериодДействия.ВидРасчета,
|ОсновныеНачисленияФактическийПериодДействия.ПериодДействияНачало КАК ПериодДействияНачало,
|ОсновныеНачисленияФактическийПериодДействия.ПериодДействияКонец КАК ПериодДействияКонец
|ИЗ
|РегистрРасчета.ОсновныеНачисления.ФактическийПериодДействия КАК ОсновныеНачисленияФактическийПериодДействия
|ГДЕ
|ОсновныеНачисленияФактическийПериодДействия.ПериодДействия МЕЖДУ &ДатаНачала И &ДатаОкончания");
Запрос.УстановитьПараметр("ДатаНачала", Период.ДатаНачала);
Запрос.УстановитьПараметр("ДатаОкончания", Период.ДатаОкончания);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Точка = ДГ.УстановитьТочку(Выборка.Сотрудник);
Серия = ДГ.УстановитьСерию(Выборка.ВидРасчета);
Значение = ДГ.ПолучитьЗначение(Точка, Серия);
Интервал = Значение.Добавить();
Интервал.Начало = Выборка.ПериодДействияНачало;
Интервал.Конец = Выборка.ПериодДействияКонец;
КонецЦикла;
ДГ.Обновление = Истина;
КонецПроцедуры
Собственно тут нам важен только код в цикле, остальные вещи вспомогательные, просто целиком привел всю реализацию этой подзадачи.
В запросе нам важно, чтобы был сотрудник, вид расчета, дата начала и дата окончания периода.
Код на самом деле очень простой, запомнить его легко, не пугайтесь, если кажется громоздким
*************************************************************************************************
Обработка записей "сторно" в расчетных задачах:
В процедуре обработки проведения (модуль объекта) формируем все движения, а далее если есть записи в других периодах получим их так
(система формирует их автоматически - помогает нам):
ЗаписиДополнения = Движения.ОсновныеНачисления.ПолучитьДополнение(); // Записывать движения для получения дополнения не нужно
Для Каждого ТекСтрока Из ЗаписиДополнения Цикл
Запись = Движения.ОсновныеНачисления.Добавить();
ЗаполнитьЗначенияСвойств(Запись, ТекСтрока);
Запись.ПериодРегистрации = ТекСтрока.ПериодРегистрацииСторно;
Запись.ПериодДействияНачало = ТекСтрока.ПериодДействияНачалоСторно;
Запись.ПериодДействияКонец = ТекСтрока.ПериодДействияКонецСторно;
КонецЦикла
А при расчете записей вставлять проверки:
Если ТекДвижение.Сторно Тогда
ТекДвижение.Сумма = - ТекДвижение.Сумма;
КонецЕсли;
*************************************************************************************************
Как определить что относить в основным начислениям, а что - к дополнительным в расчетных задачах.
Общая рекомендация такая - те начисления, которые имеют протяженность по времени относим к основным, а те, что не имеют - к дополнительным.
Но не всегда это на 100% ясно, бывают и случаи посложней, хотя их довольно мало
(например премия, которая зависит от количества рабочих в месяце дней - это ОН).
Поэтому если приведенная выше вам рекомендация не помогла, вывел для себя более развернутое правило определения:
Основные начисления:
Если по виду расчета есть зависимость от графика (имеется в виду регистр сведений с датами календаря), то он относится к основным начислениям.
Пример ОН:
- Оклад
- Что-то, что считается от количества рабочих дней (а для этого нужно использовать график): либо в периоде действия (как оклад), либо в базовом периоде
Дополнительные начисления:
То, что считается либо от начисленной суммы, либо ОТРАБОТАННОГО (а не нормы!) времени, либо вообще не зависит - это доп. начисления.
То есть: начисления для расчета которых используется норма времени (может еще и факт) - это ОН, а для которых фактические данные или вообще ничего не нужно - это ДН.
Или другими словами:
Если ВР использует норму времени, то для ПВР должен быть включен период действия.
*************************************************************************************************
Добавить возможность в форме списка справочника "Номенклатура" возможность открытия раздела встроенной справки "Работа со справочниками".
Сделать на форме команду:
&НаКлиенте
Процедура Справка(Команда)
ОткрытьСправку("v8help://1cv8/EnterprWorkingWithCatalogs");
КонецПроцедуры
Строку раздела определяем так:
Зайти в справочную информацию объекта конфигурации (в конфигураторе), написать слово, выделить его, зайти в меню Элементы/Ссылка и выбрать нужный раздел хелпа 1С, после этого ссылка подставляется автоматически. Выглядит сложно, на практике - все легко.
*************************************************************************************************
Осуществление взаимодействия между формами, например, подбор:
1. Из текущей формы открываем нужную методом "ОткрытьФорму()", вторым параметром передаем структуру с параметрами (если надо). Третьим параметром можем передать ссылку на эту форму - ЭтаФорма.
2. В открываемой форме в обработчике "ПриСозданииНаСервере()" мы можем поймать переданные в п.1 параметры через "Параметры.[ИмяПараметра]". Форма, которая инициализировала открытие этой формы, будет доступна через идентификатор "Владелец" (если она конечно была указана в п.1).
И что самое главное - будут доступны экспортные функции формы-владельца. То есть мы можем вызвать экспортную функцию исходной формы и передать туда что-то параметром для обработки подбора. А эта функция уже заполнит что нужно в исходной форме. Только одна оговорка - передавать таблицу значений между клиентскими процедурами нельзя, но мы можем поместить ее во временное хранилище и передать просто адрес ВХ, а уже там извлечь из ВХ.
*************************************************************************************************
Жизненный цикл параметров формы
Все параметры, переданные в форму в момент ее открытия видны только в процедуре «ПриСозданииНаСервере».
После создания все параметры уничтожаются и более не доступны в форме.
Исключение составляют параметры, которые в редакторе формы объявлены с признаком «Ключевой параметр».
Они определяют уникальность формы.
Такой параметр будет существовать до тех пор, пока существует сама форма.
*************************************************************************************************
Использование интерфейса "Такси"
При разработке можно установить в свойствах конфигурации обычный управляемый интерфейс 8.2 - так все заметно компактнее и привычнее.
Особенно это актуально, если сдаете удаленно - разрешение экрана очень маленькое, с интерфейсом "такси" невозможно ничего сделать.
Только не забудьте когда все сделаете поставить снова "Такси"! Иначе экзаменатор снимет балы!
*************************************************************************************************
PS: Есть отдельные типовые подзадачи, которые используются во всех задачах, именно их и нужно уметь решать (например, списание по партиям, использование ПВХ (ну это правда редко) и другие). И во всех задачах они просто повторяются (где-то одни подзадачи есть, где-то другие, просто в разных комбинациях). Тем более, что сборник же уже давно обещали новый выпустить (если еще не выпустили), в котором вроде задач должно быть намного больше, то есть нет смысла запоминать решения отдельных задач, есть смысл научиться решать отдельные типовые подзадачи, тогда решишь любую задачу.
PSS: Коллеги, если у кого-нибудь есть еще какая-либо полезная информация по подготовке к экзамену и сдаче, просьба писать в комментариях, дополним статью.
