Использование графического планшета для подписи в 1С

&НаКлиенте
Процедура ПолучитьПодпись(Команда)
	
	dynCapt  = Новый COMОбъект("Florentis.DynamicCapture");
	
	SigCtl = Новый COMОбъект("Florentis.SigCtl");
	SigCtl.Licence = "eyJhbGciOiJSUzUxMiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJMTVMiLCJleHAiOjE1NTQ4ODg2ODAsImlhdCI6MTU0NzExMjY4­MCwicmlnaHRzIjpbIkNETF9BQ0NFU1MiLCJDRExfTElWRV9TVFJFQU1JTkci­LCJDRExfVEhJUkRQQVJUWV9QRU5TIiwiQ0RMX1BIVV8xMTEiLCJTSUdfU0RL­X0NPUkUiLCJTSUdDQVBUWF9BQ0NFU1MiLCJTSUdfU0RLX0lTTyIsIlNJR19T­REtfRU5DUllQVElPTiJdLCJkZXZpY2VzIjpbIldBQ09NX0FOWSIsIlJUUyIs­IkFQUExFX1BFTkNJTCJdLCJ0eXBlIjoiZXZhbCIsImxpY19uYW1lIjoiV0lM­TF9TaWduYXR1cmVfRWRpdGlvbiIsIndhY29tX2lkIjoiYzBmYjNiYjRhMmVh­NDA1MWIzMTU2MGI4YjkyZDg2ZGUiLCJsaWNfdWlkIjoiNWI1ZDRiYTYtNGE4­Zi00MGM3LWJjMzYtMzhlNGIxMjk1NzNiIiwiYXBwc193aW5kb3dzIjpbXSwi­YXBwc19pb3MiOltdLCJhcHBzX2FuZHJvaWQiOltdLCJtYWNoaW5lX2lkcyI6­W119.Kg9mXWh74Yvxw5gXAJ3-c6yplX-W5Y1jdjPsJPNV8IRri0cpnoEuYRXbgxGcQKRkHYgJQ1yoqTzwDHA9e7mazVa­LRJsCSHvoLmHk5h61cgZRif9yalwVM1zvtQexZvANbhC7XqWqXGP38-g_W8Az-ei2MHPZ0UxDfyifyupHzOI_FVVlPL2Xg7fKx48ASGHFYRNbKsFBOE7PjGq9I­DG_0rHD7i8T8eKFa6xZ09jYH3PSFnD4qB-4dBf4m3Pos3YiWMfosNHR4Rwcx6t2Q7iNp-KOYv7lqZd08K8dO9xR8AA-4ASUMNR7Bn4u5UJWROLZn_zwcpNlGMFGq-awTRhJtQ";
	
	//CaptureResult    Capture(Who, Why, What, Key)
	//Parameters:
	//Who String specifying the signatory name. 
	//	Optional if InputWho property is set
	//Why String specifying the reason for signing. 
	//	Optional if InputWhy property is set
	//What Hash object 
	//	Derived from the data set with which the captured signature is 
	//	to be bound. Typically the data set will be the contents of the 
	//	document or form signed by the user. 
	//	SigCtlXHTML: The hash is generated automatically from the 
	//	contents of the XHTML document and cannot be supplied here. 
	//	(Optional)
	//Key Key object supplied in order to detect malicious or accidental 
	//	tampering with the signature object or the signature data it 
	//	contains. 
	//	SigCtlXHTML: Key type SHA256 is supplied automatically but 
	//	an alternative can be specified. 
	//	(Optional)
	
	ФИО = "Иванов Иван Иванович";
	ПричинаПодписи = "Распишитесь: ";
	КодВозврата = dynCapt.Capture(SigCtl, ФИО, ПричинаПодписи); //, null, null); // окно захвата подписи
	
	//Return Value:CaptureResult 
	//	CaptureOK Signature captured successfully.
	//	CaptureCancel Signature not captured because user cancelled Signature 
	//		Capture Window.
	//	CapturePadError No capture service available; typically, no functioning digitizing 
	//		tablet or other device for capturing signatures found.
	//	CaptureNotLicensed The component has not been licensed to perform capture. This 
	//		may be because a suitable licence has not been set or because 
	//		a condition of the licence has not been met, for example 
	//		required hardware, such as a particular tablet type, was not 
	//		found.
	//	CaptureError System error or some other unusual error condition.
	//	CaptureAbort Signature not captured because the handler for the PreCapture 
	//			event returned False. With SigCtlXHTML, this can indicate a 
	//			failure to parse document contents
	
	CaptureOK = 0;
	CaptureCancel = 1;
	CapturePadError = 100;
	CaptureError = 101;
	CaptureNotLicensed = 103;
	CaptureAbort = 200;
	
	Если КодВозврата = CaptureOK Тогда
		
		//Parameters:
		//outputFilename Pathname of the file in which to save the image. 
		//	May be null or empty if output type specified by flags is not 
		//	RenderOutputFilename.
		//dimensionX 
		//dimensionY
		//	Dimensions specified as DPI (dots per inch) or Pixels.
		//	Negative value = DPI (the signature is not scaled)
		//	Positive value = Pixels (the signature is scaled to fit the area)
		//mimeType Specifies the image format as one of:
		//	image/bmp
		//	image/tiff
		//	image/png
		//inkWidth Specifies the signature ink width in mm
		//inkColor 
		//inkBackground
		//	Signature ink and background colours in OLE_COLOR format
		//paddingX 
		//paddingY
		//	Padding around the signature image, added to both the left and 
		//	right for paddingX, and both the top and bottom for paddingY. 
		//	Dimensions are specified as mm or Pixels.
		//	Negative value = mm
		//	Positive value = Pixels
		//Flags A combination of RBFlags values.
		//	RenderOutputBase64 0x002000 Return bitmap as a base-64 encoded string
		//	RenderOutputBinary 0x000800 Return bitmap as binary data
		//	RenderOutputFilename 0x001000 Write bitmap to file
		//	RenderOutputPicture 0x200000 Return bitmap as Picture object
		//	RenderBackground Transparent 0x010000 Render image with a transparent background
		//	RenderColor1BPP 0x020000 Render using 1 bit-per-pixel (monochrome)
		//	RenderColor24BPP 0x040000 Render colour image with 24 bits-perpixel
		//	RenderColor32BPP 0x080000 Render colour image with 32 bits-perpixel
		//	RenderColorAntiAlias 0x100000 Render colour image with antialiasing
		//	RenderEncodeData 0x400000 Encode signature data within image
		//	RenderWatermark 0x800000 Encode watermark within image
		//	RenderClipped 0x1000000 Crop signature image, omitting any parts which were outside of the original capture window.
		//	RenderRelative 0x2000000 Renders the signature image relative to the origin of the original capture window
		
		dimensionX = 320;
		dimensionY = 200;
		ТолщинаПераММ = 0.5;
		inkColor = 16711680; //0xff0000
		inkBackground = 16777215; //0xffffff
		paddingX = -1;
		paddingY = -1;
		
		RenderOutputBase64		= 8192;		// 0x002000 Return bitmap as a base-64 encoded string
		RenderColor32BPP		= 524288;	// 0x080000 Render colour image with 32 bits-perpixel
		RenderBackground		= 65536;	// 0x010000 Render image with a transparent background
		RenderColorAntiAlias	= 1048576;	// 0x100000 Render colour image with antialiasing
		RenderEncodeData		= 4194304;	// 0x400000 Encode signature data within image
		Flags = RenderOutputBase64 + RenderColor32BPP + RenderEncodeData; // 0x2000 + 0x80000 + 0x400000; //SigObj.outputBase64 | SigObj.color32BPP | SigObj.encodeData
		//Flags = RenderOutputBase64 + RenderColor32BPP + RenderBackground + RenderColorAntiAlias;
		
		SigObj = SigCtl.Signature;
		СтрокаBase64 = SigObj.RenderBitmap("", dimensionX, dimensionY, "image/png", ТолщинаПераММ , inkColor, inkBackground, paddingX, paddingY, Flags);  
		
		ДвоичныеДанные = Base64Значение(СтрокаBase64);
		
		Объект.Подпись = Новый Картинка(ДвоичныеДанные, Истина);
		//Объект.Подпись.Записать("d:\Sign.png");
		
		АдресКартинки = ПоместитьВоВременноеХранилище(Объект.Подпись);
		
	ИначеЕсли КодВозврата = CaptureCancel Тогда
		
		Сообщить("Клиент отказался от подписи");
		
	ИначеЕсли КодВозврата = CaptureNotLicensed Тогда
		
		Сообщить("Лицензия не обнаружена или просрочена");
		
	ИначеЕсли КодВозврата = CapturePadError Тогда
		
		Сообщить("Служба получения подписи недоступна");
		
	ИначеЕсли КодВозврата = CaptureError Тогда
		
		Сообщить("Ошибка планшета");
		
	ИначеЕсли КодВозврата = CaptureAbort Тогда
		
		Сообщить("Ошибка - невозможно проанализировать содержимое документа");
		
	Иначе
		
		Сообщить("Ошибка получения подписи");
		
	КонецЕсли;
	
КонецПроцедуры